New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynkeg.F90 in branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/DYN/dynkeg.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 7 years ago

All wrk_alloc removed

  • Property svn:keywords set to Id
File size: 8.8 KB
Line 
1MODULE dynkeg
2   !!======================================================================
3   !!                       ***  MODULE  dynkeg  ***
4   !! Ocean dynamics:  kinetic energy gradient trend
5   !!======================================================================
6   !! History :  1.0  !  1987-09  (P. Andrich, M.-A. Foujols)  Original code
7   !!            7.0  !  1997-05  (G. Madec)  Split dynber into dynkeg and dynhpg
8   !!  NEMO      1.0  !  2002-07  (G. Madec)  F90: Free form and module
9   !!            3.6  !  2015-05  (N. Ducousso, G. Madec)  add Hollingsworth scheme as an option
10   !!----------------------------------------------------------------------
11   
12   !!----------------------------------------------------------------------
13   !!   dyn_keg      : update the momentum trend with the horizontal tke
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE trd_oce         ! trends: ocean variables
18   USE trddyn          ! trend manager: dynamics
19   !
20   USE in_out_manager  ! I/O manager
21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
22   USE lib_mpp         ! MPP library
23   USE prtctl          ! Print control
24   USE timing          ! Timing
25   USE bdy_oce         ! ocean open boundary conditions
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   dyn_keg    ! routine called by step module
31   
32   INTEGER, PARAMETER, PUBLIC  ::   nkeg_C2  = 0   !: 2nd order centered scheme (standard scheme)
33   INTEGER, PARAMETER, PUBLIC  ::   nkeg_HW  = 1   !: Hollingsworth et al., QJRMS, 1983
34   !
35   REAL(wp) ::   r1_48 = 1._wp / 48._wp   !: =1/(4*2*6)
36   
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.6 , NEMO Consortium (2015)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE dyn_keg( kt, kscheme )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE dyn_keg  ***
49      !!
50      !! ** Purpose :   Compute the now momentum trend due to the horizontal
51      !!      gradient of the horizontal kinetic energy and add it to the
52      !!      general momentum trend.
53      !!
54      !! ** Method  : * kscheme = nkeg_C2 : 2nd order centered scheme that
55      !!      conserve kinetic energy. Compute the now horizontal kinetic energy
56      !!         zhke = 1/2 [ mi-1( un^2 ) + mj-1( vn^2 ) ]
57      !!              * kscheme = nkeg_HW : Hollingsworth correction following
58      !!      Arakawa (2001). The now horizontal kinetic energy is given by:
59      !!         zhke = 1/6 [ mi-1(  2 * un^2 + ((un(j+1)+un(j-1))/2)^2  )
60      !!                    + mj-1(  2 * vn^2 + ((vn(i+1)+vn(i-1))/2)^2  ) ]
61      !!     
62      !!      Take its horizontal gradient and add it to the general momentum
63      !!      trend (ua,va).
64      !!         ua = ua - 1/e1u di[ zhke ]
65      !!         va = va - 1/e2v dj[ zhke ]
66      !!
67      !! ** Action : - Update the (ua, va) with the hor. ke gradient trend
68      !!             - send this trends to trd_dyn (l_trddyn=T) for post-processing
69      !!
70      !! ** References : Arakawa, A., International Geophysics 2001.
71      !!                 Hollingsworth et al., Quart. J. Roy. Meteor. Soc., 1983.
72      !!----------------------------------------------------------------------
73      INTEGER, INTENT( in ) ::   kt        ! ocean time-step index
74      INTEGER, INTENT( in ) ::   kscheme   ! =0/1   type of KEG scheme
75      !
76      INTEGER  ::   ji, jj, jk   ! dummy loop indices
77      REAL(wp) ::   zu, zv       ! temporary scalars
78      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhke
79      REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztrdu, ztrdv 
80      INTEGER  ::   jb                 ! dummy loop indices
81      INTEGER  ::   ii, ij, igrd, ib_bdy   ! local integers
82      INTEGER  ::   fu, fv
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )   CALL timing_start('dyn_keg')
86      !
87      !
88      IF( kt == nit000 ) THEN
89         IF(lwp) WRITE(numout,*)
90         IF(lwp) WRITE(numout,*) 'dyn_keg : kinetic energy gradient trend, scheme number=', kscheme
91         IF(lwp) WRITE(numout,*) '~~~~~~~'
92      ENDIF
93
94      IF( l_trddyn ) THEN           ! Save ua and va trends
95         ztrdu(:,:,:) = ua(:,:,:) 
96         ztrdv(:,:,:) = va(:,:,:) 
97      ENDIF
98     
99      zhke(:,:,jpk) = 0._wp
100     
101      IF (ln_bdy) THEN
102         ! Maria Luneva & Fred Wobus: July-2016
103         ! compensate for lack of turbulent kinetic energy on liquid bdy points
104         DO ib_bdy = 1, nb_bdy
105            IF( cn_dyn3d(ib_bdy) /= 'none' ) THEN
106               igrd = 2           ! Copying normal velocity into points outside bdy
107               DO jb = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
108                  DO jk = 1, jpkm1
109                     ii   = idx_bdy(ib_bdy)%nbi(jb,igrd)
110                     ij   = idx_bdy(ib_bdy)%nbj(jb,igrd)
111                     fu   = NINT( idx_bdy(ib_bdy)%flagu(jb,igrd) )
112                     un(ii-fu,ij,jk) = un(ii,ij,jk) * umask(ii,ij,jk)
113                  END DO
114               END DO
115               !
116               igrd = 3           ! Copying normal velocity into points outside bdy
117               DO jb = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
118                  DO jk = 1, jpkm1
119                     ii   = idx_bdy(ib_bdy)%nbi(jb,igrd)
120                     ij   = idx_bdy(ib_bdy)%nbj(jb,igrd)
121                     fv   = NINT( idx_bdy(ib_bdy)%flagv(jb,igrd) )
122                     vn(ii,ij-fv,jk) = vn(ii,ij,jk) * vmask(ii,ij,jk)
123                  END DO
124               END DO
125            ENDIF
126         ENDDO 
127      ENDIF
128
129      SELECT CASE ( kscheme )             !== Horizontal kinetic energy at T-point  ==!
130      !
131      CASE ( nkeg_C2 )                          !--  Standard scheme  --!
132         DO jk = 1, jpkm1
133            DO jj = 2, jpj
134               DO ji = fs_2, jpi   ! vector opt.
135                  zu =    un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)   &
136                     &  + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk)
137                  zv =    vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)   &
138                     &  + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk)
139                  zhke(ji,jj,jk) = 0.25_wp * ( zv + zu )
140               END DO 
141            END DO
142         END DO
143         !
144      CASE ( nkeg_HW )                          !--  Hollingsworth scheme  --!
145         DO jk = 1, jpkm1
146            DO jj = 2, jpjm1       
147               DO ji = fs_2, jpim1   ! vector opt.
148                  zu = 8._wp * ( un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)    &
149                     &         + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk) )  &
150                     &   +     ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) ) * ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) )   &
151                     &   +     ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) ) * ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) )
152                     !
153                  zv = 8._wp * ( vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)    &
154                     &         + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk) )  &
155                     &  +      ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) ) * ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) )   &
156                     &  +      ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) ) * ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) )
157                  zhke(ji,jj,jk) = r1_48 * ( zv + zu )
158               END DO 
159            END DO
160         END DO
161         CALL lbc_lnk( zhke, 'T', 1. )
162         !
163      END SELECT
164
165      IF (ln_bdy) THEN
166         ! restore velocity masks at points outside boundary
167         un(:,:,:) = un(:,:,:) * umask(:,:,:)
168         vn(:,:,:) = vn(:,:,:) * vmask(:,:,:)
169      ENDIF     
170
171
172      !
173      DO jk = 1, jpkm1                    !==  grad( KE ) added to the general momentum trends  ==!
174         DO jj = 2, jpjm1
175            DO ji = fs_2, fs_jpim1   ! vector opt.
176               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zhke(ji+1,jj  ,jk) - zhke(ji,jj,jk) ) / e1u(ji,jj)
177               va(ji,jj,jk) = va(ji,jj,jk) - ( zhke(ji  ,jj+1,jk) - zhke(ji,jj,jk) ) / e2v(ji,jj)
178            END DO
179         END DO
180      END DO
181      !
182      IF( l_trddyn ) THEN                 ! save the Kinetic Energy trends for diagnostic
183         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
184         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
185         CALL trd_dyn( ztrdu, ztrdv, jpdyn_keg, kt )
186      ENDIF
187      !
188      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' keg  - Ua: ', mask1=umask,   &
189         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
190      !
191      !
192      IF( nn_timing == 1 )   CALL timing_stop('dyn_keg')
193      !
194   END SUBROUTINE dyn_keg
195
196   !!======================================================================
197END MODULE dynkeg
Note: See TracBrowser for help on using the repository browser.