New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zrem.F90 @ 9125

Last change on this file since 9125 was 9125, checked in by timgraham, 6 years ago

Removed wrk_arrays from whole code. No change in SETTE results from this.
File size: 17.7 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
11   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
12   !!   p4z_rem_alloc :  Allocate remineralisation variables
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zche          !  chemical model
18   USE p4zprod         !  Growth rate of the 2 phyto groups
19   USE p4zlim
20   USE prtctl_trc      !  print control for debugging
21   USE iom             !  I/O manager
22
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p4z_rem         ! called in p4zbio.F90
28   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
29   PUBLIC   p4z_rem_alloc
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::  xremikc    !: remineralisation rate of DOC
33   REAL(wp), PUBLIC ::  xremikn    !: remineralisation rate of DON
34   REAL(wp), PUBLIC ::  xremikp    !: remineralisation rate of DOP
35   REAL(wp), PUBLIC ::  xremik     !: remineralisation rate of POC
36   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
37   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of POC
38   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of POC
39   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
40   REAL(wp), PUBLIC ::  feratb     !: Fe/C quota in bacteria
41   REAL(wp), PUBLIC ::  xkferb     !: Half-saturation constant for bacteria Fe/C
42
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr     !: denitrification array
44
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p4z_rem( kt, knt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_rem  ***
55      !!
56      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
61      !
62      INTEGER  ::   ji, jj, jk
63      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
64      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
65      REAL(wp) ::   zbactfer, zolimit, zonitr, zrfact2
66      REAL(wp) ::   zammonic, zoxyrem
67      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
68      CHARACTER (len=25) :: charout
69      REAL(wp), DIMENSION(jpi,jpj    ) :: ztempbac
70      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zdepprod, zfacsi, zfacsib
71      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
72      !!---------------------------------------------------------------------
73      !
74      IF( ln_timing )   CALL timing_start('p4z_rem')
75      !
76      ! Initialisation of arrys
77      zdepprod(:,:,:) = 1._wp
78      ztempbac(:,:)   = 0._wp
79      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
80      zfacsi(:,:,:)   = xsilab
81
82      ! Computation of the mean phytoplankton concentration as
83      ! a crude estimate of the bacterial biomass
84      ! this parameterization has been deduced from a model version
85      ! that was modeling explicitely bacteria
86      ! -------------------------------------------------------
87      DO jk = 1, jpkm1
88         DO jj = 1, jpj
89            DO ji = 1, jpi
90               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
91               IF( gdept_n(ji,jj,jk) < zdep ) THEN
92                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
93                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
94               ELSE
95                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
96                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
97                  zdepprod(ji,jj,jk) = zdepmin**0.273
98               ENDIF
99            END DO
100         END DO
101      END DO
102
103      IF( ln_p4z ) THEN
104         DO jk = 1, jpkm1
105            DO jj = 1, jpj
106               DO ji = 1, jpi
107                  ! DOC ammonification. Depends on depth, phytoplankton biomass
108                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
109                  zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
110                  zremik = MAX( zremik, 2.74e-4 * xstep )
111                  ! Ammonification in oxic waters with oxygen consumption
112                  ! -----------------------------------------------------
113                  zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
114                  zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
115                  ! Ammonification in suboxic waters with denitrification
116                  ! -------------------------------------------------------
117                  zammonic = zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
118                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
119                  zoxyrem           = zammonic *        nitrfac2(ji,jj,jk)
120                  !
121                  zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
122                  denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
123                  zoxyrem           = MAX( 0.e0, zoxyrem  )
124
125                  !
126                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyrem
127                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyrem
128                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
129                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk) - zoxyrem
130                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
131                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyrem
132                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk) + zoxyrem    &
133                  &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
134               END DO
135            END DO
136         END DO
137      ELSE
138         DO jk = 1, jpkm1
139            DO jj = 1, jpj
140               DO ji = 1, jpi
141                  ! DOC ammonification. Depends on depth, phytoplankton biomass
142                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
143                  ! -----------------------------------------------------------------
144                  zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
145                  zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
146
147                  zremikc = xremikc * zremik
148                  zremikn = xremikn / xremikc
149                  zremikp = xremikp / xremikc
150
151                  ! Ammonification in oxic waters with oxygen consumption
152                  ! -----------------------------------------------------
153                  zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
154                  zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
155                  zolimi(ji,jj,jk) = zolimic
156                  zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
157                  zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
158
159                  ! Ammonification in suboxic waters with denitrification
160                  ! -------------------------------------------------------
161                  zolimit = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
162                  denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
163                  denitr(ji,jj,jk) = MAX( 0.e0, denitr(ji,jj,jk) )
164                  zdenitrn  = zremikn * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
165                  zdenitrp  = zremikp * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
166
167                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
168                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
169                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr(ji,jj,jk) * rdenit
170                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitr(ji,jj,jk)
171                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
172                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
173                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
174                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitr(ji,jj,jk)
175                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
176               END DO
177            END DO
178         END DO
179         !
180      ENDIF
181
182
183      DO jk = 1, jpkm1
184         DO jj = 1, jpj
185            DO ji = 1, jpi
186               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
187               ! below 2 umol/L. Inhibited at strong light
188               ! ----------------------------------------------------------
189               zonitr  = nitrif * xstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
190               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
191               zdenitnh4 = nitrif * xstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk)
192               ! Update of the tracers trends
193               ! ----------------------------
194               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
195               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
196               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
197               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
198            END DO
199         END DO
200      END DO
201
202       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
203         WRITE(charout, FMT="('rem1')")
204         CALL prt_ctl_trc_info(charout)
205         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
206       ENDIF
207
208      DO jk = 1, jpkm1
209         DO jj = 1, jpj
210            DO ji = 1, jpi
211
212               ! Bacterial uptake of iron. No iron is available in DOC. So
213               ! Bacteries are obliged to take up iron from the water. Some
214               ! studies (especially at Papa) have shown this uptake to be significant
215               ! ----------------------------------------------------------
216               zbactfer = feratb *  rfact2 * prmax(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
217                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
218                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
219               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
220               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
221               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
222            END DO
223         END DO
224      END DO
225
226       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
227         WRITE(charout, FMT="('rem2')")
228         CALL prt_ctl_trc_info(charout)
229         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
230       ENDIF
231
232      ! Initialization of the array which contains the labile fraction
233      ! of bSi. Set to a constant in the upper ocean
234      ! ---------------------------------------------------------------
235
236      DO jk = 1, jpkm1
237         DO jj = 1, jpj
238            DO ji = 1, jpi
239               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
240               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
241               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
242               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
243               ! Remineralization rate of BSi depedant on T and saturation
244               ! ---------------------------------------------------------
245               IF ( gdept_n(ji,jj,jk) > zdep ) THEN
246                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
247                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
248                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
249                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
250                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
251               ENDIF
252               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
253               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
254               !
255               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
256               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
257               !
258            END DO
259         END DO
260      END DO
261
262      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
263         WRITE(charout, FMT="('rem3')")
264         CALL prt_ctl_trc_info(charout)
265         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
266       ENDIF
267
268      IF( knt == nrdttrc ) THEN
269          ALLOCATE( zw3d(jpi,jpj,jpk) )
270          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
271          !
272          IF( iom_use( "REMIN" ) )  THEN
273              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
274              CALL iom_put( "REMIN"  , zw3d )
275          ENDIF
276          IF( iom_use( "DENIT" ) )  THEN
277              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
278              CALL iom_put( "DENIT"  , zw3d )
279          ENDIF
280          !
281          DEALLOCATE( zw3d )
282       ENDIF
283      !
284      IF( ln_timing )   CALL timing_stop('p4z_rem')
285      !
286   END SUBROUTINE p4z_rem
287
288
289   SUBROUTINE p4z_rem_init
290      !!----------------------------------------------------------------------
291      !!                  ***  ROUTINE p4z_rem_init  ***
292      !!
293      !! ** Purpose :   Initialization of remineralization parameters
294      !!
295      !! ** Method  :   Read the nampisrem namelist and check the parameters
296      !!      called at the first timestep
297      !!
298      !! ** input   :   Namelist nampisrem
299      !!
300      !!----------------------------------------------------------------------
301      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
302         &                xremikc, xremikn, xremikp
303      INTEGER :: ios                 ! Local integer output status for namelist read
304      !!----------------------------------------------------------------------
305
306      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
307      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
308901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
309
310      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
311      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
312902   IF( ios >  0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
313      IF(lwm) WRITE ( numonp, nampisrem )
314
315      IF(lwp) THEN                         ! control print
316         WRITE(numout,*) ' '
317         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
318         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
319         IF( ln_p4z ) THEN
320            WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
321         ELSE
322            WRITE(numout,*) '    remineralization rate of DOC              xremikc   =', xremikc
323            WRITE(numout,*) '    remineralization rate of DON              xremikn   =', xremikn
324            WRITE(numout,*) '    remineralization rate of DOP              xremikp   =', xremikp
325         ENDIF
326         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
327         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
328         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
329         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
330         WRITE(numout,*) '    Bacterial Fe/C ratio                      feratb    =', feratb
331         WRITE(numout,*) '    Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
332      ENDIF
333      !
334      denitr  (:,:,:) = 0._wp
335      !
336   END SUBROUTINE p4z_rem_init
337
338
339   INTEGER FUNCTION p4z_rem_alloc()
340      !!----------------------------------------------------------------------
341      !!                     ***  ROUTINE p4z_rem_alloc  ***
342      !!----------------------------------------------------------------------
343      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
344      !
345      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
346      !
347   END FUNCTION p4z_rem_alloc
348
349   !!======================================================================
350END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.