New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmicro.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmicro.F90 @ 9125

Last change on this file since 9125 was 9125, checked in by timgraham, 6 years ago

Removed wrk_arrays from whole code. No change in SETTE results from this.

File size: 13.7 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
11   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations
17   USE p4zprod         !  production
18   USE iom             !  I/O manager
19   USE prtctl_trc      !  print control for debugging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_micro         ! called in p4zbio.F90
25   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
26
27   !! * Shared module variables
28   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
29   REAL(wp), PUBLIC ::  xpref2c     !: microzoo preference for POC
30   REAL(wp), PUBLIC ::  xpref2p     !: microzoo preference for nanophyto
31   REAL(wp), PUBLIC ::  xpref2d     !: microzoo preference for diatoms
32   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
33   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
34   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
35   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
37   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
39   REAL(wp), PUBLIC ::  xkgraz      !: non assimilated fraction of P by microzoo
40   REAL(wp), PUBLIC ::  unass       !: Efficicency of microzoo growth
41   REAL(wp), PUBLIC ::  sigma1      !: Fraction of microzoo excretion as DOM
42   REAL(wp), PUBLIC ::  epsher      !: half sturation constant for grazing 1
43
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
46   !! $Id: p4zmicro.F90 3160 2011-11-20 14:27:18Z cetlod $
47   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_micro( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_micro  ***
54      !!
55      !! ** Purpose :   Compute the sources/sinks for microzooplankton
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      INTEGER, INTENT(in) ::  kt  ! ocean time step
60      INTEGER, INTENT(in) ::  knt 
61      !
62      INTEGER  :: ji, jj, jk
63      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
64      REAL(wp) :: zgraze  , zdenom, zdenom2
65      REAL(wp) :: zfact   , zfood, zfoodlim
66      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
67      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
68      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
69      REAL(wp) :: zgrazp, zgrazm, zgrazsd
70      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
71      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing 
72      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zw3d
73      CHARACTER (len=25) :: charout
74      !!---------------------------------------------------------------------
75      !
76      IF( ln_timing )   CALL timing_start('p4z_micro')
77      !
78      DO jk = 1, jpkm1
79         DO jj = 1, jpj
80            DO ji = 1, jpi
81               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
82               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
83
84               !  Respiration rates of both zooplankton
85               !  -------------------------------------
86               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
87                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
88
89               !  Zooplankton mortality. A square function has been selected with
90               !  no real reason except that it seems to be more stable and may mimic predation.
91               !  ---------------------------------------------------------------
92               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
93
94               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
95               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
96               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
97               
98               !     Microzooplankton grazing
99               !     ------------------------
100               zfood     = xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi
101               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
102               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
103               zdenom2   = zdenom / ( zfood + rtrn )
104               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
105
106               zgrazp    = zgraze  * xpref2p * zcompaph  * zdenom2 
107               zgrazm    = zgraze  * xpref2c * zcompapoc * zdenom2 
108               zgrazsd   = zgraze  * xpref2d * zcompadi  * zdenom2 
109
110               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
111               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
112               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
113               !
114               zgraztot  = zgrazp  + zgrazm  + zgrazsd 
115               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
116               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
117
118               ! Grazing by microzooplankton
119               zgrazing(ji,jj,jk) = zgraztot
120
121               !    Various remineralization and excretion terms
122               !    --------------------------------------------
123               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztot + rtrn )
124               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztot + rtrn )
125               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
126               zepsherv  = zepshert * MIN( epsher, (1. - unass) * zgrasrat / ferat3, (1. - unass) * zgrasratn )
127               zgrafer   = zgraztot * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
128               zgrarem   = zgraztot * ( 1. - zepsherv - unass )
129               zgrapoc   = zgraztot * unass
130
131               !  Update of the TRA arrays
132               !  ------------------------
133               zgrarsig  = zgrarem * sigma1
134               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
135               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
136               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
137               !
138               IF( ln_ligand ) tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz
139               !
140               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
141               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
142               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
143               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zgrapoc
144               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
145               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
146               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
147               !   Update the arrays TRA which contain the biological sources and sinks
148               !   --------------------------------------------------------------------
149               zmortz = ztortz + zrespz
150               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztot 
151               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
152               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
153               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
154               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
155               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
156               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
157               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
158               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
159               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
160               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
161               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm
162               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
163               !
164               ! calcite production
165               zprcaca = xfracal(ji,jj,jk) * zgrazp
166               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
167               !
168               zprcaca = part * zprcaca
169               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
170               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
171               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
172            END DO
173         END DO
174      END DO
175      !
176      IF( lk_iomput ) THEN
177         IF( knt == nrdttrc ) THEN
178           ALLOCATE( zw3d(jpi,jpj,jpk) )
179           IF( iom_use( "GRAZ1" ) ) THEN
180              zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
181              CALL iom_put( "GRAZ1", zw3d )
182           ENDIF
183           DEALLOCATE( zw3d )
184         ENDIF
185      ENDIF
186      !
187      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
188         WRITE(charout, FMT="('micro')")
189         CALL prt_ctl_trc_info(charout)
190         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
191      ENDIF
192      !
193      IF( ln_timing )   CALL timing_stop('p4z_micro')
194      !
195   END SUBROUTINE p4z_micro
196
197
198   SUBROUTINE p4z_micro_init
199      !!----------------------------------------------------------------------
200      !!                  ***  ROUTINE p4z_micro_init  ***
201      !!
202      !! ** Purpose :   Initialization of microzooplankton parameters
203      !!
204      !! ** Method  :   Read the nampiszoo namelist and check the parameters
205      !!                called at the first timestep (nittrc000)
206      !!
207      !! ** input   :   Namelist nampiszoo
208      !!
209      !!----------------------------------------------------------------------
210      INTEGER ::   ios   ! Local integer
211      !
212      NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xpref2c, xpref2p, &
213         &                xpref2d,  xthreshdia,  xthreshphy,  xthreshpoc, &
214         &                xthresh, xkgraz, epsher, sigma1, unass
215      !!----------------------------------------------------------------------
216      !
217      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
218      READ  ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901)
219901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zzoo in reference namelist', lwp )
220      !
221      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
222      READ  ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 )
223902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist', lwp )
224      IF(lwm) WRITE ( numonp, namp4zzoo )
225      !
226      IF(lwp) THEN                         ! control print
227         WRITE(numout,*) ' '
228         WRITE(numout,*) ' Namelist parameters for microzooplankton, namp4zzoo'
229         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
230         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
231         WRITE(numout,*) '    microzoo preference for POC                     xpref2c     =', xpref2c
232         WRITE(numout,*) '    microzoo preference for nano                    xpref2p     =', xpref2p
233         WRITE(numout,*) '    microzoo preference for diatoms                 xpref2d     =', xpref2d
234         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
235         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
236         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
237         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
238         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
239         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
240         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
241         WRITE(numout,*) '    non assimilated fraction of P by microzoo       unass       =', unass
242         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
243         WRITE(numout,*) '    Fraction of microzoo excretion as DOM           sigma1      =', sigma1
244         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
245      ENDIF
246      !
247   END SUBROUTINE p4z_micro_init
248
249   !!======================================================================
250END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.