| 1 | MODULE ldfslp |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE ldfslp *** |
|---|
| 4 | !! Ocean physics: slopes of neutral surfaces |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1994-12 (G. Madec, M. Imbard) Original code |
|---|
| 7 | !! 8.0 ! 1997-06 (G. Madec) optimization, lbc |
|---|
| 8 | !! 8.1 ! 1999-10 (A. Jouzeau) NEW profile in the mixed layer |
|---|
| 9 | !! NEMO 1.0 ! 2002-10 (G. Madec) Free form, F90 |
|---|
| 10 | !! - ! 2005-10 (A. Beckmann) correction for s-coordinates |
|---|
| 11 | !! 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) add Griffies operator |
|---|
| 12 | !! - ! 2010-11 (F. Dupond, G. Madec) bug correction in slopes just below the ML |
|---|
| 13 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) add limiter on triad slopes |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! ldf_slp : calculates the slopes of neutral surface (Madec operator) |
|---|
| 18 | !! ldf_slp_triad : calculates the triads of isoneutral slopes (Griffies operator) |
|---|
| 19 | !! ldf_slp_mxl : calculates the slopes at the base of the mixed layer (Madec operator) |
|---|
| 20 | !! ldf_slp_init : initialization of the slopes computation |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE oce ! ocean dynamics and tracers |
|---|
| 23 | USE dom_oce ! ocean space and time domain |
|---|
| 24 | USE ldfdyn ! lateral diffusion: eddy viscosity coef. |
|---|
| 25 | USE phycst ! physical constants |
|---|
| 26 | USE zdfmxl ! mixed layer depth |
|---|
| 27 | USE eosbn2 ! equation of states |
|---|
| 28 | ! |
|---|
| 29 | USE in_out_manager ! I/O manager |
|---|
| 30 | USE prtctl ! Print control |
|---|
| 31 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 32 | USE lib_mpp ! distribued memory computing library |
|---|
| 33 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 34 | USE wrk_nemo ! work arrays |
|---|
| 35 | USE timing ! Timing |
|---|
| 36 | |
|---|
| 37 | IMPLICIT NONE |
|---|
| 38 | PRIVATE |
|---|
| 39 | |
|---|
| 40 | PUBLIC ldf_slp ! routine called by step.F90 |
|---|
| 41 | PUBLIC ldf_slp_triad ! routine called by step.F90 |
|---|
| 42 | PUBLIC ldf_slp_init ! routine called by nemogcm.F90 |
|---|
| 43 | |
|---|
| 44 | LOGICAL , PUBLIC :: l_ldfslp = .FALSE. !: slopes flag |
|---|
| 45 | |
|---|
| 46 | LOGICAL , PUBLIC :: ln_traldf_iso = .TRUE. !: iso-neutral direction |
|---|
| 47 | LOGICAL , PUBLIC :: ln_traldf_triad = .FALSE. !: griffies triad scheme |
|---|
| 48 | |
|---|
| 49 | LOGICAL , PUBLIC :: ln_triad_iso = .FALSE. !: pure horizontal mixing in ML |
|---|
| 50 | LOGICAL , PUBLIC :: ln_botmix_triad = .FALSE. !: mixing on bottom |
|---|
| 51 | REAL(wp), PUBLIC :: rn_sw_triad = 1._wp !: =1 switching triads ; =0 all four triads used |
|---|
| 52 | REAL(wp), PUBLIC :: rn_slpmax = 0.01_wp !: slope limit |
|---|
| 53 | |
|---|
| 54 | LOGICAL , PUBLIC :: l_grad_zps = .FALSE. !: special treatment for Horz Tgradients w partial steps (triad operator) |
|---|
| 55 | |
|---|
| 56 | ! !! Classic operator (Madec) |
|---|
| 57 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: uslp, wslpi !: i_slope at U- and W-points |
|---|
| 58 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: vslp, wslpj !: j-slope at V- and W-points |
|---|
| 59 | ! !! triad operator (Griffies) |
|---|
| 60 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: wslp2 !: wslp**2 from Griffies quarter cells |
|---|
| 61 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:,:) :: triadi_g, triadj_g !: skew flux slopes relative to geopotentials |
|---|
| 62 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:,:) :: triadi , triadj !: isoneutral slopes relative to model-coordinate |
|---|
| 63 | ! !! both operators |
|---|
| 64 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ah_wslp2 !: ah * slope^2 at w-point |
|---|
| 65 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: akz !: stabilizing vertical diffusivity |
|---|
| 66 | |
|---|
| 67 | ! !! Madec operator |
|---|
| 68 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: omlmask ! mask of the surface mixed layer at T-pt |
|---|
| 69 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: uslpml, wslpiml ! i_slope at U- and W-points just below the mixed layer |
|---|
| 70 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: vslpml, wslpjml ! j_slope at V- and W-points just below the mixed layer |
|---|
| 71 | |
|---|
| 72 | REAL(wp) :: repsln = 1.e-25_wp ! tiny value used as minium of di(rho), dj(rho) and dk(rho) |
|---|
| 73 | |
|---|
| 74 | !! * Substitutions |
|---|
| 75 | # include "vectopt_loop_substitute.h90" |
|---|
| 76 | !!---------------------------------------------------------------------- |
|---|
| 77 | !! NEMO/OPA 4.0 , NEMO Consortium (2014) |
|---|
| 78 | !! $Id$ |
|---|
| 79 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | CONTAINS |
|---|
| 82 | |
|---|
| 83 | SUBROUTINE ldf_slp( kt, prd, pn2 ) |
|---|
| 84 | !!---------------------------------------------------------------------- |
|---|
| 85 | !! *** ROUTINE ldf_slp *** |
|---|
| 86 | !! |
|---|
| 87 | !! ** Purpose : Compute the slopes of neutral surface (slope of isopycnal |
|---|
| 88 | !! surfaces referenced locally) (ln_traldf_iso=T). |
|---|
| 89 | !! |
|---|
| 90 | !! ** Method : The slope in the i-direction is computed at U- and |
|---|
| 91 | !! W-points (uslp, wslpi) and the slope in the j-direction is |
|---|
| 92 | !! computed at V- and W-points (vslp, wslpj). |
|---|
| 93 | !! They are bounded by 1/100 over the whole ocean, and within the |
|---|
| 94 | !! surface layer they are bounded by the distance to the surface |
|---|
| 95 | !! ( slope<= depth/l where l is the length scale of horizontal |
|---|
| 96 | !! diffusion (here, aht=2000m2/s ==> l=20km with a typical velocity |
|---|
| 97 | !! of 10cm/s) |
|---|
| 98 | !! A horizontal shapiro filter is applied to the slopes |
|---|
| 99 | !! ln_sco=T, s-coordinate, add to the previously computed slopes |
|---|
| 100 | !! the slope of the model level surface. |
|---|
| 101 | !! macro-tasked on horizontal slab (jk-loop) (2, jpk-1) |
|---|
| 102 | !! [slopes already set to zero at level 1, and to zero or the ocean |
|---|
| 103 | !! bottom slope (ln_sco=T) at level jpk in inildf] |
|---|
| 104 | !! |
|---|
| 105 | !! ** Action : - uslp, wslpi, and vslp, wslpj, the i- and j-slopes |
|---|
| 106 | !! of now neutral surfaces at u-, w- and v- w-points, resp. |
|---|
| 107 | !!---------------------------------------------------------------------- |
|---|
| 108 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 109 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: prd ! in situ density |
|---|
| 110 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: pn2 ! Brunt-Vaisala frequency (locally ref.) |
|---|
| 111 | !! |
|---|
| 112 | INTEGER :: ji , jj , jk ! dummy loop indices |
|---|
| 113 | INTEGER :: ii0, ii1 ! temporary integer |
|---|
| 114 | INTEGER :: ij0, ij1 ! temporary integer |
|---|
| 115 | REAL(wp) :: zeps, zm1_g, zm1_2g, z1_16, zcofw, z1_slpmax ! local scalars |
|---|
| 116 | REAL(wp) :: zci, zfi, zau, zbu, zai, zbi ! - - |
|---|
| 117 | REAL(wp) :: zcj, zfj, zav, zbv, zaj, zbj ! - - |
|---|
| 118 | REAL(wp) :: zck, zfk, zbw ! - - |
|---|
| 119 | REAL(wp) :: zdepu, zdepv ! - - |
|---|
| 120 | REAL(wp), POINTER, DIMENSION(:,: ) :: zslpml_hmlpu, zslpml_hmlpv |
|---|
| 121 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zwz, zww |
|---|
| 122 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zdzr |
|---|
| 123 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zgru, zgrv |
|---|
| 124 | !!---------------------------------------------------------------------- |
|---|
| 125 | ! |
|---|
| 126 | IF( nn_timing == 1 ) CALL timing_start('ldf_slp') |
|---|
| 127 | ! |
|---|
| 128 | CALL wrk_alloc( jpi,jpj,jpk, zwz, zww, zdzr, zgru, zgrv ) |
|---|
| 129 | CALL wrk_alloc( jpi,jpj, zslpml_hmlpu, zslpml_hmlpv ) |
|---|
| 130 | |
|---|
| 131 | zeps = 1.e-20_wp !== Local constant initialization ==! |
|---|
| 132 | z1_16 = 1.0_wp / 16._wp |
|---|
| 133 | zm1_g = -1.0_wp / grav |
|---|
| 134 | zm1_2g = -0.5_wp / grav |
|---|
| 135 | z1_slpmax = 1._wp / rn_slpmax |
|---|
| 136 | ! |
|---|
| 137 | zww(:,:,:) = 0._wp |
|---|
| 138 | zwz(:,:,:) = 0._wp |
|---|
| 139 | ! |
|---|
| 140 | DO jk = 1, jpk !== i- & j-gradient of density ==! |
|---|
| 141 | DO jj = 1, jpjm1 |
|---|
| 142 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 143 | zgru(ji,jj,jk) = umask(ji,jj,jk) * ( prd(ji+1,jj ,jk) - prd(ji,jj,jk) ) |
|---|
| 144 | zgrv(ji,jj,jk) = vmask(ji,jj,jk) * ( prd(ji ,jj+1,jk) - prd(ji,jj,jk) ) |
|---|
| 145 | END DO |
|---|
| 146 | END DO |
|---|
| 147 | END DO |
|---|
| 148 | IF( ln_zps ) THEN ! partial steps correction at the bottom ocean level |
|---|
| 149 | DO jj = 1, jpjm1 |
|---|
| 150 | DO ji = 1, jpim1 |
|---|
| 151 | zgru(ji,jj,mbku(ji,jj)) = gru(ji,jj) |
|---|
| 152 | zgrv(ji,jj,mbkv(ji,jj)) = grv(ji,jj) |
|---|
| 153 | END DO |
|---|
| 154 | END DO |
|---|
| 155 | ENDIF |
|---|
| 156 | IF( ln_zps .AND. ln_isfcav ) THEN ! partial steps correction at the bottom ocean level |
|---|
| 157 | DO jj = 1, jpjm1 |
|---|
| 158 | DO ji = 1, jpim1 |
|---|
| 159 | IF ( miku(ji,jj) > 1 ) zgru(ji,jj,miku(ji,jj)) = grui(ji,jj) |
|---|
| 160 | IF ( mikv(ji,jj) > 1 ) zgrv(ji,jj,mikv(ji,jj)) = grvi(ji,jj) |
|---|
| 161 | END DO |
|---|
| 162 | END DO |
|---|
| 163 | ENDIF |
|---|
| 164 | ! |
|---|
| 165 | zdzr(:,:,1) = 0._wp !== Local vertical density gradient at T-point == ! (evaluated from N^2) |
|---|
| 166 | DO jk = 2, jpkm1 |
|---|
| 167 | ! ! zdzr = d/dz(prd)= - ( prd ) / grav * mk(pn2) -- at t point |
|---|
| 168 | ! ! trick: tmask(ik ) = 0 => all pn2 = 0 => zdzr = 0 |
|---|
| 169 | ! ! else tmask(ik+1) = 0 => pn2(ik+1) = 0 => zdzr divides by 1 |
|---|
| 170 | ! ! umask(ik+1) /= 0 => all pn2 /= 0 => zdzr divides by 2 |
|---|
| 171 | ! ! NB: 1/(tmask+1) = (1-.5*tmask) substitute a / by a * ==> faster |
|---|
| 172 | zdzr(:,:,jk) = zm1_g * ( prd(:,:,jk) + 1._wp ) & |
|---|
| 173 | & * ( pn2(:,:,jk) + pn2(:,:,jk+1) ) * ( 1._wp - 0.5_wp * tmask(:,:,jk+1) ) |
|---|
| 174 | END DO |
|---|
| 175 | ! |
|---|
| 176 | ! !== Slopes just below the mixed layer ==! |
|---|
| 177 | CALL ldf_slp_mxl( prd, pn2, zgru, zgrv, zdzr ) ! output: uslpml, vslpml, wslpiml, wslpjml |
|---|
| 178 | |
|---|
| 179 | |
|---|
| 180 | ! I. slopes at u and v point | uslp = d/di( prd ) / d/dz( prd ) |
|---|
| 181 | ! =========================== | vslp = d/dj( prd ) / d/dz( prd ) |
|---|
| 182 | ! |
|---|
| 183 | IF ( ln_isfcav ) THEN |
|---|
| 184 | DO jj = 2, jpjm1 |
|---|
| 185 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 186 | zslpml_hmlpu(ji,jj) = uslpml(ji,jj) / ( MAX(hmlpt (ji,jj), hmlpt (ji+1,jj ), 5._wp) & |
|---|
| 187 | & - MAX(risfdep(ji,jj), risfdep(ji+1,jj ) ) ) |
|---|
| 188 | zslpml_hmlpv(ji,jj) = vslpml(ji,jj) / ( MAX(hmlpt (ji,jj), hmlpt (ji ,jj+1), 5._wp) & |
|---|
| 189 | & - MAX(risfdep(ji,jj), risfdep(ji ,jj+1) ) ) |
|---|
| 190 | END DO |
|---|
| 191 | END DO |
|---|
| 192 | ELSE |
|---|
| 193 | DO jj = 2, jpjm1 |
|---|
| 194 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 195 | zslpml_hmlpu(ji,jj) = uslpml(ji,jj) / MAX(hmlpt(ji,jj), hmlpt(ji+1,jj ), 5._wp) |
|---|
| 196 | zslpml_hmlpv(ji,jj) = vslpml(ji,jj) / MAX(hmlpt(ji,jj), hmlpt(ji ,jj+1), 5._wp) |
|---|
| 197 | END DO |
|---|
| 198 | END DO |
|---|
| 199 | END IF |
|---|
| 200 | |
|---|
| 201 | DO jk = 2, jpkm1 !* Slopes at u and v points |
|---|
| 202 | DO jj = 2, jpjm1 |
|---|
| 203 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 204 | ! ! horizontal and vertical density gradient at u- and v-points |
|---|
| 205 | zau = zgru(ji,jj,jk) * r1_e1u(ji,jj) |
|---|
| 206 | zav = zgrv(ji,jj,jk) * r1_e2v(ji,jj) |
|---|
| 207 | zbu = 0.5_wp * ( zdzr(ji,jj,jk) + zdzr(ji+1,jj ,jk) ) |
|---|
| 208 | zbv = 0.5_wp * ( zdzr(ji,jj,jk) + zdzr(ji ,jj+1,jk) ) |
|---|
| 209 | ! ! bound the slopes: abs(zw.)<= 1/100 and zb..<0 |
|---|
| 210 | ! ! + kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 211 | zbu = MIN( zbu, - z1_slpmax * ABS( zau ) , -7.e+3_wp/e3u_n(ji,jj,jk)* ABS( zau ) ) |
|---|
| 212 | zbv = MIN( zbv, - z1_slpmax * ABS( zav ) , -7.e+3_wp/e3v_n(ji,jj,jk)* ABS( zav ) ) |
|---|
| 213 | ! ! uslp and vslp output in zwz and zww, resp. |
|---|
| 214 | zfi = MAX( omlmask(ji,jj,jk), omlmask(ji+1,jj,jk) ) |
|---|
| 215 | zfj = MAX( omlmask(ji,jj,jk), omlmask(ji,jj+1,jk) ) |
|---|
| 216 | ! thickness of water column between surface and level k at u/v point |
|---|
| 217 | zdepu = 0.5_wp * ( ( gdept_n (ji,jj,jk) + gdept_n (ji+1,jj,jk) ) & |
|---|
| 218 | - 2 * MAX( risfdep(ji,jj), risfdep(ji+1,jj) ) - e3u_n(ji,jj,miku(ji,jj)) ) |
|---|
| 219 | zdepv = 0.5_wp * ( ( gdept_n (ji,jj,jk) + gdept_n (ji,jj+1,jk) ) & |
|---|
| 220 | - 2 * MAX( risfdep(ji,jj), risfdep(ji,jj+1) ) - e3v_n(ji,jj,mikv(ji,jj)) ) |
|---|
| 221 | ! |
|---|
| 222 | zwz(ji,jj,jk) = ( ( 1._wp - zfi) * zau / ( zbu - zeps ) & |
|---|
| 223 | & + zfi * zdepu * zslpml_hmlpu(ji,jj) ) * umask(ji,jj,jk) |
|---|
| 224 | zww(ji,jj,jk) = ( ( 1._wp - zfj) * zav / ( zbv - zeps ) & |
|---|
| 225 | & + zfj * zdepv * zslpml_hmlpv(ji,jj) ) * vmask(ji,jj,jk) |
|---|
| 226 | !!gm modif to suppress omlmask.... (as in Griffies case) |
|---|
| 227 | ! ! ! jk must be >= ML level for zf=1. otherwise zf=0. |
|---|
| 228 | ! zfi = REAL( 1 - 1/(1 + jk / MAX( nmln(ji+1,jj), nmln(ji,jj) ) ), wp ) |
|---|
| 229 | ! zfj = REAL( 1 - 1/(1 + jk / MAX( nmln(ji,jj+1), nmln(ji,jj) ) ), wp ) |
|---|
| 230 | ! zci = 0.5 * ( gdept_n(ji+1,jj,jk)+gdept_n(ji,jj,jk) ) / MAX( hmlpt(ji,jj), hmlpt(ji+1,jj), 10. ) ) |
|---|
| 231 | ! zcj = 0.5 * ( gdept_n(ji,jj+1,jk)+gdept_n(ji,jj,jk) ) / MAX( hmlpt(ji,jj), hmlpt(ji,jj+1), 10. ) ) |
|---|
| 232 | ! zwz(ji,jj,jk) = ( zfi * zai / ( zbi - zeps ) + ( 1._wp - zfi ) * wslpiml(ji,jj) * zci ) * tmask(ji,jj,jk) |
|---|
| 233 | ! zww(ji,jj,jk) = ( zfj * zaj / ( zbj - zeps ) + ( 1._wp - zfj ) * wslpjml(ji,jj) * zcj ) * tmask(ji,jj,jk) |
|---|
| 234 | !!gm end modif |
|---|
| 235 | END DO |
|---|
| 236 | END DO |
|---|
| 237 | END DO |
|---|
| 238 | CALL lbc_lnk( zwz, 'U', -1. ) ; CALL lbc_lnk( zww, 'V', -1. ) ! lateral boundary conditions |
|---|
| 239 | ! |
|---|
| 240 | ! !* horizontal Shapiro filter |
|---|
| 241 | DO jk = 2, jpkm1 |
|---|
| 242 | DO jj = 2, jpjm1, MAX(1, jpj-3) ! rows jj=2 and =jpjm1 only |
|---|
| 243 | DO ji = 2, jpim1 |
|---|
| 244 | uslp(ji,jj,jk) = z1_16 * ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 245 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 246 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 247 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 248 | & + 4.* zwz(ji ,jj ,jk) ) |
|---|
| 249 | vslp(ji,jj,jk) = z1_16 * ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 250 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 251 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 252 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 253 | & + 4.* zww(ji,jj ,jk) ) |
|---|
| 254 | END DO |
|---|
| 255 | END DO |
|---|
| 256 | DO jj = 3, jpj-2 ! other rows |
|---|
| 257 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 258 | uslp(ji,jj,jk) = z1_16 * ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 259 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 260 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 261 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 262 | & + 4.* zwz(ji ,jj ,jk) ) |
|---|
| 263 | vslp(ji,jj,jk) = z1_16 * ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 264 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 265 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 266 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 267 | & + 4.* zww(ji,jj ,jk) ) |
|---|
| 268 | END DO |
|---|
| 269 | END DO |
|---|
| 270 | ! !* decrease along coastal boundaries |
|---|
| 271 | DO jj = 2, jpjm1 |
|---|
| 272 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 273 | uslp(ji,jj,jk) = uslp(ji,jj,jk) * ( umask(ji,jj+1,jk) + umask(ji,jj-1,jk ) ) * 0.5_wp & |
|---|
| 274 | & * ( umask(ji,jj ,jk) + umask(ji,jj ,jk+1) ) * 0.5_wp |
|---|
| 275 | vslp(ji,jj,jk) = vslp(ji,jj,jk) * ( vmask(ji+1,jj,jk) + vmask(ji-1,jj,jk ) ) * 0.5_wp & |
|---|
| 276 | & * ( vmask(ji ,jj,jk) + vmask(ji ,jj,jk+1) ) * 0.5_wp |
|---|
| 277 | END DO |
|---|
| 278 | END DO |
|---|
| 279 | END DO |
|---|
| 280 | |
|---|
| 281 | |
|---|
| 282 | ! II. slopes at w point | wslpi = mij( d/di( prd ) / d/dz( prd ) |
|---|
| 283 | ! =========================== | wslpj = mij( d/dj( prd ) / d/dz( prd ) |
|---|
| 284 | ! |
|---|
| 285 | DO jk = 2, jpkm1 |
|---|
| 286 | DO jj = 2, jpjm1 |
|---|
| 287 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 288 | ! !* Local vertical density gradient evaluated from N^2 |
|---|
| 289 | zbw = zm1_2g * pn2 (ji,jj,jk) * ( prd (ji,jj,jk) + prd (ji,jj,jk-1) + 2. ) |
|---|
| 290 | ! !* Slopes at w point |
|---|
| 291 | ! ! i- & j-gradient of density at w-points |
|---|
| 292 | zci = MAX( umask(ji-1,jj,jk ) + umask(ji,jj,jk ) & |
|---|
| 293 | & + umask(ji-1,jj,jk-1) + umask(ji,jj,jk-1) , zeps ) * e1t(ji,jj) |
|---|
| 294 | zcj = MAX( vmask(ji,jj-1,jk ) + vmask(ji,jj,jk-1) & |
|---|
| 295 | & + vmask(ji,jj-1,jk-1) + vmask(ji,jj,jk ) , zeps ) * e2t(ji,jj) |
|---|
| 296 | zai = ( zgru (ji-1,jj,jk ) + zgru (ji,jj,jk-1) & |
|---|
| 297 | & + zgru (ji-1,jj,jk-1) + zgru (ji,jj,jk ) ) / zci * wmask (ji,jj,jk) |
|---|
| 298 | zaj = ( zgrv (ji,jj-1,jk ) + zgrv (ji,jj,jk-1) & |
|---|
| 299 | & + zgrv (ji,jj-1,jk-1) + zgrv (ji,jj,jk ) ) / zcj * wmask (ji,jj,jk) |
|---|
| 300 | ! ! bound the slopes: abs(zw.)<= 1/100 and zb..<0. |
|---|
| 301 | ! ! + kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 302 | zbi = MIN( zbw ,- 100._wp* ABS( zai ) , -7.e+3_wp/e3w_n(ji,jj,jk)* ABS( zai ) ) |
|---|
| 303 | zbj = MIN( zbw , -100._wp* ABS( zaj ) , -7.e+3_wp/e3w_n(ji,jj,jk)* ABS( zaj ) ) |
|---|
| 304 | ! ! wslpi and wslpj with ML flattening (output in zwz and zww, resp.) |
|---|
| 305 | zfk = MAX( omlmask(ji,jj,jk), omlmask(ji,jj,jk-1) ) ! zfk=1 in the ML otherwise zfk=0 |
|---|
| 306 | zck = ( gdepw_n(ji,jj,jk) - gdepw_n(ji,jj,mikt(ji,jj) ) ) / MAX( hmlp(ji,jj) - gdepw_n(ji,jj,mikt(ji,jj)), 10._wp ) |
|---|
| 307 | zwz(ji,jj,jk) = ( zai / ( zbi - zeps ) * ( 1._wp - zfk ) + zck * wslpiml(ji,jj) * zfk ) * wmask(ji,jj,jk) |
|---|
| 308 | zww(ji,jj,jk) = ( zaj / ( zbj - zeps ) * ( 1._wp - zfk ) + zck * wslpjml(ji,jj) * zfk ) * wmask(ji,jj,jk) |
|---|
| 309 | |
|---|
| 310 | !!gm modif to suppress omlmask.... (as in Griffies operator) |
|---|
| 311 | ! ! ! jk must be >= ML level for zfk=1. otherwise zfk=0. |
|---|
| 312 | ! zfk = REAL( 1 - 1/(1 + jk / nmln(ji+1,jj)), wp ) |
|---|
| 313 | ! zck = gdepw(ji,jj,jk) / MAX( hmlp(ji,jj), 10. ) |
|---|
| 314 | ! zwz(ji,jj,jk) = ( zfk * zai / ( zbi - zeps ) + ( 1._wp - zfk ) * wslpiml(ji,jj) * zck ) * tmask(ji,jj,jk) |
|---|
| 315 | ! zww(ji,jj,jk) = ( zfk * zaj / ( zbj - zeps ) + ( 1._wp - zfk ) * wslpjml(ji,jj) * zck ) * tmask(ji,jj,jk) |
|---|
| 316 | !!gm end modif |
|---|
| 317 | END DO |
|---|
| 318 | END DO |
|---|
| 319 | END DO |
|---|
| 320 | CALL lbc_lnk( zwz, 'T', -1. ) ; CALL lbc_lnk( zww, 'T', -1. ) ! lateral boundary conditions |
|---|
| 321 | ! |
|---|
| 322 | ! !* horizontal Shapiro filter |
|---|
| 323 | DO jk = 2, jpkm1 |
|---|
| 324 | DO jj = 2, jpjm1, MAX(1, jpj-3) ! rows jj=2 and =jpjm1 only |
|---|
| 325 | DO ji = 2, jpim1 |
|---|
| 326 | zcofw = wmask(ji,jj,jk) * z1_16 |
|---|
| 327 | wslpi(ji,jj,jk) = ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 328 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 329 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 330 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 331 | & + 4.* zwz(ji ,jj ,jk) ) * zcofw |
|---|
| 332 | |
|---|
| 333 | wslpj(ji,jj,jk) = ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 334 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 335 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 336 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 337 | & + 4.* zww(ji ,jj ,jk) ) * zcofw |
|---|
| 338 | END DO |
|---|
| 339 | END DO |
|---|
| 340 | DO jj = 3, jpj-2 ! other rows |
|---|
| 341 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 342 | zcofw = wmask(ji,jj,jk) * z1_16 |
|---|
| 343 | wslpi(ji,jj,jk) = ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 344 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 345 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 346 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 347 | & + 4.* zwz(ji ,jj ,jk) ) * zcofw |
|---|
| 348 | |
|---|
| 349 | wslpj(ji,jj,jk) = ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 350 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 351 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 352 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 353 | & + 4.* zww(ji ,jj ,jk) ) * zcofw |
|---|
| 354 | END DO |
|---|
| 355 | END DO |
|---|
| 356 | ! !* decrease in vicinity of topography |
|---|
| 357 | DO jj = 2, jpjm1 |
|---|
| 358 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 359 | zck = ( umask(ji,jj,jk) + umask(ji-1,jj,jk) ) & |
|---|
| 360 | & * ( vmask(ji,jj,jk) + vmask(ji,jj-1,jk) ) * 0.25 |
|---|
| 361 | wslpi(ji,jj,jk) = wslpi(ji,jj,jk) * zck |
|---|
| 362 | wslpj(ji,jj,jk) = wslpj(ji,jj,jk) * zck |
|---|
| 363 | END DO |
|---|
| 364 | END DO |
|---|
| 365 | END DO |
|---|
| 366 | |
|---|
| 367 | ! IV. Lateral boundary conditions |
|---|
| 368 | ! =============================== |
|---|
| 369 | CALL lbc_lnk( uslp , 'U', -1. ) ; CALL lbc_lnk( vslp , 'V', -1. ) |
|---|
| 370 | CALL lbc_lnk( wslpi, 'W', -1. ) ; CALL lbc_lnk( wslpj, 'W', -1. ) |
|---|
| 371 | |
|---|
| 372 | IF(ln_ctl) THEN |
|---|
| 373 | CALL prt_ctl(tab3d_1=uslp , clinfo1=' slp - u : ', tab3d_2=vslp, clinfo2=' v : ', kdim=jpk) |
|---|
| 374 | CALL prt_ctl(tab3d_1=wslpi, clinfo1=' slp - wi: ', tab3d_2=wslpj, clinfo2=' wj: ', kdim=jpk) |
|---|
| 375 | ENDIF |
|---|
| 376 | ! |
|---|
| 377 | CALL wrk_dealloc( jpi,jpj,jpk, zwz, zww, zdzr, zgru, zgrv ) |
|---|
| 378 | CALL wrk_dealloc( jpi,jpj, zslpml_hmlpu, zslpml_hmlpv ) |
|---|
| 379 | ! |
|---|
| 380 | IF( nn_timing == 1 ) CALL timing_stop('ldf_slp') |
|---|
| 381 | ! |
|---|
| 382 | END SUBROUTINE ldf_slp |
|---|
| 383 | |
|---|
| 384 | |
|---|
| 385 | SUBROUTINE ldf_slp_triad ( kt ) |
|---|
| 386 | !!---------------------------------------------------------------------- |
|---|
| 387 | !! *** ROUTINE ldf_slp_triad *** |
|---|
| 388 | !! |
|---|
| 389 | !! ** Purpose : Compute the squared slopes of neutral surfaces (slope |
|---|
| 390 | !! of iso-pycnal surfaces referenced locally) (ln_traldf_triad=T) |
|---|
| 391 | !! at W-points using the Griffies quarter-cells. |
|---|
| 392 | !! |
|---|
| 393 | !! ** Method : calculates alpha and beta at T-points |
|---|
| 394 | !! |
|---|
| 395 | !! ** Action : - triadi_g, triadj_g T-pts i- and j-slope triads relative to geopot. (used for eiv) |
|---|
| 396 | !! - triadi , triadj T-pts i- and j-slope triads relative to model-coordinate |
|---|
| 397 | !! - wslp2 squared slope of neutral surfaces at w-points. |
|---|
| 398 | !!---------------------------------------------------------------------- |
|---|
| 399 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
|---|
| 400 | !! |
|---|
| 401 | INTEGER :: ji, jj, jk, jl, ip, jp, kp ! dummy loop indices |
|---|
| 402 | INTEGER :: iku, ikv ! local integer |
|---|
| 403 | REAL(wp) :: zfacti, zfactj ! local scalars |
|---|
| 404 | REAL(wp) :: znot_thru_surface ! local scalars |
|---|
| 405 | REAL(wp) :: zdit, zdis, zdkt, zbu, zbti, zisw |
|---|
| 406 | REAL(wp) :: zdjt, zdjs, zdks, zbv, zbtj, zjsw |
|---|
| 407 | REAL(wp) :: zdxrho_raw, zti_coord, zti_raw, zti_lim, zti_g_raw, zti_g_lim |
|---|
| 408 | REAL(wp) :: zdyrho_raw, ztj_coord, ztj_raw, ztj_lim, ztj_g_raw, ztj_g_lim |
|---|
| 409 | REAL(wp) :: zdzrho_raw |
|---|
| 410 | REAL(wp) :: zbeta0, ze3_e1, ze3_e2 |
|---|
| 411 | REAL(wp), POINTER, DIMENSION(:,:) :: z1_mlbw |
|---|
| 412 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalbet |
|---|
| 413 | REAL(wp), POINTER, DIMENSION(:,:,:,:) :: zdxrho , zdyrho, zdzrho ! Horizontal and vertical density gradients |
|---|
| 414 | REAL(wp), POINTER, DIMENSION(:,:,:,:) :: zti_mlb, ztj_mlb ! for Griffies operator only |
|---|
| 415 | !!---------------------------------------------------------------------- |
|---|
| 416 | ! |
|---|
| 417 | IF( nn_timing == 1 ) CALL timing_start('ldf_slp_triad') |
|---|
| 418 | ! |
|---|
| 419 | CALL wrk_alloc( jpi,jpj, z1_mlbw ) |
|---|
| 420 | CALL wrk_alloc( jpi,jpj,jpk, zalbet ) |
|---|
| 421 | CALL wrk_alloc( jpi,jpj,jpk,2, zdxrho , zdyrho, zdzrho, klstart = 0 ) |
|---|
| 422 | CALL wrk_alloc( jpi,jpj, 2,2, zti_mlb, ztj_mlb, kkstart = 0, klstart = 0 ) |
|---|
| 423 | ! |
|---|
| 424 | !--------------------------------! |
|---|
| 425 | ! Some preliminary calculation ! |
|---|
| 426 | !--------------------------------! |
|---|
| 427 | ! |
|---|
| 428 | DO jl = 0, 1 !== unmasked before density i- j-, k-gradients ==! |
|---|
| 429 | ! |
|---|
| 430 | ip = jl ; jp = jl ! guaranteed nonzero gradients ( absolute value larger than repsln) |
|---|
| 431 | DO jk = 1, jpkm1 ! done each pair of triad |
|---|
| 432 | DO jj = 1, jpjm1 ! NB: not masked ==> a minimum value is set |
|---|
| 433 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 434 | zdit = ( tsb(ji+1,jj,jk,jp_tem) - tsb(ji,jj,jk,jp_tem) ) ! i-gradient of T & S at u-point |
|---|
| 435 | zdis = ( tsb(ji+1,jj,jk,jp_sal) - tsb(ji,jj,jk,jp_sal) ) |
|---|
| 436 | zdjt = ( tsb(ji,jj+1,jk,jp_tem) - tsb(ji,jj,jk,jp_tem) ) ! j-gradient of T & S at v-point |
|---|
| 437 | zdjs = ( tsb(ji,jj+1,jk,jp_sal) - tsb(ji,jj,jk,jp_sal) ) |
|---|
| 438 | zdxrho_raw = ( - rab_b(ji+ip,jj ,jk,jp_tem) * zdit + rab_b(ji+ip,jj ,jk,jp_sal) * zdis ) * r1_e1u(ji,jj) |
|---|
| 439 | zdyrho_raw = ( - rab_b(ji ,jj+jp,jk,jp_tem) * zdjt + rab_b(ji ,jj+jp,jk,jp_sal) * zdjs ) * r1_e2v(ji,jj) |
|---|
| 440 | zdxrho(ji+ip,jj ,jk,1-ip) = SIGN( MAX( repsln, ABS( zdxrho_raw ) ), zdxrho_raw ) ! keep the sign |
|---|
| 441 | zdyrho(ji ,jj+jp,jk,1-jp) = SIGN( MAX( repsln, ABS( zdyrho_raw ) ), zdyrho_raw ) |
|---|
| 442 | END DO |
|---|
| 443 | END DO |
|---|
| 444 | END DO |
|---|
| 445 | ! |
|---|
| 446 | IF( ln_zps .AND. l_grad_zps ) THEN ! partial steps: correction of i- & j-grad on bottom |
|---|
| 447 | DO jj = 1, jpjm1 |
|---|
| 448 | DO ji = 1, jpim1 |
|---|
| 449 | iku = mbku(ji,jj) ; ikv = mbkv(ji,jj) ! last ocean level (u- & v-points) |
|---|
| 450 | zdit = gtsu(ji,jj,jp_tem) ; zdjt = gtsv(ji,jj,jp_tem) ! i- & j-gradient of Temperature |
|---|
| 451 | zdis = gtsu(ji,jj,jp_sal) ; zdjs = gtsv(ji,jj,jp_sal) ! i- & j-gradient of Salinity |
|---|
| 452 | zdxrho_raw = ( - rab_b(ji+ip,jj ,iku,jp_tem) * zdit + rab_b(ji+ip,jj ,iku,jp_sal) * zdis ) * r1_e1u(ji,jj) |
|---|
| 453 | zdyrho_raw = ( - rab_b(ji ,jj+jp,ikv,jp_tem) * zdjt + rab_b(ji ,jj+jp,ikv,jp_sal) * zdjs ) * r1_e2v(ji,jj) |
|---|
| 454 | zdxrho(ji+ip,jj ,iku,1-ip) = SIGN( MAX( repsln, ABS( zdxrho_raw ) ), zdxrho_raw ) ! keep the sign |
|---|
| 455 | zdyrho(ji ,jj+jp,ikv,1-jp) = SIGN( MAX( repsln, ABS( zdyrho_raw ) ), zdyrho_raw ) |
|---|
| 456 | END DO |
|---|
| 457 | END DO |
|---|
| 458 | ENDIF |
|---|
| 459 | ! |
|---|
| 460 | END DO |
|---|
| 461 | |
|---|
| 462 | DO kp = 0, 1 !== unmasked before density i- j-, k-gradients ==! |
|---|
| 463 | DO jk = 1, jpkm1 ! done each pair of triad |
|---|
| 464 | DO jj = 1, jpj ! NB: not masked ==> a minimum value is set |
|---|
| 465 | DO ji = 1, jpi ! vector opt. |
|---|
| 466 | IF( jk+kp > 1 ) THEN ! k-gradient of T & S a jk+kp |
|---|
| 467 | zdkt = ( tsb(ji,jj,jk+kp-1,jp_tem) - tsb(ji,jj,jk+kp,jp_tem) ) |
|---|
| 468 | zdks = ( tsb(ji,jj,jk+kp-1,jp_sal) - tsb(ji,jj,jk+kp,jp_sal) ) |
|---|
| 469 | ELSE |
|---|
| 470 | zdkt = 0._wp ! 1st level gradient set to zero |
|---|
| 471 | zdks = 0._wp |
|---|
| 472 | ENDIF |
|---|
| 473 | zdzrho_raw = ( - zalbet(ji,jj,jk) * zdkt + zbeta0*zdks ) / e3w_n(ji,jj,jk+kp) |
|---|
| 474 | zdzrho(ji,jj,jk,kp) = - MIN( - repsln , zdzrho_raw ) ! force zdzrho >= repsln |
|---|
| 475 | END DO |
|---|
| 476 | END DO |
|---|
| 477 | END DO |
|---|
| 478 | END DO |
|---|
| 479 | ! |
|---|
| 480 | DO jj = 1, jpj !== Reciprocal depth of the w-point below ML base ==! |
|---|
| 481 | DO ji = 1, jpi |
|---|
| 482 | jk = MIN( nmln(ji,jj), mbkt(ji,jj) ) + 1 ! MIN in case ML depth is the ocean depth |
|---|
| 483 | z1_mlbw(ji,jj) = 1._wp / gdepw_n(ji,jj,jk) |
|---|
| 484 | END DO |
|---|
| 485 | END DO |
|---|
| 486 | ! |
|---|
| 487 | ! !== intialisations to zero ==! |
|---|
| 488 | ! |
|---|
| 489 | wslp2 (:,:,:) = 0._wp ! wslp2 will be cumulated 3D field set to zero |
|---|
| 490 | triadi_g(:,:,1,:,:) = 0._wp ; triadi_g(:,:,jpk,:,:) = 0._wp ! set surface and bottom slope to zero |
|---|
| 491 | triadj_g(:,:,1,:,:) = 0._wp ; triadj_g(:,:,jpk,:,:) = 0._wp |
|---|
| 492 | !!gm _iso set to zero missing |
|---|
| 493 | triadi (:,:,1,:,:) = 0._wp ; triadj (:,:,jpk,:,:) = 0._wp ! set surface and bottom slope to zero |
|---|
| 494 | triadj (:,:,1,:,:) = 0._wp ; triadj (:,:,jpk,:,:) = 0._wp |
|---|
| 495 | |
|---|
| 496 | !-------------------------------------! |
|---|
| 497 | ! Triads just below the Mixed Layer ! |
|---|
| 498 | !-------------------------------------! |
|---|
| 499 | ! |
|---|
| 500 | DO jl = 0, 1 ! calculate slope of the 4 triads immediately ONE level below mixed-layer base |
|---|
| 501 | DO kp = 0, 1 ! with only the slope-max limit and MASKED |
|---|
| 502 | DO jj = 1, jpjm1 |
|---|
| 503 | DO ji = 1, fs_jpim1 |
|---|
| 504 | ip = jl ; jp = jl |
|---|
| 505 | ! |
|---|
| 506 | jk = nmln(ji+ip,jj) + 1 |
|---|
| 507 | IF( jk > mbkt(ji+ip,jj) ) THEN ! ML reaches bottom |
|---|
| 508 | zti_mlb(ji+ip,jj ,1-ip,kp) = 0.0_wp |
|---|
| 509 | ELSE |
|---|
| 510 | ! Add s-coordinate slope at t-points (do this by *subtracting* gradient of depth) |
|---|
| 511 | zti_g_raw = ( zdxrho(ji+ip,jj,jk-kp,1-ip) / zdzrho(ji+ip,jj,jk-kp,kp) & |
|---|
| 512 | & - ( gdept_n(ji+1,jj,jk-kp) - gdept_n(ji,jj,jk-kp) ) * r1_e1u(ji,jj) ) * umask(ji,jj,jk) |
|---|
| 513 | ze3_e1 = e3w_n(ji+ip,jj,jk-kp) * r1_e1u(ji,jj) |
|---|
| 514 | zti_mlb(ji+ip,jj ,1-ip,kp) = SIGN( MIN( rn_slpmax, 5.0_wp * ze3_e1 , ABS( zti_g_raw ) ), zti_g_raw ) |
|---|
| 515 | ENDIF |
|---|
| 516 | ! |
|---|
| 517 | jk = nmln(ji,jj+jp) + 1 |
|---|
| 518 | IF( jk > mbkt(ji,jj+jp) ) THEN !ML reaches bottom |
|---|
| 519 | ztj_mlb(ji ,jj+jp,1-jp,kp) = 0.0_wp |
|---|
| 520 | ELSE |
|---|
| 521 | ztj_g_raw = ( zdyrho(ji,jj+jp,jk-kp,1-jp) / zdzrho(ji,jj+jp,jk-kp,kp) & |
|---|
| 522 | & - ( gdept_n(ji,jj+1,jk-kp) - gdept_n(ji,jj,jk-kp) ) / e2v(ji,jj) ) * vmask(ji,jj,jk) |
|---|
| 523 | ze3_e2 = e3w_n(ji,jj+jp,jk-kp) / e2v(ji,jj) |
|---|
| 524 | ztj_mlb(ji ,jj+jp,1-jp,kp) = SIGN( MIN( rn_slpmax, 5.0_wp * ze3_e2 , ABS( ztj_g_raw ) ), ztj_g_raw ) |
|---|
| 525 | ENDIF |
|---|
| 526 | END DO |
|---|
| 527 | END DO |
|---|
| 528 | END DO |
|---|
| 529 | END DO |
|---|
| 530 | |
|---|
| 531 | !-------------------------------------! |
|---|
| 532 | ! Triads with surface limits ! |
|---|
| 533 | !-------------------------------------! |
|---|
| 534 | ! |
|---|
| 535 | DO kp = 0, 1 ! k-index of triads |
|---|
| 536 | DO jl = 0, 1 |
|---|
| 537 | ip = jl ; jp = jl ! i- and j-indices of triads (i-k and j-k planes) |
|---|
| 538 | DO jk = 1, jpkm1 |
|---|
| 539 | ! Must mask contribution to slope from dz/dx at constant s for triads jk=1,kp=0 that poke up though ocean surface |
|---|
| 540 | znot_thru_surface = REAL( 1-1/(jk+kp), wp ) !jk+kp=1,=0.; otherwise=1.0 |
|---|
| 541 | DO jj = 1, jpjm1 |
|---|
| 542 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 543 | ! |
|---|
| 544 | ! Calculate slope relative to geopotentials used for GM skew fluxes |
|---|
| 545 | ! Add s-coordinate slope at t-points (do this by *subtracting* gradient of depth) |
|---|
| 546 | ! Limit by slope *relative to geopotentials* by rn_slpmax, and mask by psi-point |
|---|
| 547 | ! masked by umask taken at the level of dz(rho) |
|---|
| 548 | ! |
|---|
| 549 | ! raw slopes: unmasked unbounded slopes (relative to geopotential (zti_g) and model surface (zti) |
|---|
| 550 | ! |
|---|
| 551 | zti_raw = zdxrho(ji+ip,jj ,jk,1-ip) / zdzrho(ji+ip,jj ,jk,kp) ! unmasked |
|---|
| 552 | ztj_raw = zdyrho(ji ,jj+jp,jk,1-jp) / zdzrho(ji ,jj+jp,jk,kp) |
|---|
| 553 | ! |
|---|
| 554 | ! Must mask contribution to slope for triad jk=1,kp=0 that poke up though ocean surface |
|---|
| 555 | zti_coord = znot_thru_surface * ( gdept_n(ji+1,jj ,jk) - gdept_n(ji,jj,jk) ) * r1_e1u(ji,jj) |
|---|
| 556 | ztj_coord = znot_thru_surface * ( gdept_n(ji ,jj+1,jk) - gdept_n(ji,jj,jk) ) * r1_e2v(ji,jj) ! unmasked |
|---|
| 557 | zti_g_raw = zti_raw - zti_coord ! ref to geopot surfaces |
|---|
| 558 | ztj_g_raw = ztj_raw - ztj_coord |
|---|
| 559 | ! additional limit required in bilaplacian case |
|---|
| 560 | ze3_e1 = e3w_n(ji+ip,jj ,jk+kp) * r1_e1u(ji,jj) |
|---|
| 561 | ze3_e2 = e3w_n(ji ,jj+jp,jk+kp) * r1_e2v(ji,jj) |
|---|
| 562 | ! NB: hard coded factor 5 (can be a namelist parameter...) |
|---|
| 563 | zti_g_lim = SIGN( MIN( rn_slpmax, 5.0_wp * ze3_e1, ABS( zti_g_raw ) ), zti_g_raw ) |
|---|
| 564 | ztj_g_lim = SIGN( MIN( rn_slpmax, 5.0_wp * ze3_e2, ABS( ztj_g_raw ) ), ztj_g_raw ) |
|---|
| 565 | ! |
|---|
| 566 | ! Below ML use limited zti_g as is & mask |
|---|
| 567 | ! Inside ML replace by linearly reducing sx_mlb towards surface & mask |
|---|
| 568 | ! |
|---|
| 569 | zfacti = REAL( 1 - 1/(1 + (jk+kp-1)/nmln(ji+ip,jj)), wp ) ! k index of uppermost point(s) of triad is jk+kp-1 |
|---|
| 570 | zfactj = REAL( 1 - 1/(1 + (jk+kp-1)/nmln(ji,jj+jp)), wp ) ! must be .ge. nmln(ji,jj) for zfact=1 |
|---|
| 571 | ! ! otherwise zfact=0 |
|---|
| 572 | zti_g_lim = ( zfacti * zti_g_lim & |
|---|
| 573 | & + ( 1._wp - zfacti ) * zti_mlb(ji+ip,jj,1-ip,kp) & |
|---|
| 574 | & * gdepw_n(ji+ip,jj,jk+kp) * z1_mlbw(ji+ip,jj) ) * umask(ji,jj,jk+kp) |
|---|
| 575 | ztj_g_lim = ( zfactj * ztj_g_lim & |
|---|
| 576 | & + ( 1._wp - zfactj ) * ztj_mlb(ji,jj+jp,1-jp,kp) & |
|---|
| 577 | & * gdepw_n(ji,jj+jp,jk+kp) * z1_mlbw(ji,jj+jp) ) * vmask(ji,jj,jk+kp) |
|---|
| 578 | ! |
|---|
| 579 | triadi_g(ji+ip,jj ,jk,1-ip,kp) = zti_g_lim |
|---|
| 580 | triadj_g(ji ,jj+jp,jk,1-jp,kp) = ztj_g_lim |
|---|
| 581 | ! |
|---|
| 582 | ! Get coefficients of isoneutral diffusion tensor |
|---|
| 583 | ! 1. Utilise gradients *relative* to s-coordinate, so add t-point slopes (*subtract* depth gradients) |
|---|
| 584 | ! 2. We require that isoneutral diffusion gives no vertical buoyancy flux |
|---|
| 585 | ! i.e. 33 term = (real slope* 31, 13 terms) |
|---|
| 586 | ! To do this, retain limited sx**2 in vertical flux, but divide by real slope for 13/31 terms |
|---|
| 587 | ! Equivalent to tapering A_iso = sx_limited**2/(real slope)**2 |
|---|
| 588 | ! |
|---|
| 589 | zti_lim = ( zti_g_lim + zti_coord ) * umask(ji,jj,jk+kp) ! remove coordinate slope => relative to coordinate surfaces |
|---|
| 590 | ztj_lim = ( ztj_g_lim + ztj_coord ) * vmask(ji,jj,jk+kp) |
|---|
| 591 | ! |
|---|
| 592 | IF( ln_triad_iso ) THEN |
|---|
| 593 | zti_raw = zti_lim*zti_lim / zti_raw |
|---|
| 594 | ztj_raw = ztj_lim*ztj_lim / ztj_raw |
|---|
| 595 | zti_raw = SIGN( MIN( ABS(zti_lim), ABS( zti_raw ) ), zti_raw ) |
|---|
| 596 | ztj_raw = SIGN( MIN( ABS(ztj_lim), ABS( ztj_raw ) ), ztj_raw ) |
|---|
| 597 | zti_lim = zfacti * zti_lim + ( 1._wp - zfacti ) * zti_raw |
|---|
| 598 | ztj_lim = zfactj * ztj_lim + ( 1._wp - zfactj ) * ztj_raw |
|---|
| 599 | ENDIF |
|---|
| 600 | ! ! switching triad scheme |
|---|
| 601 | zisw = (rn_sw_triad - 1._wp ) + rn_sw_triad & |
|---|
| 602 | & * 2._wp * ABS( 0.5_wp - kp - ( 0.5_wp - ip ) * SIGN( 1._wp , zdxrho(ji+ip,jj,jk,1-ip) ) ) |
|---|
| 603 | zjsw = (rn_sw_triad - 1._wp ) + rn_sw_triad & |
|---|
| 604 | & * 2._wp * ABS( 0.5_wp - kp - ( 0.5_wp - jp ) * SIGN( 1._wp , zdyrho(ji,jj+jp,jk,1-jp) ) ) |
|---|
| 605 | ! |
|---|
| 606 | triadi(ji+ip,jj ,jk,1-ip,kp) = zti_lim * zisw |
|---|
| 607 | triadj(ji ,jj+jp,jk,1-jp,kp) = ztj_lim * zjsw |
|---|
| 608 | ! |
|---|
| 609 | zbu = e1e2u(ji ,jj ) * e3u_n(ji ,jj ,jk ) |
|---|
| 610 | zbv = e1e2v(ji ,jj ) * e3v_n(ji ,jj ,jk ) |
|---|
| 611 | zbti = e1e2t(ji+ip,jj ) * e3w_n(ji+ip,jj ,jk+kp) |
|---|
| 612 | zbtj = e1e2t(ji ,jj+jp) * e3w_n(ji ,jj+jp,jk+kp) |
|---|
| 613 | ! |
|---|
| 614 | wslp2(ji+ip,jj,jk+kp) = wslp2(ji+ip,jj,jk+kp) + 0.25_wp * zbu / zbti * zti_g_lim*zti_g_lim ! masked |
|---|
| 615 | wslp2(ji,jj+jp,jk+kp) = wslp2(ji,jj+jp,jk+kp) + 0.25_wp * zbv / zbtj * ztj_g_lim*ztj_g_lim |
|---|
| 616 | END DO |
|---|
| 617 | END DO |
|---|
| 618 | END DO |
|---|
| 619 | END DO |
|---|
| 620 | END DO |
|---|
| 621 | ! |
|---|
| 622 | wslp2(:,:,1) = 0._wp ! force the surface wslp to zero |
|---|
| 623 | |
|---|
| 624 | CALL lbc_lnk( wslp2, 'W', 1. ) ! lateral boundary confition on wslp2 only ==>>> gm : necessary ? to be checked |
|---|
| 625 | ! |
|---|
| 626 | CALL wrk_dealloc( jpi,jpj, z1_mlbw ) |
|---|
| 627 | CALL wrk_dealloc( jpi,jpj,jpk, zalbet ) |
|---|
| 628 | CALL wrk_dealloc( jpi,jpj,jpk,2, zdxrho , zdyrho, zdzrho, klstart = 0 ) |
|---|
| 629 | CALL wrk_dealloc( jpi,jpj, 2,2, zti_mlb, ztj_mlb, kkstart = 0, klstart = 0 ) |
|---|
| 630 | ! |
|---|
| 631 | IF( nn_timing == 1 ) CALL timing_stop('ldf_slp_triad') |
|---|
| 632 | ! |
|---|
| 633 | END SUBROUTINE ldf_slp_triad |
|---|
| 634 | |
|---|
| 635 | |
|---|
| 636 | SUBROUTINE ldf_slp_mxl( prd, pn2, p_gru, p_grv, p_dzr ) |
|---|
| 637 | !!---------------------------------------------------------------------- |
|---|
| 638 | !! *** ROUTINE ldf_slp_mxl *** |
|---|
| 639 | !! |
|---|
| 640 | !! ** Purpose : Compute the slopes of iso-neutral surface just below |
|---|
| 641 | !! the mixed layer. |
|---|
| 642 | !! |
|---|
| 643 | !! ** Method : The slope in the i-direction is computed at u- & w-points |
|---|
| 644 | !! (uslpml, wslpiml) and the slope in the j-direction is computed |
|---|
| 645 | !! at v- and w-points (vslpml, wslpjml) with the same bounds as |
|---|
| 646 | !! in ldf_slp. |
|---|
| 647 | !! |
|---|
| 648 | !! ** Action : uslpml, wslpiml : i- & j-slopes of neutral surfaces |
|---|
| 649 | !! vslpml, wslpjml just below the mixed layer |
|---|
| 650 | !! omlmask : mixed layer mask |
|---|
| 651 | !!---------------------------------------------------------------------- |
|---|
| 652 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: prd ! in situ density |
|---|
| 653 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: pn2 ! Brunt-Vaisala frequency (locally ref.) |
|---|
| 654 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: p_gru, p_grv ! i- & j-gradient of density (u- & v-pts) |
|---|
| 655 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: p_dzr ! z-gradient of density (T-point) |
|---|
| 656 | !! |
|---|
| 657 | INTEGER :: ji , jj , jk ! dummy loop indices |
|---|
| 658 | INTEGER :: iku, ikv, ik, ikm1 ! local integers |
|---|
| 659 | REAL(wp) :: zeps, zm1_g, zm1_2g, z1_slpmax ! local scalars |
|---|
| 660 | REAL(wp) :: zci, zfi, zau, zbu, zai, zbi ! - - |
|---|
| 661 | REAL(wp) :: zcj, zfj, zav, zbv, zaj, zbj ! - - |
|---|
| 662 | REAL(wp) :: zck, zfk, zbw ! - - |
|---|
| 663 | !!---------------------------------------------------------------------- |
|---|
| 664 | ! |
|---|
| 665 | IF( nn_timing == 1 ) CALL timing_start('ldf_slp_mxl') |
|---|
| 666 | ! |
|---|
| 667 | zeps = 1.e-20_wp !== Local constant initialization ==! |
|---|
| 668 | zm1_g = -1.0_wp / grav |
|---|
| 669 | zm1_2g = -0.5_wp / grav |
|---|
| 670 | z1_slpmax = 1._wp / rn_slpmax |
|---|
| 671 | ! |
|---|
| 672 | uslpml (1,:) = 0._wp ; uslpml (jpi,:) = 0._wp |
|---|
| 673 | vslpml (1,:) = 0._wp ; vslpml (jpi,:) = 0._wp |
|---|
| 674 | wslpiml(1,:) = 0._wp ; wslpiml(jpi,:) = 0._wp |
|---|
| 675 | wslpjml(1,:) = 0._wp ; wslpjml(jpi,:) = 0._wp |
|---|
| 676 | ! |
|---|
| 677 | ! !== surface mixed layer mask ! |
|---|
| 678 | DO jk = 1, jpk ! =1 inside the mixed layer, =0 otherwise |
|---|
| 679 | DO jj = 1, jpj |
|---|
| 680 | DO ji = 1, jpi |
|---|
| 681 | ik = nmln(ji,jj) - 1 |
|---|
| 682 | IF( jk <= ik ) THEN ; omlmask(ji,jj,jk) = 1._wp |
|---|
| 683 | ELSE ; omlmask(ji,jj,jk) = 0._wp |
|---|
| 684 | ENDIF |
|---|
| 685 | END DO |
|---|
| 686 | END DO |
|---|
| 687 | END DO |
|---|
| 688 | |
|---|
| 689 | |
|---|
| 690 | ! Slopes of isopycnal surfaces just before bottom of mixed layer |
|---|
| 691 | ! -------------------------------------------------------------- |
|---|
| 692 | ! The slope are computed as in the 3D case. |
|---|
| 693 | ! A key point here is the definition of the mixed layer at u- and v-points. |
|---|
| 694 | ! It is assumed to be the maximum of the two neighbouring T-point mixed layer depth. |
|---|
| 695 | ! Otherwise, a n2 value inside the mixed layer can be involved in the computation |
|---|
| 696 | ! of the slope, resulting in a too steep diagnosed slope and thus a spurious eddy |
|---|
| 697 | ! induce velocity field near the base of the mixed layer. |
|---|
| 698 | !----------------------------------------------------------------------- |
|---|
| 699 | ! |
|---|
| 700 | DO jj = 2, jpjm1 |
|---|
| 701 | DO ji = 2, jpim1 |
|---|
| 702 | ! !== Slope at u- & v-points just below the Mixed Layer ==! |
|---|
| 703 | ! |
|---|
| 704 | ! !- vertical density gradient for u- and v-slopes (from dzr at T-point) |
|---|
| 705 | iku = MIN( MAX( 1, nmln(ji,jj) , nmln(ji+1,jj) ) , jpkm1 ) ! ML (MAX of T-pts, bound by jpkm1) |
|---|
| 706 | ikv = MIN( MAX( 1, nmln(ji,jj) , nmln(ji,jj+1) ) , jpkm1 ) ! |
|---|
| 707 | zbu = 0.5_wp * ( p_dzr(ji,jj,iku) + p_dzr(ji+1,jj ,iku) ) |
|---|
| 708 | zbv = 0.5_wp * ( p_dzr(ji,jj,ikv) + p_dzr(ji ,jj+1,ikv) ) |
|---|
| 709 | ! !- horizontal density gradient at u- & v-points |
|---|
| 710 | zau = p_gru(ji,jj,iku) * r1_e1u(ji,jj) |
|---|
| 711 | zav = p_grv(ji,jj,ikv) * r1_e2v(ji,jj) |
|---|
| 712 | ! !- bound the slopes: abs(zw.)<= 1/100 and zb..<0 |
|---|
| 713 | ! kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 714 | zbu = MIN( zbu , - z1_slpmax * ABS( zau ) , -7.e+3_wp/e3u_n(ji,jj,iku)* ABS( zau ) ) |
|---|
| 715 | zbv = MIN( zbv , - z1_slpmax * ABS( zav ) , -7.e+3_wp/e3v_n(ji,jj,ikv)* ABS( zav ) ) |
|---|
| 716 | ! !- Slope at u- & v-points (uslpml, vslpml) |
|---|
| 717 | uslpml(ji,jj) = zau / ( zbu - zeps ) * umask(ji,jj,iku) |
|---|
| 718 | vslpml(ji,jj) = zav / ( zbv - zeps ) * vmask(ji,jj,ikv) |
|---|
| 719 | ! |
|---|
| 720 | ! !== i- & j-slopes at w-points just below the Mixed Layer ==! |
|---|
| 721 | ! |
|---|
| 722 | ik = MIN( nmln(ji,jj) + 1, jpk ) |
|---|
| 723 | ikm1 = MAX( 1, ik-1 ) |
|---|
| 724 | ! !- vertical density gradient for w-slope (from N^2) |
|---|
| 725 | zbw = zm1_2g * pn2 (ji,jj,ik) * ( prd (ji,jj,ik) + prd (ji,jj,ikm1) + 2. ) |
|---|
| 726 | ! !- horizontal density i- & j-gradient at w-points |
|---|
| 727 | zci = MAX( umask(ji-1,jj,ik ) + umask(ji,jj,ik ) & |
|---|
| 728 | & + umask(ji-1,jj,ikm1) + umask(ji,jj,ikm1) , zeps ) * e1t(ji,jj) |
|---|
| 729 | zcj = MAX( vmask(ji,jj-1,ik ) + vmask(ji,jj,ik ) & |
|---|
| 730 | & + vmask(ji,jj-1,ikm1) + vmask(ji,jj,ikm1) , zeps ) * e2t(ji,jj) |
|---|
| 731 | zai = ( p_gru(ji-1,jj,ik ) + p_gru(ji,jj,ik) & |
|---|
| 732 | & + p_gru(ji-1,jj,ikm1) + p_gru(ji,jj,ikm1 ) ) / zci * tmask(ji,jj,ik) |
|---|
| 733 | zaj = ( p_grv(ji,jj-1,ik ) + p_grv(ji,jj,ik ) & |
|---|
| 734 | & + p_grv(ji,jj-1,ikm1) + p_grv(ji,jj,ikm1) ) / zcj * tmask(ji,jj,ik) |
|---|
| 735 | ! !- bound the slopes: abs(zw.)<= 1/100 and zb..<0. |
|---|
| 736 | ! kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 737 | zbi = MIN( zbw , -100._wp* ABS( zai ) , -7.e+3_wp/e3w_n(ji,jj,ik)* ABS( zai ) ) |
|---|
| 738 | zbj = MIN( zbw , -100._wp* ABS( zaj ) , -7.e+3_wp/e3w_n(ji,jj,ik)* ABS( zaj ) ) |
|---|
| 739 | ! !- i- & j-slope at w-points (wslpiml, wslpjml) |
|---|
| 740 | wslpiml(ji,jj) = zai / ( zbi - zeps ) * tmask (ji,jj,ik) |
|---|
| 741 | wslpjml(ji,jj) = zaj / ( zbj - zeps ) * tmask (ji,jj,ik) |
|---|
| 742 | END DO |
|---|
| 743 | END DO |
|---|
| 744 | !!gm this lbc_lnk should be useless.... |
|---|
| 745 | CALL lbc_lnk( uslpml , 'U', -1. ) ; CALL lbc_lnk( vslpml , 'V', -1. ) ! lateral boundary cond. (sign change) |
|---|
| 746 | CALL lbc_lnk( wslpiml, 'W', -1. ) ; CALL lbc_lnk( wslpjml, 'W', -1. ) ! lateral boundary conditions |
|---|
| 747 | ! |
|---|
| 748 | IF( nn_timing == 1 ) CALL timing_stop('ldf_slp_mxl') |
|---|
| 749 | ! |
|---|
| 750 | END SUBROUTINE ldf_slp_mxl |
|---|
| 751 | |
|---|
| 752 | |
|---|
| 753 | SUBROUTINE ldf_slp_init |
|---|
| 754 | !!---------------------------------------------------------------------- |
|---|
| 755 | !! *** ROUTINE ldf_slp_init *** |
|---|
| 756 | !! |
|---|
| 757 | !! ** Purpose : Initialization for the isopycnal slopes computation |
|---|
| 758 | !! |
|---|
| 759 | !! ** Method : |
|---|
| 760 | !!---------------------------------------------------------------------- |
|---|
| 761 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 762 | INTEGER :: ierr ! local integer |
|---|
| 763 | !!---------------------------------------------------------------------- |
|---|
| 764 | ! |
|---|
| 765 | IF( nn_timing == 1 ) CALL timing_start('ldf_slp_init') |
|---|
| 766 | ! |
|---|
| 767 | IF(lwp) THEN |
|---|
| 768 | WRITE(numout,*) |
|---|
| 769 | WRITE(numout,*) 'ldf_slp_init : direction of lateral mixing' |
|---|
| 770 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 771 | ENDIF |
|---|
| 772 | ! |
|---|
| 773 | ALLOCATE( ah_wslp2(jpi,jpj,jpk) , akz(jpi,jpj,jpk) , STAT=ierr ) |
|---|
| 774 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'ldf_slp_init : unable to allocate ah_slp2 or akz' ) |
|---|
| 775 | ! |
|---|
| 776 | IF( ln_traldf_triad ) THEN ! Griffies operator : triad of slopes |
|---|
| 777 | IF(lwp) WRITE(numout,*) ' Griffies (triad) operator initialisation' |
|---|
| 778 | ALLOCATE( triadi_g(jpi,jpj,jpk,0:1,0:1) , triadj_g(jpi,jpj,jpk,0:1,0:1) , & |
|---|
| 779 | & triadi (jpi,jpj,jpk,0:1,0:1) , triadj (jpi,jpj,jpk,0:1,0:1) , & |
|---|
| 780 | & wslp2 (jpi,jpj,jpk) , STAT=ierr ) |
|---|
| 781 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'ldf_slp_init : unable to allocate Griffies operator slope' ) |
|---|
| 782 | IF( ln_dynldf_iso ) CALL ctl_stop( 'ldf_slp_init: Griffies operator on momentum not supported' ) |
|---|
| 783 | ! |
|---|
| 784 | ELSE ! Madec operator : slopes at u-, v-, and w-points |
|---|
| 785 | IF(lwp) WRITE(numout,*) ' Madec operator initialisation' |
|---|
| 786 | ALLOCATE( omlmask(jpi,jpj,jpk) , & |
|---|
| 787 | & uslp(jpi,jpj,jpk) , uslpml(jpi,jpj) , wslpi(jpi,jpj,jpk) , wslpiml(jpi,jpj) , & |
|---|
| 788 | & vslp(jpi,jpj,jpk) , vslpml(jpi,jpj) , wslpj(jpi,jpj,jpk) , wslpjml(jpi,jpj) , STAT=ierr ) |
|---|
| 789 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'ldf_slp_init : unable to allocate Madec operator slope ' ) |
|---|
| 790 | |
|---|
| 791 | ! Direction of lateral diffusion (tracers and/or momentum) |
|---|
| 792 | ! ------------------------------ |
|---|
| 793 | uslp (:,:,:) = 0._wp ; uslpml (:,:) = 0._wp ! set the slope to zero (even in s-coordinates) |
|---|
| 794 | vslp (:,:,:) = 0._wp ; vslpml (:,:) = 0._wp |
|---|
| 795 | wslpi(:,:,:) = 0._wp ; wslpiml(:,:) = 0._wp |
|---|
| 796 | wslpj(:,:,:) = 0._wp ; wslpjml(:,:) = 0._wp |
|---|
| 797 | |
|---|
| 798 | !!gm I no longer understand this..... |
|---|
| 799 | !!gm IF( (ln_traldf_hor .OR. ln_dynldf_hor) .AND. .NOT. (.NOT.ln_linssh .AND. ln_rstart) ) THEN |
|---|
| 800 | ! IF(lwp) WRITE(numout,*) ' Horizontal mixing in s-coordinate: slope = slope of s-surfaces' |
|---|
| 801 | ! |
|---|
| 802 | ! ! geopotential diffusion in s-coordinates on tracers and/or momentum |
|---|
| 803 | ! ! The slopes of s-surfaces are computed once (no call to ldfslp in step) |
|---|
| 804 | ! ! The slopes for momentum diffusion are i- or j- averaged of those on tracers |
|---|
| 805 | ! |
|---|
| 806 | ! ! set the slope of diffusion to the slope of s-surfaces |
|---|
| 807 | ! ! ( c a u t i o n : minus sign as dep has positive value ) |
|---|
| 808 | ! DO jk = 1, jpk |
|---|
| 809 | ! DO jj = 2, jpjm1 |
|---|
| 810 | ! DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 811 | ! uslp (ji,jj,jk) = - ( gdept_n(ji+1,jj,jk) - gdept_n(ji ,jj ,jk) ) * r1_e1u(ji,jj) * umask(ji,jj,jk) |
|---|
| 812 | ! vslp (ji,jj,jk) = - ( gdept_n(ji,jj+1,jk) - gdept_n(ji ,jj ,jk) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk) |
|---|
| 813 | ! wslpi(ji,jj,jk) = - ( gdepw_n(ji+1,jj,jk) - gdepw_n(ji-1,jj,jk) ) * r1_e1t(ji,jj) * wmask(ji,jj,jk) * 0.5 |
|---|
| 814 | ! wslpj(ji,jj,jk) = - ( gdepw_n(ji,jj+1,jk) - gdepw_n(ji,jj-1,jk) ) * r1_e2t(ji,jj) * wmask(ji,jj,jk) * 0.5 |
|---|
| 815 | ! END DO |
|---|
| 816 | ! END DO |
|---|
| 817 | ! END DO |
|---|
| 818 | ! CALL lbc_lnk( uslp , 'U', -1. ) ; CALL lbc_lnk( vslp , 'V', -1. ) ! Lateral boundary conditions |
|---|
| 819 | ! CALL lbc_lnk( wslpi, 'W', -1. ) ; CALL lbc_lnk( wslpj, 'W', -1. ) |
|---|
| 820 | !!gm ENDIF |
|---|
| 821 | ENDIF |
|---|
| 822 | ! |
|---|
| 823 | IF( nn_timing == 1 ) CALL timing_stop('ldf_slp_init') |
|---|
| 824 | ! |
|---|
| 825 | END SUBROUTINE ldf_slp_init |
|---|
| 826 | |
|---|
| 827 | !!====================================================================== |
|---|
| 828 | END MODULE ldfslp |
|---|
