source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/LIM_SRC_2/limthd_lac_2.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 3 years ago

All wrk_alloc removed

  • Property svn:keywords set to Id
File size: 12.3 KB
Line 
1MODULE limthd_lac_2
2#if defined key_lim2
3   !!======================================================================
4   !!                       ***  MODULE limthd_lac_2   ***
5   !!                lateral thermodynamic growth of the ice
6   !!======================================================================
7
8   !!----------------------------------------------------------------------
9   !!   lim_lat_acr_2 : lateral accretion of ice
10   !!----------------------------------------------------------------------
11   USE par_oce        ! ocean parameters
12   USE phycst
13   USE thd_ice_2
14   USE ice_2
15   USE limistate_2 
16   USE lib_mpp        ! MPP library
17   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
18
19   IMPLICIT NONE
20   PRIVATE
21
22   PUBLIC   lim_thd_lac_2   ! called by lim_thd_2
23
24   REAL(wp)  ::           &  ! constant values
25      epsi20 = 1.e-20  ,  &
26      epsi13 = 1.e-13  ,  &
27      zzero  = 0.e0    ,  &
28      zone   = 1.e0
29
30   !!----------------------------------------------------------------------
31   !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010)
32   !! $Id$
33   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
34   !!----------------------------------------------------------------------
35CONTAINS
36   
37   SUBROUTINE lim_thd_lac_2( kideb, kiut )
38      !!-------------------------------------------------------------------
39      !!               ***   ROUTINE lim_thd_lac_2  ***
40      !! 
41      !! ** Purpose : Computation of the evolution of the ice thickness and
42      !!      concentration as a function of the heat balance in the leads.
43      !!      It is only used for lateral accretion
44      !!       
45      !! ** Method  : Ice is formed in the open water when ocean lose heat
46      !!      (heat budget of open water Bl is negative) .
47      !!      Computation of the increase of 1-A (ice concentration) fol-
48      !!      lowing the law :
49      !!      (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ]
50      !!       where - h0 is the thickness of ice created in the lead
51      !!             - a is a minimum fraction for leads
52      !!             - F is a monotonic non-increasing function defined as:
53      !!                  F(X)=( 1 - X**exld )**(1.0/exld)
54      !!             - exld is the exponent closure rate (=2 default val.)
55      !!
56      !! ** Action : - Adjustment of snow and ice thicknesses and heat
57      !!                content in brine pockets
58      !!             - Updating ice internal temperature
59      !!             - Computation of variation of ice volume and mass
60      !!             - Computation of frldb after lateral accretion and
61      !!               update h_snow_1d, h_ice_1d and tbif_1d(:,:)     
62      !!
63      !! ** References :
64      !!      M. Maqueda, 1995, PhD Thesis, Univesidad Complutense Madrid
65      !!      Fichefet T. and M. Maqueda 1997, J. Geo. Res., 102(C6),
66      !!                                                12609 -12646   
67      !! History :
68      !!   1.0  !  01-04 (LIM)  original code
69      !!   2.0  !  02-08 (C. Ethe, G. Madec)  F90, mpp
70      !!-------------------------------------------------------------------
71      INTEGER , INTENT(IN)::  &
72         kideb          ,   &  ! start point on which the the computation is applied
73         kiut                  ! end point on which the the computation is applied
74
75      ! * Local variables
76      INTEGER ::            &
77         ji             ,   &  !  dummy loop indices
78         iicefr         ,   &  !  1 = existing ice ; 0 = no ice
79         iiceform       ,   &  !  1 = ice formed   ; 0 = no ice formed
80         ihemis                !  dummy indice
81      REAL(wp), DIMENSION(jpij) ::   zqbgow      !  heat budget of the open water (negative)
82      REAL(wp), DIMENSION(jpij) ::   zfrl_old    !  previous sea/ice fraction
83      REAL(wp), DIMENSION(jpij) ::   zhice_old   !  previous ice thickness
84      REAL(wp), DIMENSION(jpij) ::   zhice0      !  thickness of newly formed ice in leads
85      REAL(wp), DIMENSION(jpij) ::   zfrlmin     !  minimum fraction for leads
86      REAL(wp), DIMENSION(jpij) ::   zdhicbot    !  part of thickness of newly formed ice in leads which
87                                !  has been already used in transport for example
88      REAL(wp)  ::  &
89         zhemis           ,  &  !  hemisphere (0 = North, 1 = South)
90         zhicenew         ,  &  !  new ice thickness
91         zholds2          ,  &  !  ratio of previous ice thickness and 2
92         zhnews2          ,  &  !  ratio of new ice thickness and 2
93         zfrlnew          ,  &  !  new sea/ice fraction
94         zfrld            ,  &  !  ratio of sea/ice fraction and minimum fraction for leads
95         zfrrate          ,  &  !  leads-closure rate
96         zdfrl                  !  sea-ice fraction increment
97      REAL(wp)  ::  &
98         zdh1 , zdh2 , zdh3 , zdh4, zdh5   , &   ! tempory scalars
99         ztint , zta1 , zta2 , zta3 , zta4 , &
100         zah, zalpha , zbeta
101      !!---------------------------------------------------------------------     
102               
103     
104      !--------------------------------------------------------------
105      !   Computation of the heat budget of the open water (negative)
106      !--------------------------------------------------------------
107     
108      DO ji = kideb , kiut     
109         zqbgow(ji) = qldif_1d(ji) - qcmif_1d(ji)
110      END DO
111     
112      !-----------------------------------------------------------------
113      !   Taking the appropriate values for the corresponding hemisphere
114      !-----------------------------------------------------------------
115      DO ji = kideb , kiut
116         zhemis       = MAX( zzero , SIGN( zone , frld_1d(ji) - 2.0 ) ) 
117         ihemis       = INT( 1 + zhemis )
118         zhice0  (ji) = hiccrit( ihemis ) 
119         zfrlmin (ji) = acrit  ( ihemis )   
120         frld_1d (ji) = frld_1d(ji) - 2.0 * zhemis
121         zfrl_old(ji) = frld_1d(ji)
122      END DO
123     
124      !-------------------------------------------------------------------
125      !     Lateral Accretion (modification of the fraction of open water)
126      !     The ice formed in the leads has always a thickness zhice0, but
127      !     only a fraction zfrrate of the ice formed contributes to the
128      !     increase of the ice fraction. The remaining part (1-zfrrate)
129      !     is rather assumed to lead to an increase in the thickness of the
130      !     pre-existing ice (transport for example).
131      !     Morales Maqueda, 1995 - Fichefet and Morales Maqueda, 1997
132      !---------------------------------------------------------------------
133     
134      DO ji = kideb , kiut
135         iicefr       = 1 - MAX( 0, INT( SIGN( 1.5 * zone , zfrl_old(ji) - 1.0 + epsi13 ) ) )
136         !---computation of the leads-closure rate
137         zfrld        = MIN( zone , ( 1.0 - frld_1d(ji) ) / ( 1.0 - zfrlmin(ji) ) )
138         zfrrate      = ( 1.0 - zfrld**exld )**( 1.0 / exld )
139         !--computation of the sea-ice fraction increment and the new fraction
140         zdfrl        = ( zfrrate / zhice0(ji) )  * ( zqbgow(ji) / xlic )
141         zfrlnew      = zfrl_old(ji) + zdfrl
142         !--update the sea-ice fraction
143         frld_1d   (ji) = MAX( zfrlnew , zfrlmin(ji) )
144         !--computation of the remaining part of ice thickness which has been already used
145         zdhicbot(ji) =  ( frld_1d(ji) - zfrlnew ) * zhice0(ji) / ( 1.0 - zfrlmin(ji) )   & 
146            &         -  (  ( 1.0 - zfrrate ) / ( 1.0 - frld_1d(ji) ) )  * ( zqbgow(ji) / xlic ) 
147      END DO
148 
149      !----------------------------------------------------------------------------------------
150      !      Ajustement of snow and ice thicknesses and updating the total heat stored in brine pockets 
151      !      The thickness of newly formed ice is averaged with that of the pre-existing
152      !         (1-Anew) * hinew = (1-Aold) * hiold + ((1-Anew)-(1-Aold)) * h0
153      !      Snow is distributed over the new ice-covered area
154      !         (1-Anew) * hsnew = (1-Aold) * hsold           
155      !--------------------------------------------------------------------------------------------
156     
157      DO ji = kideb , kiut
158         iicefr       = 1 - MAX( 0, INT( SIGN( 1.5 * zone , zfrl_old(ji) - 1.0 + epsi13 ) ) )
159         zhice_old(ji) = h_ice_1d(ji)
160         zhicenew      = iicefr * zhice_old(ji) + ( 1 - iicefr ) * zhice0(ji)
161         zalpha        = ( 1. - zfrl_old(ji) ) / ( 1.- frld_1d(ji) )
162         h_snow_1d(ji) = zalpha * h_snow_1d(ji)
163         h_ice_1d (ji) = zalpha * zhicenew + ( 1.0 - zalpha ) * zhice0(ji)
164         qstbif_1d(ji) = zalpha * qstbif_1d(ji) 
165      END DO
166     
167      !-------------------------------------------------------
168      !   Ajustement of ice internal temperatures
169      !-------------------------------------------------------
170     
171      DO ji = kideb , kiut
172         iicefr      = 1 - MAX( 0, INT( SIGN( 1.5 * zone , zfrl_old(ji) - 1.0 + epsi13 ) ) )
173         iiceform    = 1 - MAX( 0 ,INT( SIGN( 1.5 * zone , zhice0(ji) - h_ice_1d(ji) ) ) )
174         zholds2     = zhice_old(ji)/ 2.
175         zhnews2     = h_ice_1d(ji) / 2.
176         zdh1        = MAX( zzero ,  zhice_old(ji)   - zhnews2 )
177         zdh2        = MAX( zzero , -zhice_old(ji)   + zhnews2 )
178         zdh3        = MAX( zzero ,  h_ice_1d(ji) - zholds2 )
179         zdh4        = MAX( zzero , -h_ice_1d(ji) + zholds2 )
180         zdh5        = MAX( zzero , zhice0(ji)      - zholds2 )
181         ztint       =       iiceform   * (  ( zholds2 - zdh3 ) * tbif_1d(ji,3) + zdh4 * tbif_1d(ji,2) )      &
182            &                           / MAX( epsi20 , h_ice_1d(ji) - zhice0(ji) )                           &
183            &                 + ( 1 - iiceform ) * tfu_1d(ji)
184         zta1        = iicefr * ( 1.  - zfrl_old(ji) ) * tbif_1d(ji,2) 
185         zta2        = iicefr * ( 1.  - zfrl_old(ji) ) * tbif_1d(ji,3)
186         zta3        = iicefr * ( 1.  - zfrl_old(ji) ) * ztint
187         zta4        = ( zfrl_old(ji) - frld_1d   (ji) ) * tfu_1d(ji)
188         zah         = ( 1. - frld_1d(ji) ) * zhnews2 
189
190         tbif_1d(ji,2) = (  MIN( zhnews2 , zholds2 )                                              * zta1   &
191            &          + ( 1 - iiceform ) * ( zholds2 - zdh1 )                                    * zta2   &
192            &          + ( iiceform * ( zhnews2 - zhice0(ji) + zdh5 ) + ( 1 - iiceform ) * zdh2 ) * zta3   & 
193            &          + MIN ( zhnews2 , zhice0(ji) )                                             * zta4   &
194            &          ) / zah
195         
196         tbif_1d(ji,3) =     ( iiceform * ( zhnews2 - zdh3 )                                           * zta1  &
197            &              + ( iiceform * zdh3 + ( 1 - iiceform ) * zdh1 )                             * zta2  &
198            &              + ( iiceform * ( zhnews2 - zdh5 ) + ( 1 - iiceform ) * ( zhnews2 - zdh1 ) ) * zta3  & 
199            &              + ( iiceform * zdh5 + ( 1 - iiceform ) * zhnews2 )                          * zta4  &
200            &            ) / zah
201         !---removing the remaining part of ice formed which has been already used
202         zbeta         = h_ice_1d(ji) / ( h_ice_1d(ji) + zdhicbot(ji) )
203         h_ice_1d(ji)  = h_ice_1d(ji) + zdhicbot(ji)
204         tbif_1d (ji,2)= zbeta * tbif_1d(ji,2) + ( 1.0 - zbeta ) * tbif_1d(ji,3)
205         tbif_1d (ji,3)= ( 2. * zbeta - 1.0 ) * tbif_1d(ji,3) + ( 2. * zdhicbot(ji) / h_ice_1d(ji) ) * tfu_1d(ji)
206         
207      END DO
208     
209      !-------------------------------------------------------------
210      !    Computation of variation of ice volume and ice mass
211      !           Vold = (1-Aold) * hiold ; Vnew = (1-Anew) * hinew
212      !           dV = Vnew - Vold
213      !-------------------------------------------------------------
214     
215      DO ji = kideb , kiut
216         dvlbq_1d  (ji) = ( 1. - frld_1d(ji) ) * h_ice_1d(ji) - ( 1. - zfrl_old(ji) ) * zhice_old(ji)
217         rdm_ice_1d(ji) = rdm_ice_1d(ji) + rhoic * dvlbq_1d(ji)
218         rdq_ice_1d(ji) = rdq_ice_1d(ji) + rcpic * dvlbq_1d(ji) * ( tfu_1d(ji) - rt0 )      ! heat content relative to rt0
219      END DO
220     
221      !
222   END SUBROUTINE lim_thd_lac_2
223#else
224   !!----------------------------------------------------------------------
225   !!                       ***  MODULE limthd_lac_2   ***
226   !!                           no sea ice model
227   !!----------------------------------------------------------------------
228CONTAINS
229   SUBROUTINE lim_thd_lac_2           ! Empty routine
230   END SUBROUTINE lim_thd_lac_2
231#endif
232   !!======================================================================
233END MODULE limthd_lac_2
Note: See TracBrowser for help on using the repository browser.