New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2017/dev_r7832_HPC08_lbclnk_3rd_dim/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2017/dev_r7832_HPC08_lbclnk_3rd_dim/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 7901

Last change on this file since 7901 was 7897, checked in by gm, 7 years ago

#1880: (HPC-08) 3D lbc_lnk with any 3rd dim + regroup global comm in stpctl.F90

  • Property svn:keywords set to Id
File size: 40.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
36   !!----------------------------------------------------------------------
37
38   !!----------------------------------------------------------------------
39   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
40   !!   nemo_init     : initialization of the NEMO system
41   !!   nemo_ctl      : initialisation of the contol print
42   !!   nemo_closefile: close remaining open files
43   !!   nemo_alloc    : dynamical allocation
44   !!   nemo_partition: calculate MPP domain decomposition
45   !!   factorise     : calculate the factors of the no. of MPI processes
46   !!----------------------------------------------------------------------
47   USE step_oce       ! module used in the ocean time stepping module (step.F90)
48   USE phycst         ! physical constant                  (par_cst routine)
49   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
50   USE usrdef_nam     ! user defined configuration
51   USE tideini        ! tidal components initialization   (tide_ini routine)
52   USE bdy_oce,   ONLY: ln_bdy
53   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
54   USE istate         ! initial state setting          (istate_init routine)
55   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
56   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
57   USE zdfini         ! vertical physics setting          (zdf_init routine)
58   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
59   USE asminc         ! assimilation increments     
60   USE asmbkg         ! writing out state trajectory
61   USE diaptr         ! poleward transports           (dia_ptr_init routine)
62   USE diadct         ! sections transports           (dia_dct_init routine)
63   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
64   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
65   USE step           ! NEMO time-stepping                 (stp     routine)
66   USE icbini         ! handle bergs, initialisation
67   USE icbstp         ! handle bergs, calving, themodynamics and transport
68   USE cpl_oasis3     ! OASIS3 coupling
69   USE c1d            ! 1D configuration
70   USE step_c1d       ! Time stepping loop for the 1D configuration
71   USE dyndmp         ! Momentum damping
72   USE stopar         ! Stochastic param.: ???
73   USE stopts         ! Stochastic param.: ???
74   USE diurnal_bulk   ! diurnal bulk SST
75   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
76   USE crsini         ! initialise grid coarsening utility
77   USE diatmb         ! Top,middle,bottom output
78   USE dia25h         ! 25h mean output
79   USE sbc_oce , ONLY : lk_oasis
80   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
81#if defined key_top
82   USE trcini         ! passive tracer initialisation
83#endif
84#if defined key_nemocice_decomp
85   USE ice_domain_size, only: nx_global, ny_global
86#endif
87   !
88   USE lib_mpp        ! distributed memory computing
89   USE mppini         ! shared/distributed memory setting (mpp_init routine)
90   USE lbcnfd , ONLY  : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
91   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
92#if defined key_iomput
93   USE xios           ! xIOserver
94#endif
95
96   IMPLICIT NONE
97   PRIVATE
98
99   PUBLIC   nemo_gcm    ! called by model.F90
100   PUBLIC   nemo_init   ! needed by AGRIF
101   PUBLIC   nemo_alloc  ! needed by TAM
102
103   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
104
105   !!----------------------------------------------------------------------
106   !! NEMO/OPA 3.7 , NEMO Consortium (2016)
107   !! $Id$
108   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
109   !!----------------------------------------------------------------------
110CONTAINS
111
112   SUBROUTINE nemo_gcm
113      !!----------------------------------------------------------------------
114      !!                     ***  ROUTINE nemo_gcm  ***
115      !!
116      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
117      !!              curvilinear mesh on the sphere.
118      !!
119      !! ** Method  : - model general initialization
120      !!              - launch the time-stepping (stp routine)
121      !!              - finalize the run by closing files and communications
122      !!
123      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
124      !!              Madec, 2008, internal report, IPSL.
125      !!----------------------------------------------------------------------
126      INTEGER ::   istp   ! time step index
127      !!----------------------------------------------------------------------
128      !
129#if defined key_agrif
130      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
131#endif
132      !
133      !                            !-----------------------!
134      CALL nemo_init               !==  Initialisations  ==!
135      !                            !-----------------------!
136#if defined key_agrif
137      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
138      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
139# if defined key_top
140      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
141# endif
142# if defined key_lim2
143      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM2
144# endif
145# if defined key_lim3
146      CALL Agrif_Declare_Var_lim3  !  "      "   "   "      "  LIM3
147# endif
148#endif
149      ! check that all process are still there... If some process have an error,
150      ! they will never enter in step and other processes will wait until the end of the cpu time!
151      IF( lk_mpp )   CALL mpp_max( nstop )
152
153      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
154
155      !                            !-----------------------!
156      !                            !==   time stepping   ==!
157      !                            !-----------------------!
158      istp = nit000
159#if defined key_c1d
160         DO WHILE ( istp <= nitend .AND. nstop == 0 )
161            CALL stp_c1d( istp )
162            istp = istp + 1
163         END DO
164#else
165          IF( lk_asminc ) THEN
166             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
167             IF( ln_asmdin ) THEN                        ! Direct initialization
168                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
169                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
170                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
171             ENDIF
172          ENDIF
173
174#if defined key_agrif
175          CALL Agrif_Regrid()
176#endif
177
178         DO WHILE ( istp <= nitend .AND. nstop == 0 )
179#if defined key_agrif
180            CALL stp                         ! AGRIF: time stepping
181#else
182            IF ( .NOT. ln_diurnal_only ) THEN
183               CALL stp( istp )                 ! standard time stepping
184            ELSE
185               CALL stp_diurnal( istp )        ! time step only the diurnal SST
186            ENDIF 
187#endif
188            istp = istp + 1
189            IF( lk_mpp )   CALL mpp_max( nstop )
190         END DO
191#endif
192
193      IF( ln_diaobs   )   CALL dia_obs_wri
194      !
195      IF( ln_icebergs )   CALL icb_end( nitend )
196
197      !                            !------------------------!
198      !                            !==  finalize the run  ==!
199      !                            !------------------------!
200      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
201      !
202      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
203         WRITE(numout,cform_err)
204         WRITE(numout,*) nstop, ' error have been found'
205      ENDIF
206      !
207#if defined key_agrif
208      IF( .NOT. Agrif_Root() ) THEN
209                         CALL Agrif_ParentGrid_To_ChildGrid()
210         IF( ln_diaobs ) CALL dia_obs_wri
211         IF( nn_timing == 1 )   CALL timing_finalize
212                                CALL Agrif_ChildGrid_To_ParentGrid()
213      ENDIF
214#endif
215      IF( nn_timing == 1 )   CALL timing_finalize
216      !
217      CALL nemo_closefile
218      !
219#if defined key_iomput
220      CALL xios_finalize                     ! end mpp communications with xios
221      IF( lk_oasis )   CALL cpl_finalize     ! end coupling and mpp communications with OASIS
222#else
223      IF( lk_oasis ) THEN
224         CALL cpl_finalize                   ! end coupling and mpp communications with OASIS
225      ELSE
226         IF( lk_mpp )   CALL mppstop         ! end mpp communications
227      ENDIF
228#endif
229      !
230   END SUBROUTINE nemo_gcm
231
232
233   SUBROUTINE nemo_init
234      !!----------------------------------------------------------------------
235      !!                     ***  ROUTINE nemo_init  ***
236      !!
237      !! ** Purpose :   initialization of the NEMO GCM
238      !!----------------------------------------------------------------------
239      INTEGER  ::   ji                 ! dummy loop indices
240      INTEGER  ::   ios, ilocal_comm   ! local integer
241      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
242      !
243      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
244         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
245         &             nn_timing, nn_diacfl
246      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
247      !!----------------------------------------------------------------------
248      !
249      cltxt  = ''
250      cltxt2 = ''
251      clnam  = '' 
252      cxios_context = 'nemo'
253      !
254      !                             ! Open reference namelist and configuration namelist files
255      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
256      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
257      !
258      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints
259      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
260901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
261      !
262      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
263      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
264902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
265      !
266      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints
267      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
268903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
269
270      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
271      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
272904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
273
274      !                             !--------------------------!
275      !                             !  Set global domain size  !   (control print return in cltxt2)
276      !                             !--------------------------!
277      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
278         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
279         !
280      ELSE                                ! user-defined namelist
281         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
282      ENDIF
283      !
284      jpk = jpkglo
285      !
286#if defined key_agrif
287      IF( .NOT. Agrif_Root() ) THEN       ! AGRIF children: specific setting (cf. agrif_user.F90)
288         jpiglo  = nbcellsx + 2 + 2*nbghostcells
289         jpjglo  = nbcellsy + 2 + 2*nbghostcells
290         jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
291         jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
292         nperio  = 0
293         jperio  = 0
294         ln_use_jattr = .false.
295      ENDIF
296#endif
297      !
298      !                             !--------------------------------------------!
299      !                             !  set communicator & select the local node  !
300      !                             !  NB: mynode also opens output.namelist.dyn !
301      !                             !      on unit number numond on first proc   !
302      !                             !--------------------------------------------!
303#if defined key_iomput
304      IF( Agrif_Root() ) THEN
305         IF( lk_oasis ) THEN
306            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
307            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
308         ELSE
309            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
310         ENDIF
311      ENDIF
312      ! Nodes selection (control print return in cltxt)
313      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
314#else
315      IF( lk_oasis ) THEN
316         IF( Agrif_Root() ) THEN
317            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
318         ENDIF
319         ! Nodes selection (control print return in cltxt)
320         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
321      ELSE
322         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
323         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
324      ENDIF
325#endif
326
327      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
328
329      lwm = (narea == 1)                                    ! control of output namelists
330      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
331
332      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
333         !                       ! now that the file has been opened in call to mynode.
334         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
335         WRITE( numond, namctl )
336         WRITE( numond, namcfg )
337         IF( .NOT.ln_read_cfg ) THEN
338            DO ji = 1, SIZE(clnam)
339               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
340            END DO
341         ENDIF
342      ENDIF
343
344      ! If dimensions of processor grid weren't specified in the namelist file
345      ! then we calculate them here now that we have our communicator size
346      IF( jpni < 1 .OR. jpnj < 1 ) THEN
347#if   defined key_mpp_mpi
348         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
349#else
350         jpni  = 1
351         jpnj  = 1
352         jpnij = jpni*jpnj
353#endif
354      ENDIF
355
356      IF( Agrif_Root() ) THEN       ! AGRIF mother: specific setting from jpni and jpnj
357#if defined key_nemocice_decomp
358         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
359         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
360#else
361         jpi = ( jpiglo     -2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
362         jpj = ( jpjglo     -2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
363#endif
364      ENDIF
365
366!!gm ???    why here  it has already been done in line 301 !
367      jpk = jpkglo                                             ! third dim
368!!gm end
369
370#if defined key_agrif
371      ! simple trick to use same vertical grid as parent but different number of levels:
372      ! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
373      ! Suppress once vertical online interpolation is ok
374      IF(.NOT.Agrif_Root())   jpkglo = Agrif_Parent( jpkglo )
375#endif
376      jpim1 = jpi-1                                            ! inner domain indices
377      jpjm1 = jpj-1                                            !   "           "
378      jpkm1 = MAX( 1, jpk-1 )                                  !   "           "
379      jpij  = jpi*jpj                                          !  jpi x j
380
381      IF(lwp) THEN                            ! open listing units
382         !
383         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
384         !
385         WRITE(numout,*)
386         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
387         WRITE(numout,*) '                       NEMO team'
388         WRITE(numout,*) '            Ocean General Circulation Model'
389         WRITE(numout,*) '                NEMO version 3.7  (2016) '
390         WRITE(numout,*)
391         WRITE(numout,*)
392         DO ji = 1, SIZE(cltxt)
393            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
394         END DO
395         WRITE(numout,*)
396         WRITE(numout,*)
397         DO ji = 1, SIZE(cltxt2)
398            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
399         END DO
400         !
401         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
402         !
403      ENDIF
404
405      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
406      CALL nemo_alloc()
407
408      !                             !-------------------------------!
409      !                             !  NEMO general initialization  !
410      !                             !-------------------------------!
411
412      CALL nemo_ctl                          ! Control prints
413
414      !                                      ! Domain decomposition
415      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
416      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
417      ENDIF
418      !
419      IF( nn_timing == 1 )  CALL timing_init
420      !
421      !                                      ! General initialization
422                            CALL     phy_cst    ! Physical constants
423                            CALL     eos_init   ! Equation of state
424      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
425                            CALL     wad_init   ! Wetting and drying options
426                            CALL     dom_init   ! Domain
427      IF( ln_crs        )   CALL     crs_init   ! coarsened grid: domain initialization
428      IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
429      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
430     
431      CALL diurnal_sst_bulk_init            ! diurnal sst
432      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
433     
434      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
435      IF ( ln_diurnal_only ) THEN
436         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
437         CALL     sbc_init   ! Forcings : surface module
438         CALL tra_qsr_init   ! penetrative solar radiation qsr
439         IF( ln_diaobs     ) THEN                  ! Observation & model comparison
440            CALL dia_obs_init            ! Initialize observational data
441            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
442         ENDIF     
443         !                                     ! Assimilation increments
444         IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
445                 
446         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
447         RETURN
448      ENDIF
449     
450                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
451
452      !                                      ! external forcing
453!!gm to be added : creation and call of sbc_apr_init
454                            CALL    tide_init   ! tidal harmonics
455                            CALL     sbc_init   ! surface boundary conditions (including sea-ice)
456                            CALL     bdy_init   ! Open boundaries initialisation
457      !                                      ! Ocean physics
458      !                                         ! Vertical physics
459                            CALL     zdf_init      ! namelist read
460                            CALL zdf_bfr_init      ! bottom friction
461      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
462      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
463      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
464      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
465      IF( lk_zdfddm     )   CALL zdf_ddm_init      ! double diffusive mixing
466         
467      !                                         ! Lateral physics
468                            CALL ldf_tra_init      ! Lateral ocean tracer physics
469                            CALL ldf_eiv_init      ! eddy induced velocity param.
470                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
471
472      !                                         ! Active tracers
473                            CALL tra_qsr_init      ! penetrative solar radiation qsr
474                            CALL tra_bbc_init      ! bottom heat flux
475      IF( lk_trabbl     )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
476                            CALL tra_dmp_init      ! internal tracer damping
477                            CALL tra_adv_init      ! horizontal & vertical advection
478                            CALL tra_ldf_init      ! lateral mixing
479                            CALL tra_zdf_init      ! vertical mixing and after tracer fields
480
481      !                                         ! Dynamics
482      IF( lk_c1d        )   CALL dyn_dmp_init      ! internal momentum damping
483                            CALL dyn_adv_init      ! advection (vector or flux form)
484                            CALL dyn_vor_init      ! vorticity term including Coriolis
485                            CALL dyn_ldf_init      ! lateral mixing
486                            CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
487                            CALL dyn_zdf_init      ! vertical diffusion
488                            CALL dyn_spg_init      ! surface pressure gradient
489
490#if defined key_top
491      !                                      ! Passive tracers
492                            CALL     trc_init
493#endif
494      IF( l_ldfslp      )   CALL ldf_slp_init   ! slope of lateral mixing
495
496      !                                      ! Icebergs
497                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
498
499      !                                      ! Misc. options
500                            CALL sto_par_init   ! Stochastic parametrization
501      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
502     
503      !                                      ! Diagnostics
504      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
505                            CALL dia_cfl_init   ! Initialise CFL diagnostics
506                            CALL dia_ptr_init   ! Poleward TRansports initialization
507      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
508                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
509                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
510                            CALL dia_obs_init            ! Initialize observational data
511      IF( ln_diaobs     )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
512
513      !                                         ! Assimilation increments
514      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
515      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
516                            CALL dia_tmb_init  ! TMB outputs
517                            CALL dia_25h_init  ! 25h mean  outputs
518      !
519   END SUBROUTINE nemo_init
520
521
522   SUBROUTINE nemo_ctl
523      !!----------------------------------------------------------------------
524      !!                     ***  ROUTINE nemo_ctl  ***
525      !!
526      !! ** Purpose :   control print setting
527      !!
528      !! ** Method  : - print namctl information and check some consistencies
529      !!----------------------------------------------------------------------
530      !
531      IF(lwp) THEN                  ! control print
532         WRITE(numout,*)
533         WRITE(numout,*) 'nemo_ctl: Control prints'
534         WRITE(numout,*) '~~~~~~~ '
535         WRITE(numout,*) '   Namelist namctl'
536         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
537         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
538         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
539         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
540         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
541         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
542         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
543         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
544         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
545      ENDIF
546      !
547      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
548      nictls    = nn_ictls
549      nictle    = nn_ictle
550      njctls    = nn_jctls
551      njctle    = nn_jctle
552      isplt     = nn_isplt
553      jsplt     = nn_jsplt
554
555      IF(lwp) THEN                  ! control print
556         WRITE(numout,*)
557         WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
558         WRITE(numout,*) '~~~~~~ '
559         WRITE(numout,*) '   Namelist namcfg'
560         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
561         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
562         WRITE(numout,*) '      write configuration definition file           ln_write_cfg     = ', ln_write_cfg
563         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
564         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
565      ENDIF
566      !                             ! Parameter control
567      !
568      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
569         IF( lk_mpp .AND. jpnij > 1 ) THEN
570            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
571         ELSE
572            IF( isplt == 1 .AND. jsplt == 1  ) THEN
573               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
574                  &           ' - the print control will be done over the whole domain' )
575            ENDIF
576            ijsplt = isplt * jsplt            ! total number of processors ijsplt
577         ENDIF
578         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
579         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
580         !
581         !                              ! indices used for the SUM control
582         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
583            lsp_area = .FALSE.
584         ELSE                                             ! print control done over a specific  area
585            lsp_area = .TRUE.
586            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
587               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
588               nictls = 1
589            ENDIF
590            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
591               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
592               nictle = jpiglo
593            ENDIF
594            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
595               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
596               njctls = 1
597            ENDIF
598            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
599               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
600               njctle = jpjglo
601            ENDIF
602         ENDIF
603      ENDIF
604      !
605      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
606         &                                               'f2003 standard. '                              ,  &
607         &                                               'Compile with key_nosignedzero enabled' )
608      !
609   END SUBROUTINE nemo_ctl
610
611
612   SUBROUTINE nemo_closefile
613      !!----------------------------------------------------------------------
614      !!                     ***  ROUTINE nemo_closefile  ***
615      !!
616      !! ** Purpose :   Close the files
617      !!----------------------------------------------------------------------
618      !
619      IF( lk_mpp )   CALL mppsync
620      !
621      CALL iom_close                                 ! close all input/output files managed by iom_*
622      !
623      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
624      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
625      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
626      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
627      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
628      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
629      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
630      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
631      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
632      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
633      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
634      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
635      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
636      !
637      numout = 6                                     ! redefine numout in case it is used after this point...
638      !
639   END SUBROUTINE nemo_closefile
640
641
642   SUBROUTINE nemo_alloc
643      !!----------------------------------------------------------------------
644      !!                     ***  ROUTINE nemo_alloc  ***
645      !!
646      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
647      !!
648      !! ** Method  :
649      !!----------------------------------------------------------------------
650      USE diawri    , ONLY: dia_wri_alloc
651      USE dom_oce   , ONLY: dom_oce_alloc
652      USE trc_oce   , ONLY: trc_oce_alloc
653#if defined key_diadct 
654      USE diadct    , ONLY: diadct_alloc 
655#endif
656      USE bdy_oce   , ONLY: bdy_oce_alloc
657      !
658      INTEGER :: ierr
659      !!----------------------------------------------------------------------
660      !
661      ierr =        oce_alloc       ()          ! ocean
662      ierr = ierr + dia_wri_alloc   ()
663      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
664      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
665      !
666      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
667      !
668#if defined key_diadct 
669      ierr = ierr + diadct_alloc    ()          !
670#endif
671      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
672      !
673      IF( lk_mpp    )   CALL mpp_sum( ierr )
674      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
675      !
676   END SUBROUTINE nemo_alloc
677
678
679   SUBROUTINE nemo_partition( num_pes )
680      !!----------------------------------------------------------------------
681      !!                 ***  ROUTINE nemo_partition  ***
682      !!
683      !! ** Purpose :
684      !!
685      !! ** Method  :
686      !!----------------------------------------------------------------------
687      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
688      !
689      INTEGER, PARAMETER :: nfactmax = 20
690      INTEGER :: nfact ! The no. of factors returned
691      INTEGER :: ierr  ! Error flag
692      INTEGER :: ji
693      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
694      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
695      !!----------------------------------------------------------------------
696      !
697      ierr = 0
698      !
699      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
700      !
701      IF( nfact <= 1 ) THEN
702         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
703         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
704         jpnj = 1
705         jpni = num_pes
706      ELSE
707         ! Search through factors for the pair that are closest in value
708         mindiff = 1000000
709         imin    = 1
710         DO ji = 1, nfact-1, 2
711            idiff = ABS( ifact(ji) - ifact(ji+1) )
712            IF( idiff < mindiff ) THEN
713               mindiff = idiff
714               imin = ji
715            ENDIF
716         END DO
717         jpnj = ifact(imin)
718         jpni = ifact(imin + 1)
719      ENDIF
720      !
721      jpnij = jpni*jpnj
722      !
723   END SUBROUTINE nemo_partition
724
725
726   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
727      !!----------------------------------------------------------------------
728      !!                     ***  ROUTINE factorise  ***
729      !!
730      !! ** Purpose :   return the prime factors of n.
731      !!                knfax factors are returned in array kfax which is of
732      !!                maximum dimension kmaxfax.
733      !! ** Method  :
734      !!----------------------------------------------------------------------
735      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
736      INTEGER                    , INTENT(  out) ::   kerr, knfax
737      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
738      !
739      INTEGER :: ifac, jl, inu
740      INTEGER, PARAMETER :: ntest = 14
741      INTEGER, DIMENSION(ntest) ::   ilfax
742      !!----------------------------------------------------------------------
743      !
744      ! lfax contains the set of allowed factors.
745      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
746      !
747      ! Clear the error flag and initialise output vars
748      kerr  = 0
749      kfax  = 1
750      knfax = 0
751      !
752      ! Find the factors of n.
753      IF( kn == 1 )   GOTO 20
754
755      ! nu holds the unfactorised part of the number.
756      ! knfax holds the number of factors found.
757      ! l points to the allowed factor list.
758      ! ifac holds the current factor.
759      !
760      inu   = kn
761      knfax = 0
762      !
763      DO jl = ntest, 1, -1
764         !
765         ifac = ilfax(jl)
766         IF( ifac > inu )   CYCLE
767
768         ! Test whether the factor will divide.
769
770         IF( MOD(inu,ifac) == 0 ) THEN
771            !
772            knfax = knfax + 1            ! Add the factor to the list
773            IF( knfax > kmaxfax ) THEN
774               kerr = 6
775               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
776               return
777            ENDIF
778            kfax(knfax) = ifac
779            ! Store the other factor that goes with this one
780            knfax = knfax + 1
781            kfax(knfax) = inu / ifac
782            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
783         ENDIF
784         !
785      END DO
786      !
787   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
788      !
789   END SUBROUTINE factorise
790
791#if defined key_mpp_mpi
792
793   SUBROUTINE nemo_northcomms
794      !!----------------------------------------------------------------------
795      !!                     ***  ROUTINE  nemo_northcomms  ***
796      !! ** Purpose :   Setup for north fold exchanges with explicit
797      !!                point-to-point messaging
798      !!
799      !! ** Method :   Initialization of the northern neighbours lists.
800      !!----------------------------------------------------------------------
801      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
802      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
803      !!----------------------------------------------------------------------
804      INTEGER  ::   sxM, dxM, sxT, dxT, jn
805      INTEGER  ::   njmppmax
806      !!----------------------------------------------------------------------
807      !
808      njmppmax = MAXVAL( njmppt )
809      !
810      !initializes the north-fold communication variables
811      isendto(:) = 0
812      nsndto     = 0
813      !
814      !if I am a process in the north
815      IF ( njmpp == njmppmax ) THEN
816          !sxM is the first point (in the global domain) needed to compute the
817          !north-fold for the current process
818          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
819          !dxM is the last point (in the global domain) needed to compute the
820          !north-fold for the current process
821          dxM = jpiglo - nimppt(narea) + 2
822
823          !loop over the other north-fold processes to find the processes
824          !managing the points belonging to the sxT-dxT range
825 
826          DO jn = 1, jpni
827                !sxT is the first point (in the global domain) of the jn
828                !process
829                sxT = nfiimpp(jn, jpnj)
830                !dxT is the last point (in the global domain) of the jn
831                !process
832                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
833                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
834                   nsndto = nsndto + 1
835                   isendto(nsndto) = jn
836                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
837                   nsndto = nsndto + 1
838                   isendto(nsndto) = jn
839                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
840                   nsndto = nsndto + 1
841                   isendto(nsndto) = jn
842                ENDIF
843          END DO
844          nfsloop = 1
845          nfeloop = nlci
846          DO jn = 2,jpni-1
847           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
848              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
849                 nfsloop = nldi
850              ENDIF
851              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
852                 nfeloop = nlei
853              ENDIF
854           ENDIF
855        END DO
856
857      ENDIF
858      l_north_nogather = .TRUE.
859   END SUBROUTINE nemo_northcomms
860
861#else
862   SUBROUTINE nemo_northcomms      ! Dummy routine
863      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
864   END SUBROUTINE nemo_northcomms
865#endif
866
867   !!======================================================================
868END MODULE nemogcm
869
Note: See TracBrowser for help on using the repository browser.