New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 8016

Last change on this file since 8016 was 8016, checked in by timgraham, 7 years ago

Delete some remaining "USE wrk_array" lines
  • Property svn:keywords set to Id
File size: 24.6 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE phycst          ! physical constants
20   USE eosbn2          ! ocean equation of state
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   zps_hde     ! routine called by step.F90
30   PUBLIC   zps_hde_isf ! routine called by step.F90
31
32   !! * Substitutions
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
42      &                          prd, pgru, pgrv    )
43      !!----------------------------------------------------------------------
44      !!                     ***  ROUTINE zps_hde  ***
45      !!                   
46      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
47      !!      at u- and v-points with a linear interpolation for z-coordinate
48      !!      with partial steps.
49      !!
50      !! ** Method  :   In z-coord with partial steps, scale factors on last
51      !!      levels are different for each grid point, so that T, S and rd
52      !!      points are not at the same depth as in z-coord. To have horizontal
53      !!      gradients again, we interpolate T and S at the good depth :
54      !!      Linear interpolation of T, S   
55      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
56      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
57      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
58      !!         This formulation computes the two cases:
59      !!                 CASE 1                   CASE 2 
60      !!         k-1  ___ ___________   k-1   ___ ___________
61      !!                    Ti  T~                  T~  Ti+1
62      !!                  _____                        _____
63      !!         k        |   |Ti+1     k           Ti |   |
64      !!                  |   |____                ____|   |
65      !!              ___ |   |   |           ___  |   |   |
66      !!                 
67      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
68      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
69      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
70      !!          or
71      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
72      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
73      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
74      !!          Idem for di(s) and dj(s)         
75      !!
76      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
77      !!      depth zh from interpolated T and S for the different formulations
78      !!      of the equation of state (eos).
79      !!      Gradient formulation for rho :
80      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
81      !!
82      !! ** Action  : compute for top interfaces
83      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
84      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
85      !!----------------------------------------------------------------------
86      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
87      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
88      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
89      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
90      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
91      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
92      !
93      INTEGER  ::   ji, jj, jn                  ! Dummy loop indices
94      INTEGER  ::   iku, ikv, ikum1, ikvm1      ! partial step level (ocean bottom level) at u- and v-points
95      REAL(wp) ::   ze3wu, ze3wv, zmaxu, zmaxv  ! local scalars
96      REAL(wp), DIMENSION(jpi,jpj)      ::   zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
97      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::   zti, ztj             !
98      !!----------------------------------------------------------------------
99      !
100      IF( nn_timing == 1 )   CALL timing_start( 'zps_hde')
101      !
102      pgtu(:,:,:)=0._wp   ;   zti (:,:,:)=0._wp   ;   zhi (:,:  )=0._wp
103      pgtv(:,:,:)=0._wp   ;   ztj (:,:,:)=0._wp   ;   zhj (:,:  )=0._wp
104      !
105      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
106         !
107         DO jj = 1, jpjm1
108            DO ji = 1, jpim1
109               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
110               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
111!!gm BUG ? when applied to before fields, e3w_b should be used....
112               ze3wu = e3w_n(ji+1,jj  ,iku) - e3w_n(ji,jj,iku)
113               ze3wv = e3w_n(ji  ,jj+1,ikv) - e3w_n(ji,jj,ikv)
114               !
115               ! i- direction
116               IF( ze3wu >= 0._wp ) THEN      ! case 1
117                  zmaxu =  ze3wu / e3w_n(ji+1,jj,iku)
118                  ! interpolated values of tracers
119                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
120                  ! gradient of  tracers
121                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
122               ELSE                           ! case 2
123                  zmaxu = -ze3wu / e3w_n(ji,jj,iku)
124                  ! interpolated values of tracers
125                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
126                  ! gradient of tracers
127                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
128               ENDIF
129               !
130               ! j- direction
131               IF( ze3wv >= 0._wp ) THEN      ! case 1
132                  zmaxv =  ze3wv / e3w_n(ji,jj+1,ikv)
133                  ! interpolated values of tracers
134                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
135                  ! gradient of tracers
136                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
137               ELSE                           ! case 2
138                  zmaxv =  -ze3wv / e3w_n(ji,jj,ikv)
139                  ! interpolated values of tracers
140                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
141                  ! gradient of tracers
142                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
143               ENDIF
144            END DO
145         END DO
146         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
147         !
148      END DO
149      !               
150      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
151         pgru(:,:) = 0._wp
152         pgrv(:,:) = 0._wp                ! depth of the partial step level
153         DO jj = 1, jpjm1
154            DO ji = 1, jpim1
155               iku = mbku(ji,jj)
156               ikv = mbkv(ji,jj)
157               ze3wu  = e3w_n(ji+1,jj  ,iku) - e3w_n(ji,jj,iku)
158               ze3wv  = e3w_n(ji  ,jj+1,ikv) - e3w_n(ji,jj,ikv)
159               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept_n(ji  ,jj,iku)     ! i-direction: case 1
160               ELSE                        ;   zhi(ji,jj) = gdept_n(ji+1,jj,iku)     ! -     -      case 2
161               ENDIF
162               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept_n(ji,jj  ,ikv)     ! j-direction: case 1
163               ELSE                        ;   zhj(ji,jj) = gdept_n(ji,jj+1,ikv)     ! -     -      case 2
164               ENDIF
165            END DO
166         END DO
167         !
168         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
169         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
170         !
171         DO jj = 1, jpjm1                 ! Gradient of density at the last level
172            DO ji = 1, jpim1
173               iku = mbku(ji,jj)
174               ikv = mbkv(ji,jj)
175               ze3wu  = e3w_n(ji+1,jj  ,iku) - e3w_n(ji,jj,iku)
176               ze3wv  = e3w_n(ji  ,jj+1,ikv) - e3w_n(ji,jj,ikv)
177               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
178               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
179               ENDIF
180               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
181               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
182               ENDIF
183            END DO
184         END DO
185         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
186         !
187      END IF
188      !
189      IF( nn_timing == 1 )   CALL timing_stop( 'zps_hde')
190      !
191   END SUBROUTINE zps_hde
192   !
193   SUBROUTINE zps_hde_isf( kt, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
194      &                          prd, pgru, pgrv, pgrui, pgrvi )
195      !!----------------------------------------------------------------------
196      !!                     ***  ROUTINE zps_hde_isf  ***
197      !!                   
198      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
199      !!      at u- and v-points with a linear interpolation for z-coordinate
200      !!      with partial steps for top (ice shelf) and bottom.
201      !!
202      !! ** Method  :   In z-coord with partial steps, scale factors on last
203      !!      levels are different for each grid point, so that T, S and rd
204      !!      points are not at the same depth as in z-coord. To have horizontal
205      !!      gradients again, we interpolate T and S at the good depth :
206      !!      For the bottom case:
207      !!      Linear interpolation of T, S   
208      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
209      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
210      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
211      !!         This formulation computes the two cases:
212      !!                 CASE 1                   CASE 2 
213      !!         k-1  ___ ___________   k-1   ___ ___________
214      !!                    Ti  T~                  T~  Ti+1
215      !!                  _____                        _____
216      !!         k        |   |Ti+1     k           Ti |   |
217      !!                  |   |____                ____|   |
218      !!              ___ |   |   |           ___  |   |   |
219      !!                 
220      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
221      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
222      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
223      !!          or
224      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
225      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
226      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
227      !!          Idem for di(s) and dj(s)         
228      !!
229      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
230      !!      depth zh from interpolated T and S for the different formulations
231      !!      of the equation of state (eos).
232      !!      Gradient formulation for rho :
233      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
234      !!
235      !!      For the top case (ice shelf): As for the bottom case but upside down
236      !!
237      !! ** Action  : compute for top and bottom interfaces
238      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
239      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
240      !!----------------------------------------------------------------------
241      INTEGER                              , INTENT(in   )           ::  kt           ! ocean time-step index
242      INTEGER                              , INTENT(in   )           ::  kjpt         ! number of tracers
243      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta          ! 4D tracers fields
244      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
245      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
246      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
247      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
248      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
249      !
250      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
251      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
252      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
253      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
254      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
255      !!----------------------------------------------------------------------
256      !
257      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde_isf')
258      !
259      pgtu (:,:,:) = 0._wp   ;   pgtv (:,:,:) =0._wp
260      pgtui(:,:,:) = 0._wp   ;   pgtvi(:,:,:) =0._wp
261      zti  (:,:,:) = 0._wp   ;   ztj  (:,:,:) =0._wp
262      zhi  (:,:  ) = 0._wp   ;   zhj  (:,:  ) =0._wp
263      !
264      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
265         !
266         DO jj = 1, jpjm1
267            DO ji = 1, jpim1
268
269               iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
270               ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
271               ze3wu = gdept_n(ji+1,jj,iku) - gdept_n(ji,jj,iku)
272               ze3wv = gdept_n(ji,jj+1,ikv) - gdept_n(ji,jj,ikv)
273               !
274               ! i- direction
275               IF( ze3wu >= 0._wp ) THEN      ! case 1
276                  zmaxu =  ze3wu / e3w_n(ji+1,jj,iku)
277                  ! interpolated values of tracers
278                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
279                  ! gradient of  tracers
280                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
281               ELSE                           ! case 2
282                  zmaxu = -ze3wu / e3w_n(ji,jj,iku)
283                  ! interpolated values of tracers
284                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
285                  ! gradient of tracers
286                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
287               ENDIF
288               !
289               ! j- direction
290               IF( ze3wv >= 0._wp ) THEN      ! case 1
291                  zmaxv =  ze3wv / e3w_n(ji,jj+1,ikv)
292                  ! interpolated values of tracers
293                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
294                  ! gradient of tracers
295                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
296               ELSE                           ! case 2
297                  zmaxv =  -ze3wv / e3w_n(ji,jj,ikv)
298                  ! interpolated values of tracers
299                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
300                  ! gradient of tracers
301                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
302               ENDIF
303
304            END DO
305         END DO
306         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
307         !
308      END DO
309
310      ! horizontal derivative of density anomalies (rd)
311      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
312         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
313         !
314         DO jj = 1, jpjm1
315            DO ji = 1, jpim1
316
317               iku = mbku(ji,jj)
318               ikv = mbkv(ji,jj)
319               ze3wu = gdept_n(ji+1,jj,iku) - gdept_n(ji,jj,iku)
320               ze3wv = gdept_n(ji,jj+1,ikv) - gdept_n(ji,jj,ikv)
321               !
322               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept_n(ji  ,jj,iku)    ! i-direction: case 1
323               ELSE                        ;   zhi(ji,jj) = gdept_n(ji+1,jj,iku)    ! -     -      case 2
324               ENDIF
325               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept_n(ji,jj  ,ikv)    ! j-direction: case 1
326               ELSE                        ;   zhj(ji,jj) = gdept_n(ji,jj+1,ikv)    ! -     -      case 2
327               ENDIF
328
329            END DO
330         END DO
331
332         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
333         ! step and store it in  zri, zrj for each  case
334         CALL eos( zti, zhi, zri )
335         CALL eos( ztj, zhj, zrj )
336
337         DO jj = 1, jpjm1                 ! Gradient of density at the last level
338            DO ji = 1, jpim1
339               iku = mbku(ji,jj)
340               ikv = mbkv(ji,jj)
341               ze3wu = gdept_n(ji+1,jj,iku) - gdept_n(ji,jj,iku)
342               ze3wv = gdept_n(ji,jj+1,ikv) - gdept_n(ji,jj,ikv)
343
344               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
345               ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
346               ENDIF
347               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
348               ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
349               ENDIF
350
351            END DO
352         END DO
353
354         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
355         !
356      END IF
357      !
358      !     !==  (ISH)  compute grui and gruvi  ==!
359      !
360      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
361         DO jj = 1, jpjm1
362            DO ji = 1, jpim1
363               iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
364               ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
365               !
366               ! (ISF) case partial step top and bottom in adjacent cell in vertical
367               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
368               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
369               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
370               ze3wu  =  gdept_n(ji,jj,iku) - gdept_n(ji+1,jj,iku)
371               ze3wv  =  gdept_n(ji,jj,ikv) - gdept_n(ji,jj+1,ikv) 
372
373               ! i- direction
374               IF( ze3wu >= 0._wp ) THEN      ! case 1
375                  zmaxu = ze3wu / e3w_n(ji+1,jj,ikup1)
376                  ! interpolated values of tracers
377                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
378                  ! gradient of tracers
379                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
380               ELSE                           ! case 2
381                  zmaxu = - ze3wu / e3w_n(ji,jj,ikup1)
382                  ! interpolated values of tracers
383                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
384                  ! gradient of  tracers
385                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
386               ENDIF
387               !
388               ! j- direction
389               IF( ze3wv >= 0._wp ) THEN      ! case 1
390                  zmaxv =  ze3wv / e3w_n(ji,jj+1,ikvp1)
391                  ! interpolated values of tracers
392                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
393                  ! gradient of tracers
394                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
395               ELSE                           ! case 2
396                  zmaxv =  - ze3wv / e3w_n(ji,jj,ikvp1)
397                  ! interpolated values of tracers
398                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
399                  ! gradient of tracers
400                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
401               ENDIF
402
403            END DO
404         END DO
405         CALL lbc_lnk( pgtui(:,:,jn), 'U', -1. ); CALL lbc_lnk( pgtvi(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
406         !
407      END DO
408
409      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
410         !
411         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
412         DO jj = 1, jpjm1
413            DO ji = 1, jpim1
414
415               iku = miku(ji,jj)
416               ikv = mikv(ji,jj)
417               ze3wu  =  gdept_n(ji,jj,iku) - gdept_n(ji+1,jj,iku)
418               ze3wv  =  gdept_n(ji,jj,ikv) - gdept_n(ji,jj+1,ikv) 
419               !
420               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept_n(ji  ,jj,iku)    ! i-direction: case 1
421               ELSE                        ;   zhi(ji,jj) = gdept_n(ji+1,jj,iku)    ! -     -      case 2
422               ENDIF
423
424               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept_n(ji,jj  ,ikv)    ! j-direction: case 1
425               ELSE                        ;   zhj(ji,jj) = gdept_n(ji,jj+1,ikv)    ! -     -      case 2
426               ENDIF
427
428            END DO
429         END DO
430         !
431         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
432         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
433         !
434         DO jj = 1, jpjm1                 ! Gradient of density at the last level
435            DO ji = 1, jpim1
436               iku = miku(ji,jj) 
437               ikv = mikv(ji,jj) 
438               ze3wu  =  gdept_n(ji,jj,iku) - gdept_n(ji+1,jj,iku)
439               ze3wv  =  gdept_n(ji,jj,ikv) - gdept_n(ji,jj+1,ikv) 
440
441               IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
442               ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
443               ENDIF
444               IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
445               ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
446               ENDIF
447
448            END DO
449         END DO
450         CALL lbc_lnk( pgrui   , 'U', -1. ); CALL lbc_lnk( pgrvi   , 'V', -1. )   ! Lateral boundary conditions
451         !
452      END IF 
453      !
454      IF( nn_timing == 1 )   CALL timing_stop( 'zps_hde_isf')
455      !
456   END SUBROUTINE zps_hde_isf
457   !!======================================================================
458END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.