New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zrem.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 7 years ago

All wrk_alloc removed
File size: 17.4 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
11   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
12   !!   p4z_rem_alloc :  Allocate remineralisation variables
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zche          !  chemical model
18   USE p4zprod         !  Growth rate of the 2 phyto groups
19   USE p4zlim
20   USE prtctl_trc      !  print control for debugging
21   USE iom             !  I/O manager
22
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p4z_rem         ! called in p4zbio.F90
28   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
29   PUBLIC   p4z_rem_alloc
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::  xremikc    !: remineralisation rate of DOC
33   REAL(wp), PUBLIC ::  xremikn    !: remineralisation rate of DON
34   REAL(wp), PUBLIC ::  xremikp    !: remineralisation rate of DOP
35   REAL(wp), PUBLIC ::  xremik     !: remineralisation rate of POC
36   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
37   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of POC
38   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of POC
39   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
40   REAL(wp), PUBLIC ::  feratb     !: Fe/C quota in bacteria
41   REAL(wp), PUBLIC ::  xkferb     !: Half-saturation constant for bacteria Fe/C
42
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr     !: denitrification array
44
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p4z_rem( kt, knt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_rem  ***
55      !!
56      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      !
61      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
62      !
63      INTEGER  ::   ji, jj, jk
64      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
65      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
66      REAL(wp) ::   zbactfer, zolimit, zonitr, zrfact2
67      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
68      CHARACTER (len=25) :: charout
69      REAL(wp), DIMENSION(jpi,jpj) :: ztempbac
70      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zdepprod, zfacsi, zw3d, zfacsib
71      !!---------------------------------------------------------------------
72      !
73      IF( nn_timing == 1 )  CALL timing_start('p4z_rem')
74      !
75      ! Allocate temporary workspace
76
77      ! Initialisation of temprary arrys
78      zdepprod(:,:,:) = 1._wp
79      ztempbac(:,:)   = 0._wp
80      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
81      zfacsi(:,:,:)   = xsilab
82
83      ! Computation of the mean phytoplankton concentration as
84      ! a crude estimate of the bacterial biomass
85      ! this parameterization has been deduced from a model version
86      ! that was modeling explicitely bacteria
87      ! -------------------------------------------------------
88      DO jk = 1, jpkm1
89         DO jj = 1, jpj
90            DO ji = 1, jpi
91               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
92               IF( gdept_n(ji,jj,jk) < zdep ) THEN
93                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
94                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
95               ELSE
96                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
97                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
98                  zdepprod(ji,jj,jk) = zdepmin**0.273
99               ENDIF
100            END DO
101         END DO
102      END DO
103
104      IF( ln_p4z ) THEN
105         DO jk = 1, jpkm1
106            DO jj = 1, jpj
107               DO ji = 1, jpi
108                  ! DOC ammonification. Depends on depth, phytoplankton biomass
109                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
110                  zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
111                  zremik = MAX( zremik, 2.74e-4 * xstep )
112                  ! Ammonification in oxic waters with oxygen consumption
113                  ! -----------------------------------------------------
114                  zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
115                  zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
116                  ! Ammonification in suboxic waters with denitrification
117                  ! -------------------------------------------------------
118                  denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit,   &
119                     &                     zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)  )
120                  !
121                  zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
122                  denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
123                  !
124                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
125                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
126                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
127                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk)
128                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
129                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
130                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk)    &
131                  &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
132               END DO
133            END DO
134         END DO
135      ELSE
136         DO jk = 1, jpkm1
137            DO jj = 1, jpj
138               DO ji = 1, jpi
139                  ! DOC ammonification. Depends on depth, phytoplankton biomass
140                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
141                  ! -----------------------------------------------------------------
142                  zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
143                  zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
144
145                  zremikc = xremikc * zremik
146                  zremikn = xremikn / xremikc
147                  zremikp = xremikp / xremikc
148
149                  ! Ammonification in oxic waters with oxygen consumption
150                  ! -----------------------------------------------------
151                  zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
152                  zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
153                  zolimi(ji,jj,jk) = zolimic
154                  zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
155                  zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
156
157                  ! Ammonification in suboxic waters with denitrification
158                  ! -------------------------------------------------------
159                  zolimit = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
160                  denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
161                  denitr(ji,jj,jk) = MAX( 0.e0, denitr(ji,jj,jk) )
162                  zdenitrn  = zremikn * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
163                  zdenitrp  = zremikp * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
164
165                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
166                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
167                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr(ji,jj,jk) * rdenit
168                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitr(ji,jj,jk)
169                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
170                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
171                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
172                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitr(ji,jj,jk)
173                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
174               END DO
175            END DO
176         END DO
177         !
178      ENDIF
179
180
181      DO jk = 1, jpkm1
182         DO jj = 1, jpj
183            DO ji = 1, jpi
184               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
185               ! below 2 umol/L. Inhibited at strong light
186               ! ----------------------------------------------------------
187               zonitr  = nitrif * xstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
188               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
189               zdenitnh4 = nitrif * xstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk)
190               ! Update of the tracers trends
191               ! ----------------------------
192               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
193               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
194               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
195               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
196            END DO
197         END DO
198      END DO
199
200       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
201         WRITE(charout, FMT="('rem1')")
202         CALL prt_ctl_trc_info(charout)
203         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
204       ENDIF
205
206      DO jk = 1, jpkm1
207         DO jj = 1, jpj
208            DO ji = 1, jpi
209
210               ! Bacterial uptake of iron. No iron is available in DOC. So
211               ! Bacteries are obliged to take up iron from the water. Some
212               ! studies (especially at Papa) have shown this uptake to be significant
213               ! ----------------------------------------------------------
214               zbactfer = feratb *  rfact2 * prmax(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
215                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
216                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
217               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
218               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
219               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
220            END DO
221         END DO
222      END DO
223
224       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
225         WRITE(charout, FMT="('rem2')")
226         CALL prt_ctl_trc_info(charout)
227         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
228       ENDIF
229
230      ! Initialization of the array which contains the labile fraction
231      ! of bSi. Set to a constant in the upper ocean
232      ! ---------------------------------------------------------------
233
234      DO jk = 1, jpkm1
235         DO jj = 1, jpj
236            DO ji = 1, jpi
237               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
238               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
239               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
240               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
241               ! Remineralization rate of BSi depedant on T and saturation
242               ! ---------------------------------------------------------
243               IF ( gdept_n(ji,jj,jk) > zdep ) THEN
244                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
245                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
246                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
247                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
248                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
249               ENDIF
250               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
251               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
252               !
253               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
254               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
255               !
256            END DO
257         END DO
258      END DO
259
260      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
261         WRITE(charout, FMT="('rem3')")
262         CALL prt_ctl_trc_info(charout)
263         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
264       ENDIF
265
266      IF( knt == nrdttrc ) THEN
267          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
268          !
269          IF( iom_use( "REMIN" ) )  THEN
270              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
271              CALL iom_put( "REMIN"  , zw3d )
272          ENDIF
273          IF( iom_use( "DENIT" ) )  THEN
274              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
275              CALL iom_put( "DENIT"  , zw3d )
276          ENDIF
277          !
278       ENDIF
279      !
280      !
281      IF( nn_timing == 1 )  CALL timing_stop('p4z_rem')
282      !
283   END SUBROUTINE p4z_rem
284
285
286   SUBROUTINE p4z_rem_init
287      !!----------------------------------------------------------------------
288      !!                  ***  ROUTINE p4z_rem_init  ***
289      !!
290      !! ** Purpose :   Initialization of remineralization parameters
291      !!
292      !! ** Method  :   Read the nampisrem namelist and check the parameters
293      !!      called at the first timestep
294      !!
295      !! ** input   :   Namelist nampisrem
296      !!
297      !!----------------------------------------------------------------------
298      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
299         &                xremikc, xremikn, xremikp
300      INTEGER :: ios                 ! Local integer output status for namelist read
301
302      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
303      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
304901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
305
306      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
307      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
308902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
309      IF(lwm) WRITE ( numonp, nampisrem )
310
311      IF(lwp) THEN                         ! control print
312         WRITE(numout,*) ' '
313         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
314         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
315         IF( ln_p4z ) THEN
316            WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
317         ELSE
318            WRITE(numout,*) '    remineralization rate of DOC              xremikc   =', xremikc
319            WRITE(numout,*) '    remineralization rate of DON              xremikn   =', xremikn
320            WRITE(numout,*) '    remineralization rate of DOP              xremikp   =', xremikp
321         ENDIF
322         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
323         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
324         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
325         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
326         WRITE(numout,*) '    Bacterial Fe/C ratio                      feratb    =', feratb
327         WRITE(numout,*) '    Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
328      ENDIF
329      !
330      denitr  (:,:,:) = 0._wp
331      !
332   END SUBROUTINE p4z_rem_init
333
334
335   INTEGER FUNCTION p4z_rem_alloc()
336      !!----------------------------------------------------------------------
337      !!                     ***  ROUTINE p4z_rem_alloc  ***
338      !!----------------------------------------------------------------------
339      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
340      !
341      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
342      !
343   END FUNCTION p4z_rem_alloc
344
345   !!======================================================================
346END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.