New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/stpctl.F90 @ 9023

Last change on this file since 9023 was 9023, checked in by timgraham, 6 years ago

Merged METO_MERCATOR branch and resolved all conflicts in OPA_SRC

  • Property svn:keywords set to Id
File size: 7.0 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!            3.7  ! 2016-09  (G. Madec)  Remove solver
12   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   stp_ctl      : Control the run
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE c1d             ! 1D vertical configuration
21   !
22   USE in_out_manager  ! I/O manager
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE lib_mpp         ! distributed memory computing
25   USE wet_dry,    ONLY: ll_wd, ssh_ref    ! reference depth for negative bathy
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC stp_ctl           ! routine called by step.F90
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 4.0 , NEMO Consortium (2017)
33   !! $Id$
34   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE stp_ctl( kt, kindic )
39      !!----------------------------------------------------------------------
40      !!                    ***  ROUTINE stp_ctl  ***
41      !!                     
42      !! ** Purpose :   Control the run
43      !!
44      !! ** Method  : - Save the time step in numstp
45      !!              - Print it each 50 time steps
46      !!              - Stop the run IF problem encountered by setting indic=-3
47      !!                Problems checked: |ssh| maximum larger than 10 m
48      !!                                  |U|   maximum larger than 10 m/s
49      !!                                  negative sea surface salinity
50      !!
51      !! ** Actions :   "time.step" file = last ocean time-step
52      !!                "run.stat"  file = run statistics
53      !!----------------------------------------------------------------------
54      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
55      INTEGER, INTENT(inout) ::   kindic   ! error indicator
56      !!
57      INTEGER  ::   ji, jj, jk             ! dummy loop indices
58      INTEGER  ::   iih, ijh               ! local integers
59      INTEGER  ::   iiu, iju, iku          !   -       -
60      INTEGER  ::   iis, ijs, iks          !   -       -
61      REAL(wp) ::   zzz                    ! local real
62      INTEGER , DIMENSION(3) ::   ilocu, ilocs
63      INTEGER , DIMENSION(2) ::   iloch
64      REAL(wp), DIMENSION(3) ::   zmax
65      !!----------------------------------------------------------------------
66      !
67      IF( kt == nit000 .AND. lwp ) THEN
68         WRITE(numout,*)
69         WRITE(numout,*) 'stp_ctl : time-stepping control'
70         WRITE(numout,*) '~~~~~~~'
71         !                                ! open time.step file
72         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
73         !                                ! open run.stat file
74         CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
75      ENDIF
76      !
77      IF(lwp) THEN                        !==  current time step  ==!   ("time.step" file)
78         WRITE ( numstp, '(1x, i8)' )   kt
79         REWIND( numstp )
80      ENDIF
81      !
82      !                                   !==  test of extrema  ==!
83      IF( ll_wd ) THEN
84         zmax(1) = MAXVAL(  ABS( sshn(:,:) + ssh_ref*tmask(:,:,1) )  )           ! ssh max
85      ELSE
86         zmax(1) = MAXVAL(  ABS( sshn(:,:) )  )                                  ! ssh max
87      ENDIF
88      zmax(2) = MAXVAL(  ABS( un(:,:,:) )  )                                  ! velocity max (zonal only)
89      zmax(3) = MAXVAL( -tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )   ! minus salinity max
90      !
91      IF( lk_mpp )   CALL mpp_max_multiple( zmax(:), 3 ) ! max over the global domain
92      !
93      IF( MOD( kt, nwrite ) == 1 .AND. lwp ) THEN
94         WRITE(numout,*) ' ==>> time-step= ', kt, ' |ssh| max: ',   zmax(1), ' |U| max: ', zmax(2),   &
95            &                                     ' S min: '    , - zmax(3)
96      ENDIF
97      !
98      IF (  zmax(1) >  15._wp .OR.   &                     ! too large sea surface height ( > 10 m)
99         &  zmax(2) >  10._wp .OR.   &                     ! too large velocity ( > 10 m/s)
100         &  zmax(3) >=  0._wp .OR.   &                     ! negative or zero sea surface salinity
101         &  ISNAN( zmax(1) + zmax(2) + zmax(3) )  ) THEN   ! NaN encounter in the tests
102         IF( lk_mpp ) THEN
103            CALL mpp_maxloc( ABS(sshn)        , ssmask(:,:)  , zzz, iih, ijh )
104            CALL mpp_maxloc( ABS(un)          , umask (:,:,:), zzz, iiu, iju, iku )
105            CALL mpp_minloc( tsn(:,:,:,jp_sal), tmask (:,:,:), zzz, iis, ijs, iks )
106         ELSE
107            iloch = MINLOC( ABS( sshn(:,:)   )                               )
108            ilocu = MAXLOC( ABS( un  (:,:,:) )                               )
109            ilocs = MINLOC( tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )
110            iih = iloch(1) + nimpp - 1   ;   ijh = iloch(2) + njmpp - 1
111            iiu = ilocu(1) + nimpp - 1   ;   iju = ilocu(2) + njmpp - 1   ;   iku = ilocu(3)
112            iis = ilocs(1) + nimpp - 1   ;   ijs = ilocs(2) + njmpp - 1   ;   iks = ilocu(3)
113         ENDIF
114         IF(lwp) THEN
115            WRITE(numout,cform_err)
116            WRITE(numout,*) ' stpctl: |ssh| > 10 m   or   |U| > 10 m/s   or   S < 0   or   NaN encounter in the tests'
117            WRITE(numout,*) ' ====== '
118            WRITE(numout,9100) kt,   zmax(1), iih, ijh
119            WRITE(numout,9200) kt,   zmax(2), iiu, iju, iku
120            WRITE(numout,9300) kt, - zmax(3), iis, ijs, iks
121            WRITE(numout,*)
122            WRITE(numout,*) '          output of last computed fields in output.abort.nc file'
123         ENDIF
124         kindic = -3
125      ENDIF
1269100  FORMAT (' kt=',i8,'   |ssh| max: ',1pg11.4,', at  i j  : ',2i5)
1279200  FORMAT (' kt=',i8,'   |U|   max: ',1pg11.4,', at  i j k: ',3i5)
1289300  FORMAT (' kt=',i8,'   S     min: ',1pg11.4,', at  i j  : ',2i5)
129      !
130      !                                            !==  run statistics  ==!   ("run.stat" file)
131      IF(lwp) WRITE(numrun,9400) kt, zmax(1), zmax(2), - zmax(3)
132      !
1339400  FORMAT(' it :', i8, '    |ssh|_max: ', e16.10, ' |U|_max: ',e16.10,' S_min: ',e16.10)
134      !
135   END SUBROUTINE stp_ctl
136
137   !!======================================================================
138END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.