New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsink.F90 @ 9124

Last change on this file since 9124 was 9124, checked in by gm, 6 years ago

dev_merge_2017: ln_timing instead of nn_timing + restricted timing to nemo_init and routine called by step in OPA_SRC

File size: 17.2 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!             3.5  !  2012-07  (O. Aumont) Introduce potential time-splitting
10   !!----------------------------------------------------------------------
11   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
12   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
13   !!   p4z_sink_alloc :  Allocate sinking speed variables
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE prtctl_trc      !  print control for debugging
19   USE iom             !  I/O manager
20   USE lib_mpp
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sink         ! called in p4zbio.F90
26   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
27   PUBLIC   p4z_sink_alloc
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
30   !                                                          !  (different meanings depending on the parameterization)
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingn, sinking2n  !: POC sinking fluxes
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingp, sinking2p  !: POC sinking fluxes
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfep      !: Fep sinking fluxes
37
38   INTEGER  :: ik100
39
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
42   !! $Id: p4zsink.F90 3160 2011-11-20 14:27:18Z cetlod $
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   !!----------------------------------------------------------------------
48   !!   'standard sinking parameterisation'                  ???
49   !!----------------------------------------------------------------------
50
51   SUBROUTINE p4z_sink ( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_sink  ***
54      !!
55      !! ** Purpose :   Compute vertical flux of particulate matter due to
56      !!                gravitational sinking
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      INTEGER, INTENT(in) :: kt, knt
61      INTEGER  ::   ji, jj, jk, jit
62      INTEGER  ::   iiter1, iiter2
63      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
64      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2, zaggdoc3
65      REAL(wp) ::   zfact, zwsmax, zmax
66      CHARACTER (len=25) :: charout
67      REAL(wp), POINTER, DIMENSION(:,:,:) :: zw3d
68      REAL(wp), POINTER, DIMENSION(:,:  ) :: zw2d
69      !!---------------------------------------------------------------------
70      !
71      IF( ln_timing )   CALL timing_start('p4z_sink')
72
73
74      ! Initialization of some global variables
75      ! ---------------------------------------
76      prodpoc(:,:,:) = 0.
77      conspoc(:,:,:) = 0.
78      prodgoc(:,:,:) = 0.
79      consgoc(:,:,:) = 0.
80
81      !
82      !    Sinking speeds of detritus is increased with depth as shown
83      !    by data and from the coagulation theory
84      !    -----------------------------------------------------------
85      DO jk = 1, jpkm1
86         DO jj = 1, jpj
87            DO ji = 1,jpi
88               zmax  = MAX( heup_01(ji,jj), hmld(ji,jj) )
89               zfact = MAX( 0., gdepw_n(ji,jj,jk+1) - zmax ) / wsbio2scale
90               wsbio4(ji,jj,jk) = wsbio2 + MAX(0., ( wsbio2max - wsbio2 )) * zfact
91            END DO
92         END DO
93      END DO
94
95      ! limit the values of the sinking speeds to avoid numerical instabilities 
96      wsbio3(:,:,:) = wsbio
97
98      !
99      ! OA This is (I hope) a temporary solution for the problem that may
100      ! OA arise in specific situation where the CFL criterion is broken
101      ! OA for vertical sedimentation of particles. To avoid this, a time
102      ! OA splitting algorithm has been coded. A specific maximum
103      ! OA iteration number is provided and may be specified in the namelist
104      ! OA This is to avoid very large iteration number when explicit free
105      ! OA surface is used (for instance). When niter?max is set to 1,
106      ! OA this computation is skipped. The crude old threshold method is
107      ! OA then applied. This also happens when niter exceeds nitermax.
108      IF( MAX( niter1max, niter2max ) == 1 ) THEN
109        iiter1 = 1
110        iiter2 = 1
111      ELSE
112        iiter1 = 1
113        iiter2 = 1
114        DO jk = 1, jpkm1
115          DO jj = 1, jpj
116             DO ji = 1, jpi
117                IF( tmask(ji,jj,jk) == 1) THEN
118                   zwsmax =  0.5 * e3t_n(ji,jj,jk) / xstep
119                   iiter1 =  MAX( iiter1, INT( wsbio3(ji,jj,jk) / zwsmax ) )
120                   iiter2 =  MAX( iiter2, INT( wsbio4(ji,jj,jk) / zwsmax ) )
121                ENDIF
122             END DO
123          END DO
124        END DO
125        IF( lk_mpp ) THEN
126           CALL mpp_max( iiter1 )
127           CALL mpp_max( iiter2 )
128        ENDIF
129        iiter1 = MIN( iiter1, niter1max )
130        iiter2 = MIN( iiter2, niter2max )
131      ENDIF
132
133      DO jk = 1,jpkm1
134         DO jj = 1, jpj
135            DO ji = 1, jpi
136               IF( tmask(ji,jj,jk) == 1 ) THEN
137                 zwsmax = 0.5 * e3t_n(ji,jj,jk) / xstep
138                 wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax * REAL( iiter1, wp ) )
139                 wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax * REAL( iiter2, wp ) )
140               ENDIF
141            END DO
142         END DO
143      END DO
144
145      wscal (:,:,:) = wsbio4(:,:,:)
146
147      !  Initializa to zero all the sinking arrays
148      !   -----------------------------------------
149      sinking (:,:,:) = 0.e0
150      sinking2(:,:,:) = 0.e0
151      sinkcal (:,:,:) = 0.e0
152      sinkfer (:,:,:) = 0.e0
153      sinksil (:,:,:) = 0.e0
154      sinkfer2(:,:,:) = 0.e0
155
156      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
157      !   -----------------------------------------------------
158      DO jit = 1, iiter1
159        CALL p4z_sink2( wsbio3, sinking , jppoc, iiter1 )
160        CALL p4z_sink2( wsbio3, sinkfer , jpsfe, iiter1 )
161      END DO
162
163      DO jit = 1, iiter2
164        CALL p4z_sink2( wsbio4, sinking2, jpgoc, iiter2 )
165        CALL p4z_sink2( wsbio4, sinkfer2, jpbfe, iiter2 )
166        CALL p4z_sink2( wsbio4, sinksil , jpgsi, iiter2 )
167        CALL p4z_sink2( wscal , sinkcal , jpcal, iiter2 )
168      END DO
169
170      IF( ln_p5z ) THEN
171         sinkingn (:,:,:) = 0.e0
172         sinking2n(:,:,:) = 0.e0
173         sinkingp (:,:,:) = 0.e0
174         sinking2p(:,:,:) = 0.e0
175
176         !   Compute the sedimentation term using p4zsink2 for all the sinking particles
177         !   -----------------------------------------------------
178         DO jit = 1, iiter1
179           CALL p4z_sink2( wsbio3, sinkingn , jppon, iiter1 )
180           CALL p4z_sink2( wsbio3, sinkingp , jppop, iiter1 )
181         END DO
182
183         DO jit = 1, iiter2
184           CALL p4z_sink2( wsbio4, sinking2n, jpgon, iiter2 )
185           CALL p4z_sink2( wsbio4, sinking2p, jpgop, iiter2 )
186         END DO
187      ENDIF
188
189      IF( ln_ligand ) THEN
190         wsfep (:,:,:) = wfep
191         DO jk = 1,jpkm1
192            DO jj = 1, jpj
193               DO ji = 1, jpi
194                  IF( tmask(ji,jj,jk) == 1 ) THEN
195                    zwsmax = 0.5 * e3t_n(ji,jj,jk) / xstep
196                    wsfep(ji,jj,jk) = MIN( wsfep(ji,jj,jk), zwsmax * REAL( iiter1, wp ) )
197                  ENDIF
198               END DO
199            END DO
200         END DO
201         !
202         sinkfep(:,:,:) = 0.e0
203         DO jit = 1, iiter1
204           CALL p4z_sink2( wsfep, sinkfep , jpfep, iiter1 )
205         END DO
206      ENDIF
207
208     ! Total carbon export per year
209     IF( iom_use( "tcexp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
210        &   t_oce_co2_exp = glob_sum( ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * e1e2t(:,:) * tmask(:,:,1) )
211     !
212     IF( lk_iomput ) THEN
213       IF( knt == nrdttrc ) THEN
214          CALL wrk_alloc( jpi, jpj,      zw2d )
215          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
216          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
217          !
218          IF( iom_use( "EPC100" ) )  THEN
219              zw2d(:,:) = ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of carbon at 100m
220              CALL iom_put( "EPC100"  , zw2d )
221          ENDIF
222          IF( iom_use( "EPFE100" ) )  THEN
223              zw2d(:,:) = ( sinkfer(:,:,ik100) + sinkfer2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of iron at 100m
224              CALL iom_put( "EPFE100"  , zw2d )
225          ENDIF
226          IF( iom_use( "EPCAL100" ) )  THEN
227              zw2d(:,:) = sinkcal(:,:,ik100) * zfact * tmask(:,:,1) ! Export of calcite at 100m
228              CALL iom_put( "EPCAL100"  , zw2d )
229          ENDIF
230          IF( iom_use( "EPSI100" ) )  THEN
231              zw2d(:,:) =  sinksil(:,:,ik100) * zfact * tmask(:,:,1) ! Export of bigenic silica at 100m
232              CALL iom_put( "EPSI100"  , zw2d )
233          ENDIF
234          IF( iom_use( "EXPC" ) )  THEN
235              zw3d(:,:,:) = ( sinking(:,:,:) + sinking2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of carbon in the water column
236              CALL iom_put( "EXPC"  , zw3d )
237          ENDIF
238          IF( iom_use( "EXPFE" ) )  THEN
239              zw3d(:,:,:) = ( sinkfer(:,:,:) + sinkfer2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of iron
240              CALL iom_put( "EXPFE"  , zw3d )
241          ENDIF
242          IF( iom_use( "EXPCAL" ) )  THEN
243              zw3d(:,:,:) = sinkcal(:,:,:) * zfact * tmask(:,:,:) ! Export of calcite
244              CALL iom_put( "EXPCAL"  , zw3d )
245          ENDIF
246          IF( iom_use( "EXPSI" ) )  THEN
247              zw3d(:,:,:) = sinksil(:,:,:) * zfact * tmask(:,:,:) ! Export of bigenic silica
248              CALL iom_put( "EXPSI"  , zw3d )
249          ENDIF
250          IF( iom_use( "tcexp" ) )  CALL iom_put( "tcexp" , t_oce_co2_exp * zfact )   ! molC/s
251          !
252          CALL wrk_dealloc( jpi, jpj,      zw2d )
253          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
254        ENDIF
255      ENDIF
256      !
257      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
258         WRITE(charout, FMT="('sink')")
259         CALL prt_ctl_trc_info(charout)
260         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
261      ENDIF
262      !
263      IF( ln_timing )   CALL timing_stop('p4z_sink')
264      !
265   END SUBROUTINE p4z_sink
266
267
268   SUBROUTINE p4z_sink_init
269      !!----------------------------------------------------------------------
270      !!                  ***  ROUTINE p4z_sink_init  ***
271      !!----------------------------------------------------------------------
272      INTEGER :: jk
273      !!----------------------------------------------------------------------
274      !
275      ik100 = 10        !  last level where depth less than 100 m
276      DO jk = jpkm1, 1, -1
277         IF( gdept_1d(jk) > 100. )  ik100 = jk - 1
278      END DO
279      IF (lwp) WRITE(numout,*)
280      IF (lwp) WRITE(numout,*) ' Level corresponding to 100m depth ',  ik100 + 1
281      IF (lwp) WRITE(numout,*)
282      !
283      t_oce_co2_exp = 0._wp
284      !
285   END SUBROUTINE p4z_sink_init
286
287
288   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra, kiter )
289      !!---------------------------------------------------------------------
290      !!                     ***  ROUTINE p4z_sink2  ***
291      !!
292      !! ** Purpose :   Compute the sedimentation terms for the various sinking
293      !!     particles. The scheme used to compute the trends is based
294      !!     on MUSCL.
295      !!
296      !! ** Method  : - this ROUTINE compute not exactly the advection but the
297      !!      transport term, i.e.  div(u*tra).
298      !!---------------------------------------------------------------------
299      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
300      INTEGER , INTENT(in   )                         ::   kiter     ! number of iterations for time-splitting
301      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
302      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
303      !
304      INTEGER  ::   ji, jj, jk, jn
305      REAL(wp) ::   zigma,zew,zign, zflx, zstep
306      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztraz, zakz, zwsink2, ztrb 
307      !!---------------------------------------------------------------------
308      !
309      IF( ln_timing )   CALL timing_start('p4z_sink2')
310      !
311      ! Allocate temporary workspace
312      CALL wrk_alloc( jpi, jpj, jpk, ztraz, zakz, zwsink2, ztrb )
313
314      zstep = rfact2 / REAL( kiter, wp ) / 2.
315
316      ztraz(:,:,:) = 0.e0
317      zakz (:,:,:) = 0.e0
318      ztrb (:,:,:) = trb(:,:,:,jp_tra)
319
320      DO jk = 1, jpkm1
321         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
322      END DO
323      zwsink2(:,:,1) = 0.e0
324
325
326      ! Vertical advective flux
327      DO jn = 1, 2
328         !  first guess of the slopes interior values
329         DO jk = 2, jpkm1
330            ztraz(:,:,jk) = ( trb(:,:,jk-1,jp_tra) - trb(:,:,jk,jp_tra) ) * tmask(:,:,jk)
331         END DO
332         ztraz(:,:,1  ) = 0.0
333         ztraz(:,:,jpk) = 0.0
334
335         ! slopes
336         DO jk = 2, jpkm1
337            DO jj = 1,jpj
338               DO ji = 1, jpi
339                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
340                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
341               END DO
342            END DO
343         END DO
344         
345         ! Slopes limitation
346         DO jk = 2, jpkm1
347            DO jj = 1, jpj
348               DO ji = 1, jpi
349                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
350                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
351               END DO
352            END DO
353         END DO
354         
355         ! vertical advective flux
356         DO jk = 1, jpkm1
357            DO jj = 1, jpj     
358               DO ji = 1, jpi   
359                  zigma = zwsink2(ji,jj,jk+1) * zstep / e3w_n(ji,jj,jk+1)
360                  zew   = zwsink2(ji,jj,jk+1)
361                  psinkflx(ji,jj,jk+1) = -zew * ( trb(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
362               END DO
363            END DO
364         END DO
365         !
366         ! Boundary conditions
367         psinkflx(:,:,1  ) = 0.e0
368         psinkflx(:,:,jpk) = 0.e0
369         
370         DO jk=1,jpkm1
371            DO jj = 1,jpj
372               DO ji = 1, jpi
373                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t_n(ji,jj,jk)
374                  trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + zflx
375               END DO
376            END DO
377         END DO
378
379      ENDDO
380
381      DO jk = 1,jpkm1
382         DO jj = 1,jpj
383            DO ji = 1, jpi
384               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t_n(ji,jj,jk)
385               ztrb(ji,jj,jk) = ztrb(ji,jj,jk) + 2. * zflx
386            END DO
387         END DO
388      END DO
389
390      trb(:,:,:,jp_tra) = ztrb(:,:,:)
391      psinkflx(:,:,:)   = 2. * psinkflx(:,:,:)
392      !
393      CALL wrk_dealloc( jpi, jpj, jpk, ztraz, zakz, zwsink2, ztrb )
394      !
395      IF( ln_timing )  CALL timing_stop('p4z_sink2')
396      !
397   END SUBROUTINE p4z_sink2
398
399
400   INTEGER FUNCTION p4z_sink_alloc()
401      !!----------------------------------------------------------------------
402      !!                     ***  ROUTINE p4z_sink_alloc  ***
403      !!----------------------------------------------------------------------
404      INTEGER :: ierr(3)
405      !!----------------------------------------------------------------------
406      !
407      ierr(:) = 0
408      !
409      ALLOCATE( sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                    ,     &               
410         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                    ,     &               
411         &      sinkfer2(jpi,jpj,jpk)                                           ,     &               
412         &      sinkfer(jpi,jpj,jpk)                                            , STAT=ierr(1) )               
413         !
414      IF( ln_ligand ) ALLOCATE( sinkfep(jpi,jpj,jpk)                            , STAT=ierr(2) ) 
415         
416      IF( ln_p5z    ) ALLOCATE( sinkingn(jpi,jpj,jpk), sinking2n(jpi,jpj,jpk)   ,     &
417         &                      sinkingp(jpi,jpj,jpk), sinking2p(jpi,jpj,jpk)   , STAT=ierr(3) )
418      !
419      p4z_sink_alloc = MAXVAL( ierr )
420      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
421      !
422   END FUNCTION p4z_sink_alloc
423   
424   !!======================================================================
425END MODULE p4zsink
Note: See TracBrowser for help on using the repository browser.