| 1 | MODULE p4zsed |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4sed *** |
|---|
| 4 | !! TOP : PISCES Compute loss of organic matter in the sediments |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004-03 (O. Aumont) Original code |
|---|
| 7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 8 | !! 3.4 ! 2011-06 (C. Ethe) USE of fldread |
|---|
| 9 | !! 3.5 ! 2012-07 (O. Aumont) improvment of river input of nutrients |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! p4z_sed : Compute loss of organic matter in the sediments |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 14 | USE trc ! passive tracers common variables |
|---|
| 15 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 16 | USE p4zlim ! Co-limitations of differents nutrients |
|---|
| 17 | USE p4zsbc ! External source of nutrients |
|---|
| 18 | USE p4zint ! interpolation and computation of various fields |
|---|
| 19 | USE iom ! I/O manager |
|---|
| 20 | USE prtctl_trc ! print control for debugging |
|---|
| 21 | |
|---|
| 22 | IMPLICIT NONE |
|---|
| 23 | PRIVATE |
|---|
| 24 | |
|---|
| 25 | PUBLIC p4z_sed |
|---|
| 26 | PUBLIC p4z_sed_alloc |
|---|
| 27 | |
|---|
| 28 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot !: Nitrogen fixation |
|---|
| 29 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,: ) :: sdenit !: Nitrate reduction in the sediments |
|---|
| 30 | REAL(wp) :: r1_rday !: inverse of rday |
|---|
| 31 | |
|---|
| 32 | !!---------------------------------------------------------------------- |
|---|
| 33 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 34 | !! $Id$ |
|---|
| 35 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | CONTAINS |
|---|
| 38 | |
|---|
| 39 | SUBROUTINE p4z_sed( kt, knt ) |
|---|
| 40 | !!--------------------------------------------------------------------- |
|---|
| 41 | !! *** ROUTINE p4z_sed *** |
|---|
| 42 | !! |
|---|
| 43 | !! ** Purpose : Compute loss of organic matter in the sediments. This |
|---|
| 44 | !! is by no way a sediment model. The loss is simply |
|---|
| 45 | !! computed to balance the inout from rivers and dust |
|---|
| 46 | !! |
|---|
| 47 | !! ** Method : - ??? |
|---|
| 48 | !!--------------------------------------------------------------------- |
|---|
| 49 | ! |
|---|
| 50 | INTEGER, INTENT(in) :: kt, knt ! ocean time step |
|---|
| 51 | INTEGER :: ji, jj, jk, ikt |
|---|
| 52 | REAL(wp) :: zsumsedsi, zsumsedpo4, zsumsedcal |
|---|
| 53 | REAL(wp) :: zrivalk, zrivsil, zrivno3 |
|---|
| 54 | REAL(wp) :: zwflux, zfminus, zfplus |
|---|
| 55 | REAL(wp) :: zlim, zfact, zfactcal |
|---|
| 56 | REAL(wp) :: zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit |
|---|
| 57 | REAL(wp) :: zsiloss, zcaloss, zws3, zws4, zwsc, zdep |
|---|
| 58 | REAL(wp) :: zwstpoc, zwstpon, zwstpop |
|---|
| 59 | REAL(wp) :: ztrfer, ztrpo4s, ztrdp, zwdust, zmudia, ztemp |
|---|
| 60 | REAL(wp) :: xdiano3, xdianh4 |
|---|
| 61 | REAL(wp) :: zwssfep |
|---|
| 62 | ! |
|---|
| 63 | CHARACTER (len=25) :: charout |
|---|
| 64 | REAL(wp), DIMENSION(jpi,jpj) :: zsidep, zwork1, zwork2, zwork3 |
|---|
| 65 | REAL(wp), DIMENSION(jpi,jpj) :: zdenit2d, zironice, zbureff |
|---|
| 66 | REAL(wp), DIMENSION(jpi,jpj) :: zwsbio3, zwsbio4, zwscal |
|---|
| 67 | REAL(wp), DIMENSION(jpi,jpj) :: zsedcal, zsedsi, zsedc |
|---|
| 68 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztrpo4, ztrdop, zirondep, zsoufer, zpdep, zlight |
|---|
| 69 | REAL(wp), DIMENSION(jpi,jpj) :: zwsfep |
|---|
| 70 | |
|---|
| 71 | !!--------------------------------------------------------------------- |
|---|
| 72 | ! |
|---|
| 73 | IF( nn_timing == 1 ) CALL timing_start('p4z_sed') |
|---|
| 74 | ! |
|---|
| 75 | IF( kt == nittrc000 .AND. knt == 1 ) r1_rday = 1. / rday |
|---|
| 76 | ! |
|---|
| 77 | ! Allocate temporary workspace |
|---|
| 78 | |
|---|
| 79 | |
|---|
| 80 | zdenit2d(:,:) = 0.e0 |
|---|
| 81 | zbureff (:,:) = 0.e0 |
|---|
| 82 | zwork1 (:,:) = 0.e0 |
|---|
| 83 | zwork2 (:,:) = 0.e0 |
|---|
| 84 | zwork3 (:,:) = 0.e0 |
|---|
| 85 | zsedsi (:,:) = 0.e0 |
|---|
| 86 | zsedcal (:,:) = 0.e0 |
|---|
| 87 | zsedc (:,:) = 0.e0 |
|---|
| 88 | |
|---|
| 89 | |
|---|
| 90 | ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al. |
|---|
| 91 | ! ---------------------------------------------------- |
|---|
| 92 | IF( ln_ironice ) THEN |
|---|
| 93 | ! |
|---|
| 94 | ! |
|---|
| 95 | DO jj = 1, jpj |
|---|
| 96 | DO ji = 1, jpi |
|---|
| 97 | zdep = rfact2 / e3t_n(ji,jj,1) |
|---|
| 98 | zwflux = fmmflx(ji,jj) / 1000._wp |
|---|
| 99 | zfminus = MIN( 0._wp, -zwflux ) * trb(ji,jj,1,jpfer) * zdep |
|---|
| 100 | zfplus = MAX( 0._wp, -zwflux ) * icefeinput * zdep |
|---|
| 101 | zironice(ji,jj) = zfplus + zfminus |
|---|
| 102 | END DO |
|---|
| 103 | END DO |
|---|
| 104 | ! |
|---|
| 105 | tra(:,:,1,jpfer) = tra(:,:,1,jpfer) + zironice(:,:) |
|---|
| 106 | ! |
|---|
| 107 | IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) ) & |
|---|
| 108 | & CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice |
|---|
| 109 | ! |
|---|
| 110 | ! |
|---|
| 111 | ENDIF |
|---|
| 112 | |
|---|
| 113 | ! Add the external input of nutrients from dust deposition |
|---|
| 114 | ! ---------------------------------------------------------- |
|---|
| 115 | IF( ln_dust ) THEN |
|---|
| 116 | ! |
|---|
| 117 | ! ! Iron and Si deposition at the surface |
|---|
| 118 | IF( ln_solub ) THEN |
|---|
| 119 | zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss |
|---|
| 120 | ELSE |
|---|
| 121 | zirondep(:,:,1) = dustsolub * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss |
|---|
| 122 | ENDIF |
|---|
| 123 | zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 28.1 |
|---|
| 124 | zpdep (:,:,1) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 31. / po4r |
|---|
| 125 | ! ! Iron solubilization of particles in the water column |
|---|
| 126 | ! ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ; wdust in m/j |
|---|
| 127 | zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday ) |
|---|
| 128 | DO jk = 2, jpkm1 |
|---|
| 129 | zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -gdept_n(:,:,jk) / 540. ) |
|---|
| 130 | zpdep (:,:,jk) = zirondep(:,:,jk) * 0.023 |
|---|
| 131 | END DO |
|---|
| 132 | ! ! Iron solubilization of particles in the water column |
|---|
| 133 | tra(:,:,1,jpsil) = tra(:,:,1,jpsil) + zsidep (:,:) |
|---|
| 134 | tra(:,:,:,jppo4) = tra(:,:,:,jppo4) + zpdep (:,:,:) |
|---|
| 135 | tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + zirondep(:,:,:) |
|---|
| 136 | ! |
|---|
| 137 | IF( lk_iomput ) THEN |
|---|
| 138 | IF( knt == nrdttrc ) THEN |
|---|
| 139 | IF( iom_use( "Irondep" ) ) & |
|---|
| 140 | & CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron |
|---|
| 141 | IF( iom_use( "pdust" ) ) & |
|---|
| 142 | & CALL iom_put( "pdust" , dust(:,:) / ( wdust * rday ) * tmask(:,:,1) ) ! dust concentration at surface |
|---|
| 143 | ENDIF |
|---|
| 144 | ENDIF |
|---|
| 145 | ! |
|---|
| 146 | ENDIF |
|---|
| 147 | |
|---|
| 148 | ! Add the external input of nutrients from river |
|---|
| 149 | ! ---------------------------------------------------------- |
|---|
| 150 | IF( ln_river ) THEN |
|---|
| 151 | DO jj = 1, jpj |
|---|
| 152 | DO ji = 1, jpi |
|---|
| 153 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 154 | tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + rivdip(ji,jj) * rfact2 |
|---|
| 155 | tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + rivdin(ji,jj) * rfact2 |
|---|
| 156 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + rivdic(ji,jj) * 5.e-5 * rfact2 |
|---|
| 157 | tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + rivdsi(ji,jj) * rfact2 |
|---|
| 158 | tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + rivdic(ji,jj) * rfact2 |
|---|
| 159 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2 |
|---|
| 160 | ENDDO |
|---|
| 161 | ENDDO |
|---|
| 162 | ENDDO |
|---|
| 163 | IF( ln_p5z ) THEN |
|---|
| 164 | DO jj = 1, jpj |
|---|
| 165 | DO ji = 1, jpi |
|---|
| 166 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 167 | tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + rivdop(ji,jj) * rfact2 |
|---|
| 168 | tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + rivdon(ji,jj) * rfact2 |
|---|
| 169 | tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + rivdoc(ji,jj) * rfact2 |
|---|
| 170 | ENDDO |
|---|
| 171 | ENDDO |
|---|
| 172 | ENDDO |
|---|
| 173 | ENDIF |
|---|
| 174 | ENDIF |
|---|
| 175 | |
|---|
| 176 | ! Add the external input of nutrients from nitrogen deposition |
|---|
| 177 | ! ---------------------------------------------------------- |
|---|
| 178 | IF( ln_ndepo ) THEN |
|---|
| 179 | tra(:,:,1,jpno3) = tra(:,:,1,jpno3) + nitdep(:,:) * rfact2 |
|---|
| 180 | tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2 |
|---|
| 181 | ENDIF |
|---|
| 182 | |
|---|
| 183 | ! Add the external input of iron from sediment mobilization |
|---|
| 184 | ! ------------------------------------------------------ |
|---|
| 185 | IF( ln_ironsed ) THEN |
|---|
| 186 | tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + ironsed(:,:,:) * rfact2 |
|---|
| 187 | IF( ln_ligand ) tra(:,:,:,jpfep) = tra(:,:,:,jpfep) + ( ironsed(:,:,:) * fep_rats ) * rfact2 |
|---|
| 188 | ! |
|---|
| 189 | IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) ) & |
|---|
| 190 | & CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments |
|---|
| 191 | ENDIF |
|---|
| 192 | |
|---|
| 193 | ! Add the external input of iron from hydrothermal vents |
|---|
| 194 | ! ------------------------------------------------------ |
|---|
| 195 | IF( ln_hydrofe ) THEN |
|---|
| 196 | tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2 |
|---|
| 197 | IF( ln_ligand ) THEN |
|---|
| 198 | tra(:,:,:,jpfep) = tra(:,:,:,jpfep) + ( hydrofe(:,:,:) * fep_rath ) * rfact2 |
|---|
| 199 | tra(:,:,:,jplgw) = tra(:,:,:,jplgw) + ( hydrofe(:,:,:) * lgw_rath ) * rfact2 |
|---|
| 200 | ENDIF |
|---|
| 201 | ! |
|---|
| 202 | IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) ) & |
|---|
| 203 | & CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input |
|---|
| 204 | ENDIF |
|---|
| 205 | |
|---|
| 206 | ! OA: Warning, the following part is necessary to avoid CFL problems above the sediments |
|---|
| 207 | ! -------------------------------------------------------------------- |
|---|
| 208 | DO jj = 1, jpj |
|---|
| 209 | DO ji = 1, jpi |
|---|
| 210 | ikt = mbkt(ji,jj) |
|---|
| 211 | zdep = e3t_n(ji,jj,ikt) / xstep |
|---|
| 212 | zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) ) |
|---|
| 213 | zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) ) |
|---|
| 214 | zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) ) |
|---|
| 215 | END DO |
|---|
| 216 | END DO |
|---|
| 217 | ! |
|---|
| 218 | IF( ln_ligand ) THEN |
|---|
| 219 | DO jj = 1, jpj |
|---|
| 220 | DO ji = 1, jpi |
|---|
| 221 | ikt = mbkt(ji,jj) |
|---|
| 222 | zdep = e3t_n(ji,jj,ikt) / xstep |
|---|
| 223 | zwsfep(ji,jj) = MIN( 0.99 * zdep, wsfep(ji,jj,ikt) ) |
|---|
| 224 | END DO |
|---|
| 225 | ENDDO |
|---|
| 226 | ENDIF |
|---|
| 227 | |
|---|
| 228 | IF( .NOT.lk_sed ) THEN |
|---|
| 229 | ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used |
|---|
| 230 | ! Computation of the fraction of organic matter that is permanently buried from Dunne's model |
|---|
| 231 | ! ------------------------------------------------------- |
|---|
| 232 | DO jj = 1, jpj |
|---|
| 233 | DO ji = 1, jpi |
|---|
| 234 | IF( tmask(ji,jj,1) == 1 ) THEN |
|---|
| 235 | ikt = mbkt(ji,jj) |
|---|
| 236 | zflx = ( trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) & |
|---|
| 237 | & + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E3 * 1E6 / 1E4 |
|---|
| 238 | zflx = LOG10( MAX( 1E-3, zflx ) ) |
|---|
| 239 | zo2 = LOG10( MAX( 10. , trb(ji,jj,ikt,jpoxy) * 1E6 ) ) |
|---|
| 240 | zno3 = LOG10( MAX( 1. , trb(ji,jj,ikt,jpno3) * 1E6 * rno3 ) ) |
|---|
| 241 | zdep = LOG10( gdepw_n(ji,jj,ikt+1) ) |
|---|
| 242 | zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3 & |
|---|
| 243 | & + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2 |
|---|
| 244 | zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) ) |
|---|
| 245 | ! |
|---|
| 246 | zflx = ( trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) & |
|---|
| 247 | & + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6 |
|---|
| 248 | zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2 |
|---|
| 249 | ENDIF |
|---|
| 250 | END DO |
|---|
| 251 | END DO |
|---|
| 252 | |
|---|
| 253 | ! Loss of biogenic silicon, Caco3 organic carbon in the sediments. |
|---|
| 254 | ! First, the total loss is computed. |
|---|
| 255 | ! The factor for calcite comes from the alkalinity effect |
|---|
| 256 | ! ------------------------------------------------------------- |
|---|
| 257 | DO jj = 1, jpj |
|---|
| 258 | DO ji = 1, jpi |
|---|
| 259 | IF( tmask(ji,jj,1) == 1 ) THEN |
|---|
| 260 | ikt = mbkt(ji,jj) |
|---|
| 261 | zwork1(ji,jj) = trb(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj) |
|---|
| 262 | zwork2(ji,jj) = trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) |
|---|
| 263 | ! For calcite, burial efficiency is made a function of saturation |
|---|
| 264 | zfactcal = MIN( excess(ji,jj,ikt), 0.2 ) |
|---|
| 265 | zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) ) |
|---|
| 266 | zwork3(ji,jj) = trb(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal |
|---|
| 267 | ENDIF |
|---|
| 268 | END DO |
|---|
| 269 | END DO |
|---|
| 270 | zsumsedsi = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday |
|---|
| 271 | zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday |
|---|
| 272 | zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday |
|---|
| 273 | ! |
|---|
| 274 | ENDIF |
|---|
| 275 | |
|---|
| 276 | ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean. |
|---|
| 277 | ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers) |
|---|
| 278 | ! ------------------------------------------------------ |
|---|
| 279 | IF( .NOT.lk_sed ) zrivsil = 1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn ) |
|---|
| 280 | |
|---|
| 281 | DO jj = 1, jpj |
|---|
| 282 | DO ji = 1, jpi |
|---|
| 283 | ikt = mbkt(ji,jj) |
|---|
| 284 | zdep = xstep / e3t_n(ji,jj,ikt) |
|---|
| 285 | zwsc = zwscal (ji,jj) * zdep |
|---|
| 286 | zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc |
|---|
| 287 | zcaloss = trb(ji,jj,ikt,jpcal) * zwsc |
|---|
| 288 | ! |
|---|
| 289 | tra(ji,jj,ikt,jpgsi) = tra(ji,jj,ikt,jpgsi) - zsiloss |
|---|
| 290 | tra(ji,jj,ikt,jpcal) = tra(ji,jj,ikt,jpcal) - zcaloss |
|---|
| 291 | END DO |
|---|
| 292 | END DO |
|---|
| 293 | ! |
|---|
| 294 | IF( .NOT.lk_sed ) THEN |
|---|
| 295 | DO jj = 1, jpj |
|---|
| 296 | DO ji = 1, jpi |
|---|
| 297 | ikt = mbkt(ji,jj) |
|---|
| 298 | zdep = xstep / e3t_n(ji,jj,ikt) |
|---|
| 299 | zwsc = zwscal (ji,jj) * zdep |
|---|
| 300 | zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc |
|---|
| 301 | zcaloss = trb(ji,jj,ikt,jpcal) * zwsc |
|---|
| 302 | tra(ji,jj,ikt,jpsil) = tra(ji,jj,ikt,jpsil) + zsiloss * zrivsil |
|---|
| 303 | ! |
|---|
| 304 | zfactcal = MIN( excess(ji,jj,ikt), 0.2 ) |
|---|
| 305 | zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) ) |
|---|
| 306 | zrivalk = 1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn ) |
|---|
| 307 | tra(ji,jj,ikt,jptal) = tra(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0 |
|---|
| 308 | tra(ji,jj,ikt,jpdic) = tra(ji,jj,ikt,jpdic) + zcaloss * zrivalk |
|---|
| 309 | zsedcal(ji,jj) = (1.0 - zrivalk) * zcaloss / zdep |
|---|
| 310 | zsedsi (ji,jj) = (1.0 - zrivsil) * zsiloss / zdep |
|---|
| 311 | END DO |
|---|
| 312 | END DO |
|---|
| 313 | ENDIF |
|---|
| 314 | ! |
|---|
| 315 | DO jj = 1, jpj |
|---|
| 316 | DO ji = 1, jpi |
|---|
| 317 | ikt = mbkt(ji,jj) |
|---|
| 318 | zdep = xstep / e3t_n(ji,jj,ikt) |
|---|
| 319 | zws4 = zwsbio4(ji,jj) * zdep |
|---|
| 320 | zws3 = zwsbio3(ji,jj) * zdep |
|---|
| 321 | tra(ji,jj,ikt,jpgoc) = tra(ji,jj,ikt,jpgoc) - trb(ji,jj,ikt,jpgoc) * zws4 |
|---|
| 322 | tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3 |
|---|
| 323 | tra(ji,jj,ikt,jpbfe) = tra(ji,jj,ikt,jpbfe) - trb(ji,jj,ikt,jpbfe) * zws4 |
|---|
| 324 | tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3 |
|---|
| 325 | END DO |
|---|
| 326 | END DO |
|---|
| 327 | ! |
|---|
| 328 | IF( ln_ligand ) THEN |
|---|
| 329 | DO jj = 1, jpj |
|---|
| 330 | DO ji = 1, jpi |
|---|
| 331 | ikt = mbkt(ji,jj) |
|---|
| 332 | zdep = xstep / e3t_n(ji,jj,ikt) |
|---|
| 333 | zwssfep = zwsfep(ji,jj) * zdep |
|---|
| 334 | tra(ji,jj,ikt,jpfep) = tra(ji,jj,ikt,jpfep) - trb(ji,jj,ikt,jpfep) * zwssfep |
|---|
| 335 | END DO |
|---|
| 336 | END DO |
|---|
| 337 | ENDIF |
|---|
| 338 | ! |
|---|
| 339 | IF( ln_p5z ) THEN |
|---|
| 340 | DO jj = 1, jpj |
|---|
| 341 | DO ji = 1, jpi |
|---|
| 342 | ikt = mbkt(ji,jj) |
|---|
| 343 | zdep = xstep / e3t_n(ji,jj,ikt) |
|---|
| 344 | zws4 = zwsbio4(ji,jj) * zdep |
|---|
| 345 | zws3 = zwsbio3(ji,jj) * zdep |
|---|
| 346 | tra(ji,jj,ikt,jpgon) = tra(ji,jj,ikt,jpgon) - trb(ji,jj,ikt,jpgon) * zws4 |
|---|
| 347 | tra(ji,jj,ikt,jppon) = tra(ji,jj,ikt,jppon) - trb(ji,jj,ikt,jppon) * zws3 |
|---|
| 348 | tra(ji,jj,ikt,jpgop) = tra(ji,jj,ikt,jpgop) - trb(ji,jj,ikt,jpgop) * zws4 |
|---|
| 349 | tra(ji,jj,ikt,jppop) = tra(ji,jj,ikt,jppop) - trb(ji,jj,ikt,jppop) * zws3 |
|---|
| 350 | END DO |
|---|
| 351 | END DO |
|---|
| 352 | ENDIF |
|---|
| 353 | |
|---|
| 354 | IF( .NOT.lk_sed ) THEN |
|---|
| 355 | ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification |
|---|
| 356 | ! in the sediments and just above the sediments. Not very clever, but simpliest option. |
|---|
| 357 | DO jj = 1, jpj |
|---|
| 358 | DO ji = 1, jpi |
|---|
| 359 | ikt = mbkt(ji,jj) |
|---|
| 360 | zdep = xstep / e3t_n(ji,jj,ikt) |
|---|
| 361 | zws4 = zwsbio4(ji,jj) * zdep |
|---|
| 362 | zws3 = zwsbio3(ji,jj) * zdep |
|---|
| 363 | zrivno3 = 1. - zbureff(ji,jj) |
|---|
| 364 | zwstpoc = trb(ji,jj,ikt,jpgoc) * zws4 + trb(ji,jj,ikt,jppoc) * zws3 |
|---|
| 365 | zpdenit = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 ) |
|---|
| 366 | z1pdenit = zwstpoc * zrivno3 - zpdenit |
|---|
| 367 | zolimit = MIN( ( trb(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) ) |
|---|
| 368 | zdenitt = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) ) |
|---|
| 369 | tra(ji,jj,ikt,jpdoc) = tra(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt |
|---|
| 370 | tra(ji,jj,ikt,jppo4) = tra(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt |
|---|
| 371 | tra(ji,jj,ikt,jpnh4) = tra(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt |
|---|
| 372 | tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt) |
|---|
| 373 | tra(ji,jj,ikt,jpoxy) = tra(ji,jj,ikt,jpoxy) - zolimit * o2ut |
|---|
| 374 | tra(ji,jj,ikt,jptal) = tra(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) ) |
|---|
| 375 | tra(ji,jj,ikt,jpdic) = tra(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt |
|---|
| 376 | sdenit(ji,jj) = rdenit * zpdenit * e3t_n(ji,jj,ikt) |
|---|
| 377 | zsedc(ji,jj) = (1. - zrivno3) * zwstpoc / zdep |
|---|
| 378 | IF( ln_p5z ) THEN |
|---|
| 379 | zwstpop = trb(ji,jj,ikt,jpgop) * zws4 + trb(ji,jj,ikt,jppop) * zws3 |
|---|
| 380 | zwstpon = trb(ji,jj,ikt,jpgon) * zws4 + trb(ji,jj,ikt,jppon) * zws3 |
|---|
| 381 | tra(ji,jj,ikt,jpdon) = tra(ji,jj,ikt,jpdon) + (z1pdenit - zolimit - zdenitt) * zwstpon / (zwstpoc + rtrn) |
|---|
| 382 | tra(ji,jj,ikt,jpdop) = tra(ji,jj,ikt,jpdop) + (z1pdenit - zolimit - zdenitt) * zwstpop / (zwstpoc + rtrn) |
|---|
| 383 | ENDIF |
|---|
| 384 | END DO |
|---|
| 385 | END DO |
|---|
| 386 | ENDIF |
|---|
| 387 | |
|---|
| 388 | |
|---|
| 389 | ! Nitrogen fixation process |
|---|
| 390 | ! Small source iron from particulate inorganic iron |
|---|
| 391 | !----------------------------------- |
|---|
| 392 | DO jk = 1, jpkm1 |
|---|
| 393 | zlight (:,:,jk) = ( 1.- EXP( -etot_ndcy(:,:,jk) / diazolight ) ) * ( 1. - fr_i(:,:) ) |
|---|
| 394 | zsoufer(:,:,jk) = zlight(:,:,jk) * 2E-11 / ( 2E-11 + biron(:,:,jk) ) |
|---|
| 395 | ENDDO |
|---|
| 396 | IF( ln_p4z ) THEN |
|---|
| 397 | DO jk = 1, jpkm1 |
|---|
| 398 | DO jj = 1, jpj |
|---|
| 399 | DO ji = 1, jpi |
|---|
| 400 | ! ! Potential nitrogen fixation dependant on temperature and iron |
|---|
| 401 | zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) ) |
|---|
| 402 | IF( zlim <= 0.2 ) zlim = 0.01 |
|---|
| 403 | zfact = zlim * rfact2 |
|---|
| 404 | |
|---|
| 405 | ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) ) |
|---|
| 406 | ztrpo4s = trb (ji,jj,jk,jppo4) / ( concnnh4 + trb (ji,jj,jk,jppo4) ) |
|---|
| 407 | nitrpot(ji,jj,jk) = MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday ) & |
|---|
| 408 | & * zfact * MIN( ztrfer, ztrpo4s ) * zlight(ji,jj,jk) |
|---|
| 409 | END DO |
|---|
| 410 | END DO |
|---|
| 411 | END DO |
|---|
| 412 | ELSE ! p5z |
|---|
| 413 | DO jk = 1, jpkm1 |
|---|
| 414 | DO jj = 1, jpj |
|---|
| 415 | DO ji = 1, jpi |
|---|
| 416 | ! ! Potential nitrogen fixation dependant on temperature and iron |
|---|
| 417 | ztemp = tsn(ji,jj,jk,jp_tem) |
|---|
| 418 | zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625 |
|---|
| 419 | ! Potential nitrogen fixation dependant on temperature and iron |
|---|
| 420 | xdianh4 = trb(ji,jj,jk,jpnh4) / ( concnnh4 + trb(ji,jj,jk,jpnh4) ) |
|---|
| 421 | xdiano3 = trb(ji,jj,jk,jpno3) / ( concnno3 + trb(ji,jj,jk,jpno3) ) * (1. - xdianh4) |
|---|
| 422 | zlim = ( 1.- xdiano3 - xdianh4 ) |
|---|
| 423 | IF( zlim <= 0.1 ) zlim = 0.01 |
|---|
| 424 | zfact = zlim * rfact2 |
|---|
| 425 | ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) ) |
|---|
| 426 | ztrpo4(ji,jj,jk) = trb(ji,jj,jk,jppo4) / ( 1E-6 + trb(ji,jj,jk,jppo4) ) |
|---|
| 427 | ztrdop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( 1E-6 + trb(ji,jj,jk,jpdop) ) * (1. - ztrpo4(ji,jj,jk)) |
|---|
| 428 | ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) |
|---|
| 429 | nitrpot(ji,jj,jk) = zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk) |
|---|
| 430 | END DO |
|---|
| 431 | END DO |
|---|
| 432 | END DO |
|---|
| 433 | ENDIF |
|---|
| 434 | |
|---|
| 435 | ! Nitrogen change due to nitrogen fixation |
|---|
| 436 | ! ---------------------------------------- |
|---|
| 437 | IF( ln_p4z ) THEN |
|---|
| 438 | DO jk = 1, jpkm1 |
|---|
| 439 | DO jj = 1, jpj |
|---|
| 440 | DO ji = 1, jpi |
|---|
| 441 | zfact = nitrpot(ji,jj,jk) * nitrfix |
|---|
| 442 | tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zfact |
|---|
| 443 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zfact |
|---|
| 444 | tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2nit * zfact |
|---|
| 445 | tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trb(ji,jj,jk,jppo4) ) & |
|---|
| 446 | & * 0.002 * trb(ji,jj,jk,jpdoc) * xstep |
|---|
| 447 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * xstep |
|---|
| 448 | END DO |
|---|
| 449 | END DO |
|---|
| 450 | END DO |
|---|
| 451 | ELSE ! p5z |
|---|
| 452 | DO jk = 1, jpkm1 |
|---|
| 453 | DO jj = 1, jpj |
|---|
| 454 | DO ji = 1, jpi |
|---|
| 455 | zfact = nitrpot(ji,jj,jk) * nitrfix |
|---|
| 456 | tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zfact / 3.0 |
|---|
| 457 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zfact / 3.0 |
|---|
| 458 | tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) & |
|---|
| 459 | & * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn) |
|---|
| 460 | tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zfact * 1.0 / 3.0 |
|---|
| 461 | tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zfact * 1.0 / 3.0 |
|---|
| 462 | tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + 16.0 / 46.0 * zfact / 3.0 & |
|---|
| 463 | & - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk) & |
|---|
| 464 | & / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn) |
|---|
| 465 | tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zfact * 1.0 / 3.0 * 2.0 / 3.0 |
|---|
| 466 | tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zfact * 1.0 / 3.0 * 2.0 /3.0 |
|---|
| 467 | tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0 |
|---|
| 468 | tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfact * 1.0 / 3.0 * 1.0 / 3.0 |
|---|
| 469 | tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) + zfact * 1.0 / 3.0 * 1.0 /3.0 |
|---|
| 470 | tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0 |
|---|
| 471 | tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0 |
|---|
| 472 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - 30E-6 * zfact * 1.0 / 3.0 |
|---|
| 473 | tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0 |
|---|
| 474 | tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0 |
|---|
| 475 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday |
|---|
| 476 | END DO |
|---|
| 477 | END DO |
|---|
| 478 | END DO |
|---|
| 479 | ! |
|---|
| 480 | ENDIF |
|---|
| 481 | |
|---|
| 482 | IF( lk_iomput ) THEN |
|---|
| 483 | IF( knt == nrdttrc ) THEN |
|---|
| 484 | zfact = 1.e+3 * rfact2r * rno3 ! conversion from molC/l/kt to molN/m3/s |
|---|
| 485 | IF( iom_use("Nfix" ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * zfact * tmask(:,:,:) ) ! nitrogen fixation |
|---|
| 486 | IF( iom_use("INTNFIX") ) THEN ! nitrogen fixation rate in ocean ( vertically integrated ) |
|---|
| 487 | zwork1(:,:) = 0. |
|---|
| 488 | DO jk = 1, jpkm1 |
|---|
| 489 | zwork1(:,:) = zwork1(:,:) + nitrpot(:,:,jk) * nitrfix * zfact * e3t_n(:,:,jk) * tmask(:,:,jk) |
|---|
| 490 | ENDDO |
|---|
| 491 | CALL iom_put( "INTNFIX" , zwork1 ) |
|---|
| 492 | ENDIF |
|---|
| 493 | IF( iom_use("SedCal" ) ) CALL iom_put( "SedCal", zsedcal(:,:) * 1.e+3 ) |
|---|
| 494 | IF( iom_use("SedSi" ) ) CALL iom_put( "SedSi", zsedsi (:,:) * 1.e+3 ) |
|---|
| 495 | IF( iom_use("SedC" ) ) CALL iom_put( "SedC", zsedc (:,:) * 1.e+3 ) |
|---|
| 496 | IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", sdenit (:,:) * 1.e+3 * rno3 ) |
|---|
| 497 | ENDIF |
|---|
| 498 | ENDIF |
|---|
| 499 | ! |
|---|
| 500 | IF(ln_ctl) THEN ! print mean trends (USEd for debugging) |
|---|
| 501 | WRITE(charout, fmt="('sed ')") |
|---|
| 502 | CALL prt_ctl_trc_info(charout) |
|---|
| 503 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
|---|
| 504 | ENDIF |
|---|
| 505 | ! |
|---|
| 506 | ! |
|---|
| 507 | IF( nn_timing == 1 ) CALL timing_stop('p4z_sed') |
|---|
| 508 | ! |
|---|
| 509 | END SUBROUTINE p4z_sed |
|---|
| 510 | |
|---|
| 511 | |
|---|
| 512 | INTEGER FUNCTION p4z_sed_alloc() |
|---|
| 513 | !!---------------------------------------------------------------------- |
|---|
| 514 | !! *** ROUTINE p4z_sed_alloc *** |
|---|
| 515 | !!---------------------------------------------------------------------- |
|---|
| 516 | ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc ) |
|---|
| 517 | ! |
|---|
| 518 | IF( p4z_sed_alloc /= 0 ) CALL ctl_warn('p4z_sed_alloc: failed to allocate arrays') |
|---|
| 519 | ! |
|---|
| 520 | END FUNCTION p4z_sed_alloc |
|---|
| 521 | |
|---|
| 522 | |
|---|
| 523 | !!====================================================================== |
|---|
| 524 | END MODULE p4zsed |
|---|
