New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim_2.F90 in branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim_2.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 7 years ago

All wrk_alloc removed

  • Property svn:keywords set to Id
File size: 13.1 KB
Line 
1MODULE sbcice_lim_2
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim_2  ***
4   !! Surface module :  update surface ocean boundary condition over ice covered area using LIM sea-ice model
5   !! Sea-Ice model  :  LIM-2 Sea ice model time-stepping
6   !!======================================================================
7   !! History :  1.0   !  06-2006  (G. Madec)  from icestp_2.F90
8   !!            3.0   !  08-2008  (S. Masson, E. .... ) coupled interface
9   !!            3.3   !  05-2009  (G.Garric) addition of the lim2_evp case
10   !!----------------------------------------------------------------------
11#if defined key_lim2
12   !!----------------------------------------------------------------------
13   !!   'key_lim2' :                                    LIM-2 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   sbc_ice_lim_2   : sea-ice model time-stepping and update ocean sbc over ice-covered area
16   !!----------------------------------------------------------------------
17   USE oce              ! ocean dynamics and tracers
18   USE dom_oce          ! ocean space and time domain
19   USE ice_2
20   USE par_ice_2
21   USE iceini_2
22   USE dom_ice_2
23
24   USE sbc_oce          ! Surface boundary condition: ocean fields
25   USE sbc_ice          ! Surface boundary condition: ice   fields
26   USE sbcblk           ! Surface boundary condition: bulk
27   USE sbccpl           ! Surface boundary condition: coupled interface
28   USE albedo
29
30   USE phycst           ! Define parameters for the routines
31   USE eosbn2           ! equation of state
32   USE limdyn_2
33   USE limtrp_2
34   USE limdmp_2
35   USE limthd_2
36   USE limsbc_2         ! sea surface boundary condition
37   USE limdia_2
38   USE limwri_2
39   USE limrst_2
40
41   USE c1d              ! 1D vertical configuration
42
43   USE lbclnk           ! lateral boundary condition - MPP link
44   USE lib_mpp          ! MPP library
45   USE iom              ! I/O manager library
46   USE in_out_manager   ! I/O manager
47   USE prtctl           ! Print control
48
49# if defined key_agrif
50   USE agrif_ice
51   USE agrif_lim2_update
52# endif
53
54   USE bdy_oce   , ONLY: ln_bdy
55   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
56
57   IMPLICIT NONE
58   PRIVATE
59
60   PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90
61
62   !! * Substitutions
63#  include "vectopt_loop_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
66   !! $Id$
67   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE sbc_ice_lim_2( kt, ksbc )
72      !!---------------------------------------------------------------------
73      !!                  ***  ROUTINE sbc_ice_lim_2  ***
74      !!                   
75      !! ** Purpose :   update the ocean surface boundary condition via the
76      !!                Louvain la Neuve Sea Ice Model time stepping
77      !!
78      !! ** Method  :   ice model time stepping
79      !!              - call the ice dynamics routine
80      !!              - call the ice advection/diffusion routine
81      !!              - call the ice thermodynamics routine
82      !!              - call the routine that computes mass and
83      !!                heat fluxes at the ice/ocean interface
84      !!              - save the outputs
85      !!              - save the outputs for restart when necessary
86      !!
87      !! ** Action  : - time evolution of the LIM sea-ice model
88      !!              - update all sbc variables below sea-ice:
89      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
90      !!---------------------------------------------------------------------
91      INTEGER, INTENT(in) ::   kt      ! ocean time step
92      INTEGER, INTENT(in) ::   ksbc    ! type of sbc ( =4 bulk ; =5 coupled )
93      !!
94      INTEGER  ::   ji, jj   ! dummy loop indices
95      REAL(wp), DIMENSION(jpi,jpj,1) :: zalb_os   ! ice albedo under overcast sky
96      REAL(wp), DIMENSION(jpi,jpj,1) :: zalb_cs   ! ice albedo under clear sky
97      REAL(wp), DIMENSION(jpi,jpj,1) :: zalb_ice  ! mean ice albedo
98      REAL(wp), DIMENSION(jpi,jpj,1) :: zsist     ! ice surface temperature (K)
99      REAL(wp), DIMENSION(jpi,jpj) :: zutau_ice, zvtau_ice 
100      !!----------------------------------------------------------------------
101
102      IF( kt == nit000 ) THEN
103         IF(lwp) WRITE(numout,*)
104         IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' 
105         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM) time stepping'
106         !
107         CALL ice_init_2
108         !
109# if defined key_agrif
110         IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim2   ! AGRIF: set the meshes
111# endif
112      ENDIF
113
114      !                                        !----------------------!
115      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only  !
116         !                                     !----------------------!
117# if defined key_agrif
118         IF( .NOT. Agrif_Root() ) lim_nbstep = MOD(lim_nbstep,Agrif_rhot()&
119         &*Agrif_PArent(nn_fsbc)/REAL(nn_fsbc)) + 1
120# endif
121
122
123         !  Bulk Formulea !
124         !----------------!
125         ! ... mean surface ocean current at ice dynamics point
126         SELECT CASE( cp_ice_msh )
127         CASE( 'I' )                  !== B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
128            DO jj = 2, jpj
129               DO ji = 2, jpi   ! NO vector opt. possible
130                  u_oce(ji,jj) = 0.5_wp * ( ssu_m(ji-1,jj  ) * umask(ji-1,jj  ,1) &
131                     &                    + ssu_m(ji-1,jj-1) * umask(ji-1,jj-1,1) ) * tmu(ji,jj)
132                  v_oce(ji,jj) = 0.5_wp * ( ssv_m(ji  ,jj-1) * vmask(ji  ,jj-1,1) &
133                     &                    + ssv_m(ji-1,jj-1) * vmask(ji-1,jj-1,1) ) * tmu(ji,jj)
134               END DO
135            END DO
136            CALL lbc_lnk( u_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
137            CALL lbc_lnk( v_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
138            !
139         CASE( 'C' )                  !== C-grid ice dynamics :   U & V-points (same as ocean)
140            u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)                     ! mean surface ocean current at ice velocity point
141            v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
142            !
143         END SELECT
144
145         ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
146         CALL eos_fzp( sss_m(:,:), tfu(:,:) )
147         tfu(:,:) = tfu(:,:) + rt0
148
149         zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) )
150
151         ! Ice albedo
152
153         CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), &
154                                 reshape( hsnif, (/jpi,jpj,1/) ), &
155                          zalb_cs, zalb_os )
156
157         SELECT CASE( ksbc )
158         CASE( jp_blk , jp_purecpl )   ! BULK and COUPLED bulk formulations
159
160            ! albedo depends on cloud fraction because of non-linear spectral effects
161            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
162
163         END SELECT
164
165         ! ... Sea-ice surface boundary conditions output from bulk formulae :
166         !     - utau_ice   ! surface ice stress i-component (I-point)   [N/m2]
167         !     - vtau_ice   ! surface ice stress j-component (I-point)   [N/m2]
168         !     - qns_ice    ! non solar heat flux over ice   (T-point)   [W/m2]
169         !     - qsr_ice    !     solar heat flux over ice   (T-point)   [W/m2]
170         !     - qla_ice    ! latent    heat flux over ice   (T-point)   [W/m2]
171         !     - dqns_ice   ! non solar heat sensistivity    (T-point)   [W/m2]
172         !     - dqla_ice   ! latent    heat sensistivity    (T-point)   [W/m2]
173         !     - tprecip    ! total precipitation            (T-point)   [Kg/m2/s]
174         !     - sprecip    ! solid precipitation            (T-point)   [Kg/m2/s]
175         !     - fr1_i0     ! 1sr fraction of qsr penetration in ice     [%]
176         !     - fr2_i0     ! 2nd fraction of qsr penetration in ice     [%]
177         !
178         SELECT CASE( ksbc )
179         !
180         CASE( jp_blk )           ! Bulk formulation
181            CALL blk_ice_tau
182            CALL blk_ice_flx( zsist, zalb_ice )
183            !
184         CASE( jp_purecpl )            ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics)
185            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
186            !
187         END SELECT
188         
189         IF( ln_mixcpl) THEN
190            CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
191            utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
192            vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
193         ENDIF
194
195         CALL iom_put( 'utau_ice', utau_ice )     ! Wind stress over ice along i-axis at I-point
196         CALL iom_put( 'vtau_ice', vtau_ice )     ! Wind stress over ice along j-axis at I-point
197
198         IF(ln_ctl) THEN         ! print mean trends (used for debugging)
199            CALL prt_ctl_info( 'Ice Forcings ' )
200            CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip  : ', tab2d_2=sprecip , clinfo2=' Snow    : ' )
201            CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' )
202            CALL prt_ctl( tab2d_1=sst_m   ,clinfo1=' sbc_ice_lim: sst     : ', tab2d_2=sss_m   , clinfo2=' sss     : ' )
203            CALL prt_ctl( tab2d_1=u_oce   ,clinfo1=' sbc_ice_lim: u_io    : ', tab2d_2=v_oce   , clinfo2=' v_io    : ' )
204            CALL prt_ctl( tab2d_1=hsnif   ,clinfo1=' sbc_ice_lim: hsnif  1: ', tab2d_2=hicif   , clinfo2=' hicif   : ' )
205            CALL prt_ctl( tab2d_1=frld    ,clinfo1=' sbc_ice_lim: frld   1: ', tab2d_2=sist    , clinfo2=' sist    : ' )
206         ENDIF
207
208         ! ---------------- !
209         !  Ice model step  !
210         ! ---------------- !
211         numit = numit + nn_fsbc                           ! Ice model time step
212
213                           CALL lim_rst_opn_2  ( kt )  ! Open Ice restart file
214         IF( .NOT. lk_c1d ) THEN                       ! Ice dynamics & transport (except in 1D case)
215                           CALL lim_dyn_2      ( kt )      ! Ice dynamics    ( rheology/dynamics )
216                           CALL lim_trp_2      ( kt )      ! Ice transport   ( Advection/diffusion )
217           IF( ln_limdmp ) CALL lim_dmp_2      ( kt )      ! Ice damping
218           IF( ln_bdy    ) CALL bdy_ice_lim( kt ) ! bdy ice thermo
219         END IF
220         !                                             ! Ice surface fluxes in coupled mode
221         IF( ln_cpl ) THEN   ! pure coupled and mixed forced-coupled configurations
222            a_i(:,:,1)=fr_i
223            CALL sbc_cpl_ice_flx( frld,                                              &
224            !                                optional arguments, used only in 'mixed oce-ice' case
225            &                                             palbi=zalb_ice, psst=sst_m, pist=zsist )
226            sprecip(:,:) = - emp_ice(:,:)   ! Ugly patch, WARNING, in coupled mode, sublimation included in snow (parsub = 0.)
227         ENDIF
228                           CALL lim_thd_2      ( kt )      ! Ice thermodynamics
229                           CALL lim_sbc_flx_2  ( kt )      ! update surface ocean mass, heat & salt fluxes
230
231         IF(  .NOT. lk_mpp )THEN
232            IF( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 )   &
233            &              CALL lim_dia_2      ( kt )      ! Ice Diagnostics
234         ENDIF
235# if ! defined key_iomput
236                           CALL lim_wri_2      ( kt )      ! Ice outputs
237# endif
238         IF( lrst_ice  )   CALL lim_rst_write_2( kt )      ! Ice restart file
239         !
240# if defined key_agrif && defined key_lim2
241         IF( .NOT. Agrif_Root() )   CALL agrif_update_lim2( kt )
242# endif
243         !
244         !
245      ENDIF                                    ! End sea-ice time step only
246      !
247      !                                        !--------------------------!
248      !                                        !  at all ocean time step  !
249      !                                        !--------------------------!
250      !                                               
251      !                                              ! Update surface ocean stresses (only in ice-dynamic case)
252      !                                                   ! otherwise the atm.-ocean stresses are used everywhere
253      IF( ln_limdyn    )   CALL lim_sbc_tau_2( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
254      !
255   END SUBROUTINE sbc_ice_lim_2
256
257#else
258   !!----------------------------------------------------------------------
259   !!   Default option           Dummy module      NO LIM 2.0 sea-ice model
260   !!----------------------------------------------------------------------
261CONTAINS
262   SUBROUTINE sbc_ice_lim_2 ( kt, ksbc )     ! Dummy routine
263      INTEGER, INTENT(in) ::   kt, ksbc   
264      WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc
265   END SUBROUTINE sbc_ice_lim_2
266#endif
267
268   !!======================================================================
269END MODULE sbcice_lim_2
Note: See TracBrowser for help on using the repository browser.