New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_cen.F90 in branches/2017/dev_r7881_ENHANCE09_RK3/NEMOGCM/NEMO/RK3_SRC/TRA – NEMO

source: branches/2017/dev_r7881_ENHANCE09_RK3/NEMOGCM/NEMO/RK3_SRC/TRA/traadv_cen.F90 @ 8568

Last change on this file since 8568 was 8568, checked in by gm, 7 years ago

#1911 (ENHANCE-09): PART I.2 - _NONE option + remove zts + see associated wiki page
File size: 10.8 KB
Line 
1MODULE traadv_cen
2   !!======================================================================
3   !!                     ***  MODULE  traadv_cen  ***
4   !! Ocean  tracers:   advective trend (2nd/4th order centered)
5   !!======================================================================
6   !! History :  3.7  ! 2014-05  (G. Madec)  original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   tra_adv_cen   : update the tracer trend with the advection trends using a centered or scheme (2nd or 4th order)
11   !!                   NB: on the vertical it is actually a 4th order COMPACT scheme which is used
12   !!----------------------------------------------------------------------
13   USE dom_oce        ! ocean space and time domain
14   USE eosbn2         ! equation of state
15   USE traadv_fct     ! acces to routine interp_4th_cpt
16   USE trd_oce        ! trends: ocean variables
17   USE trdtra         ! trends manager: tracers
18   USE diaptr         ! poleward transport diagnostics
19   USE diaar5         ! AR5 diagnostics
20   !
21   USE in_out_manager ! I/O manager
22   USE iom            ! IOM library
23   USE trc_oce        ! share passive tracers/Ocean variables
24   USE lib_mpp        ! MPP library
25   USE timing         ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   tra_adv_cen   ! called by traadv.F90
31   
32   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
33
34   LOGICAL ::   l_trd   ! flag to compute trends
35   LOGICAL ::   l_ptr   ! flag to compute poleward transport
36   LOGICAL ::   l_hst   ! flag to compute heat/salt transport
37
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 4.0, NEMO Consortium (2017)
42   !! $Id:$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_adv_cen( kt, kit000, cdtype, pun, pvn, pwn,     &
48      &                                        ptn, pta, kjpt, kn_cen_h, kn_cen_v ) 
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE tra_adv_cen  ***
51      !!                 
52      !! ** Purpose :   Compute the now trend due to the advection of tracers
53      !!      and add it to the general trend of passive tracer equations.
54      !!
55      !! ** Method  :   The advection is evaluated by a 2nd or 4th order scheme
56      !!               using now fields (leap-frog scheme).
57      !!       kn_cen_h = 2  ==>> 2nd order centered scheme on the horizontal
58      !!                = 4  ==>> 4th order    -        -       -      -
59      !!       kn_cen_v = 2  ==>> 2nd order centered scheme on the vertical
60      !!                = 4  ==>> 4th order COMPACT  scheme     -      -
61      !!
62      !! ** Action : - update pta  with the now advective tracer trends
63      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
64      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
65      !!----------------------------------------------------------------------
66      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
70      INTEGER                              , INTENT(in   ) ::   kn_cen_h        ! =2/4 (2nd or 4th order scheme)
71      INTEGER                              , INTENT(in   ) ::   kn_cen_v        ! =2/4 (2nd or 4th order scheme)
72      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
73      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptn             ! now tracer fields
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
75      !
76      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
77      INTEGER  ::   ierr             ! local integer
78      REAL(wp) ::   zC2t_u, zC4t_u   ! local scalars
79      REAL(wp) ::   zC2t_v, zC4t_v   !   -      -
80      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwx, zwy, zwz, ztu, ztv, ztw
81      !!----------------------------------------------------------------------
82      !
83      IF( ln_timing )   CALL timing_start('tra_adv_cen')
84      !
85      IF( kt == kit000 )  THEN
86         IF(lwp) WRITE(numout,*)
87         IF(lwp) WRITE(numout,*) 'tra_adv_cen : centered advection scheme on ', cdtype, ' order h/v =', kn_cen_h,'/', kn_cen_v
88         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
89      ENDIF
90      !                          ! set local switches
91      l_trd = .FALSE.
92      l_hst = .FALSE.
93      l_ptr = .FALSE.
94      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )        l_trd = .TRUE.
95      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                                 l_ptr = .TRUE. 
96      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
97         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )   l_hst = .TRUE.
98      !
99      !                   
100      zwz(:,:, 1 ) = 0._wp       ! surface & bottom vertical flux set to zero for all tracers
101      zwz(:,:,jpk) = 0._wp
102      !
103      DO jn = 1, kjpt            !==  loop over the tracers  ==!
104         !
105         SELECT CASE( kn_cen_h )       !--  Horizontal fluxes  --!
106         !
107         CASE(  2  )                         !* 2nd order centered
108            DO jk = 1, jpkm1
109               DO jj = 1, jpjm1
110                  DO ji = 1, fs_jpim1   ! vector opt.
111                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn) )
112                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn) )
113                  END DO
114               END DO
115            END DO
116            !
117         CASE(  4  )                         !* 4th order centered
118            ztu(:,:,jpk) = 0._wp                   ! Bottom value : flux set to zero
119            ztv(:,:,jpk) = 0._wp
120            DO jk = 1, jpkm1                       ! masked gradient
121               DO jj = 2, jpjm1
122                  DO ji = fs_2, fs_jpim1   ! vector opt.
123                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
124                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
125                  END DO
126               END DO
127            END DO
128            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond.
129            !
130            DO jk = 1, jpkm1                       ! Horizontal advective fluxes
131               DO jj = 2, jpjm1
132                  DO ji = 1, fs_jpim1   ! vector opt.
133                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! C2 interpolation of T at u- & v-points (x2)
134                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
135                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
136                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj,jk) - ztu(ji+1,jj,jk) )
137                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji,jj-1,jk) - ztv(ji,jj+1,jk) )
138                     !                                                  ! C4 fluxes
139                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u
140                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v
141                  END DO
142               END DO
143            END DO         
144            !
145         CASE DEFAULT
146            CALL ctl_stop( 'traadv_fct: wrong value for nn_fct' )
147         END SELECT
148         !
149         SELECT CASE( kn_cen_v )       !--  Vertical fluxes  --!   (interior)
150         !
151         CASE(  2  )                         !* 2nd order centered
152            DO jk = 2, jpk
153               DO jj = 2, jpjm1
154                  DO ji = fs_2, fs_jpim1   ! vector opt.
155                     zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
156                  END DO
157               END DO
158            END DO
159            !
160         CASE(  4  )                         !* 4th order compact
161            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )      ! ztw = interpolated value of T at w-point
162            DO jk = 2, jpkm1
163               DO jj = 2, jpjm1
164                  DO ji = fs_2, fs_jpim1
165                     zwz(ji,jj,jk) = pwn(ji,jj,jk) * ztw(ji,jj,jk) * wmask(ji,jj,jk)
166                  END DO
167               END DO
168            END DO
169            !
170         END SELECT
171         !
172         IF( ln_linssh ) THEN                !* top value   (linear free surf. only as zwz is multiplied by wmask)
173            IF( ln_isfcav ) THEN                  ! ice-shelf cavities (top of the ocean)
174               DO jj = 1, jpj
175                  DO ji = 1, jpi
176                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptn(ji,jj,mikt(ji,jj),jn) 
177                  END DO
178               END DO   
179            ELSE                                   ! no ice-shelf cavities (only ocean surface)
180               zwz(:,:,1) = pwn(:,:,1) * ptn(:,:,1,jn)
181            ENDIF
182         ENDIF
183         !               
184         DO jk = 1, jpkm1              !--  Divergence of advective fluxes  --!
185            DO jj = 2, jpjm1
186               DO ji = fs_2, fs_jpim1   ! vector opt.
187                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn)    &
188                     &             - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )    &
189                     &                + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )    &
190                     &                + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)  ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
191               END DO
192            END DO
193         END DO
194         !                             ! trend diagnostics
195         IF( l_trd ) THEN
196            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptn(:,:,:,jn) )
197            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptn(:,:,:,jn) )
198            CALL trd_tra( kt, cdtype, jn, jptra_zad, zwz, pwn, ptn(:,:,:,jn) )
199         END IF
200         !                                 ! "Poleward" heat and salt transports
201         IF( l_ptr )   CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
202         !                                 !  heat and salt transport
203         IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
204         !
205      END DO
206      !
207      IF( ln_timing )   CALL timing_stop('tra_adv_cen')
208      !
209   END SUBROUTINE tra_adv_cen
210   
211   !!======================================================================
212END MODULE traadv_cen
Note: See TracBrowser for help on using the repository browser.