New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_cen.F90 in branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_cen.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 7 years ago

All wrk_alloc removed
File size: 10.8 KB
Line 
1MODULE traadv_cen
2   !!======================================================================
3   !!                     ***  MODULE  traadv_cen  ***
4   !! Ocean  tracers:   advective trend (2nd/4th order centered)
5   !!======================================================================
6   !! History :  3.7  ! 2014-05  (G. Madec)  original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   tra_adv_cen   : update the tracer trend with the advection trends using a centered or scheme (2nd or 4th order)
11   !!                   NB: on the vertical it is actually a 4th order COMPACT scheme which is used
12   !!----------------------------------------------------------------------
13   USE oce      , ONLY: tsn ! now ocean temperature and salinity
14   USE dom_oce        ! ocean space and time domain
15   USE eosbn2         ! equation of state
16   USE traadv_fct     ! acces to routine interp_4th_cpt
17   USE trd_oce        ! trends: ocean variables
18   USE trdtra         ! trends manager: tracers
19   USE diaptr         ! poleward transport diagnostics
20   USE diaar5         ! AR5 diagnostics
21   !
22   USE in_out_manager ! I/O manager
23   USE iom            ! IOM library
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE lib_mpp        ! MPP library
26   USE timing         ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   tra_adv_cen       ! routine called by step.F90
32   
33   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
34
35   LOGICAL :: l_trd   ! flag to compute trends
36   LOGICAL :: l_ptr   ! flag to compute poleward transport
37   LOGICAL :: l_hst   ! flag to compute heat/salt transport
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE tra_adv_cen( kt, kit000, cdtype, pun, pvn, pwn,     &
49      &                                             ptn, pta, kjpt, kn_cen_h, kn_cen_v ) 
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_adv_cen  ***
52      !!                 
53      !! ** Purpose :   Compute the now trend due to the advection of tracers
54      !!      and add it to the general trend of passive tracer equations.
55      !!
56      !! ** Method  :   The advection is evaluated by a 2nd or 4th order scheme
57      !!               using now fields (leap-frog scheme).
58      !!       kn_cen_h = 2  ==>> 2nd order centered scheme on the horizontal
59      !!                = 4  ==>> 4th order    -        -       -      -
60      !!       kn_cen_v = 2  ==>> 2nd order centered scheme on the vertical
61      !!                = 4  ==>> 4th order COMPACT  scheme     -      -
62      !!
63      !! ** Action : - update pta  with the now advective tracer trends
64      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
65      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
66      !!----------------------------------------------------------------------
67      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
68      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
69      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
70      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
71      INTEGER                              , INTENT(in   ) ::   kn_cen_h        ! =2/4 (2nd or 4th order scheme)
72      INTEGER                              , INTENT(in   ) ::   kn_cen_v        ! =2/4 (2nd or 4th order scheme)
73      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptn             ! now tracer fields
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
76      !
77      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
78      INTEGER  ::   ierr             ! local integer
79      REAL(wp) ::   zC2t_u, zC4t_u   ! local scalars
80      REAL(wp) ::   zC2t_v, zC4t_v   !   -      -
81      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwx, zwy, zwz, ztu, ztv, ztw
82      !!----------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('tra_adv_cen')
85      !
86      !
87      IF( kt == kit000 )  THEN
88         IF(lwp) WRITE(numout,*)
89         IF(lwp) WRITE(numout,*) 'tra_adv_cen : centered advection scheme on ', cdtype, ' order h/v =', kn_cen_h,'/', kn_cen_v
90         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
91      ENDIF
92      !
93      l_trd = .FALSE.
94      l_hst = .FALSE.
95      l_ptr = .FALSE.
96      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )        l_trd = .TRUE.
97      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                                 l_ptr = .TRUE. 
98      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
99         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )   l_hst = .TRUE.
100      !
101      !                   
102      zwz(:,:, 1 ) = 0._wp       ! surface & bottom vertical flux set to zero for all tracers
103      zwz(:,:,jpk) = 0._wp
104      !
105      DO jn = 1, kjpt            !==  loop over the tracers  ==!
106         !
107         SELECT CASE( kn_cen_h )       !--  Horizontal fluxes  --!
108         !
109         CASE(  2  )                         !* 2nd order centered
110            DO jk = 1, jpkm1
111               DO jj = 1, jpjm1
112                  DO ji = 1, fs_jpim1   ! vector opt.
113                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn) )
114                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn) )
115                  END DO
116               END DO
117            END DO
118            !
119         CASE(  4  )                         !* 4th order centered
120            ztu(:,:,jpk) = 0._wp                   ! Bottom value : flux set to zero
121            ztv(:,:,jpk) = 0._wp
122            DO jk = 1, jpkm1                       ! masked gradient
123               DO jj = 2, jpjm1
124                  DO ji = fs_2, fs_jpim1   ! vector opt.
125                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
126                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
127                  END DO
128               END DO
129            END DO
130            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
131            !
132            DO jk = 1, jpkm1                       ! Horizontal advective fluxes
133               DO jj = 2, jpjm1
134                  DO ji = 1, fs_jpim1   ! vector opt.
135                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! C2 interpolation of T at u- & v-points (x2)
136                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
137                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
138                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj,jk) - ztu(ji+1,jj,jk) )
139                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji,jj-1,jk) - ztv(ji,jj+1,jk) )
140                     !                                                  ! C4 fluxes
141                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u
142                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v
143                  END DO
144               END DO
145            END DO         
146            !
147         CASE DEFAULT
148            CALL ctl_stop( 'traadv_fct: wrong value for nn_fct' )
149         END SELECT
150         !
151         SELECT CASE( kn_cen_v )       !--  Vertical fluxes  --!   (interior)
152         !
153         CASE(  2  )                         !* 2nd order centered
154            DO jk = 2, jpk
155               DO jj = 2, jpjm1
156                  DO ji = fs_2, fs_jpim1   ! vector opt.
157                     zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
158                  END DO
159               END DO
160            END DO
161            !
162         CASE(  4  )                         !* 4th order compact
163            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )      ! ztw = interpolated value of T at w-point
164            DO jk = 2, jpkm1
165               DO jj = 2, jpjm1
166                  DO ji = fs_2, fs_jpim1
167                     zwz(ji,jj,jk) = pwn(ji,jj,jk) * ztw(ji,jj,jk) * wmask(ji,jj,jk)
168                  END DO
169               END DO
170            END DO
171            !
172         END SELECT
173         !
174         IF( ln_linssh ) THEN                !* top value   (linear free surf. only as zwz is multiplied by wmask)
175            IF( ln_isfcav ) THEN                  ! ice-shelf cavities (top of the ocean)
176               DO jj = 1, jpj
177                  DO ji = 1, jpi
178                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptn(ji,jj,mikt(ji,jj),jn) 
179                  END DO
180               END DO   
181            ELSE                                   ! no ice-shelf cavities (only ocean surface)
182               zwz(:,:,1) = pwn(:,:,1) * ptn(:,:,1,jn)
183            ENDIF
184         ENDIF
185         !               
186         DO jk = 1, jpkm1              !--  Divergence of advective fluxes  --!
187            DO jj = 2, jpjm1
188               DO ji = fs_2, fs_jpim1   ! vector opt.
189                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn)    &
190                     &             - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )    &
191                     &                + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )    &
192                     &                + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)  ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
193               END DO
194            END DO
195         END DO
196         !                             ! trend diagnostics
197         IF( l_trd ) THEN
198            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptn(:,:,:,jn) )
199            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptn(:,:,:,jn) )
200            CALL trd_tra( kt, cdtype, jn, jptra_zad, zwz, pwn, ptn(:,:,:,jn) )
201         END IF
202         !                                 ! "Poleward" heat and salt transports
203         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
204         !                                 !  heat and salt transport
205         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
206         !
207      END DO
208      !
209      !
210      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_cen')
211      !
212   END SUBROUTINE tra_adv_cen
213   
214   !!======================================================================
215END MODULE traadv_cen
Note: See TracBrowser for help on using the repository browser.