New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
crsfld.F90 in branches/2017/dev_r7881_ENHANCE09_RK3/NEMOGCM/NEMO/OPA_SRC/CRS – NEMO

source: branches/2017/dev_r7881_ENHANCE09_RK3/NEMOGCM/NEMO/OPA_SRC/CRS/crsfld.F90 @ 8215

Last change on this file since 8215 was 8215, checked in by gm, 7 years ago

#1911 (ENHANCE-09): PART 0 - phasing with branch dev_r7832_HPC09_ZDF revision 8214

  • Property svn:keywords set to Id
File size: 12.1 KB
Line 
1MODULE crsfld
2   !!======================================================================
3   !!                     ***  MODULE  crsdfld  ***
4   !!  Ocean coarsening :  coarse ocean fields
5   !!=====================================================================
6   !!   2012-07  (J. Simeon, C. Calone, G. Madec, C. Ethe)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   crs_fld       : create the standard output files for coarse grid and prep
11   !!                       other variables needed to be passed to TOP
12   !!----------------------------------------------------------------------
13   USE crs
14   USE crsdom
15   USE crslbclnk
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! Surface boundary condition: ocean fields
19   USE zdf_oce         ! vertical  physics: ocean fields
20   USE ldftra          ! ocean active tracers: lateral diffusivity & EIV coefficients
21   USE zdfddm          ! vertical  physics: double diffusion
22   !
23   USE in_out_manager  ! I/O manager
24   USE iom             !
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE timing          ! preformance summary
27   USE wrk_nemo        ! working array
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   crs_fld                 ! routines called by step.F90
33
34   !! * Substitutions
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
38   !! $Id$
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE crs_fld( kt )
44      !!---------------------------------------------------------------------
45      !!                  ***  ROUTINE crs_fld  ***
46      !!                   
47      !! ** Purpose :   Basic output of coarsened dynamics and tracer fields
48      !!      NETCDF format is used by default
49      !!      1. Accumulate in time the dimensionally-weighted fields
50      !!      2. At time of output, rescale [1] by dimension and time
51      !!         to yield the spatial and temporal average.
52      !!  See. sbcmod.F90
53      !!
54      !! ** Method  : 
55      !!----------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
57      !
58      INTEGER  ::   ji, jj, jk        ! dummy loop indices
59      REAL(wp) ::   z2dcrsu, z2dcrsv  ! local scalars
60      REAL(wp) ::   zztmp             !   -      -
61      !
62      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ze3t, ze3u, ze3v, ze3w   ! 3D workspace for e3
63      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zt, zt_crs, z3d
64      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zs, zs_crs 
65      !!----------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )   CALL timing_start('crs_fld')
68
69      !  Initialize arrays
70      CALL wrk_alloc( jpi,jpj,jpk,   ze3t, ze3w )
71      CALL wrk_alloc( jpi,jpj,jpk,   ze3u, ze3v )
72      CALL wrk_alloc( jpi,jpj,jpk,   zt  , zs  , z3d )
73      !
74      CALL wrk_alloc( jpi_crs,jpj_crs,jpk,   zt_crs, zs_crs )
75
76      ! Depth work arrrays
77      ze3t(:,:,:) = e3t_n(:,:,:)
78      ze3u(:,:,:) = e3u_n(:,:,:)
79      ze3v(:,:,:) = e3v_n(:,:,:)
80      ze3w(:,:,:) = e3w_n(:,:,:)
81
82      IF( kt == nit000  ) THEN
83         tsn_crs  (:,:,:,:) = 0._wp    ! temp/sal  array, now
84         un_crs   (:,:,:  ) = 0._wp    ! u-velocity
85         vn_crs   (:,:,:  ) = 0._wp    ! v-velocity
86         wn_crs   (:,:,:  ) = 0._wp    ! w
87         avs_crs  (:,:,:  ) = 0._wp    ! avt
88         hdivn_crs(:,:,:  ) = 0._wp    ! hdiv
89         sshn_crs (:,:    ) = 0._wp    ! ssh
90         utau_crs (:,:    ) = 0._wp    ! taux
91         vtau_crs (:,:    ) = 0._wp    ! tauy
92         wndm_crs (:,:    ) = 0._wp    ! wind speed
93         qsr_crs  (:,:    ) = 0._wp    ! qsr
94         emp_crs  (:,:    ) = 0._wp    ! emp
95         emp_b_crs(:,:    ) = 0._wp    ! emp
96         rnf_crs  (:,:    ) = 0._wp    ! runoff
97         fr_i_crs (:,:    ) = 0._wp    ! ice cover
98      ENDIF
99
100      CALL iom_swap( "nemo_crs" )    ! swap on the coarse grid
101
102      ! 2. Coarsen fields at each time step
103      ! --------------------------------------------------------
104
105      !  Temperature
106      zt(:,:,:) = tsn(:,:,:,jp_tem)  ;      zt_crs(:,:,:) = 0._wp
107      CALL crs_dom_ope( zt, 'VOL', 'T', tmask, zt_crs, p_e12=e1e2t, p_e3=ze3t, psgn=1.0 )
108      tsn_crs(:,:,:,jp_tem) = zt_crs(:,:,:)
109
110      CALL iom_put( "toce", tsn_crs(:,:,:,jp_tem) )    ! temp
111      CALL iom_put( "sst" , tsn_crs(:,:,1,jp_tem) )    ! sst
112
113     
114      !  Salinity
115      zs(:,:,:) = tsn(:,:,:,jp_sal)  ;      zs_crs(:,:,:) = 0._wp
116      CALL crs_dom_ope( zs, 'VOL', 'T', tmask, zs_crs, p_e12=e1e2t, p_e3=ze3t, psgn=1.0 )
117      tsn_crs(:,:,:,jp_sal) = zt_crs(:,:,:)
118
119      CALL iom_put( "soce" , tsn_crs(:,:,:,jp_sal) )    ! sal
120      CALL iom_put( "sss"  , tsn_crs(:,:,1,jp_sal) )    ! sss
121
122      !  U-velocity
123      CALL crs_dom_ope( un, 'SUM', 'U', umask, un_crs, p_e12=e2u, p_e3=ze3u, p_surf_crs=e2e3u_msk, psgn=-1.0 )
124      !
125      zt(:,:,:) = 0._wp     ;    zs(:,:,:) = 0._wp  ;   zt_crs(:,:,:) = 0._wp   ;    zs_crs(:,:,:) = 0._wp
126      DO jk = 1, jpkm1
127         DO jj = 2, jpjm1
128            DO ji = 2, jpim1   
129               zt(ji,jj,jk)  = un(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_tem) + tsn(ji+1,jj,jk,jp_tem) ) 
130               zs(ji,jj,jk)  = un(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_sal) + tsn(ji+1,jj,jk,jp_sal) ) 
131            END DO
132         END DO
133      END DO
134      CALL crs_dom_ope( zt, 'SUM', 'U', umask, zt_crs, p_e12=e2u, p_e3=ze3u, p_surf_crs=e2e3u_msk, psgn=-1.0 )
135      CALL crs_dom_ope( zs, 'SUM', 'U', umask, zs_crs, p_e12=e2u, p_e3=ze3u, p_surf_crs=e2e3u_msk, psgn=-1.0 )
136
137      CALL iom_put( "uoce"  , un_crs )   ! i-current
138      CALL iom_put( "uocet" , zt_crs )   ! uT
139      CALL iom_put( "uoces" , zs_crs )   ! uS
140
141      !  V-velocity
142      CALL crs_dom_ope( vn, 'SUM', 'V', vmask, vn_crs, p_e12=e1v, p_e3=ze3v, p_surf_crs=e1e3v_msk, psgn=-1.0 )
143      !                                                                                 
144      zt(:,:,:) = 0._wp     ;    zs(:,:,:) = 0._wp  ;   zt_crs(:,:,:) = 0._wp   ;    zs_crs(:,:,:) = 0._wp
145      DO jk = 1, jpkm1
146         DO jj = 2, jpjm1
147            DO ji = 2, jpim1   
148               zt(ji,jj,jk)  = vn(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_tem) + tsn(ji,jj+1,jk,jp_tem) ) 
149               zs(ji,jj,jk)  = vn(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_sal) + tsn(ji,jj+1,jk,jp_sal) ) 
150            END DO
151         END DO
152      END DO
153      CALL crs_dom_ope( zt, 'SUM', 'V', vmask, zt_crs, p_e12=e1v, p_e3=ze3v, p_surf_crs=e1e3v_msk, psgn=-1.0 )
154      CALL crs_dom_ope( zs, 'SUM', 'V', vmask, zs_crs, p_e12=e1v, p_e3=ze3v, p_surf_crs=e1e3v_msk, psgn=-1.0 )
155 
156      CALL iom_put( "voce"  , vn_crs )   ! i-current
157      CALL iom_put( "vocet" , zt_crs )   ! vT
158      CALL iom_put( "voces" , zs_crs )   ! vS
159
160      IF( iom_use( "eken") ) THEN     !      kinetic energy
161         z3d(:,:,jk) = 0._wp 
162         DO jk = 1, jpkm1
163            DO jj = 2, jpjm1
164               DO ji = fs_2, fs_jpim1   ! vector opt.
165                  zztmp  = r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
166                  z3d(ji,jj,jk) = 0.25_wp * zztmp * (                                    &
167                     &            un(ji-1,jj,jk)**2 * e2u(ji-1,jj) * e3u_n(ji-1,jj,jk)   &
168                     &          + un(ji  ,jj,jk)**2 * e2u(ji  ,jj) * e3u_n(ji  ,jj,jk)   &
169                     &          + vn(ji,jj-1,jk)**2 * e1v(ji,jj-1) * e3v_n(ji,jj-1,jk)   &
170                     &          + vn(ji,jj  ,jk)**2 * e1v(ji,jj  ) * e3v_n(ji,jj  ,jk)   )
171               END DO
172            END DO
173         END DO
174         CALL lbc_lnk( z3d, 'T', 1. )
175         !
176         CALL crs_dom_ope( z3d, 'VOL', 'T', tmask, zt_crs, p_e12=e1e2t, p_e3=ze3t, psgn=1.0 )
177         CALL iom_put( "eken", zt_crs )
178      ENDIF
179      !  Horizontal divergence ( following OPA_SRC/DYN/divhor.F90 )
180      DO jk = 1, jpkm1
181         DO ji = 2, jpi_crsm1
182            DO jj = 2, jpj_crsm1
183               IF( tmask_crs(ji,jj,jk ) > 0 ) THEN
184                   z2dcrsu =  ( un_crs(ji  ,jj  ,jk) * crs_surfu_wgt(ji  ,jj  ,jk) ) &
185                      &     - ( un_crs(ji-1,jj  ,jk) * crs_surfu_wgt(ji-1,jj  ,jk) )
186                   z2dcrsv =  ( vn_crs(ji  ,jj  ,jk) * crs_surfv_wgt(ji  ,jj  ,jk) ) &
187                      &     - ( vn_crs(ji  ,jj-1,jk) * crs_surfv_wgt(ji  ,jj-1,jk) )
188                   !
189                   hdivn_crs(ji,jj,jk) = ( z2dcrsu + z2dcrsv ) / crs_volt_wgt(ji,jj,jk) 
190               ENDIF
191            END DO
192         END DO
193      END DO
194      CALL crs_lbc_lnk( hdivn_crs, 'T', 1.0 )
195      !
196      CALL iom_put( "hdiv", hdivn_crs ) 
197
198
199      !  W-velocity
200      IF( ln_crs_wn ) THEN
201         CALL crs_dom_ope( wn, 'SUM', 'W', tmask, wn_crs, p_e12=e1e2t, p_surf_crs=e1e2w_msk, psgn=1.0 )
202       !  CALL crs_dom_ope( wn, 'VOL', 'W', tmask, wn_crs, p_e12=e1e2t, p_e3=ze3w )
203      ELSE
204        wn_crs(:,:,jpk) = 0._wp
205        DO jk = jpkm1, 1, -1
206           wn_crs(:,:,jk) = wn_crs(:,:,jk+1) - e3t_crs(:,:,jk) * hdivn_crs(:,:,jk)
207        ENDDO
208      ENDIF
209      CALL iom_put( "woce", wn_crs  )   ! vertical velocity
210      !  free memory
211
212      !  avs
213      SELECT CASE ( nn_crs_kz )
214         CASE ( 0 )
215            CALL crs_dom_ope( avt, 'VOL', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0 )
216            CALL crs_dom_ope( avs, 'VOL', 'W', tmask, avs_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0 )
217         CASE ( 1 )
218            CALL crs_dom_ope( avt, 'MAX', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0 )
219            CALL crs_dom_ope( avs, 'MAX', 'W', tmask, avs_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0 )
220         CASE ( 2 )
221            CALL crs_dom_ope( avt, 'MIN', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0 )
222            CALL crs_dom_ope( avs, 'MIN', 'W', tmask, avs_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0 )
223      END SELECT
224      !
225      CALL iom_put( "avt", avt_crs )   !  Kz on T
226      CALL iom_put( "avs", avs_crs )   !  Kz on S
227     
228      !  sbc fields 
229      CALL crs_dom_ope( sshn , 'VOL', 'T', tmask, sshn_crs , p_e12=e1e2t, p_e3=ze3t           , psgn=1.0 ) 
230      CALL crs_dom_ope( utau , 'SUM', 'U', umask, utau_crs , p_e12=e2u  , p_surf_crs=e2u_crs  , psgn=1.0 )
231      CALL crs_dom_ope( vtau , 'SUM', 'V', vmask, vtau_crs , p_e12=e1v  , p_surf_crs=e1v_crs  , psgn=1.0 )
232      CALL crs_dom_ope( wndm , 'SUM', 'T', tmask, wndm_crs , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
233      CALL crs_dom_ope( rnf  , 'MAX', 'T', tmask, rnf_crs                                     , psgn=1.0 )
234      CALL crs_dom_ope( qsr  , 'SUM', 'T', tmask, qsr_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
235      CALL crs_dom_ope( emp_b, 'SUM', 'T', tmask, emp_b_crs, p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
236      CALL crs_dom_ope( emp  , 'SUM', 'T', tmask, emp_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
237      CALL crs_dom_ope( sfx  , 'SUM', 'T', tmask, sfx_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
238      CALL crs_dom_ope( fr_i , 'SUM', 'T', tmask, fr_i_crs , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
239
240      CALL iom_put( "ssh"      , sshn_crs )   ! ssh output
241      CALL iom_put( "utau"     , utau_crs )   ! i-tau output
242      CALL iom_put( "vtau"     , vtau_crs )   ! j-tau output
243      CALL iom_put( "wspd"     , wndm_crs )   ! wind speed output
244      CALL iom_put( "runoffs"  , rnf_crs  )   ! runoff output
245      CALL iom_put( "qsr"      , qsr_crs  )   ! qsr output
246      CALL iom_put( "empmr"    , emp_crs  )   ! water flux output
247      CALL iom_put( "saltflx"  , sfx_crs  )   ! salt flux output
248      CALL iom_put( "ice_cover", fr_i_crs )   ! ice cover output
249
250      !  free memory
251      CALL wrk_dealloc( jpi,jpj,jpk,   ze3t, ze3w )
252      CALL wrk_dealloc( jpi,jpj,jpk,   ze3u, ze3v )
253      CALL wrk_dealloc( jpi,jpj,jpk,   zt  , zs   )
254      CALL wrk_dealloc( jpi_crs,jpj_crs,jpk,   zt_crs, zs_crs )
255      !
256      CALL iom_swap( "nemo" )     ! return back on high-resolution grid
257      !
258      IF( nn_timing == 1 )   CALL timing_stop('crs_fld')
259      !
260   END SUBROUTINE crs_fld
261
262   !!======================================================================
263END MODULE crsfld
Note: See TracBrowser for help on using the repository browser.