New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf.F90 in branches/2017/dev_r7881_HPC09_ZDF/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2017/dev_r7881_HPC09_ZDF/NEMOGCM/NEMO/OPA_SRC/DYN/dynldf.F90 @ 7953

Last change on this file since 7953 was 7753, checked in by mocavero, 7 years ago

Reverting trunk to remove OpenMP
  • Property svn:keywords set to Id
File size: 10.3 KB
Line 
1MODULE dynldf
2   !!======================================================================
3   !!                       ***  MODULE  dynldf  ***
4   !! Ocean physics:  lateral diffusivity trends
5   !!=====================================================================
6   !! History :  2.0  ! 2005-11  (G. Madec)  Original code (new step architecture)
7   !!            3.7  ! 2014-01  (F. Lemarie, G. Madec)  restructuration/simplification of ahm specification,
8   !!                 !                                  add velocity dependent coefficient and optional read in file
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_ldf      : update the dynamics trend with the lateral diffusion
13   !!   dyn_ldf_init : initialization, namelist read, and parameters control
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE phycst         ! physical constants
18   USE ldfdyn         ! lateral diffusion: eddy viscosity coef.
19   USE ldfslp         ! lateral diffusion: slopes of mixing orientation
20   USE dynldf_lap_blp ! lateral mixing   (dyn_ldf_lap & dyn_ldf_blp routines)
21   USE dynldf_iso     ! lateral mixing                 (dyn_ldf_iso routine )
22   USE trd_oce        ! trends: ocean variables
23   USE trddyn         ! trend manager: dynamics   (trd_dyn      routine)
24   !
25   USE prtctl         ! Print control
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! distribued memory computing library
28   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
29   USE wrk_nemo       ! Memory Allocation
30   USE timing         ! Timing
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   dyn_ldf       ! called by step module
36   PUBLIC   dyn_ldf_init  ! called by opa  module
37
38   !                      ! Parameter to control the type of lateral viscous operator
39   INTEGER, PARAMETER, PUBLIC ::   np_ERROR  =-10   ! error in setting the operator
40   INTEGER, PARAMETER, PUBLIC ::   np_no_ldf = 00   ! without operator (i.e. no lateral viscous trend)
41   !                          !!      laplacian     !    bilaplacian    !
42   INTEGER, PARAMETER, PUBLIC ::   np_lap    = 10   ,   np_blp    = 20  ! iso-level operator
43   INTEGER, PARAMETER, PUBLIC ::   np_lap_i  = 11                       ! iso-neutral or geopotential operator
44
45   INTEGER ::   nldf   ! type of lateral diffusion used defined from ln_dynldf_... (namlist logicals)
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE dyn_ldf( kt )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE dyn_ldf  ***
59      !!
60      !! ** Purpose :   compute the lateral ocean dynamics physics.
61      !!----------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
63      !
64      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
65      !!----------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )  CALL timing_start('dyn_ldf')
68      !
69      IF( l_trddyn )   THEN                      ! temporary save of momentum trends
70         CALL wrk_alloc( jpi,jpj,jpk,   ztrdu, ztrdv )
71         ztrdu(:,:,:) = ua(:,:,:) 
72         ztrdv(:,:,:) = va(:,:,:) 
73      ENDIF
74
75      SELECT CASE ( nldf )                       ! compute lateral mixing trend and add it to the general trend
76      !
77      CASE ( np_lap   )    ;   CALL dyn_ldf_lap  ( kt, ub, vb, ua, va, 1 )      ! iso-level    laplacian
78      CASE ( np_lap_i )    ;   CALL dyn_ldf_iso  ( kt )                         ! rotated      laplacian
79      CASE ( np_blp   )    ;   CALL dyn_ldf_blp  ( kt, ub, vb, ua, va    )      ! iso-level bi-laplacian
80      !
81      END SELECT
82
83      IF( l_trddyn ) THEN                        ! save the horizontal diffusive trends for further diagnostics
84         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
85         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
86         CALL trd_dyn( ztrdu, ztrdv, jpdyn_ldf, kt )
87         CALL wrk_dealloc( jpi,jpj,jpk,   ztrdu, ztrdv )
88      ENDIF
89      !                                          ! print sum trends (used for debugging)
90      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' ldf  - Ua: ', mask1=umask,   &
91         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
92      !
93      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf')
94      !
95   END SUBROUTINE dyn_ldf
96
97
98   SUBROUTINE dyn_ldf_init
99      !!----------------------------------------------------------------------
100      !!                  ***  ROUTINE dyn_ldf_init  ***
101      !!
102      !! ** Purpose :   initializations of the horizontal ocean dynamics physics
103      !!----------------------------------------------------------------------
104      INTEGER ::   ioptio, ierr         ! temporary integers
105      !!----------------------------------------------------------------------
106      !
107      !                                   ! Namelist nam_dynldf: already read in ldfdyn module
108      !
109      IF(lwp) THEN                        ! Namelist print
110         WRITE(numout,*)
111         WRITE(numout,*) 'dyn_ldf_init : Choice of the lateral diffusive operator on dynamics'
112         WRITE(numout,*) '~~~~~~~~~~~~'
113         WRITE(numout,*) '   Namelist nam_dynldf : set lateral mixing parameters (type, direction, coefficients)'
114         WRITE(numout,*) '      laplacian operator          ln_dynldf_lap = ', ln_dynldf_lap
115         WRITE(numout,*) '      bilaplacian operator        ln_dynldf_blp = ', ln_dynldf_blp
116         WRITE(numout,*) '      iso-level                   ln_dynldf_lev = ', ln_dynldf_lev
117         WRITE(numout,*) '      horizontal (geopotential)   ln_dynldf_hor = ', ln_dynldf_hor
118         WRITE(numout,*) '      iso-neutral                 ln_dynldf_iso = ', ln_dynldf_iso
119      ENDIF
120      !                                   ! use of lateral operator or not
121      nldf = np_ERROR
122      ioptio = 0
123      IF( ln_dynldf_lap )   ioptio = ioptio + 1
124      IF( ln_dynldf_blp )   ioptio = ioptio + 1
125      IF( ioptio >  1   )   CALL ctl_stop( 'dyn_ldf_init: use ONE or NONE of the 2 lap/bilap operator type on momentum' )
126      IF( ioptio == 0   )   nldf = np_no_ldf     ! No lateral mixing operator
127      !
128      IF( nldf /= np_no_ldf ) THEN        ! direction ==>> type of operator 
129         ioptio = 0
130         IF( ln_dynldf_lev )   ioptio = ioptio + 1
131         IF( ln_dynldf_hor )   ioptio = ioptio + 1
132         IF( ln_dynldf_iso )   ioptio = ioptio + 1
133         IF( ioptio >  1   )   CALL ctl_stop( '          use only ONE direction (level/hor/iso)' )
134         IF( ioptio == 0   )   CALL ctl_stop( '          use at least ONE direction (level/hor/iso)' )
135         !
136         !                                   ! Set nldf, the type of lateral diffusion, from ln_dynldf_... logicals
137         ierr = 0
138         IF ( ln_dynldf_lap ) THEN      ! laplacian operator
139            IF ( ln_zco ) THEN                ! z-coordinate
140               IF ( ln_dynldf_lev )   nldf = np_lap     ! iso-level = horizontal (no rotation)
141               IF ( ln_dynldf_hor )   nldf = np_lap     ! iso-level = horizontal (no rotation)
142               IF ( ln_dynldf_iso )   nldf = np_lap_i   ! iso-neutral            (   rotation)
143            ENDIF
144            IF ( ln_zps ) THEN             ! z-coordinate with partial step
145               IF ( ln_dynldf_lev )   nldf = np_lap     ! iso-level              (no rotation)
146               IF ( ln_dynldf_hor )   nldf = np_lap     ! iso-level              (no rotation)
147               IF ( ln_dynldf_iso )   nldf = np_lap_i   ! iso-neutral            (   rotation)
148            ENDIF
149            IF ( ln_sco ) THEN             ! s-coordinate
150               IF ( ln_dynldf_lev )   nldf = np_lap     ! iso-level = horizontal (no rotation)
151               IF ( ln_dynldf_hor )   nldf = np_lap_i   ! horizontal             (   rotation)
152               IF ( ln_dynldf_iso )   nldf = np_lap_i   ! iso-neutral            (   rotation)
153            ENDIF
154         ENDIF
155         !
156         IF( ln_dynldf_blp ) THEN          ! bilaplacian operator
157            IF ( ln_zco ) THEN                ! z-coordinate
158               IF ( ln_dynldf_lev )   nldf = np_blp     ! iso-level = horizontal (no rotation)
159               IF ( ln_dynldf_hor )   nldf = np_blp     ! iso-level = horizontal (no rotation)
160               IF ( ln_dynldf_iso )   ierr = 2          ! iso-neutral            (   rotation)
161            ENDIF
162            IF ( ln_zps ) THEN             ! z-coordinate with partial step
163               IF ( ln_dynldf_lev )   nldf = np_blp     ! iso-level              (no rotation)
164               IF ( ln_dynldf_hor )   nldf = np_blp     ! iso-level              (no rotation)
165               IF ( ln_dynldf_iso )   ierr = 2          ! iso-neutral            (   rotation)
166            ENDIF
167            IF ( ln_sco ) THEN             ! s-coordinate
168               IF ( ln_dynldf_lev )   nldf = np_blp     ! iso-level              (no rotation)
169               IF ( ln_dynldf_hor )   ierr = 2          ! horizontal             (   rotation)
170               IF ( ln_dynldf_iso )   ierr = 2          ! iso-neutral            (   rotation)
171            ENDIF
172         ENDIF
173         !
174         IF( ierr == 2 )   CALL ctl_stop( 'rotated bi-laplacian operator does not exist' )
175         !
176         IF( nldf == np_lap_i )   l_ldfslp = .TRUE.      ! rotation require the computation of the slopes
177         !
178      ENDIF
179
180      IF(lwp) THEN
181         WRITE(numout,*)
182         IF( nldf == np_no_ldf )   WRITE(numout,*) '      ===>>   NO lateral viscosity'
183         IF( nldf == np_lap    )   WRITE(numout,*) '      ===>>   iso-level laplacian operator'
184         IF( nldf == np_lap_i  )   WRITE(numout,*) '      ===>>   rotated laplacian operator with iso-level background'
185         IF( nldf == np_blp    )   WRITE(numout,*) '      ===>>   iso-level bi-laplacian operator'
186      ENDIF
187      !
188   END SUBROUTINE dyn_ldf_init
189
190   !!======================================================================
191END MODULE dynldf
Note: See TracBrowser for help on using the repository browser.