source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/CRS/crsfld.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 4 years ago

All wrk_alloc removed

  • Property svn:keywords set to Id
File size: 10.5 KB
Line 
1MODULE crsfld
2   !!======================================================================
3   !!                     ***  MODULE  crsdfld  ***
4   !!  Ocean coarsening :  coarse ocean fields
5   !!=====================================================================
6   !!   2012-07  (J. Simeon, C. Calone, G. Madec, C. Ethe)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   crs_fld       : create the standard output files for coarse grid and prep
11   !!                       other variables needed to be passed to TOP
12   !!----------------------------------------------------------------------
13   USE crs
14   USE crsdom
15   USE crslbclnk
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! Surface boundary condition: ocean fields
19   USE zdf_oce         ! vertical  physics: ocean fields
20   USE ldftra          ! ocean active tracers: lateral diffusivity & EIV coefficients
21   USE zdfddm          ! vertical  physics: double diffusion
22   !
23   USE in_out_manager  ! I/O manager
24   USE iom             !
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE timing          ! preformance summary
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   crs_fld                 ! routines called by step.F90
32
33   !! * Substitutions
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE crs_fld( kt )
43      !!---------------------------------------------------------------------
44      !!                  ***  ROUTINE crs_fld  ***
45      !!                   
46      !! ** Purpose :   Basic output of coarsened dynamics and tracer fields
47      !!      NETCDF format is used by default
48      !!      1. Accumulate in time the dimensionally-weighted fields
49      !!      2. At time of output, rescale [1] by dimension and time
50      !!         to yield the spatial and temporal average.
51      !!  See. sbcmod.F90
52      !!
53      !! ** Method  : 
54      !!----------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
56      !
57      INTEGER  ::   ji, jj, jk        ! dummy loop indices
58      REAL(wp) ::   z2dcrsu, z2dcrsv  ! local scalars
59      !
60      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze3t, ze3u, ze3v, ze3w   ! 3D workspace for e3
61      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zt, zs
62      REAL(wp), DIMENSION(jpi_crs,jpj_crs,jpk) ::   zt_crs, zs_crs 
63      !!----------------------------------------------------------------------
64      !
65      IF( nn_timing == 1 )   CALL timing_start('crs_fld')
66
67      !  Initialize arrays
68      !
69
70      ! Depth work arrrays
71      ze3t(:,:,:) = e3t_n(:,:,:)
72      ze3u(:,:,:) = e3u_n(:,:,:)
73      ze3v(:,:,:) = e3v_n(:,:,:)
74      ze3w(:,:,:) = e3w_n(:,:,:)
75
76      IF( kt == nit000  ) THEN
77         tsn_crs  (:,:,:,:) = 0._wp    ! temp/sal  array, now
78         un_crs   (:,:,:  ) = 0._wp    ! u-velocity
79         vn_crs   (:,:,:  ) = 0._wp    ! v-velocity
80         wn_crs   (:,:,:  ) = 0._wp    ! w
81         avt_crs  (:,:,:  ) = 0._wp    ! avt
82         hdivn_crs(:,:,:  ) = 0._wp    ! hdiv
83         rke_crs  (:,:,:  ) = 0._wp    ! rke
84         sshn_crs (:,:    ) = 0._wp    ! ssh
85         utau_crs (:,:    ) = 0._wp    ! taux
86         vtau_crs (:,:    ) = 0._wp    ! tauy
87         wndm_crs (:,:    ) = 0._wp    ! wind speed
88         qsr_crs  (:,:    ) = 0._wp    ! qsr
89         emp_crs  (:,:    ) = 0._wp    ! emp
90         emp_b_crs(:,:    ) = 0._wp    ! emp
91         rnf_crs  (:,:    ) = 0._wp    ! runoff
92         fr_i_crs (:,:    ) = 0._wp    ! ice cover
93      ENDIF
94
95      CALL iom_swap( "nemo_crs" )    ! swap on the coarse grid
96
97      ! 2. Coarsen fields at each time step
98      ! --------------------------------------------------------
99
100      !  Temperature
101      zt(:,:,:) = tsn(:,:,:,jp_tem)  ;      zt_crs(:,:,:) = 0._wp
102      CALL crs_dom_ope( zt, 'VOL', 'T', tmask, zt_crs, p_e12=e1e2t, p_e3=ze3t, psgn=1.0 )
103      tsn_crs(:,:,:,jp_tem) = zt_crs(:,:,:)
104
105      CALL iom_put( "toce", tsn_crs(:,:,:,jp_tem) )    ! temp
106      CALL iom_put( "sst" , tsn_crs(:,:,1,jp_tem) )    ! sst
107
108     
109      !  Salinity
110      zs(:,:,:) = tsn(:,:,:,jp_sal)  ;      zs_crs(:,:,:) = 0._wp
111      CALL crs_dom_ope( zs, 'VOL', 'T', tmask, zs_crs, p_e12=e1e2t, p_e3=ze3t, psgn=1.0 )
112      tsn_crs(:,:,:,jp_sal) = zt_crs(:,:,:)
113
114      CALL iom_put( "soce" , tsn_crs(:,:,:,jp_sal) )    ! sal
115      CALL iom_put( "sss"  , tsn_crs(:,:,1,jp_sal) )    ! sss
116
117      !  U-velocity
118      CALL crs_dom_ope( un, 'SUM', 'U', umask, un_crs, p_e12=e2u, p_e3=ze3u, p_surf_crs=e2e3u_msk, psgn=-1.0 )
119      !
120      zt(:,:,:) = 0._wp     ;    zs(:,:,:) = 0._wp  ;   zt_crs(:,:,:) = 0._wp   ;    zs_crs(:,:,:) = 0._wp
121      DO jk = 1, jpkm1
122         DO jj = 2, jpjm1
123            DO ji = 2, jpim1   
124               zt(ji,jj,jk)  = un(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_tem) + tsn(ji+1,jj,jk,jp_tem) ) 
125               zs(ji,jj,jk)  = un(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_sal) + tsn(ji+1,jj,jk,jp_sal) ) 
126            END DO
127         END DO
128      END DO
129      CALL crs_dom_ope( zt, 'SUM', 'U', umask, zt_crs, p_e12=e2u, p_e3=ze3u, p_surf_crs=e2e3u_msk, psgn=-1.0 )
130      CALL crs_dom_ope( zs, 'SUM', 'U', umask, zs_crs, p_e12=e2u, p_e3=ze3u, p_surf_crs=e2e3u_msk, psgn=-1.0 )
131
132      CALL iom_put( "uoce"  , un_crs )   ! i-current
133      CALL iom_put( "uocet" , zt_crs )   ! uT
134      CALL iom_put( "uoces" , zs_crs )   ! uS
135
136      !  V-velocity
137      CALL crs_dom_ope( vn, 'SUM', 'V', vmask, vn_crs, p_e12=e1v, p_e3=ze3v, p_surf_crs=e1e3v_msk, psgn=-1.0 )
138      !                                                                                 
139      zt(:,:,:) = 0._wp     ;    zs(:,:,:) = 0._wp  ;   zt_crs(:,:,:) = 0._wp   ;    zs_crs(:,:,:) = 0._wp
140      DO jk = 1, jpkm1
141         DO jj = 2, jpjm1
142            DO ji = 2, jpim1   
143               zt(ji,jj,jk)  = vn(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_tem) + tsn(ji,jj+1,jk,jp_tem) ) 
144               zs(ji,jj,jk)  = vn(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_sal) + tsn(ji,jj+1,jk,jp_sal) ) 
145            END DO
146         END DO
147      END DO
148      CALL crs_dom_ope( zt, 'SUM', 'V', vmask, zt_crs, p_e12=e1v, p_e3=ze3v, p_surf_crs=e1e3v_msk, psgn=-1.0 )
149      CALL crs_dom_ope( zs, 'SUM', 'V', vmask, zs_crs, p_e12=e1v, p_e3=ze3v, p_surf_crs=e1e3v_msk, psgn=-1.0 )
150 
151      CALL iom_put( "voce"  , vn_crs )   ! i-current
152      CALL iom_put( "vocet" , zt_crs )   ! vT
153      CALL iom_put( "voces" , zs_crs )   ! vS
154
155     
156      !  Kinetic energy
157      CALL crs_dom_ope( rke, 'VOL', 'T', tmask, rke_crs, p_e12=e1e2t, p_e3=ze3t, psgn=1.0 )
158      CALL iom_put( "eken", rke_crs )
159
160      !  Horizontal divergence ( following OPA_SRC/DYN/divhor.F90 )
161      DO jk = 1, jpkm1
162         DO ji = 2, jpi_crsm1
163            DO jj = 2, jpj_crsm1
164               IF( tmask_crs(ji,jj,jk ) > 0 ) THEN
165                   z2dcrsu =  ( un_crs(ji  ,jj  ,jk) * crs_surfu_wgt(ji  ,jj  ,jk) ) &
166                      &     - ( un_crs(ji-1,jj  ,jk) * crs_surfu_wgt(ji-1,jj  ,jk) )
167                   z2dcrsv =  ( vn_crs(ji  ,jj  ,jk) * crs_surfv_wgt(ji  ,jj  ,jk) ) &
168                      &     - ( vn_crs(ji  ,jj-1,jk) * crs_surfv_wgt(ji  ,jj-1,jk) )
169                   !
170                   hdivn_crs(ji,jj,jk) = ( z2dcrsu + z2dcrsv ) / crs_volt_wgt(ji,jj,jk) 
171               ENDIF
172            ENDDO
173         ENDDO
174      ENDDO
175      CALL crs_lbc_lnk( hdivn_crs, 'T', 1.0 )
176      !
177      CALL iom_put( "hdiv", hdivn_crs ) 
178
179
180      !  W-velocity
181      IF( ln_crs_wn ) THEN
182         CALL crs_dom_ope( wn, 'SUM', 'W', tmask, wn_crs, p_e12=e1e2t, p_surf_crs=e1e2w_msk, psgn=1.0 )
183       !  CALL crs_dom_ope( wn, 'VOL', 'W', tmask, wn_crs, p_e12=e1e2t, p_e3=ze3w )
184      ELSE
185        wn_crs(:,:,jpk) = 0._wp
186        DO jk = jpkm1, 1, -1
187           wn_crs(:,:,jk) = wn_crs(:,:,jk+1) - e3t_crs(:,:,jk) * hdivn_crs(:,:,jk)
188        ENDDO
189      ENDIF
190      CALL iom_put( "woce", wn_crs  )   ! vertical velocity
191      !  free memory
192
193      !  avt, avs
194!!gm BUG   TOP always uses avs !!!
195      SELECT CASE ( nn_crs_kz )
196         CASE ( 0 )
197            CALL crs_dom_ope( avt, 'VOL', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0 )
198         CASE ( 1 )
199            CALL crs_dom_ope( avt, 'MAX', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0 )
200         CASE ( 2 )
201            CALL crs_dom_ope( avt, 'MIN', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0 )
202      END SELECT
203      !
204      CALL iom_put( "avt", avt_crs )   !  Kz
205     
206      !  sbc fields 
207      CALL crs_dom_ope( sshn , 'VOL', 'T', tmask, sshn_crs , p_e12=e1e2t, p_e3=ze3t           , psgn=1.0 ) 
208      CALL crs_dom_ope( utau , 'SUM', 'U', umask, utau_crs , p_e12=e2u  , p_surf_crs=e2u_crs  , psgn=1.0 )
209      CALL crs_dom_ope( vtau , 'SUM', 'V', vmask, vtau_crs , p_e12=e1v  , p_surf_crs=e1v_crs  , psgn=1.0 )
210      CALL crs_dom_ope( wndm , 'SUM', 'T', tmask, wndm_crs , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
211      CALL crs_dom_ope( rnf  , 'MAX', 'T', tmask, rnf_crs                                     , psgn=1.0 )
212      CALL crs_dom_ope( qsr  , 'SUM', 'T', tmask, qsr_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
213      CALL crs_dom_ope( emp_b, 'SUM', 'T', tmask, emp_b_crs, p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
214      CALL crs_dom_ope( emp  , 'SUM', 'T', tmask, emp_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
215      CALL crs_dom_ope( sfx  , 'SUM', 'T', tmask, sfx_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
216      CALL crs_dom_ope( fr_i , 'SUM', 'T', tmask, fr_i_crs , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
217
218      CALL iom_put( "ssh"      , sshn_crs )   ! ssh output
219      CALL iom_put( "utau"     , utau_crs )   ! i-tau output
220      CALL iom_put( "vtau"     , vtau_crs )   ! j-tau output
221      CALL iom_put( "wspd"     , wndm_crs )   ! wind speed output
222      CALL iom_put( "runoffs"  , rnf_crs  )   ! runoff output
223      CALL iom_put( "qsr"      , qsr_crs  )   ! qsr output
224      CALL iom_put( "empmr"    , emp_crs  )   ! water flux output
225      CALL iom_put( "saltflx"  , sfx_crs  )   ! salt flux output
226      CALL iom_put( "ice_cover", fr_i_crs )   ! ice cover output
227
228      !  free memory
229      !
230      CALL iom_swap( "nemo" )     ! return back on high-resolution grid
231      !
232      IF( nn_timing == 1 )   CALL timing_stop('crs_fld')
233      !
234   END SUBROUTINE crs_fld
235
236   !!======================================================================
237END MODULE crsfld
Note: See TracBrowser for help on using the repository browser.