New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdytides.F90 in branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/BDY/bdytides.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 7 years ago

All wrk_alloc removed
  • Property svn:keywords set to Id
File size: 27.7 KB
Line 
1MODULE bdytides
2   !!======================================================================
3   !!                       ***  MODULE  bdytides  ***
4   !! Ocean dynamics:   Tidal forcing at open boundaries
5   !!======================================================================
6   !! History :  2.0  !  2007-01  (D.Storkey)  Original code
7   !!            2.3  !  2008-01  (J.Holt)  Add date correction. Origins POLCOMS v6.3 2007
8   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
9   !!            3.3  !  2010-09  (D.Storkey and E.O'Dea)  bug fixes
10   !!            3.4  !  2012-09  (G. Reffray and J. Chanut) New inputs + mods
11   !!            3.5  !  2013-07  (J. Chanut) Compliant with time splitting changes
12   !!----------------------------------------------------------------------
13   !!   bdytide_init  : read of namelist and initialisation of tidal harmonics data
14   !!   tide_update   : calculation of tidal forcing at each timestep
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE phycst         ! physical constants
19   USE bdy_oce        ! ocean open boundary conditions
20   USE tideini        !
21   USE daymod         ! calendar
22   !
23   USE in_out_manager ! I/O units
24   USE iom            ! xIO server
25   USE fldread        !
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE timing         ! timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   bdytide_init     ! routine called in bdy_init
33   PUBLIC   bdytide_update   ! routine called in bdy_dta
34   PUBLIC   bdy_dta_tides    ! routine called in dyn_spg_ts
35
36   TYPE, PUBLIC ::   TIDES_DATA     !: Storage for external tidal harmonics data
37      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh0     !: Tidal constituents : SSH0   (read in file)
38      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u0, v0   !: Tidal constituents : U0, V0 (read in file)
39      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh      !: Tidal constituents : SSH    (after nodal cor.)
40      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u , v    !: Tidal constituents : U , V  (after nodal cor.)
41   END TYPE TIDES_DATA
42
43!$AGRIF_DO_NOT_TREAT
44   TYPE(TIDES_DATA), PUBLIC, DIMENSION(jp_bdy), TARGET :: tides  !: External tidal harmonics data
45!$AGRIF_END_DO_NOT_TREAT
46   TYPE(OBC_DATA)  , PUBLIC, DIMENSION(jp_bdy) :: dta_bdy_s  !: bdy external data (slow component)
47
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE bdytide_init
56      !!----------------------------------------------------------------------
57      !!                    ***  SUBROUTINE bdytide_init  ***
58      !!                     
59      !! ** Purpose : - Read in namelist for tides and initialise external
60      !!                tidal harmonics data
61      !!
62      !!----------------------------------------------------------------------
63      !! namelist variables
64      !!-------------------
65      CHARACTER(len=80)                         ::   filtide             !: Filename root for tidal input files
66      LOGICAL                                   ::   ln_bdytide_2ddta    !: If true, read 2d harmonic data
67      LOGICAL                                   ::   ln_bdytide_conj     !: If true, assume complex conjugate tidal data
68      !!
69      INTEGER                                   ::   ib_bdy, itide, ib   !: dummy loop indices
70      INTEGER                                   ::   ii, ij              !: dummy loop indices
71      INTEGER                                   ::   inum, igrd
72      INTEGER, DIMENSION(3)                     ::   ilen0       !: length of boundary data (from OBC arrays)
73      INTEGER, POINTER, DIMENSION(:)            ::   nblen, nblenrim     ! short cuts
74      INTEGER                                   ::   ios                 ! Local integer output status for namelist read
75      CHARACTER(len=80)                         ::   clfile              !: full file name for tidal input file
76      REAL(wp),ALLOCATABLE, DIMENSION(:,:,:)    ::   dta_read            !: work space to read in tidal harmonics data
77      REAL(wp), DIMENSION(jpi,jpj)         ::   ztr, zti            !:  "     "    "   "   "   "        "      "
78      !!
79      TYPE(TIDES_DATA),  POINTER                ::   td                  !: local short cut   
80      TYPE(MAP_POINTER), DIMENSION(jpbgrd)      ::   ibmap_ptr           !: array of pointers to nbmap
81      !!
82      NAMELIST/nambdy_tide/filtide, ln_bdytide_2ddta, ln_bdytide_conj
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )   CALL timing_start('bdytide_init')
86      !
87      IF (nb_bdy>0) THEN
88         IF(lwp) WRITE(numout,*)
89         IF(lwp) WRITE(numout,*) 'bdytide_init : initialization of tidal harmonic forcing at open boundaries'
90         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
91      ENDIF
92
93      REWIND(numnam_cfg)
94
95      DO ib_bdy = 1, nb_bdy
96         IF( nn_dyn2d_dta(ib_bdy) >= 2 ) THEN
97            !
98            td => tides(ib_bdy)
99            nblen => idx_bdy(ib_bdy)%nblen
100            nblenrim => idx_bdy(ib_bdy)%nblenrim
101
102            ! Namelist nambdy_tide : tidal harmonic forcing at open boundaries
103            filtide(:) = ''
104
105            ! Don't REWIND here - may need to read more than one of these namelists.
106            READ  ( numnam_ref, nambdy_tide, IOSTAT = ios, ERR = 901)
107901         IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_tide in reference namelist', lwp )
108            READ  ( numnam_cfg, nambdy_tide, IOSTAT = ios, ERR = 902 )
109902         IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_tide in configuration namelist', lwp )
110            IF(lwm) WRITE ( numond, nambdy_tide )
111            !                                               ! Parameter control and print
112            IF(lwp) WRITE(numout,*) '  '
113            IF(lwp) WRITE(numout,*) '          Namelist nambdy_tide : tidal harmonic forcing at open boundaries'
114            IF(lwp) WRITE(numout,*) '             read tidal data in 2d files: ', ln_bdytide_2ddta
115            IF(lwp) WRITE(numout,*) '             assume complex conjugate   : ', ln_bdytide_conj
116            IF(lwp) WRITE(numout,*) '             Number of tidal components to read: ', nb_harmo
117            IF(lwp) THEN
118                    WRITE(numout,*) '             Tidal components: ' 
119               DO itide = 1, nb_harmo
120                  WRITE(numout,*)  '                 ', Wave(ntide(itide))%cname_tide 
121               END DO
122            ENDIF
123            IF(lwp) WRITE(numout,*) ' '
124
125            ! Allocate space for tidal harmonics data - get size from OBC data arrays
126            ! -----------------------------------------------------------------------
127
128            ! JC: If FRS scheme is used, we assume that tidal is needed over the whole
129            ! relaxation area     
130            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN   ;   ilen0(:) = nblen   (:)
131            ELSE                                   ;   ilen0(:) = nblenrim(:)
132            ENDIF
133
134            ALLOCATE( td%ssh0( ilen0(1), nb_harmo, 2 ) )
135            ALLOCATE( td%ssh ( ilen0(1), nb_harmo, 2 ) )
136
137            ALLOCATE( td%u0( ilen0(2), nb_harmo, 2 ) )
138            ALLOCATE( td%u ( ilen0(2), nb_harmo, 2 ) )
139
140            ALLOCATE( td%v0( ilen0(3), nb_harmo, 2 ) )
141            ALLOCATE( td%v ( ilen0(3), nb_harmo, 2 ) )
142
143            td%ssh0(:,:,:) = 0._wp
144            td%ssh (:,:,:) = 0._wp
145            td%u0  (:,:,:) = 0._wp
146            td%u   (:,:,:) = 0._wp
147            td%v0  (:,:,:) = 0._wp
148            td%v   (:,:,:) = 0._wp
149
150            IF( ln_bdytide_2ddta ) THEN
151               ! It is assumed that each data file contains all complex harmonic amplitudes
152               ! given on the global domain (ie global, jpiglo x jpjglo)
153               !
154               !
155               ! SSH fields
156               clfile = TRIM(filtide)//'_grid_T.nc'
157               CALL iom_open( clfile , inum ) 
158               igrd = 1                       ! Everything is at T-points here
159               DO itide = 1, nb_harmo
160                  CALL iom_get( inum, jpdom_autoglo, TRIM(Wave(ntide(itide))%cname_tide)//'_z1', ztr(:,:) )
161                  CALL iom_get( inum, jpdom_autoglo, TRIM(Wave(ntide(itide))%cname_tide)//'_z2', zti(:,:) ) 
162                  DO ib = 1, ilen0(igrd)
163                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
164                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
165                     td%ssh0(ib,itide,1) = ztr(ii,ij)
166                     td%ssh0(ib,itide,2) = zti(ii,ij)
167                  END DO
168               END DO
169               CALL iom_close( inum )
170               !
171               ! U fields
172               clfile = TRIM(filtide)//'_grid_U.nc'
173               CALL iom_open( clfile , inum ) 
174               igrd = 2                       ! Everything is at U-points here
175               DO itide = 1, nb_harmo
176                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(Wave(ntide(itide))%cname_tide)//'_u1', ztr(:,:) )
177                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(Wave(ntide(itide))%cname_tide)//'_u2', zti(:,:) )
178                  DO ib = 1, ilen0(igrd)
179                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
180                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
181                     td%u0(ib,itide,1) = ztr(ii,ij)
182                     td%u0(ib,itide,2) = zti(ii,ij)
183                  END DO
184               END DO
185               CALL iom_close( inum )
186               !
187               ! V fields
188               clfile = TRIM(filtide)//'_grid_V.nc'
189               CALL iom_open( clfile , inum ) 
190               igrd = 3                       ! Everything is at V-points here
191               DO itide = 1, nb_harmo
192                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(Wave(ntide(itide))%cname_tide)//'_v1', ztr(:,:) )
193                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(Wave(ntide(itide))%cname_tide)//'_v2', zti(:,:) )
194                  DO ib = 1, ilen0(igrd)
195                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
196                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
197                     td%v0(ib,itide,1) = ztr(ii,ij)
198                     td%v0(ib,itide,2) = zti(ii,ij)
199                  END DO
200               END DO 
201               CALL iom_close( inum )
202               !
203               !
204            ELSE           
205               !
206               ! Read tidal data only on bdy segments
207               !
208               ALLOCATE( dta_read( MAXVAL(ilen0(1:3)), 1, 1 ) )
209               !
210               ! Set map structure
211               ibmap_ptr(1)%ptr => idx_bdy(ib_bdy)%nbmap(:,1)   ;   ibmap_ptr(1)%ll_unstruc = ln_coords_file(ib_bdy)
212               ibmap_ptr(2)%ptr => idx_bdy(ib_bdy)%nbmap(:,2)   ;   ibmap_ptr(2)%ll_unstruc = ln_coords_file(ib_bdy)
213               ibmap_ptr(3)%ptr => idx_bdy(ib_bdy)%nbmap(:,3)   ;   ibmap_ptr(3)%ll_unstruc = ln_coords_file(ib_bdy)
214
215               ! Open files and read in tidal forcing data
216               ! -----------------------------------------
217
218               DO itide = 1, nb_harmo
219                  !                                                              ! SSH fields
220                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_T.nc'
221                  CALL iom_open( clfile, inum )
222                  CALL fld_map( inum, 'z1' , dta_read(1:ilen0(1),1:1,1:1) , 1,  ibmap_ptr(1) )
223                  td%ssh0(:,itide,1) = dta_read(1:ilen0(1),1,1)
224                  CALL fld_map( inum, 'z2' , dta_read(1:ilen0(1),1:1,1:1) , 1,  ibmap_ptr(1) )
225                  td%ssh0(:,itide,2) = dta_read(1:ilen0(1),1,1)
226                  CALL iom_close( inum )
227                  !                                                              ! U fields
228                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_U.nc'
229                  CALL iom_open( clfile, inum )
230                  CALL fld_map( inum, 'u1' , dta_read(1:ilen0(2),1:1,1:1) , 1, ibmap_ptr(2) )
231                  td%u0(:,itide,1) = dta_read(1:ilen0(2),1,1)
232                  CALL fld_map( inum, 'u2' , dta_read(1:ilen0(2),1:1,1:1) , 1, ibmap_ptr(2) )
233                  td%u0(:,itide,2) = dta_read(1:ilen0(2),1,1)
234                  CALL iom_close( inum )
235                  !                                                              ! V fields
236                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_V.nc'
237                  CALL iom_open( clfile, inum )
238                  CALL fld_map( inum, 'v1' , dta_read(1:ilen0(3),1:1,1:1) , 1, ibmap_ptr(3) )
239                  td%v0(:,itide,1) = dta_read(1:ilen0(3),1,1)
240                  CALL fld_map( inum, 'v2' , dta_read(1:ilen0(3),1:1,1:1) , 1, ibmap_ptr(3) )
241                  td%v0(:,itide,2) = dta_read(1:ilen0(3),1,1)
242                  CALL iom_close( inum )
243                  !
244               END DO ! end loop on tidal components
245               !
246               DEALLOCATE( dta_read )
247               !
248            ENDIF ! ln_bdytide_2ddta=.true.
249            !
250            IF( ln_bdytide_conj ) THEN    ! assume complex conjugate in data files
251               td%ssh0(:,:,2) = - td%ssh0(:,:,2)
252               td%u0  (:,:,2) = - td%u0  (:,:,2)
253               td%v0  (:,:,2) = - td%v0  (:,:,2)
254            ENDIF
255            !
256            ! Allocate slow varying data in the case of time splitting:
257            ! Do it anyway because at this stage knowledge of free surface scheme is unknown
258            ALLOCATE( dta_bdy_s(ib_bdy)%ssh ( ilen0(1) ) )
259            ALLOCATE( dta_bdy_s(ib_bdy)%u2d ( ilen0(2) ) )
260            ALLOCATE( dta_bdy_s(ib_bdy)%v2d ( ilen0(3) ) )
261            dta_bdy_s(ib_bdy)%ssh(:) = 0._wp
262            dta_bdy_s(ib_bdy)%u2d(:) = 0._wp
263            dta_bdy_s(ib_bdy)%v2d(:) = 0._wp
264            !
265         ENDIF ! nn_dyn2d_dta(ib_bdy) >= 2
266         !
267      END DO ! loop on ib_bdy
268      !
269      IF( nn_timing == 1 )   CALL timing_stop('bdytide_init')
270      !
271   END SUBROUTINE bdytide_init
272
273
274   SUBROUTINE bdytide_update( kt, idx, dta, td, jit, time_offset )
275      !!----------------------------------------------------------------------
276      !!                 ***  SUBROUTINE bdytide_update  ***
277      !!               
278      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
279      !!               
280      !!----------------------------------------------------------------------
281      INTEGER          , INTENT(in   ) ::   kt          ! Main timestep counter
282      TYPE(OBC_INDEX)  , INTENT(in   ) ::   idx         ! OBC indices
283      TYPE(OBC_DATA)   , INTENT(inout) ::   dta         ! OBC external data
284      TYPE(TIDES_DATA) , INTENT(inout) ::   td          ! tidal harmonics data
285      INTEGER, OPTIONAL, INTENT(in   ) ::   jit         ! Barotropic timestep counter (for timesplitting option)
286      INTEGER, OPTIONAL, INTENT(in   ) ::   time_offset ! time offset in units of timesteps. NB. if jit
287      !                                                 ! is present then units = subcycle timesteps.
288      !                                                 ! time_offset = 0  => get data at "now"    time level
289      !                                                 ! time_offset = -1 => get data at "before" time level
290      !                                                 ! time_offset = +1 => get data at "after"  time level
291      !                                                 ! etc.
292      !
293      INTEGER  ::   itide, igrd, ib       ! dummy loop indices
294      INTEGER  ::   time_add              ! time offset in units of timesteps
295      INTEGER, DIMENSION(3) ::   ilen0    ! length of boundary data (from OBC arrays)
296      REAL(wp) ::   z_arg, z_sarg, zflag, zramp   ! local scalars   
297      REAL(wp), DIMENSION(jpmax_harmo) :: z_sist, z_cost
298      !!----------------------------------------------------------------------
299      !
300      IF( nn_timing == 1 )   CALL timing_start('bdytide_update')
301      !
302      ilen0(1) =  SIZE(td%ssh(:,1,1))
303      ilen0(2) =  SIZE(td%u(:,1,1))
304      ilen0(3) =  SIZE(td%v(:,1,1))
305
306      zflag=1
307      IF ( PRESENT(jit) ) THEN
308        IF ( jit /= 1 ) zflag=0
309      ENDIF
310
311      IF ( (nsec_day == NINT(0.5_wp * rdt) .OR. kt==nit000) .AND. zflag==1 ) THEN
312        !
313        kt_tide = kt - (nsec_day - 0.5_wp * rdt)/rdt
314        !
315        IF(lwp) THEN
316           WRITE(numout,*)
317           WRITE(numout,*) 'bdytide_update : (re)Initialization of the tidal bdy forcing at kt=',kt
318           WRITE(numout,*) '~~~~~~~~~~~~~~ '
319        ENDIF
320        !
321        CALL tide_init_elevation ( idx, td )
322        CALL tide_init_velocities( idx, td )
323        !
324      ENDIF
325
326      time_add = 0
327      IF( PRESENT(time_offset) ) THEN
328         time_add = time_offset
329      ENDIF
330         
331      IF( PRESENT(jit) ) THEN 
332         z_arg = ((kt-kt_tide) * rdt + (jit+0.5_wp*(time_add-1)) * rdt / REAL(nn_baro,wp) )
333      ELSE                             
334         z_arg = ((kt-kt_tide)+time_add) * rdt
335      ENDIF
336
337      ! Linear ramp on tidal component at open boundaries
338      zramp = 1._wp
339      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg + (kt_tide-nit000)*rdt)/(rdttideramp*rday),0._wp),1._wp)
340
341      DO itide = 1, nb_harmo
342         z_sarg = z_arg * omega_tide(itide)
343         z_cost(itide) = COS( z_sarg )
344         z_sist(itide) = SIN( z_sarg )
345      END DO
346
347      DO itide = 1, nb_harmo
348         igrd=1                              ! SSH on tracer grid
349         DO ib = 1, ilen0(igrd)
350            dta%ssh(ib) = dta%ssh(ib) + zramp*(td%ssh(ib,itide,1)*z_cost(itide) + td%ssh(ib,itide,2)*z_sist(itide))
351         END DO
352         igrd=2                              ! U grid
353         DO ib = 1, ilen0(igrd)
354            dta%u2d(ib) = dta%u2d(ib) + zramp*(td%u  (ib,itide,1)*z_cost(itide) + td%u  (ib,itide,2)*z_sist(itide))
355         END DO
356         igrd=3                              ! V grid
357         DO ib = 1, ilen0(igrd) 
358            dta%v2d(ib) = dta%v2d(ib) + zramp*(td%v  (ib,itide,1)*z_cost(itide) + td%v  (ib,itide,2)*z_sist(itide))
359         END DO
360      END DO
361      !
362      IF( nn_timing == 1 )   CALL timing_stop('bdytide_update')
363      !
364   END SUBROUTINE bdytide_update
365
366
367   SUBROUTINE bdy_dta_tides( kt, kit, time_offset )
368      !!----------------------------------------------------------------------
369      !!                 ***  SUBROUTINE bdy_dta_tides  ***
370      !!               
371      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
372      !!               
373      !!----------------------------------------------------------------------
374      INTEGER,           INTENT(in) ::   kt          ! Main timestep counter
375      INTEGER, OPTIONAL, INTENT(in) ::   kit         ! Barotropic timestep counter (for timesplitting option)
376      INTEGER, OPTIONAL, INTENT(in) ::   time_offset ! time offset in units of timesteps. NB. if kit
377      !                                              ! is present then units = subcycle timesteps.
378      !                                              ! time_offset = 0  => get data at "now"    time level
379      !                                              ! time_offset = -1 => get data at "before" time level
380      !                                              ! time_offset = +1 => get data at "after"  time level
381      !                                              ! etc.
382      !
383      LOGICAL  ::   lk_first_btstp            ! =.TRUE. if time splitting and first barotropic step
384      INTEGER  ::   itide, ib_bdy, ib, igrd   ! loop indices
385      INTEGER  ::   time_add                  ! time offset in units of timesteps
386      INTEGER, DIMENSION(jpbgrd)   ::   ilen0 
387      INTEGER, DIMENSION(1:jpbgrd) ::   nblen, nblenrim  ! short cuts
388      REAL(wp) ::   z_arg, z_sarg, zramp, zoff, z_cost, z_sist     
389      !!----------------------------------------------------------------------
390      !
391      IF( nn_timing == 1 )   CALL timing_start('bdy_dta_tides')
392      !
393      lk_first_btstp=.TRUE.
394      IF ( PRESENT(kit).AND.( kit /= 1 ) ) THEN ; lk_first_btstp=.FALSE. ; ENDIF
395
396      time_add = 0
397      IF( PRESENT(time_offset) ) THEN
398         time_add = time_offset
399      ENDIF
400     
401      ! Absolute time from model initialization:   
402      IF( PRESENT(kit) ) THEN 
403         z_arg = ( kt + (kit+time_add-1) / REAL(nn_baro,wp) ) * rdt
404      ELSE                             
405         z_arg = ( kt + time_add ) * rdt
406      ENDIF
407
408      ! Linear ramp on tidal component at open boundaries
409      zramp = 1.
410      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg - nit000*rdt)/(rdttideramp*rday),0.),1.)
411
412      DO ib_bdy = 1,nb_bdy
413         !
414         IF( nn_dyn2d_dta(ib_bdy) >= 2 ) THEN
415            !
416            nblen(1:jpbgrd) = idx_bdy(ib_bdy)%nblen(1:jpbgrd)
417            nblenrim(1:jpbgrd) = idx_bdy(ib_bdy)%nblenrim(1:jpbgrd)
418            !
419            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN   ;   ilen0(:) = nblen   (:)
420            ELSE                                   ;   ilen0(:) = nblenrim(:)
421            ENDIF     
422            !
423            ! We refresh nodal factors every day below
424            ! This should be done somewhere else
425            IF ( ( nsec_day == NINT(0.5_wp * rdt) .OR. kt==nit000 ) .AND. lk_first_btstp ) THEN
426               !
427               kt_tide = kt - (nsec_day - 0.5_wp * rdt)/rdt
428               !
429               IF(lwp) THEN
430               WRITE(numout,*)
431               WRITE(numout,*) 'bdy_tide_dta : Refresh nodal factors for tidal open bdy data at kt=',kt
432               WRITE(numout,*) '~~~~~~~~~~~~~~ '
433               ENDIF
434               !
435               CALL tide_init_elevation ( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
436               CALL tide_init_velocities( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
437               !
438            ENDIF
439            zoff = -kt_tide * rdt ! time offset relative to nodal factor computation time
440            !
441            ! If time splitting, initialize arrays from slow varying open boundary data:
442            IF ( PRESENT(kit) ) THEN           
443               IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy(ib_bdy)%ssh(1:ilen0(1)) = dta_bdy_s(ib_bdy)%ssh(1:ilen0(1))
444               IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy(ib_bdy)%u2d(1:ilen0(2)) = dta_bdy_s(ib_bdy)%u2d(1:ilen0(2))
445               IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy(ib_bdy)%v2d(1:ilen0(3)) = dta_bdy_s(ib_bdy)%v2d(1:ilen0(3))
446            ENDIF
447            !
448            ! Update open boundary data arrays:
449            DO itide = 1, nb_harmo
450               !
451               z_sarg = (z_arg + zoff) * omega_tide(itide)
452               z_cost = zramp * COS( z_sarg )
453               z_sist = zramp * SIN( z_sarg )
454               !
455               IF ( dta_bdy(ib_bdy)%ll_ssh ) THEN
456                  igrd=1                              ! SSH on tracer grid
457                  DO ib = 1, ilen0(igrd)
458                     dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + &
459                        &                      ( tides(ib_bdy)%ssh(ib,itide,1)*z_cost + &
460                        &                        tides(ib_bdy)%ssh(ib,itide,2)*z_sist )
461                  END DO
462               ENDIF
463               !
464               IF ( dta_bdy(ib_bdy)%ll_u2d ) THEN
465                  igrd=2                              ! U grid
466                  DO ib = 1, ilen0(igrd)
467                     dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) + &
468                        &                      ( tides(ib_bdy)%u(ib,itide,1)*z_cost + &
469                        &                        tides(ib_bdy)%u(ib,itide,2)*z_sist )
470                  END DO
471               ENDIF
472               !
473               IF ( dta_bdy(ib_bdy)%ll_v2d ) THEN
474                  igrd=3                              ! V grid
475                  DO ib = 1, ilen0(igrd) 
476                     dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) + &
477                        &                      ( tides(ib_bdy)%v(ib,itide,1)*z_cost + &
478                        &                        tides(ib_bdy)%v(ib,itide,2)*z_sist )
479                  END DO
480               ENDIF
481            END DO             
482         END IF
483      END DO
484      !
485      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_tides')
486      !
487   END SUBROUTINE bdy_dta_tides
488
489
490   SUBROUTINE tide_init_elevation( idx, td )
491      !!----------------------------------------------------------------------
492      !!                 ***  ROUTINE tide_init_elevation  ***
493      !!----------------------------------------------------------------------
494      TYPE(OBC_INDEX) , INTENT(in   ) ::   idx   ! OBC indices
495      TYPE(TIDES_DATA), INTENT(inout) ::   td    ! tidal harmonics data
496      !
497      INTEGER ::   itide, igrd, ib       ! dummy loop indices
498      INTEGER, DIMENSION(1) ::   ilen0   ! length of boundary data (from OBC arrays)
499      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
500      !!----------------------------------------------------------------------
501      !
502      igrd=1   
503                              ! SSH on tracer grid.
504      ilen0(1) =  SIZE(td%ssh0(:,1,1))
505      !
506      ALLOCATE( mod_tide(ilen0(igrd)), phi_tide(ilen0(igrd)) )
507      !
508      DO itide = 1, nb_harmo
509         DO ib = 1, ilen0(igrd)
510            mod_tide(ib)=SQRT(td%ssh0(ib,itide,1)**2.+td%ssh0(ib,itide,2)**2.)
511            phi_tide(ib)=ATAN2(-td%ssh0(ib,itide,2),td%ssh0(ib,itide,1))
512         END DO
513         DO ib = 1 , ilen0(igrd)
514            mod_tide(ib)=mod_tide(ib)*ftide(itide)
515            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
516         ENDDO
517         DO ib = 1 , ilen0(igrd)
518            td%ssh(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
519            td%ssh(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
520         ENDDO
521      END DO
522      !
523      DEALLOCATE( mod_tide, phi_tide )
524      !
525   END SUBROUTINE tide_init_elevation
526
527
528   SUBROUTINE tide_init_velocities( idx, td )
529      !!----------------------------------------------------------------------
530      !!                 ***  ROUTINE tide_init_elevation  ***
531      !!----------------------------------------------------------------------
532      TYPE(OBC_INDEX) , INTENT(in   ) ::   idx   ! OBC indices
533      TYPE(TIDES_DATA), INTENT(inout) ::   td    ! tidal harmonics data
534      !
535      INTEGER ::   itide, igrd, ib       ! dummy loop indices
536      INTEGER, DIMENSION(3) ::   ilen0   ! length of boundary data (from OBC arrays)
537      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
538      !!----------------------------------------------------------------------
539      !
540      ilen0(2) =  SIZE(td%u0(:,1,1))
541      ilen0(3) =  SIZE(td%v0(:,1,1))
542      !
543      igrd=2                                 ! U grid.
544      !
545      ALLOCATE( mod_tide(ilen0(igrd)) , phi_tide(ilen0(igrd)) )
546      !
547      DO itide = 1, nb_harmo
548         DO ib = 1, ilen0(igrd)
549            mod_tide(ib)=SQRT(td%u0(ib,itide,1)**2.+td%u0(ib,itide,2)**2.)
550            phi_tide(ib)=ATAN2(-td%u0(ib,itide,2),td%u0(ib,itide,1))
551         END DO
552         DO ib = 1, ilen0(igrd)
553            mod_tide(ib)=mod_tide(ib)*ftide(itide)
554            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
555         ENDDO
556         DO ib = 1, ilen0(igrd)
557            td%u(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
558            td%u(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
559         ENDDO
560      END DO
561      !
562      DEALLOCATE( mod_tide , phi_tide )
563      !
564      igrd=3                                 ! V grid.
565      !
566      ALLOCATE( mod_tide(ilen0(igrd)) , phi_tide(ilen0(igrd)) )
567
568      DO itide = 1, nb_harmo
569         DO ib = 1, ilen0(igrd)
570            mod_tide(ib)=SQRT(td%v0(ib,itide,1)**2.+td%v0(ib,itide,2)**2.)
571            phi_tide(ib)=ATAN2(-td%v0(ib,itide,2),td%v0(ib,itide,1))
572         END DO
573         DO ib = 1, ilen0(igrd)
574            mod_tide(ib)=mod_tide(ib)*ftide(itide)
575            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
576         ENDDO
577         DO ib = 1, ilen0(igrd)
578            td%v(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
579            td%v(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
580         ENDDO
581      END DO
582      !
583      DEALLOCATE( mod_tide, phi_tide )
584      !
585  END SUBROUTINE tide_init_velocities
586
587   !!======================================================================
588END MODULE bdytides
589
Note: See TracBrowser for help on using the repository browser.