New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap_blp.F90 in branches/2017/dev_r7881_ENHANCE09_RK3/NEMOGCM/NEMO/RK3_SRC/TRA – NEMO

source: branches/2017/dev_r7881_ENHANCE09_RK3/NEMOGCM/NEMO/RK3_SRC/TRA/traldf_lap_blp.F90 @ 8568

Last change on this file since 8568 was 8568, checked in by gm, 7 years ago

#1911 (ENHANCE-09): PART I.2 - _NONE option + remove zts + see associated wiki page
  • Property svn:keywords set to Id
File size: 14.4 KB
Line 
1MODULE traldf_lap_blp
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap_blp  ***
4   !! Ocean tracers:  lateral diffusivity trend  (laplacian and bilaplacian)
5   !!==============================================================================
6   !! History :  3.7  ! 2014-01  (G. Madec, S. Masson)  Original code, re-entrant laplacian
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_lap   : tracer trend update with iso-level laplacian diffusive operator
11   !!   tra_ldf_blp   : tracer trend update with iso-level or iso-neutral bilaplacian operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and active tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ldftra         ! lateral physics: eddy diffusivity
16   USE traldf_iso     ! iso-neutral lateral diffusion (standard operator)     (tra_ldf_iso   routine)
17   USE traldf_triad   ! iso-neutral lateral diffusion (triad    operator)     (tra_ldf_triad routine)
18   USE diaptr         ! poleward transport diagnostics
19   USE diaar5         ! AR5 diagnostics
20   USE trc_oce        ! share passive tracers/Ocean variables
21   USE zpshde         ! partial step: hor. derivative     (zps_hde routine)
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O library
25   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
26   USE lib_mpp        ! distribued memory computing library
27   USE timing         ! Timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_ldf_lap   ! called by traldf.F90
33   PUBLIC   tra_ldf_blp   ! called by traldf.F90
34
35   !                      ! Flag to control the type of lateral diffusive operator
36   INTEGER, PARAMETER, PUBLIC ::   np_ERROR  =-10   ! error in specification of lateral diffusion
37   INTEGER, PARAMETER, PUBLIC ::   np_no_ldf = 00   ! without operator (i.e. no lateral diffusive trend)
38   !                          !!      laplacian     !    bilaplacian    !
39   INTEGER, PARAMETER, PUBLIC ::   np_lap    = 10   ,   np_blp    = 20  ! iso-level operator
40   INTEGER, PARAMETER, PUBLIC ::   np_lap_i  = 11   ,   np_blp_i  = 21  ! standard iso-neutral or geopotential operator
41   INTEGER, PARAMETER, PUBLIC ::   np_lap_it = 12   ,   np_blp_it = 22  ! triad    iso-neutral or geopotential operator
42
43   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
44   LOGICAL  ::   l_hst   ! flag to compute heat transport
45
46   !! * Substitutions
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_ldf_lap( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
56      &                                                    pgui, pgvi,   &
57      &                                        ptb , pta , kjpt, kpass ) 
58      !!----------------------------------------------------------------------
59      !!                  ***  ROUTINE tra_ldf_lap  ***
60      !!                   
61      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
62      !!      trend and add it to the general trend of tracer equation.
63      !!
64      !! ** Method  :   Second order diffusive operator evaluated using before
65      !!      fields (forward time scheme). The horizontal diffusive trends of
66      !!      the tracer is given by:
67      !!          difft = 1/(e1e2t*e3t) {  di-1[ pahu e2u*e3u/e1u di(tb) ]
68      !!                                 + dj-1[ pahv e1v*e3v/e2v dj(tb) ] }
69      !!      Add this trend to the general tracer trend pta :
70      !!          pta = pta + difft
71      !!
72      !! ** Action  : - Update pta arrays with the before iso-level
73      !!                harmonic mixing trend.
74      !!----------------------------------------------------------------------
75      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
76      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
77      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
78      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
79      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
80      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
81      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
82      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
83      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
85      !
86      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
87      REAL(wp) ::   zsign            ! local scalars
88      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztu, ztv, zaheeu, zaheev
89      !!----------------------------------------------------------------------
90      !
91      IF( ln_timing )   CALL timing_start('tra_ldf_lap')
92      !
93      IF( kt == nit000 .AND. lwp )  THEN
94         WRITE(numout,*)
95         WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype, ', pass=', kpass
96         WRITE(numout,*) '~~~~~~~~~~~ '
97      ENDIF
98      !
99      l_hst = .FALSE.
100      l_ptr = .FALSE.
101      IF( cdtype == 'TRA' .AND. ln_diaptr )                                                l_ptr = .TRUE. 
102      IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
103         &                        iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
104      !
105      !                                !==  Initialization of metric arrays used for all tracers  ==!
106      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
107      ELSE                    ;   zsign = -1._wp
108      ENDIF
109      DO jk = 1, jpkm1
110         DO jj = 1, jpjm1
111            DO ji = 1, fs_jpim1   ! vector opt.
112               zaheeu(ji,jj,jk) = zsign * pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u_n(ji,jj,jk)   !!gm   * umask(ji,jj,jk) pah masked!
113               zaheev(ji,jj,jk) = zsign * pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v_n(ji,jj,jk)   !!gm   * vmask(ji,jj,jk)
114            END DO
115         END DO
116      END DO
117      !
118      !                             ! =========== !
119      DO jn = 1, kjpt               ! tracer loop !
120         !                          ! =========== !   
121         !                               
122         DO jk = 1, jpkm1              !== First derivative (gradient)  ==!
123            DO jj = 1, jpjm1
124               DO ji = 1, fs_jpim1
125                  ztu(ji,jj,jk) = zaheeu(ji,jj,jk) * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
126                  ztv(ji,jj,jk) = zaheev(ji,jj,jk) * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
127               END DO
128            END DO
129         END DO 
130         IF( ln_zps ) THEN                ! set gradient at bottom/top ocean level
131            DO jj = 1, jpjm1                    ! bottom
132               DO ji = 1, fs_jpim1
133                  ztu(ji,jj,mbku(ji,jj)) = zaheeu(ji,jj,mbku(ji,jj)) * pgu(ji,jj,jn)
134                  ztv(ji,jj,mbkv(ji,jj)) = zaheev(ji,jj,mbkv(ji,jj)) * pgv(ji,jj,jn)
135               END DO
136            END DO 
137            IF( ln_isfcav ) THEN                ! top in ocean cavities only
138               DO jj = 1, jpjm1
139                  DO ji = 1, fs_jpim1   ! vector opt.
140                     IF( miku(ji,jj) > 1 )   ztu(ji,jj,miku(ji,jj)) = zaheeu(ji,jj,miku(ji,jj)) * pgui(ji,jj,jn) 
141                     IF( mikv(ji,jj) > 1 )   ztv(ji,jj,mikv(ji,jj)) = zaheev(ji,jj,mikv(ji,jj)) * pgvi(ji,jj,jn) 
142                  END DO
143               END DO
144            ENDIF
145         ENDIF
146         !
147         DO jk = 1, jpkm1              !== Second derivative (divergence) added to the general tracer trends  ==!
148            DO jj = 2, jpjm1
149               DO ji = fs_2, fs_jpim1
150                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)     &
151                     &                                   + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )   &
152                     &                                / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) )
153               END DO
154            END DO
155         END DO 
156         !
157         !                             !== "Poleward" diffusive heat or salt transports  ==!
158         IF( ( kpass == 1 .AND. .NOT.ln_traldf_blp ) .OR.  &     !==  first pass only (  laplacian)  ==!
159             ( kpass == 2 .AND.      ln_traldf_blp ) ) THEN      !==  2nd   pass only (bilaplacian)  ==!
160
161            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', -ztv(:,:,:)  )
162            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', -ztu(:,:,:), -ztv(:,:,:) )
163         ENDIF
164         !                          ! ==================
165      END DO                        ! end of tracer loop
166      !                             ! ==================
167      !
168      IF( ln_timing )   CALL timing_stop('tra_ldf_lap')
169      !
170   END SUBROUTINE tra_ldf_lap
171   
172
173   SUBROUTINE tra_ldf_blp( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
174      &                                                    pgui, pgvi,   &
175      &                                                    ptb , pta , kjpt, kldf )
176      !!----------------------------------------------------------------------
177      !!                 ***  ROUTINE tra_ldf_blp  ***
178      !!                   
179      !! ** Purpose :   Compute the before lateral tracer diffusive
180      !!      trend and add it to the general trend of tracer equation.
181      !!
182      !! ** Method  :   The lateral diffusive trends is provided by a bilaplacian
183      !!      operator applied to before field (forward in time).
184      !!      It is computed by two successive calls to laplacian routine
185      !!
186      !! ** Action :   pta   updated with the before rotated bilaplacian diffusion
187      !!----------------------------------------------------------------------
188      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
189      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
190      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
191      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
192      INTEGER                              , INTENT(in   ) ::   kldf       ! type of operator used
193      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
194      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
195      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top levels
196      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
197      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
198      !
199      INTEGER ::   ji, jj, jk, jn   ! dummy loop indices
200      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt) :: zlap         ! laplacian at t-point
201      REAL(wp), DIMENSION(jpi,jpj,    kjpt) :: zglu, zglv   ! bottom GRADh of the laplacian (u- and v-points)
202      REAL(wp), DIMENSION(jpi,jpj,    kjpt) :: zgui, zgvi   ! top    GRADh of the laplacian (u- and v-points)
203      !!---------------------------------------------------------------------
204      !
205      IF( ln_timing )   CALL timing_start('tra_ldf_blp')
206      !
207      IF( kt == kit000 .AND. lwp )  THEN
208         WRITE(numout,*)
209         SELECT CASE ( kldf )
210         CASE ( np_blp    )   ;   WRITE(numout,*) 'tra_ldf_blp : iso-level   bilaplacian operator on ', cdtype
211         CASE ( np_blp_i  )   ;   WRITE(numout,*) 'tra_ldf_blp : iso-neutral bilaplacian operator on ', cdtype, ' (Standard)'
212         CASE ( np_blp_it )   ;   WRITE(numout,*) 'tra_ldf_blp : iso-neutral bilaplacian operator on ', cdtype, ' (triad)'
213         END SELECT
214         WRITE(numout,*) '~~~~~~~~~~~'
215      ENDIF
216
217      zlap(:,:,:,:) = 0._wp
218      !
219      SELECT CASE ( kldf )       !==  1st laplacian applied to ptb (output in zlap)  ==!
220      !
221      CASE ( np_blp    )               ! iso-level bilaplacian
222         CALL tra_ldf_lap  ( kt, kit000, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, ptb,      zlap, kjpt, 1 )
223      CASE ( np_blp_i  )               ! rotated   bilaplacian : standard operator (Madec)
224         CALL tra_ldf_iso  ( kt, kit000, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, ptb, ptb, zlap, kjpt, 1 )
225      CASE ( np_blp_it )               ! rotated  bilaplacian : triad operator (griffies)
226         CALL tra_ldf_triad( kt, kit000, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, ptb, ptb, zlap, kjpt, 1 )
227      END SELECT
228      !
229      DO jn = 1, kjpt
230         CALL lbc_lnk( zlap(:,:,:,jn) , 'T', 1. )     ! Lateral boundary conditions (unchanged sign)
231      END DO
232      !                                               ! Partial top/bottom cell: GRADh( zlap ) 
233      IF( ln_isfcav .AND. ln_zps ) THEN   ;   CALL zps_hde_isf( kt, kjpt, zlap, zglu, zglv, zgui, zgvi )  ! both top & bottom
234      ELSEIF(             ln_zps ) THEN   ;   CALL zps_hde    ( kt, kjpt, zlap, zglu, zglv )              ! only bottom
235      ENDIF
236      !
237      SELECT CASE ( kldf )       !==  2nd laplacian applied to zlap (output in pta)  ==!
238      !
239      CASE ( np_blp    )               ! iso-level bilaplacian
240         CALL tra_ldf_lap  ( kt, kit000, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, pta,      kjpt, 2 )
241      CASE ( np_blp_i  )               ! rotated   bilaplacian : standard operator (Madec)
242         CALL tra_ldf_iso  ( kt, kit000, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, ptb, pta, kjpt, 2 )
243      CASE ( np_blp_it )               ! rotated  bilaplacian : triad operator (griffies)
244         CALL tra_ldf_triad( kt, kit000, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, ptb, pta, kjpt, 2 )
245      END SELECT
246      !
247      IF( ln_timing )   CALL timing_stop('tra_ldf_blp')
248      !
249   END SUBROUTINE tra_ldf_blp
250
251   !!==============================================================================
252END MODULE traldf_lap_blp
Note: See TracBrowser for help on using the repository browser.