New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf.F90 in branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/TRA/traldf.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 7 years ago

All wrk_alloc removed
  • Property svn:keywords set to Id
File size: 11.4 KB
Line 
1MODULE traldf
2   !!======================================================================
3   !!                       ***  MODULE  traldf  ***
4   !! Ocean Active tracers : lateral diffusive trends
5   !!=====================================================================
6   !! History :  9.0  ! 2005-11  (G. Madec)  Original code
7   !!  NEMO      3.0  ! 2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            3.7  ! 2013-12  (G. Madec) remove the optional computation from T & S anomaly profiles and traldf_bilapg
9   !!             -   ! 2013-12  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
10   !!             -   ! 2014-01  (G. Madec, S. Masson)  restructuration/simplification of lateral diffusive operators
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   tra_ldf       : update the tracer trend with the lateral diffusion trend
15   !!   tra_ldf_init  : initialization, namelist read, and parameters control
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers
18   USE dom_oce        ! ocean space and time domain
19   USE phycst         ! physical constants
20   USE ldftra         ! lateral diffusion: eddy diffusivity & EIV coeff.
21   USE ldfslp         ! lateral diffusion: iso-neutral slope
22   USE traldf_lap_blp ! lateral diffusion: laplacian iso-level            operator  (tra_ldf_lap/_blp   routines)
23   USE traldf_iso     ! lateral diffusion: laplacian iso-neutral standard operator  (tra_ldf_iso        routine )
24   USE traldf_triad   ! lateral diffusion: laplacian iso-neutral triad    operator  (tra_ldf_triad      routine )
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! ocean active tracers trends
27   !
28   USE prtctl         ! Print control
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing library
31   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
32   USE timing         ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf        ! called by step.F90
38   PUBLIC   tra_ldf_init   ! called by nemogcm.F90
39   !
40   INTEGER ::   nldf = 0   ! type of lateral diffusion used defined from ln_traldf_... (namlist logicals)
41   
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_ldf( kt )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_ldf  ***
54      !!
55      !! ** Purpose :   compute the lateral ocean tracer physics.
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
58      !!
59      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  ztrdt, ztrds
60      !!----------------------------------------------------------------------
61      !
62      IF( nn_timing == 1 )   CALL timing_start('tra_ldf')
63      !
64      IF( l_trdtra )   THEN                    !* Save ta and sa trends
65         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) 
66         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
67      ENDIF
68      !
69      SELECT CASE ( nldf )                     !* compute lateral mixing trend and add it to the general trend
70      CASE ( np_lap   )                                  ! laplacian: iso-level operator
71         CALL tra_ldf_lap  ( kt, nit000,'TRA', ahtu, ahtv, gtsu, gtsv, gtui, gtvi, tsb,      tsa, jpts,  1   )
72      CASE ( np_lap_i )                                  ! laplacian: standard iso-neutral operator (Madec)
73         CALL tra_ldf_iso  ( kt, nit000,'TRA', ahtu, ahtv, gtsu, gtsv, gtui, gtvi, tsb, tsb, tsa, jpts,  1   )
74      CASE ( np_lap_it )                                 ! laplacian: triad iso-neutral operator (griffies)
75         CALL tra_ldf_triad( kt, nit000,'TRA', ahtu, ahtv, gtsu, gtsv, gtui, gtvi, tsb, tsb, tsa, jpts,  1   )
76      CASE ( np_blp , np_blp_i , np_blp_it )             ! bilaplacian: iso-level & iso-neutral operators
77         CALL tra_ldf_blp  ( kt, nit000,'TRA', ahtu, ahtv, gtsu, gtsv, gtui, gtvi, tsb      , tsa, jpts, nldf )
78      END SELECT
79      !
80      IF( l_trdtra )   THEN                    !* save the horizontal diffusive trends for further diagnostics
81         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
82         ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:)
83         CALL trd_tra( kt, 'TRA', jp_tem, jptra_ldf, ztrdt )
84         CALL trd_tra( kt, 'TRA', jp_sal, jptra_ldf, ztrds )
85      ENDIF
86      !                                        !* print mean trends (used for debugging)
87      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' ldf  - Ta: ', mask1=tmask,               &
88         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
89      !
90      IF( nn_timing == 1 )   CALL timing_stop('tra_ldf')
91      !
92   END SUBROUTINE tra_ldf
93
94
95   SUBROUTINE tra_ldf_init
96      !!----------------------------------------------------------------------
97      !!                  ***  ROUTINE tra_ldf_init  ***
98      !!
99      !! ** Purpose :   Choice of the operator for the lateral tracer diffusion
100      !!
101      !! ** Method  :   set nldf from the namtra_ldf logicals
102      !!----------------------------------------------------------------------
103      INTEGER ::   ioptio, ierr   ! temporary integers
104      !!----------------------------------------------------------------------
105      !
106      IF(lwp) THEN                     ! Namelist print
107         WRITE(numout,*)
108         WRITE(numout,*) 'tra_ldf_init : lateral tracer diffusive operator'
109         WRITE(numout,*) '~~~~~~~~~~~~'
110         WRITE(numout,*) '   Namelist namtra_ldf: already read in ldftra module'
111         WRITE(numout,*) '      see ldf_tra_init report for lateral mixing parameters'
112      ENDIF
113      !                                   ! use of lateral operator or not
114      nldf   = np_ERROR
115      ioptio = 0
116      IF( ln_traldf_lap )   ioptio = ioptio + 1
117      IF( ln_traldf_blp )   ioptio = ioptio + 1
118      IF( ioptio >  1   )   CALL ctl_stop( 'tra_ldf_init: use ONE or NONE of the 2 lap/bilap operator type on tracer' )
119      IF( ioptio == 0   )   nldf = np_no_ldf     ! No lateral diffusion
120      !
121      IF( nldf /= np_no_ldf ) THEN        ! direction ==>> type of operator 
122         ioptio = 0
123         IF( ln_traldf_lev )   ioptio = ioptio + 1
124         IF( ln_traldf_hor )   ioptio = ioptio + 1
125         IF( ln_traldf_iso )   ioptio = ioptio + 1
126         IF( ioptio >  1 )   CALL ctl_stop( 'tra_ldf_init: use only ONE direction (level/hor/iso)' )
127         !
128         !                                ! defined the type of lateral diffusion from ln_traldf_... logicals
129         ierr = 0
130         IF( ln_traldf_lap ) THEN         ! laplacian operator
131            IF ( ln_zco ) THEN               ! z-coordinate
132               IF ( ln_traldf_lev   )   nldf = np_lap     ! iso-level = horizontal (no rotation)
133               IF ( ln_traldf_hor   )   nldf = np_lap     ! iso-level = horizontal (no rotation)
134               IF ( ln_traldf_iso   )   nldf = np_lap_i   ! iso-neutral: standard  (   rotation)
135               IF ( ln_traldf_triad )   nldf = np_lap_it  ! iso-neutral: triad     (   rotation)
136            ENDIF
137            IF ( ln_zps ) THEN               ! z-coordinate with partial step
138               IF ( ln_traldf_lev   )   ierr = 1          ! iso-level not allowed
139               IF ( ln_traldf_hor   )   nldf = np_lap     ! horizontal             (no rotation)
140               IF ( ln_traldf_iso   )   nldf = np_lap_i   ! iso-neutral: standard     (rotation)
141               IF ( ln_traldf_triad )   nldf = np_lap_it  ! iso-neutral: triad        (rotation)
142            ENDIF
143            IF ( ln_sco ) THEN               ! s-coordinate
144               IF ( ln_traldf_lev   )   nldf = np_lap     ! iso-level              (no rotation)
145               IF ( ln_traldf_hor   )   nldf = np_lap_i   ! horizontal             (   rotation)
146               IF ( ln_traldf_iso   )   nldf = np_lap_i   ! iso-neutral: standard  (   rotation)
147               IF ( ln_traldf_triad )   nldf = np_lap_it  ! iso-neutral: triad     (   rotation)
148            ENDIF
149         ENDIF
150         !
151         IF( ln_traldf_blp ) THEN         ! bilaplacian operator
152            IF ( ln_zco ) THEN               ! z-coordinate
153               IF ( ln_traldf_lev   )   nldf = np_blp     ! iso-level = horizontal (no rotation)
154               IF ( ln_traldf_hor   )   nldf = np_blp     ! iso-level = horizontal (no rotation)
155               IF ( ln_traldf_iso   )   nldf = np_blp_i   ! iso-neutral: standard  (   rotation)
156               IF ( ln_traldf_triad )   nldf = np_blp_it  ! iso-neutral: triad     (   rotation)
157            ENDIF
158            IF ( ln_zps ) THEN               ! z-coordinate with partial step
159               IF ( ln_traldf_lev   )   ierr = 1          ! iso-level not allowed
160               IF ( ln_traldf_hor   )   nldf = np_blp     ! horizontal             (no rotation)
161               IF ( ln_traldf_iso   )   nldf = np_blp_i   ! iso-neutral: standard  (   rotation)
162               IF ( ln_traldf_triad )   nldf = np_blp_it  ! iso-neutral: triad     (   rotation)
163            ENDIF
164            IF ( ln_sco ) THEN               ! s-coordinate
165               IF ( ln_traldf_lev   )   nldf = np_blp     ! iso-level              (no rotation)
166               IF ( ln_traldf_hor   )   nldf = np_blp_it  ! horizontal             (   rotation)
167               IF ( ln_traldf_iso   )   nldf = np_blp_i   ! iso-neutral: standard  (   rotation)
168               IF ( ln_traldf_triad )   nldf = np_blp_it  ! iso-neutral: triad     (   rotation)
169            ENDIF
170         ENDIF
171         IF( ierr == 1 )   CALL ctl_stop( 'iso-level in z-partial step, not allowed' )
172      ENDIF
173      !
174      IF( ln_ldfeiv .AND. .NOT.( ln_traldf_iso .OR. ln_traldf_triad ) )                                    &
175           &            CALL ctl_stop( 'eddy induced velocity on tracers requires iso-neutral laplacian diffusion' )
176      IF( ln_isfcav .AND. ln_traldf_triad ) &
177           &            CALL ctl_stop( ' ice shelf cavity and traldf_triad not tested' )
178           !
179      IF(  nldf == np_lap_i .OR. nldf == np_lap_it .OR. &
180         & nldf == np_blp_i .OR. nldf == np_blp_it  )   l_ldfslp = .TRUE.    ! slope of neutral surfaces required
181      !
182      IF(lwp) THEN
183         WRITE(numout,*)
184         SELECT CASE( nldf )
185         CASE( np_no_ldf )   ;   WRITE(numout,*) '      ===>>   NO lateral diffusion'
186         CASE( np_lap    )   ;   WRITE(numout,*) '      ===>>   laplacian iso-level operator'
187         CASE( np_lap_i  )   ;   WRITE(numout,*) '      ===>>   Rotated laplacian operator (standard)'
188         CASE( np_lap_it )   ;   WRITE(numout,*) '      ===>>   Rotated laplacian operator (triad)'
189         CASE( np_blp    )   ;   WRITE(numout,*) '      ===>>   bilaplacian iso-level operator'
190         CASE( np_blp_i  )   ;   WRITE(numout,*) '      ===>>   Rotated bilaplacian operator (standard)'
191         CASE( np_blp_it )   ;   WRITE(numout,*) '      ===>>   Rotated bilaplacian operator (triad)'
192         END SELECT
193      ENDIF
194      !
195   END SUBROUTINE tra_ldf_init
196
197   !!======================================================================
198END MODULE traldf
Note: See TracBrowser for help on using the repository browser.