source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/BDY/bdydyn.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 3 years ago

All wrk_alloc removed

  • Property svn:keywords set to Id
File size: 5.6 KB
Line 
1MODULE bdydyn
2   !!======================================================================
3   !!                       ***  MODULE  bdydyn  ***
4   !! Unstructured Open Boundary Cond. :   Apply boundary conditions to velocities
5   !!======================================================================
6   !! History :  1.0  !  2005-02  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-07  (D. Storkey) Move Flather implementation to separate routine.
8   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
9   !!            3.2  !  2008-04  (R. Benshila) consider velocity instead of transport
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!----------------------------------------------------------------------
14   !!   bdy_dyn        : split velocities into barotropic and baroclinic parts
15   !!                    and call bdy_dyn2d and bdy_dyn3d to apply boundary
16   !!                    conditions
17   !!----------------------------------------------------------------------
18   USE timing          ! Timing
19   USE oce             ! ocean dynamics and tracers
20   USE dom_oce         ! ocean space and time domain
21   USE bdy_oce         ! ocean open boundary conditions
22   USE bdydyn2d        ! open boundary conditions for barotropic solution
23   USE bdydyn3d        ! open boundary conditions for baroclinic velocities
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE in_out_manager  !
26   USE domvvl          ! variable volume
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   bdy_dyn    ! routine called in dyn_nxt
32
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
35   !! $Id$
36   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE bdy_dyn( kt, dyn3d_only )
41      !!----------------------------------------------------------------------
42      !!                  ***  SUBROUTINE bdy_dyn  ***
43      !!
44      !! ** Purpose : - Wrapper routine for bdy_dyn2d and bdy_dyn3d.
45      !!
46      !!----------------------------------------------------------------------
47      INTEGER, INTENT(in)           ::   kt           ! Main time step counter
48      LOGICAL, INTENT(in), OPTIONAL ::   dyn3d_only   ! T => only update baroclinic velocities
49      !
50      INTEGER ::   jk, ii, ij, ib_bdy, ib, igrd     ! Loop counter
51      LOGICAL ::   ll_dyn2d, ll_dyn3d, ll_orlanski
52      REAL(wp), DIMENSION(jpi,jpj) :: pua2d, pva2d     ! after barotropic velocities
53      !!----------------------------------------------------------------------
54      !
55      IF( nn_timing == 1 )   CALL timing_start('bdy_dyn')
56      !
57      ll_dyn2d = .true.
58      ll_dyn3d = .true.
59      !
60      IF( PRESENT(dyn3d_only) ) THEN
61         IF( dyn3d_only )   ll_dyn2d = .false.
62      ENDIF
63      !
64      ll_orlanski = .false.
65      DO ib_bdy = 1, nb_bdy
66         IF ( cn_dyn2d(ib_bdy) == 'orlanski' .OR. cn_dyn2d(ib_bdy) == 'orlanski_npo' &
67     &   .OR. cn_dyn3d(ib_bdy) == 'orlanski' .OR. cn_dyn3d(ib_bdy) == 'orlanski_npo')   ll_orlanski = .true.
68      END DO
69
70      !-------------------------------------------------------
71      ! Set pointers
72      !-------------------------------------------------------
73
74
75      !-------------------------------------------------------
76      ! Split velocities into barotropic and baroclinic parts
77      !-------------------------------------------------------
78
79      !                          ! "After" velocities:
80      pua2d(:,:) = 0._wp
81      pva2d(:,:) = 0._wp     
82      DO jk = 1, jpkm1
83         pua2d(:,:) = pua2d(:,:) + e3u_a(:,:,jk) * ua(:,:,jk) * umask(:,:,jk)
84         pva2d(:,:) = pva2d(:,:) + e3v_a(:,:,jk) * va(:,:,jk) * vmask(:,:,jk)
85      END DO
86      pua2d(:,:) = pua2d(:,:) * r1_hu_a(:,:)
87      pva2d(:,:) = pva2d(:,:) * r1_hv_a(:,:)
88
89      DO jk = 1 , jpkm1
90         ua(:,:,jk) = ( ua(:,:,jk) - pua2d(:,:) ) * umask(:,:,jk)
91         va(:,:,jk) = ( va(:,:,jk) - pva2d(:,:) ) * vmask(:,:,jk)
92      END DO
93
94
95      IF( ll_orlanski ) THEN     ! "Before" velocities (Orlanski condition only)
96         DO jk = 1 , jpkm1
97            ub(:,:,jk) = ( ub(:,:,jk) - ub_b(:,:) ) * umask(:,:,jk)
98            vb(:,:,jk) = ( vb(:,:,jk) - vb_b(:,:) ) * vmask(:,:,jk)
99         END DO
100      ENDIF
101
102      !-------------------------------------------------------
103      ! Apply boundary conditions to barotropic and baroclinic
104      ! parts separately
105      !-------------------------------------------------------
106
107      IF( ll_dyn2d )   CALL bdy_dyn2d( kt, pua2d, pva2d, ub_b, vb_b, r1_hu_a(:,:), r1_hv_a(:,:), ssha )
108
109      IF( ll_dyn3d )   CALL bdy_dyn3d( kt )
110
111      !-------------------------------------------------------
112      ! Recombine velocities
113      !-------------------------------------------------------
114      !
115      DO jk = 1 , jpkm1
116         ua(:,:,jk) = ( ua(:,:,jk) + pua2d(:,:) ) * umask(:,:,jk)
117         va(:,:,jk) = ( va(:,:,jk) + pva2d(:,:) ) * vmask(:,:,jk)
118      END DO
119      !
120      IF ( ll_orlanski ) THEN
121         DO jk = 1 , jpkm1
122            ub(:,:,jk) = ( ub(:,:,jk) + ub_b(:,:) ) * umask(:,:,jk)
123            vb(:,:,jk) = ( vb(:,:,jk) + vb_b(:,:) ) * vmask(:,:,jk)
124         END DO
125      END IF
126      !
127      !
128      IF( nn_timing == 1 )   CALL timing_stop('bdy_dyn')
129      !
130   END SUBROUTINE bdy_dyn
131
132   !!======================================================================
133END MODULE bdydyn
Note: See TracBrowser for help on using the repository browser.