New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 9570

Last change on this file since 9570 was 9570, checked in by nicolasmartin, 6 years ago

Global renaming for core routines (./NEMO)

  • Folders
    • LIM_SRC_3 -> ICE_SRC
    • OPA_SRC -> OCE_SRC
  • CPP key: key_lim3 -> key_si3
  • Modules, (sub)routines and variables names
    • MPI: mpi_comm_opa -> mpi_comm_oce, MPI_COMM_OPA -> MPI_COMM_OCE, mpi_init_opa -> mpi_init_oce
    • AGRIF: agrif_opa_* -> agrif_oce_*, agrif_lim3_* -> agrif_si3_* and few more
    • TOP-PISCES: p.zlim -> p.zice, namp.zlim -> namp.zice
  • Comments
    • NEMO/OPA -> NEMO/OCE
    • ESIM|LIM3 -> SI3
  • Property svn:keywords set to Id
File size: 26.2 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11   !!   p4z_sed        :  Compute loss of organic matter in the sediments
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zice          !  Co-limitations of differents nutrients
17   USE p4zsbc          !  External source of nutrients
18   USE p4zint          !  interpolation and computation of various fields
19   USE iom             !  I/O manager
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sed 
26   PUBLIC   p4z_sed_alloc
27 
28   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
30   REAL(wp) :: r1_rday                  !: inverse of rday
31
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE p4z_sed( kt, knt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE p4z_sed  ***
42      !!
43      !! ** Purpose :   Compute loss of organic matter in the sediments. This
44      !!              is by no way a sediment model. The loss is simply
45      !!              computed to balance the inout from rivers and dust
46      !!
47      !! ** Method  : - ???
48      !!---------------------------------------------------------------------
49      !
50      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
51      INTEGER  ::   ji, jj, jk, ikt
52      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
53      REAL(wp) ::   zrivalk, zrivsil, zrivno3
54      REAL(wp) ::  zwflux, zfminus, zfplus
55      REAL(wp) ::  zlim, zfact, zfactcal
56      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zolimit
57      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
58      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
59      REAL(wp) ::  ztrfer, ztrpo4s, ztrdp, zwdust, zmudia, ztemp
60      REAL(wp) ::  xdiano3, xdianh4
61      REAL(wp) ::  zwssfep
62      !
63      CHARACTER (len=25) :: charout
64      REAL(wp), DIMENSION(jpi,jpj    ) :: zwork1, zwork2, zwork3
65      REAL(wp), DIMENSION(jpi,jpj    ) :: zdenit2d, zbureff
66      REAL(wp), DIMENSION(jpi,jpj    ) :: zwsbio3, zwsbio4, zwscal
67      REAL(wp), DIMENSION(jpi,jpj    ) :: zsedcal, zsedsi, zsedc
68      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zsoufer, zlight
69      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrpo4, ztrdop, zirondep, zpdep
70      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zsidep, zwsfep, zironice
71      !!---------------------------------------------------------------------
72      !
73      IF( ln_timing )  CALL timing_start('p4z_sed')
74      !
75      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
76      !
77      ! Allocate temporary workspace
78      IF( ln_p5z )    ALLOCATE( ztrpo4(jpi,jpj,jpk), ztrdop(jpi,jpj,jpk) )
79      IF( ln_ligand ) ALLOCATE( zwsfep(jpi,jpj) )
80
81
82      zdenit2d(:,:) = 0.e0
83      zbureff (:,:) = 0.e0
84      zwork1  (:,:) = 0.e0
85      zwork2  (:,:) = 0.e0
86      zwork3  (:,:) = 0.e0
87      zsedsi  (:,:) = 0.e0
88      zsedcal (:,:) = 0.e0
89      zsedc   (:,:) = 0.e0
90
91
92      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
93      ! ----------------------------------------------------
94      IF( ln_ironice ) THEN 
95         !                                             
96         ALLOCATE( zironice(jpi,jpj) )
97         !                                             
98         DO jj = 1, jpj
99            DO ji = 1, jpi
100               zdep    = rfact2 / e3t_n(ji,jj,1)
101               zwflux  = fmmflx(ji,jj) / 1000._wp
102               zfminus = MIN( 0._wp, -zwflux ) * trb(ji,jj,1,jpfer) * zdep
103               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
104               zironice(ji,jj) =  zfplus + zfminus
105            END DO
106         END DO
107         !
108         tra(:,:,1,jpfer) = tra(:,:,1,jpfer) + zironice(:,:) 
109         !
110         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) )   &
111            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
112         !
113         DEALLOCATE( zironice )
114         !                                             
115      ENDIF
116
117      ! Add the external input of nutrients from dust deposition
118      ! ----------------------------------------------------------
119      IF( ln_dust ) THEN
120         !                                             
121         ALLOCATE( zsidep(jpi,jpj), zpdep(jpi,jpj,jpk), zirondep(jpi,jpj,jpk) )
122         !                                              ! Iron and Si deposition at the surface
123         IF( ln_solub ) THEN
124            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
125         ELSE
126            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
127         ENDIF
128         zsidep(:,:)   = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 28.1 
129         zpdep (:,:,1) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 31. / po4r 
130         !                                              ! Iron solubilization of particles in the water column
131         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
132         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
133         DO jk = 2, jpkm1
134            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -gdept_n(:,:,jk) / 540. )
135            zpdep   (:,:,jk) = zirondep(:,:,jk) * 0.023
136         END DO
137         !                                              ! Iron solubilization of particles in the water column
138         tra(:,:,1,jpsil) = tra(:,:,1,jpsil) + zsidep  (:,:)
139         DO jk = 1, jpkm1
140            tra(:,:,jk,jppo4) = tra(:,:,jk,jppo4) + zpdep   (:,:,jk)
141            tra(:,:,jk,jpfer) = tra(:,:,jk,jpfer) + zirondep(:,:,jk) 
142         ENDDO
143         !
144         IF( lk_iomput ) THEN
145            IF( knt == nrdttrc ) THEN
146                IF( iom_use( "Irondep" ) )   &
147                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
148                IF( iom_use( "pdust" ) )   &
149                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
150            ENDIF
151         ENDIF
152         DEALLOCATE( zsidep, zpdep, zirondep )
153         !                                             
154      ENDIF
155     
156      ! Add the external input of nutrients from river
157      ! ----------------------------------------------------------
158      IF( ln_river ) THEN
159         DO jj = 1, jpj
160            DO ji = 1, jpi
161               DO jk = 1, nk_rnf(ji,jj)
162                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) +  rivdip(ji,jj) * rfact2
163                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) +  rivdin(ji,jj) * rfact2
164                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) +  rivdic(ji,jj) * 5.e-5 * rfact2
165                  tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) +  rivdsi(ji,jj) * rfact2
166                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +  rivdic(ji,jj) * rfact2
167                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
168               ENDDO
169            ENDDO
170         ENDDO
171         IF( ln_p5z ) THEN
172            DO jj = 1, jpj
173               DO ji = 1, jpi
174                  DO jk = 1, nk_rnf(ji,jj)
175                     tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + rivdop(ji,jj) * rfact2
176                     tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + rivdon(ji,jj) * rfact2
177                     tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + rivdoc(ji,jj) * rfact2
178                  ENDDO
179               ENDDO
180            ENDDO
181         ENDIF
182      ENDIF
183     
184      ! Add the external input of nutrients from nitrogen deposition
185      ! ----------------------------------------------------------
186      IF( ln_ndepo ) THEN
187         tra(:,:,1,jpno3) = tra(:,:,1,jpno3) + nitdep(:,:) * rfact2
188         tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
189      ENDIF
190
191      ! Add the external input of iron from sediment mobilization
192      ! ------------------------------------------------------
193      IF( ln_ironsed ) THEN
194                         tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
195         IF( ln_ligand ) tra(:,:,:,jpfep) = tra(:,:,:,jpfep) + ( ironsed(:,:,:) * fep_rats ) * rfact2
196         !
197         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
198            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
199      ENDIF
200
201      ! Add the external input of iron from hydrothermal vents
202      ! ------------------------------------------------------
203      IF( ln_hydrofe ) THEN
204            tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
205         IF( ln_ligand ) THEN
206            tra(:,:,:,jpfep) = tra(:,:,:,jpfep) + ( hydrofe(:,:,:) * fep_rath ) * rfact2
207            tra(:,:,:,jplgw) = tra(:,:,:,jplgw) + ( hydrofe(:,:,:) * lgw_rath ) * rfact2
208         ENDIF
209         !
210         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) )   &
211            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
212      ENDIF
213
214      ! OA: Warning, the following part is necessary to avoid CFL problems above the sediments
215      ! --------------------------------------------------------------------
216      DO jj = 1, jpj
217         DO ji = 1, jpi
218            ikt  = mbkt(ji,jj)
219            zdep = e3t_n(ji,jj,ikt) / xstep
220            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
221            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
222            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
223         END DO
224      END DO
225      !
226      IF( ln_ligand ) THEN
227         DO jj = 1, jpj
228            DO ji = 1, jpi
229               ikt  = mbkt(ji,jj)
230               zdep = e3t_n(ji,jj,ikt) / xstep
231               zwsfep(ji,jj)  = MIN( 0.99 * zdep, wsfep(ji,jj,ikt)  )
232            END DO
233         ENDDO
234      ENDIF
235
236      IF( .NOT.lk_sed ) THEN
237         ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
238         ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
239         ! -------------------------------------------------------
240         DO jj = 1, jpj
241            DO ji = 1, jpi
242              IF( tmask(ji,jj,1) == 1 ) THEN
243                 ikt = mbkt(ji,jj)
244                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
245                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
246                 zflx  = LOG10( MAX( 1E-3, zflx ) )
247                 zo2   = LOG10( MAX( 10. , trb(ji,jj,ikt,jpoxy) * 1E6 ) )
248                 zno3  = LOG10( MAX( 1.  , trb(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
249                 zdep  = LOG10( gdepw_n(ji,jj,ikt+1) )
250                 zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
251                   &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
252                 zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
253                   !
254                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
255                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
256                 zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
257                ENDIF
258              END DO
259           END DO 
260
261           ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
262           ! First, the total loss is computed.
263           ! The factor for calcite comes from the alkalinity effect
264           ! -------------------------------------------------------------
265           DO jj = 1, jpj
266              DO ji = 1, jpi
267                 IF( tmask(ji,jj,1) == 1 ) THEN
268                    ikt = mbkt(ji,jj) 
269                    zwork1(ji,jj) = trb(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
270                    zwork2(ji,jj) = trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
271                    ! For calcite, burial efficiency is made a function of saturation
272                    zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
273                    zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
274                    zwork3(ji,jj) = trb(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
275                ENDIF
276            END DO
277         END DO
278         zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
279         zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
280         zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
281         !
282      ENDIF
283
284      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
285      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
286      ! ------------------------------------------------------
287      IF( .NOT.lk_sed )  zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn )
288
289      DO jj = 1, jpj
290         DO ji = 1, jpi
291            ikt  = mbkt(ji,jj)
292            zdep = xstep / e3t_n(ji,jj,ikt) 
293            zwsc = zwscal (ji,jj) * zdep
294            zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
295            zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
296            !
297            tra(ji,jj,ikt,jpgsi) = tra(ji,jj,ikt,jpgsi) - zsiloss
298            tra(ji,jj,ikt,jpcal) = tra(ji,jj,ikt,jpcal) - zcaloss
299         END DO
300      END DO
301      !
302      IF( .NOT.lk_sed ) THEN
303         DO jj = 1, jpj
304            DO ji = 1, jpi
305               ikt  = mbkt(ji,jj)
306               zdep = xstep / e3t_n(ji,jj,ikt) 
307               zwsc = zwscal (ji,jj) * zdep
308               zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
309               zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
310               tra(ji,jj,ikt,jpsil) = tra(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
311               !
312               zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
313               zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
314               zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
315               tra(ji,jj,ikt,jptal) =  tra(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
316               tra(ji,jj,ikt,jpdic) =  tra(ji,jj,ikt,jpdic) + zcaloss * zrivalk
317               zsedcal(ji,jj) = (1.0 - zrivalk) * zcaloss * e3t_n(ji,jj,ikt) 
318               zsedsi (ji,jj) = (1.0 - zrivsil) * zsiloss * e3t_n(ji,jj,ikt) 
319            END DO
320         END DO
321      ENDIF
322      !
323      DO jj = 1, jpj
324         DO ji = 1, jpi
325            ikt  = mbkt(ji,jj)
326            zdep = xstep / e3t_n(ji,jj,ikt) 
327            zws4 = zwsbio4(ji,jj) * zdep
328            zws3 = zwsbio3(ji,jj) * zdep
329            tra(ji,jj,ikt,jpgoc) = tra(ji,jj,ikt,jpgoc) - trb(ji,jj,ikt,jpgoc) * zws4 
330            tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
331            tra(ji,jj,ikt,jpbfe) = tra(ji,jj,ikt,jpbfe) - trb(ji,jj,ikt,jpbfe) * zws4
332            tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
333         END DO
334      END DO
335      !
336      IF( ln_ligand ) THEN
337         DO jj = 1, jpj
338            DO ji = 1, jpi
339               ikt     = mbkt(ji,jj)
340               zdep    = xstep / e3t_n(ji,jj,ikt) 
341               zwssfep = zwsfep(ji,jj) * zdep
342               tra(ji,jj,ikt,jpfep) = tra(ji,jj,ikt,jpfep) - trb(ji,jj,ikt,jpfep) * zwssfep
343            END DO
344         END DO
345      ENDIF
346      !
347      IF( ln_p5z ) THEN
348         DO jj = 1, jpj
349            DO ji = 1, jpi
350               ikt  = mbkt(ji,jj)
351               zdep = xstep / e3t_n(ji,jj,ikt) 
352               zws4 = zwsbio4(ji,jj) * zdep
353               zws3 = zwsbio3(ji,jj) * zdep
354               tra(ji,jj,ikt,jpgon) = tra(ji,jj,ikt,jpgon) - trb(ji,jj,ikt,jpgon) * zws4
355               tra(ji,jj,ikt,jppon) = tra(ji,jj,ikt,jppon) - trb(ji,jj,ikt,jppon) * zws3
356               tra(ji,jj,ikt,jpgop) = tra(ji,jj,ikt,jpgop) - trb(ji,jj,ikt,jpgop) * zws4
357               tra(ji,jj,ikt,jppop) = tra(ji,jj,ikt,jppop) - trb(ji,jj,ikt,jppop) * zws3
358            END DO
359         END DO
360      ENDIF
361
362      IF( .NOT.lk_sed ) THEN
363         ! The 0.5 factor in zpdenit is to avoid negative NO3 concentration after
364         ! denitrification in the sediments. Not very clever, but simpliest option.
365         DO jj = 1, jpj
366            DO ji = 1, jpi
367               ikt  = mbkt(ji,jj)
368               zdep = xstep / e3t_n(ji,jj,ikt) 
369               zws4 = zwsbio4(ji,jj) * zdep
370               zws3 = zwsbio3(ji,jj) * zdep
371               zrivno3 = 1. - zbureff(ji,jj)
372               zwstpoc = trb(ji,jj,ikt,jpgoc) * zws4 + trb(ji,jj,ikt,jppoc) * zws3
373               zpdenit  = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
374               z1pdenit = zwstpoc * zrivno3 - zpdenit
375               zolimit = MIN( ( trb(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
376               tra(ji,jj,ikt,jpdoc) = tra(ji,jj,ikt,jpdoc) + z1pdenit - zolimit
377               tra(ji,jj,ikt,jppo4) = tra(ji,jj,ikt,jppo4) + zpdenit + zolimit
378               tra(ji,jj,ikt,jpnh4) = tra(ji,jj,ikt,jpnh4) + zpdenit + zolimit
379               tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) - rdenit * zpdenit
380               tra(ji,jj,ikt,jpoxy) = tra(ji,jj,ikt,jpoxy) - zolimit * o2ut
381               tra(ji,jj,ikt,jptal) = tra(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * zpdenit )
382               tra(ji,jj,ikt,jpdic) = tra(ji,jj,ikt,jpdic) + zpdenit + zolimit 
383               sdenit(ji,jj) = rdenit * zpdenit * e3t_n(ji,jj,ikt)
384               zsedc(ji,jj)   = (1. - zrivno3) * zwstpoc * e3t_n(ji,jj,ikt)
385               IF( ln_p5z ) THEN
386                  zwstpop              = trb(ji,jj,ikt,jpgop) * zws4 + trb(ji,jj,ikt,jppop) * zws3
387                  zwstpon              = trb(ji,jj,ikt,jpgon) * zws4 + trb(ji,jj,ikt,jppon) * zws3
388                  tra(ji,jj,ikt,jpdon) = tra(ji,jj,ikt,jpdon) + ( z1pdenit - zolimit ) * zwstpon / (zwstpoc + rtrn)
389                  tra(ji,jj,ikt,jpdop) = tra(ji,jj,ikt,jpdop) + ( z1pdenit - zolimit ) * zwstpop / (zwstpoc + rtrn)
390               ENDIF
391            END DO
392         END DO
393       ENDIF
394
395
396      ! Nitrogen fixation process
397      ! Small source iron from particulate inorganic iron
398      !-----------------------------------
399      DO jk = 1, jpkm1
400         zlight (:,:,jk) =  ( 1.- EXP( -etot_ndcy(:,:,jk) / diazolight ) ) * ( 1. - fr_i(:,:) ) 
401         zsoufer(:,:,jk) = zlight(:,:,jk) * 2E-11 / ( 2E-11 + biron(:,:,jk) )
402      ENDDO
403      IF( ln_p4z ) THEN
404         DO jk = 1, jpkm1
405            DO jj = 1, jpj
406               DO ji = 1, jpi
407                  !                      ! Potential nitrogen fixation dependant on temperature and iron
408                  zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
409                  IF( zlim <= 0.2 )   zlim = 0.01
410                  zfact = zlim * rfact2
411
412                  ztrfer  = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
413                  ztrpo4s = trb  (ji,jj,jk,jppo4) / ( concnnh4   + trb  (ji,jj,jk,jppo4) ) 
414                  nitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday ) &
415                    &                *  zfact * MIN( ztrfer, ztrpo4s ) * zlight(ji,jj,jk)
416               END DO
417            END DO
418         END DO
419      ELSE       ! p5z
420         DO jk = 1, jpkm1
421            DO jj = 1, jpj
422               DO ji = 1, jpi
423                  !                      ! Potential nitrogen fixation dependant on temperature and iron
424                  ztemp = tsn(ji,jj,jk,jp_tem)
425                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
426                  !       Potential nitrogen fixation dependant on temperature and iron
427                  xdianh4 = trb(ji,jj,jk,jpnh4) / ( concnnh4 + trb(ji,jj,jk,jpnh4) )
428                  xdiano3 = trb(ji,jj,jk,jpno3) / ( concnno3 + trb(ji,jj,jk,jpno3) ) * (1. - xdianh4)
429                  zlim = ( 1.- xdiano3 - xdianh4 )
430                  IF( zlim <= 0.1 )   zlim = 0.01
431                  zfact = zlim * rfact2
432                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
433                  ztrpo4(ji,jj,jk) = trb(ji,jj,jk,jppo4) / ( 1E-6 + trb(ji,jj,jk,jppo4) )
434                  ztrdop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( 1E-6 + trb(ji,jj,jk,jpdop) ) * (1. - ztrpo4(ji,jj,jk))
435                  ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
436                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
437               END DO
438            END DO
439         END DO
440      ENDIF
441
442      ! Nitrogen change due to nitrogen fixation
443      ! ----------------------------------------
444      IF( ln_p4z ) THEN
445         DO jk = 1, jpkm1
446            DO jj = 1, jpj
447               DO ji = 1, jpi
448                  zfact = nitrpot(ji,jj,jk) * nitrfix
449                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) +             zfact
450                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3      * zfact
451                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2nit     * zfact 
452                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trb(ji,jj,jk,jppo4) ) &
453                  &                     * 0.002 * trb(ji,jj,jk,jpdoc) * xstep
454                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * xstep
455              END DO
456            END DO
457         END DO
458      ELSE    ! p5z
459         DO jk = 1, jpkm1
460            DO jj = 1, jpj
461               DO ji = 1, jpi
462                  zfact = nitrpot(ji,jj,jk) * nitrfix
463                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zfact / 3.0
464                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zfact / 3.0
465                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
466                  &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
467                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zfact * 1.0 / 3.0
468                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zfact * 1.0 / 3.0
469                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + 16.0 / 46.0 * zfact / 3.0  &
470                  &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
471                  &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
472                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zfact * 1.0 / 3.0 * 2.0 / 3.0
473                  tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zfact * 1.0 / 3.0 * 2.0 /3.0
474                  tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
475                  tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfact * 1.0 / 3.0 * 1.0 / 3.0
476                  tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) + zfact * 1.0 / 3.0 * 1.0 /3.0
477                  tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
478                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
479                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - 30E-6 * zfact * 1.0 / 3.0 
480                  tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
481                  tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
482                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
483              END DO
484            END DO
485         END DO
486         !
487      ENDIF
488
489      IF( lk_iomput ) THEN
490         IF( knt == nrdttrc ) THEN
491            zfact = 1.e+3 * rfact2r !  conversion from molC/l/kt  to molN/m3/s
492            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
493            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
494               zwork1(:,:) = 0.
495               DO jk = 1, jpkm1
496                 zwork1(:,:) = zwork1(:,:) + nitrpot(:,:,jk) * nitrfix * rno3 * zfact * e3t_n(:,:,jk) * tmask(:,:,jk)
497               ENDDO
498               CALL iom_put( "INTNFIX" , zwork1 ) 
499            ENDIF
500            IF( iom_use("SedCal" ) ) CALL iom_put( "SedCal", zsedcal(:,:) * zfact )
501            IF( iom_use("SedSi" ) )  CALL iom_put( "SedSi",  zsedsi (:,:) * zfact )
502            IF( iom_use("SedC" ) )   CALL iom_put( "SedC",   zsedc  (:,:) * zfact )
503            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", sdenit (:,:) * zfact * rno3 )
504         ENDIF
505      ENDIF
506      !
507      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
508         WRITE(charout, fmt="('sed ')")
509         CALL prt_ctl_trc_info(charout)
510         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
511      ENDIF
512      !
513      IF( ln_p5z )    DEALLOCATE( ztrpo4, ztrdop )
514      IF( ln_ligand ) DEALLOCATE( zwsfep )
515      !
516      IF( ln_timing )  CALL timing_stop('p4z_sed')
517      !
518   END SUBROUTINE p4z_sed
519
520
521   INTEGER FUNCTION p4z_sed_alloc()
522      !!----------------------------------------------------------------------
523      !!                     ***  ROUTINE p4z_sed_alloc  ***
524      !!----------------------------------------------------------------------
525      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
526      !
527      IF( p4z_sed_alloc /= 0 )   CALL ctl_warn('p4z_sed_alloc: failed to allocate arrays')
528      !
529   END FUNCTION p4z_sed_alloc
530
531   !!======================================================================
532END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.