| 1 | MODULE dynzdf_exp |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE dynzdf_exp *** |
|---|
| 4 | !! Ocean dynamics: vertical component(s) of the momentum mixing trend |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 8.0 ! 1997-05 (G. Madec) vertical component of isopycnal |
|---|
| 8 | !! NEMO 0.5 ! 2002-08 (G. Madec) F90: Free form and module |
|---|
| 9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 10 | !! 3.7 ! 2015-11 (J. Chanut) output velocities instead of trends |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! dyn_zdf_exp : update the momentum trend with the vertical diffusion using a split-explicit scheme |
|---|
| 15 | !! and perform the Leap-Frog time integration. |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE phycst ! physical constants |
|---|
| 20 | USE zdf_oce ! ocean vertical physics |
|---|
| 21 | USE dynadv , ONLY: ln_dynadv_vec ! Momentum advection form |
|---|
| 22 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 23 | ! |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE lib_mpp ! MPP library |
|---|
| 26 | USE timing ! Timing |
|---|
| 27 | |
|---|
| 28 | IMPLICIT NONE |
|---|
| 29 | PRIVATE |
|---|
| 30 | |
|---|
| 31 | PUBLIC dyn_zdf_exp ! called by step.F90 |
|---|
| 32 | |
|---|
| 33 | !! * Substitutions |
|---|
| 34 | # include "vectopt_loop_substitute.h90" |
|---|
| 35 | !!---------------------------------------------------------------------- |
|---|
| 36 | !! NEMO/OPA 3.7 , NEMO Consortium (2015) |
|---|
| 37 | !! $Id$ |
|---|
| 38 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | CONTAINS |
|---|
| 41 | |
|---|
| 42 | SUBROUTINE dyn_zdf_exp( kt, p2dt ) |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | !! *** ROUTINE dyn_zdf_exp *** |
|---|
| 45 | !! |
|---|
| 46 | !! ** Purpose : Compute the trend due to the vert. momentum diffusion |
|---|
| 47 | !! and perform the Leap-Frog time stepping. |
|---|
| 48 | !! |
|---|
| 49 | !! ** Method : - Split-explicit forward time stepping. |
|---|
| 50 | !! The vertical mixing of momentum is given by: |
|---|
| 51 | !! diffu = dz( avmu dz(u) ) = 1/e3u dk+1( avmu/e3uw dk(ub) ) |
|---|
| 52 | !! Surface boundary conditions: wind stress input (averaged over kt-1/2 & kt+1/2) |
|---|
| 53 | !! Bottom boundary conditions : bottom stress (cf zdfbfr.F90) |
|---|
| 54 | !! Add this trend to the general trend ua : |
|---|
| 55 | !! ua = ua + dz( avmu dz(u) ) |
|---|
| 56 | !! - Leap-Frog time stepping (Asselin filter will be applied in dyn_nxt) |
|---|
| 57 | !! ua = ub + 2*dt * ua vector form or linear free surf. |
|---|
| 58 | !! ua = ( e3u_b*ub + 2*dt * e3u_n*ua ) / e3u_a otherwise |
|---|
| 59 | !! |
|---|
| 60 | !! ** Action : - (ua,va) after velocity |
|---|
| 61 | !!--------------------------------------------------------------------- |
|---|
| 62 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 63 | REAL(wp), INTENT(in) :: p2dt ! time-step |
|---|
| 64 | ! |
|---|
| 65 | INTEGER :: ji, jj, jk, jl ! dummy loop indices |
|---|
| 66 | REAL(wp) :: zlavmr, zua, zva ! local scalars |
|---|
| 67 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwx, zwy, zwz, zww |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | ! |
|---|
| 70 | IF( nn_timing == 1 ) CALL timing_start('dyn_zdf_exp') |
|---|
| 71 | ! |
|---|
| 72 | ! |
|---|
| 73 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 74 | WRITE(numout,*) |
|---|
| 75 | WRITE(numout,*) 'dyn_zdf_exp : vertical momentum diffusion - explicit operator' |
|---|
| 76 | WRITE(numout,*) '~~~~~~~~~~~ ' |
|---|
| 77 | ENDIF |
|---|
| 78 | ! |
|---|
| 79 | ! !== vertical mixing trend ==! |
|---|
| 80 | ! |
|---|
| 81 | zlavmr = 1. / REAL( nn_zdfexp ) |
|---|
| 82 | ! |
|---|
| 83 | DO jj = 2, jpjm1 ! Surface boundary condition |
|---|
| 84 | DO ji = 2, jpim1 |
|---|
| 85 | zwy(ji,jj,1) = ( utau_b(ji,jj) + utau(ji,jj) ) * r1_rau0 |
|---|
| 86 | zww(ji,jj,1) = ( vtau_b(ji,jj) + vtau(ji,jj) ) * r1_rau0 |
|---|
| 87 | END DO |
|---|
| 88 | END DO |
|---|
| 89 | DO jk = 1, jpk ! Initialization of x, z and contingently trends array |
|---|
| 90 | DO jj = 2, jpjm1 |
|---|
| 91 | DO ji = 2, jpim1 |
|---|
| 92 | zwx(ji,jj,jk) = ub(ji,jj,jk) |
|---|
| 93 | zwz(ji,jj,jk) = vb(ji,jj,jk) |
|---|
| 94 | END DO |
|---|
| 95 | END DO |
|---|
| 96 | END DO |
|---|
| 97 | ! |
|---|
| 98 | DO jl = 1, nn_zdfexp ! Time splitting loop |
|---|
| 99 | ! |
|---|
| 100 | DO jk = 2, jpk ! First vertical derivative |
|---|
| 101 | DO jj = 2, jpjm1 |
|---|
| 102 | DO ji = 2, jpim1 |
|---|
| 103 | zwy(ji,jj,jk) = avmu(ji,jj,jk) * ( zwx(ji,jj,jk-1) - zwx(ji,jj,jk) ) / e3uw_n(ji,jj,jk) |
|---|
| 104 | zww(ji,jj,jk) = avmv(ji,jj,jk) * ( zwz(ji,jj,jk-1) - zwz(ji,jj,jk) ) / e3vw_n(ji,jj,jk) |
|---|
| 105 | END DO |
|---|
| 106 | END DO |
|---|
| 107 | END DO |
|---|
| 108 | DO jk = 1, jpkm1 ! Second vertical derivative and trend estimation at kt+l*rdt/nn_zdfexp |
|---|
| 109 | DO jj = 2, jpjm1 |
|---|
| 110 | DO ji = 2, jpim1 |
|---|
| 111 | zua = zlavmr * ( zwy(ji,jj,jk) - zwy(ji,jj,jk+1) ) / e3u_n(ji,jj,jk) |
|---|
| 112 | zva = zlavmr * ( zww(ji,jj,jk) - zww(ji,jj,jk+1) ) / e3v_n(ji,jj,jk) |
|---|
| 113 | ua(ji,jj,jk) = ua(ji,jj,jk) + zua |
|---|
| 114 | va(ji,jj,jk) = va(ji,jj,jk) + zva |
|---|
| 115 | ! |
|---|
| 116 | zwx(ji,jj,jk) = zwx(ji,jj,jk) + p2dt * zua * umask(ji,jj,jk) |
|---|
| 117 | zwz(ji,jj,jk) = zwz(ji,jj,jk) + p2dt * zva * vmask(ji,jj,jk) |
|---|
| 118 | END DO |
|---|
| 119 | END DO |
|---|
| 120 | END DO |
|---|
| 121 | END DO ! End of time splitting |
|---|
| 122 | ! |
|---|
| 123 | ! |
|---|
| 124 | ! !== Leap-Frog time integration ==! |
|---|
| 125 | ! |
|---|
| 126 | IF( ln_dynadv_vec .OR. ln_linssh ) THEN ! applied on velocity |
|---|
| 127 | DO jk = 1, jpkm1 |
|---|
| 128 | ua(:,:,jk) = ( ub(:,:,jk) + p2dt * ua(:,:,jk) ) * umask(:,:,jk) |
|---|
| 129 | va(:,:,jk) = ( vb(:,:,jk) + p2dt * va(:,:,jk) ) * vmask(:,:,jk) |
|---|
| 130 | END DO |
|---|
| 131 | ELSE ! applied on thickness weighted velocity |
|---|
| 132 | DO jk = 1, jpkm1 |
|---|
| 133 | ua(:,:,jk) = ( e3u_b(:,:,jk) * ub(:,:,jk) & |
|---|
| 134 | & + p2dt * e3u_n(:,:,jk) * ua(:,:,jk) ) / e3u_a(:,:,jk) * umask(:,:,jk) |
|---|
| 135 | va(:,:,jk) = ( e3v_b(:,:,jk) * vb(:,:,jk) & |
|---|
| 136 | & + p2dt * e3v_n(:,:,jk) * va(:,:,jk) ) / e3v_a(:,:,jk) * vmask(:,:,jk) |
|---|
| 137 | END DO |
|---|
| 138 | ENDIF |
|---|
| 139 | ! |
|---|
| 140 | ! |
|---|
| 141 | IF( nn_timing == 1 ) CALL timing_stop('dyn_zdf_exp') |
|---|
| 142 | ! |
|---|
| 143 | END SUBROUTINE dyn_zdf_exp |
|---|
| 144 | |
|---|
| 145 | !!============================================================================== |
|---|
| 146 | END MODULE dynzdf_exp |
|---|
