| 1 | MODULE dynadv_cen2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE dynadv *** |
|---|
| 4 | !! Ocean dynamics: Update the momentum trend with the flux form advection |
|---|
| 5 | !! using a 2nd order centred scheme |
|---|
| 6 | !!====================================================================== |
|---|
| 7 | !! History : 2.0 ! 2006-08 (G. Madec, S. Theetten) Original code |
|---|
| 8 | !! 3.2 ! 2009-07 (R. Benshila) Suppression of rigid-lid option |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! dyn_adv_cen2 : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | USE oce ! ocean dynamics and tracers |
|---|
| 15 | USE dom_oce ! ocean space and time domain |
|---|
| 16 | USE trd_oce ! trends: ocean variables |
|---|
| 17 | USE trddyn ! trend manager: dynamics |
|---|
| 18 | ! |
|---|
| 19 | USE in_out_manager ! I/O manager |
|---|
| 20 | USE lib_mpp ! MPP library |
|---|
| 21 | USE prtctl ! Print control |
|---|
| 22 | USE timing ! Timing |
|---|
| 23 | |
|---|
| 24 | IMPLICIT NONE |
|---|
| 25 | PRIVATE |
|---|
| 26 | |
|---|
| 27 | PUBLIC dyn_adv_cen2 ! routine called by step.F90 |
|---|
| 28 | |
|---|
| 29 | !! * Substitutions |
|---|
| 30 | # include "vectopt_loop_substitute.h90" |
|---|
| 31 | !!---------------------------------------------------------------------- |
|---|
| 32 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
|---|
| 33 | !! $Id$ |
|---|
| 34 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 35 | !!---------------------------------------------------------------------- |
|---|
| 36 | CONTAINS |
|---|
| 37 | |
|---|
| 38 | SUBROUTINE dyn_adv_cen2( kt ) |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | !! *** ROUTINE dyn_adv_cen2 *** |
|---|
| 41 | !! |
|---|
| 42 | !! ** Purpose : Compute the now momentum advection trend in flux form |
|---|
| 43 | !! and the general trend of the momentum equation. |
|---|
| 44 | !! |
|---|
| 45 | !! ** Method : Trend evaluated using now fields (centered in time) |
|---|
| 46 | !! |
|---|
| 47 | !! ** Action : (ua,va) updated with the now vorticity term trend |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
|---|
| 50 | ! |
|---|
| 51 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 52 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfw |
|---|
| 53 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zfu, zfv |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | ! |
|---|
| 56 | IF( nn_timing == 1 ) CALL timing_start('dyn_adv_cen2') |
|---|
| 57 | ! |
|---|
| 58 | ! |
|---|
| 59 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 60 | WRITE(numout,*) |
|---|
| 61 | WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection' |
|---|
| 62 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 63 | ENDIF |
|---|
| 64 | ! |
|---|
| 65 | IF( l_trddyn ) THEN ! trends: store the input trends |
|---|
| 66 | zfu_uw(:,:,:) = ua(:,:,:) |
|---|
| 67 | zfv_vw(:,:,:) = va(:,:,:) |
|---|
| 68 | ENDIF |
|---|
| 69 | ! |
|---|
| 70 | ! !== Horizontal advection ==! |
|---|
| 71 | ! |
|---|
| 72 | DO jk = 1, jpkm1 ! horizontal transport |
|---|
| 73 | zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u_n(:,:,jk) * un(:,:,jk) |
|---|
| 74 | zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v_n(:,:,jk) * vn(:,:,jk) |
|---|
| 75 | DO jj = 1, jpjm1 ! horizontal momentum fluxes (at T- and F-point) |
|---|
| 76 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 77 | zfu_t(ji+1,jj ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj ,jk) ) |
|---|
| 78 | zfv_f(ji ,jj ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji ,jj+1,jk) ) |
|---|
| 79 | zfu_f(ji ,jj ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj ,jk) ) |
|---|
| 80 | zfv_t(ji ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji ,jj+1,jk) ) |
|---|
| 81 | END DO |
|---|
| 82 | END DO |
|---|
| 83 | DO jj = 2, jpjm1 ! divergence of horizontal momentum fluxes |
|---|
| 84 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 85 | ua(ji,jj,jk) = ua(ji,jj,jk) - ( zfu_t(ji+1,jj,jk) - zfu_t(ji,jj ,jk) & |
|---|
| 86 | & + zfv_f(ji ,jj,jk) - zfv_f(ji,jj-1,jk) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk) |
|---|
| 87 | va(ji,jj,jk) = va(ji,jj,jk) - ( zfu_f(ji,jj ,jk) - zfu_f(ji-1,jj,jk) & |
|---|
| 88 | & + zfv_t(ji,jj+1,jk) - zfv_t(ji ,jj,jk) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk) |
|---|
| 89 | END DO |
|---|
| 90 | END DO |
|---|
| 91 | END DO |
|---|
| 92 | ! |
|---|
| 93 | IF( l_trddyn ) THEN ! trends: send trend to trddyn for diagnostic |
|---|
| 94 | zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:) |
|---|
| 95 | zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:) |
|---|
| 96 | CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt ) |
|---|
| 97 | zfu_t(:,:,:) = ua(:,:,:) |
|---|
| 98 | zfv_t(:,:,:) = va(:,:,:) |
|---|
| 99 | ENDIF |
|---|
| 100 | ! |
|---|
| 101 | ! !== Vertical advection ==! |
|---|
| 102 | ! |
|---|
| 103 | DO jj = 2, jpjm1 ! surface/bottom advective fluxes set to zero |
|---|
| 104 | DO ji = fs_2, fs_jpim1 |
|---|
| 105 | zfu_uw(ji,jj,jpk) = 0._wp ; zfv_vw(jj,jj,jpk) = 0._wp |
|---|
| 106 | zfu_uw(ji,jj, 1 ) = 0._wp ; zfv_vw(jj,jj, 1 ) = 0._wp |
|---|
| 107 | END DO |
|---|
| 108 | END DO |
|---|
| 109 | IF( ln_linssh ) THEN ! linear free surface: advection through the surface |
|---|
| 110 | DO jj = 2, jpjm1 |
|---|
| 111 | DO ji = fs_2, fs_jpim1 |
|---|
| 112 | zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji+1,jj) * wn(ji+1,jj,1) ) * un(ji,jj,1) |
|---|
| 113 | zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji,jj+1) * wn(ji,jj+1,1) ) * vn(ji,jj,1) |
|---|
| 114 | END DO |
|---|
| 115 | END DO |
|---|
| 116 | ENDIF |
|---|
| 117 | DO jk = 2, jpkm1 ! interior advective fluxes |
|---|
| 118 | DO jj = 2, jpj ! 1/4 * Vertical transport |
|---|
| 119 | DO ji = 2, jpi |
|---|
| 120 | zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk) |
|---|
| 121 | END DO |
|---|
| 122 | END DO |
|---|
| 123 | DO jj = 2, jpjm1 |
|---|
| 124 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 125 | zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) ) |
|---|
| 126 | zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) ) |
|---|
| 127 | END DO |
|---|
| 128 | END DO |
|---|
| 129 | END DO |
|---|
| 130 | DO jk = 1, jpkm1 ! divergence of vertical momentum flux divergence |
|---|
| 131 | DO jj = 2, jpjm1 |
|---|
| 132 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 133 | ua(ji,jj,jk) = ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk) |
|---|
| 134 | va(ji,jj,jk) = va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk) |
|---|
| 135 | END DO |
|---|
| 136 | END DO |
|---|
| 137 | END DO |
|---|
| 138 | ! |
|---|
| 139 | IF( l_trddyn ) THEN ! trends: send trend to trddyn for diagnostic |
|---|
| 140 | zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:) |
|---|
| 141 | zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:) |
|---|
| 142 | CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt ) |
|---|
| 143 | ENDIF |
|---|
| 144 | ! ! Control print |
|---|
| 145 | IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask, & |
|---|
| 146 | & tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' ) |
|---|
| 147 | ! |
|---|
| 148 | ! |
|---|
| 149 | IF( nn_timing == 1 ) CALL timing_stop('dyn_adv_cen2') |
|---|
| 150 | ! |
|---|
| 151 | END SUBROUTINE dyn_adv_cen2 |
|---|
| 152 | |
|---|
| 153 | !!============================================================================== |
|---|
| 154 | END MODULE dynadv_cen2 |
|---|
