source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 3 years ago

All wrk_alloc removed

  • Property svn:keywords set to Id
File size: 21.0 KB
Line 
1MODULE limsbc
2   !!======================================================================
3   !!                       ***  MODULE limsbc   ***
4   !!           computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :   -   ! 2006-07 (M. Vancoppelle)  LIM3 original code
7   !!            3.0  ! 2008-03 (C. Tallandier)  surface module
8   !!             -   ! 2008-04 (C. Tallandier)  split in 2 + new ice-ocean coupling
9   !!            3.3  ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
10   !!                 !                  + simplification of the ice-ocean stress calculation
11   !!            3.4  ! 2011-02 (G. Madec) dynamical allocation
12   !!             -   ! 2012    (D. Iovino) salt flux change
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!            3.5  ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3'                                    LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   lim_sbc_alloc : allocate the limsbc arrays
21   !!   lim_sbc_init  : initialisation
22   !!   lim_sbc_flx   : updates mass, heat and salt fluxes at the ocean surface
23   !!   lim_sbc_tau   : update i- and j-stresses, and its modulus at the ocean surface
24   !!----------------------------------------------------------------------
25   USE par_oce        ! ocean parameters
26   USE oce     , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass
27   USE phycst         ! physical constants
28   USE dom_oce        ! ocean domain
29   USE ice            ! LIM sea-ice variables
30   USE sbc_ice        ! Surface boundary condition: sea-ice fields
31   USE sbc_oce        ! Surface boundary condition: ocean fields
32   USE sbccpl         ! Surface boundary condition: coupled interface
33   USE albedo         ! albedo parameters
34   USE traqsr         ! add penetration of solar flux in the calculation of heat budget
35   USE domvvl         ! Variable volume
36   USE limctl         !
37   USE limcons        !
38   USE bdy_oce  , ONLY: ln_bdy
39   !
40   USE in_out_manager ! I/O manager
41   USE iom            ! xIO server
42   USE lbclnk         ! ocean lateral boundary condition - MPP exchanges
43   USE lib_mpp        ! MPP library
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   lim_sbc_init   ! called by sbc_lim_init
50   PUBLIC   lim_sbc_flx    ! called by sbc_ice_lim
51   PUBLIC   lim_sbc_tau    ! called by sbc_ice_lim
52
53   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
54   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
55   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   soce_0  , sice_0     ! cst SSS and ice salinity (levitating sea-ice)
56
57   !! * Substitutions
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   INTEGER FUNCTION lim_sbc_alloc()
67      !!-------------------------------------------------------------------
68      !!             ***  ROUTINE lim_sbc_alloc ***
69      !!-------------------------------------------------------------------
70      ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) ,                       &
71         &      sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc)
72         !
73      IF( lk_mpp             )   CALL mpp_sum( lim_sbc_alloc )
74      IF( lim_sbc_alloc /= 0 )   CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
75   END FUNCTION lim_sbc_alloc
76
77
78   SUBROUTINE lim_sbc_flx( kt )
79      !!-------------------------------------------------------------------
80      !!                ***  ROUTINE lim_sbc_flx ***
81      !! 
82      !! ** Purpose :   Update the surface ocean boundary condition for heat
83      !!              salt and mass over areas where sea-ice is non-zero
84      !!         
85      !! ** Action  : - computes the heat and freshwater/salt fluxes
86      !!              at the ice-ocean interface.
87      !!              - Update the ocean sbc
88      !!     
89      !! ** Outputs : - qsr     : sea heat flux:     solar
90      !!              - qns     : sea heat flux: non solar
91      !!              - emp     : freshwater budget: volume flux
92      !!              - sfx     : salt flux
93      !!              - fr_i    : ice fraction
94      !!              - tn_ice  : sea-ice surface temperature
95      !!              - alb_ice : sea-ice albedo (recomputed only for coupled mode)
96      !!
97      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
98      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
99      !!              These refs are now obsolete since everything has been revised
100      !!              The ref should be Rousset et al., 2015
101      !!---------------------------------------------------------------------
102      INTEGER, INTENT(in) ::   kt   ! number of iteration
103      !
104      INTEGER  ::   ji, jj, jl, jk   ! dummy loop indices
105      REAL(wp) ::   zqmass           ! Heat flux associated with mass exchange ice->ocean (W.m-2)
106      REAL(wp) ::   zqsr             ! New solar flux received by the ocean
107      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zalb_cs, zalb_os     ! 3D workspace
108      REAL(wp), DIMENSION(jpi,jpj)   ::   zalb                 ! 2D workspace
109      !!---------------------------------------------------------------------
110
111      ! --- case we bypass ice thermodynamics --- !
112      IF( .NOT. ln_limthd ) THEN   ! we suppose ice is impermeable => ocean is isolated from atmosphere
113         hfx_in   (:,:)   = pfrld(:,:) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
114         hfx_out  (:,:)   = pfrld(:,:) *   qns_oce(:,:)                  + qemp_oce(:,:)
115         ftr_ice  (:,:,:) = 0._wp
116         emp_ice  (:,:)   = 0._wp
117         qemp_ice (:,:)   = 0._wp
118         qevap_ice(:,:,:) = 0._wp
119      ENDIF
120     
121      ! albedo output
122
123      zalb(:,:) = 0._wp
124      WHERE     ( at_i_b <= epsi06 )  ;  zalb(:,:) = 0.066_wp
125      ELSEWHERE                       ;  zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b
126      END WHERE
127      IF( iom_use('alb_ice' ) )  CALL iom_put( "alb_ice"  , zalb(:,:) )           ! ice albedo output
128
129      zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + 0.066_wp * ( 1._wp - at_i_b )     
130      IF( iom_use('albedo'  ) )  CALL iom_put( "albedo"  , zalb(:,:) )           ! ice albedo output
131
132
133      DO jj = 1, jpj
134         DO ji = 1, jpi
135
136            !------------------------------------------!
137            !      heat flux at the ocean surface      !
138            !------------------------------------------!
139            ! Solar heat flux reaching the ocean = zqsr (W.m-2)
140            !---------------------------------------------------
141            zqsr = qsr_tot(ji,jj)
142            DO jl = 1, jpl
143               zqsr = zqsr - a_i_b(ji,jj,jl) * (  qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) 
144            END DO
145
146            ! Total heat flux reaching the ocean = hfx_out (W.m-2)
147            !---------------------------------------------------
148            zqmass         = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC)
149            hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr
150
151            ! Add the residual from heat diffusion equation and sublimation (W.m-2)
152            !----------------------------------------------------------------------
153            hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) +   &
154               &           ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) )
155
156            ! New qsr and qns used to compute the oceanic heat flux at the next time step
157            !----------------------------------------------------------------------------
158            qsr(ji,jj) = zqsr                                     
159            qns(ji,jj) = hfx_out(ji,jj) - zqsr             
160
161            !------------------------------------------!
162            !      mass flux at the ocean surface      !
163            !------------------------------------------!
164            !  case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
165            !  -------------------------------------------------------------------------------------
166            !  The idea of this approach is that the system that we consider is the ICE-OCEAN system
167            !  Thus  FW  flux  =  External ( E-P+snow melt)
168            !       Salt flux  =  Exchanges in the ice-ocean system then converted into FW
169            !                     Associated to Ice formation AND Ice melting
170            !                     Even if i see Ice melting as a FW and SALT flux
171            !       
172            ! mass flux from ice/ocean
173            wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj)   &
174                           + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) 
175
176            ! mass flux at the ocean/ice interface
177            fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) )              ! F/M mass flux save at least for biogeochemical model
178            emp(ji,jj)    = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj)   ! mass flux + F/M mass flux (always ice/ocean mass exchange)
179         END DO
180      END DO
181
182      !------------------------------------------!
183      !      salt flux at the ocean surface      !
184      !------------------------------------------!
185      sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:)   &
186         &     + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:) + sfx_sub(:,:) + sfx_lam(:,:)
187
188      !-------------------------------------------------------------!
189      !   mass of snow and ice per unit area for embedded sea-ice   !
190      !-------------------------------------------------------------!
191      IF( nn_ice_embd /= 0 ) THEN
192         ! save mass from the previous ice time step
193         snwice_mass_b(:,:) = snwice_mass(:,:)                 
194         ! new mass per unit area
195         snwice_mass  (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  ) 
196         ! time evolution of snow+ice mass
197         snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice
198      ENDIF
199
200      !-----------------------------------------------!
201      !   Storing the transmitted variables           !
202      !-----------------------------------------------!
203      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
204      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
205
206      !------------------------------------------------------------------------!
207      !    Snow/ice albedo (only if sent to coupler, useless in forced mode)   !
208      !------------------------------------------------------------------------!
209      CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os )  ! cloud-sky and overcast-sky ice albedos
210      alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
211
212      ! conservation test
213      IF( ln_limdiachk .AND. .NOT. ln_bdy)  CALL lim_cons_final( 'limsbc' )
214
215      ! control prints
216      IF( ln_limctl )   CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' )
217      IF( ln_ctl )      CALL lim_prt3D( 'limsbc' )
218
219   END SUBROUTINE lim_sbc_flx
220
221
222   SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
223      !!-------------------------------------------------------------------
224      !!                ***  ROUTINE lim_sbc_tau ***
225      !! 
226      !! ** Purpose : Update the ocean surface stresses due to the ice
227      !!         
228      !! ** Action  : * at each ice time step (every nn_fsbc time step):
229      !!                - compute the modulus of ice-ocean relative velocity
230      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
231      !!                      tmod_io = rhoco * | U_ice-U_oce |
232      !!                - update the modulus of stress at ocean surface
233      !!                      taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce |
234      !!              * at each ocean time step (every kt):
235      !!                  compute linearized ice-ocean stresses as
236      !!                      Utau = tmod_io * | U_ice - pU_oce |
237      !!                using instantaneous current ocean velocity (usually before)
238      !!
239      !!    NB: - ice-ocean rotation angle no more allowed
240      !!        - here we make an approximation: taum is only computed every ice time step
241      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
242      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
243      !!
244      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
245      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
246      !!---------------------------------------------------------------------
247      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
248      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
249      !
250      INTEGER  ::   ji, jj   ! dummy loop indices
251      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
252      REAL(wp) ::   zat_v, zvtau_ice, zv_t, zrhoco  !   -      -
253      !!---------------------------------------------------------------------
254      zrhoco = rau0 * rn_cio
255      !
256      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
257         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
258            DO ji = fs_2, fs_jpim1
259               !                                               ! 2*(U_ice-U_oce) at T-point
260               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
261               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
262               !                                              ! |U_ice-U_oce|^2
263               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
264               !                                               ! update the ocean stress modulus
265               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt
266               tmod_io(ji,jj) = zrhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
267            END DO
268         END DO
269         CALL lbc_lnk_multi( taum, 'T', 1., tmod_io, 'T', 1. )
270         !
271         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
272         vtau_oce(:,:) = vtau(:,:)
273         !
274      ENDIF
275      !
276      !                                      !==  every ocean time-step  ==!
277      !
278      DO jj = 2, jpjm1                                !* update the stress WITHOUT a ice-ocean rotation angle
279         DO ji = fs_2, fs_jpim1   ! Vect. Opt.
280            zat_u  = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp   ! ice area at u and V-points
281            zat_v  = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp
282            !                                                   ! linearized quadratic drag formulation
283            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
284            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
285            !                                                   ! stresses at the ocean surface
286            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
287            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
288         END DO
289      END DO
290      CALL lbc_lnk_multi( utau, 'U', -1., vtau, 'V', -1. )   ! lateral boundary condition
291      !
292     
293   END SUBROUTINE lim_sbc_tau
294
295
296   SUBROUTINE lim_sbc_init
297      !!-------------------------------------------------------------------
298      !!                  ***  ROUTINE lim_sbc_init  ***
299      !!             
300      !! ** Purpose : Preparation of the file ice_evolu for the output of
301      !!      the temporal evolution of key variables
302      !!
303      !! ** input   : Namelist namicedia
304      !!-------------------------------------------------------------------
305      INTEGER  ::   ji, jj, jk               ! dummy loop indices
306      REAL(wp) ::   zcoefu, zcoefv, zcoeff   ! local scalar
307      !!-------------------------------------------------------------------
308      !
309      IF(lwp) WRITE(numout,*)
310      IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
311      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   '
312
313      !                                      ! allocate lim_sbc array
314      IF( lim_sbc_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
315      !
316      soce_0(:,:) = soce                     ! constant SSS and ice salinity used in levitating sea-ice case
317      sice_0(:,:) = sice
318      !                                      ! decrease ocean & ice reference salinities in the Baltic Sea area
319      WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND.   &
320         &   54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp         ) 
321         soce_0(:,:) = 4._wp
322         sice_0(:,:) = 2._wp
323      END WHERE
324      !
325      IF( .NOT. ln_rstart ) THEN
326         !                                      ! embedded sea ice
327         IF( nn_ice_embd /= 0 ) THEN            ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass
328            snwice_mass  (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  )
329            snwice_mass_b(:,:) = snwice_mass(:,:)
330         ELSE
331            snwice_mass  (:,:) = 0._wp          ! no mass exchanges
332            snwice_mass_b(:,:) = 0._wp          ! no mass exchanges
333         ENDIF
334         IF( nn_ice_embd == 2 ) THEN            ! full embedment (case 2) deplete the initial ssh below sea-ice area
335            sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0
336            sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0
337
338!!gm I really don't like this stuff here...  Find a way to put that elsewhere or differently
339!!gm
340            IF( .NOT.ln_linssh ) THEN
341               DO jk = 1,jpkm1                     ! adjust initial vertical scale factors
342                  e3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
343                  e3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
344               END DO
345               e3t_a(:,:,:) = e3t_b(:,:,:)
346               ! Reconstruction of all vertical scale factors at now and before time-steps
347               ! =========================================================================
348               ! Horizontal scale factor interpolations
349               ! --------------------------------------
350               CALL dom_vvl_interpol( e3t_b(:,:,:), e3u_b(:,:,:), 'U' )
351               CALL dom_vvl_interpol( e3t_b(:,:,:), e3v_b(:,:,:), 'V' )
352               CALL dom_vvl_interpol( e3t_n(:,:,:), e3u_n(:,:,:), 'U' )
353               CALL dom_vvl_interpol( e3t_n(:,:,:), e3v_n(:,:,:), 'V' )
354               CALL dom_vvl_interpol( e3u_n(:,:,:), e3f_n(:,:,:), 'F' )
355               ! Vertical scale factor interpolations
356                 ! ------------------------------------
357               CALL dom_vvl_interpol( e3t_n(:,:,:), e3w_n (:,:,:), 'W'  )
358               CALL dom_vvl_interpol( e3u_n(:,:,:), e3uw_n(:,:,:), 'UW' )
359               CALL dom_vvl_interpol( e3v_n(:,:,:), e3vw_n(:,:,:), 'VW' )
360               CALL dom_vvl_interpol( e3u_b(:,:,:), e3uw_b(:,:,:), 'UW' )
361               CALL dom_vvl_interpol( e3v_b(:,:,:), e3vw_b(:,:,:), 'VW' )
362               ! t- and w- points depth
363               ! ----------------------
364!!gm not sure of that....
365               gdept_n(:,:,1) = 0.5_wp * e3w_n(:,:,1)
366               gdepw_n(:,:,1) = 0.0_wp
367               gde3w_n(:,:,1) = gdept_n(:,:,1) - sshn(:,:)
368               DO jk = 2, jpk
369                  gdept_n(:,:,jk) = gdept_n(:,:,jk-1) + e3w_n(:,:,jk)
370                  gdepw_n(:,:,jk) = gdepw_n(:,:,jk-1) + e3t_n(:,:,jk-1)
371                  gde3w_n(:,:,jk) = gdept_n(:,:,jk  ) - sshn   (:,:)
372               END DO
373            ENDIF
374         ENDIF
375      ENDIF ! .NOT. ln_rstart
376      !
377   END SUBROUTINE lim_sbc_init
378
379#else
380   !!----------------------------------------------------------------------
381   !!   Default option :        Dummy module       NO LIM 3.0 sea-ice model
382   !!----------------------------------------------------------------------
383CONTAINS
384   SUBROUTINE lim_sbc           ! Dummy routine
385   END SUBROUTINE lim_sbc
386#endif 
387
388   !!======================================================================
389END MODULE limsbc
Note: See TracBrowser for help on using the repository browser.