source: branches/2017/dev_r7881_HPC09_ZDF/NEMOGCM/NEMO/OPA_SRC/DYN/dynzdf.F90 @ 7953

Last change on this file since 7953 was 7953, checked in by gm, 3 years ago

#1880 (HPC-09): add zdfphy (the ZDF manager) + remove all key_…

  • Property svn:keywords set to Id
File size: 5.9 KB
Line 
1MODULE dynzdf
2   !!==============================================================================
3   !!                 ***  MODULE  dynzdf  ***
4   !! Ocean dynamics :  vertical component of the momentum mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dyn_zdf       : Update the momentum trend with the vertical diffusion
12   !!   dyn_zdf_init  : initializations of the vertical diffusion scheme
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE zdf_oce        ! ocean vertical physics variables
17   USE dynzdf_exp     ! vertical diffusion: explicit (dyn_zdf_exp     routine)
18   USE dynzdf_imp     ! vertical diffusion: implicit (dyn_zdf_imp     routine)
19   USE ldfdyn         ! lateral diffusion: eddy viscosity coef.
20   USE trd_oce        ! trends: ocean variables
21   USE trddyn         ! trend manager: dynamics
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE prtctl         ! Print control
26   USE wrk_nemo       ! Memory Allocation
27   USE timing         ! Timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   dyn_zdf       !  routine called by step.F90
33   PUBLIC   dyn_zdf_init  !  routine called by opa.F90
34
35   INTEGER  ::   nzdf = 0   ! type vertical diffusion algorithm used, defined from ln_zdf... namlist logicals
36
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44
45CONTAINS
46   
47   SUBROUTINE dyn_zdf( kt )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE dyn_zdf  ***
50      !!
51      !! ** Purpose :   compute the vertical ocean dynamics physics.
52      !!---------------------------------------------------------------------
53      !!
54      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index
55      !
56      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
57      !!---------------------------------------------------------------------
58      !
59      IF( nn_timing == 1 )   CALL timing_start('dyn_zdf')
60      !
61      !                                          ! set time step
62      IF( neuler == 0 .AND. kt == nit000     ) THEN   ;   r2dt =      rdt   ! = rdt (restart with Euler time stepping)
63      ELSEIF(               kt <= nit000 + 1 ) THEN   ;   r2dt = 2. * rdt   ! = 2 rdt (leapfrog)
64      ENDIF
65
66      IF( l_trddyn )   THEN                      ! temporary save of ta and sa trends
67         CALL wrk_alloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
68         ztrdu(:,:,:) = ua(:,:,:)
69         ztrdv(:,:,:) = va(:,:,:)
70      ENDIF
71
72      SELECT CASE ( nzdf )                       ! compute lateral mixing trend and add it to the general trend
73      !
74      CASE ( 0 )   ;   CALL dyn_zdf_exp( kt, r2dt )      ! explicit scheme
75      CASE ( 1 )   ;   CALL dyn_zdf_imp( kt, r2dt )      ! implicit scheme
76      !
77      END SELECT
78
79      IF( l_trddyn )   THEN                      ! save the vertical diffusive trends for further diagnostics
80         ztrdu(:,:,:) = ( ua(:,:,:) - ub(:,:,:) ) / r2dt - ztrdu(:,:,:)
81         ztrdv(:,:,:) = ( va(:,:,:) - vb(:,:,:) ) / r2dt - ztrdv(:,:,:)
82         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zdf, kt )
83         CALL wrk_dealloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
84      ENDIF
85      !                                          ! print mean trends (used for debugging)
86      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' zdf  - Ua: ', mask1=umask,               &
87         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
88         !
89      IF( nn_timing == 1 )   CALL timing_stop('dyn_zdf')
90      !
91   END SUBROUTINE dyn_zdf
92
93
94   SUBROUTINE dyn_zdf_init
95      !!----------------------------------------------------------------------
96      !!                 ***  ROUTINE dyn_zdf_init  ***
97      !!
98      !! ** Purpose :   initialization of the vertical diffusion scheme
99      !!
100      !! ** Method  :   implicit (euler backward) scheme (default)
101      !!                explicit (time-splitting) scheme if ln_zdfexp=T
102      !!----------------------------------------------------------------------
103      USE zdftke
104      USE zdfgls
105      !!----------------------------------------------------------------------
106      !
107      ! Choice from ln_zdfexp (namzdf namelist variable read in zdfphy module)
108      IF( ln_zdfexp ) THEN   ;   nzdf = 0           ! use explicit scheme
109      ELSE                   ;   nzdf = 1           ! use implicit scheme
110      ENDIF
111      !
112      ! Force implicit schemes
113      IF( ln_zdftke .OR. ln_zdfgls   )   nzdf = 1   ! TKE or GLS physics
114      IF( ln_dynldf_iso              )   nzdf = 1   ! iso-neutral lateral physics
115      IF( ln_dynldf_hor .AND. ln_sco )   nzdf = 1   ! horizontal lateral physics in s-coordinate
116      !
117      IF(lwp) THEN                                  ! Print the choice
118         WRITE(numout,*)
119         WRITE(numout,*) 'dyn_zdf_init : vertical dynamics physics scheme'
120         WRITE(numout,*) '~~~~~~~~~~~'
121         IF( nzdf ==  0 )   WRITE(numout,*) '      ===>>   Explicit time-splitting scheme'
122         IF( nzdf ==  1 )   WRITE(numout,*) '      ===>>   Implicit (euler backward) scheme'
123      ENDIF
124      !
125   END SUBROUTINE dyn_zdf_init
126
127   !!==============================================================================
128END MODULE dynzdf
Note: See TracBrowser for help on using the repository browser.