New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/2017/dev_r8126_ROBUST08_no_ghost/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2017/dev_r8126_ROBUST08_no_ghost/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 8809

Last change on this file since 8809 was 8186, checked in by acc, 7 years ago

Branch 2017/dev_r8126_ROBUST08_no_ghost. Incorporation of re-written lbc routines. This introduces generic routines for: lbc_lnk, lbc_lnk_multi, lbc_nfd, mpp_bdy, mpp_lnk and mpp_nfd in .h90 files which are pre-processor included multiple times (with different arguments) to recreate equivalences to all the original variants from a much smaller code base (more than 2000 lines shorter). These changes have been SETTE tested and shown to reproduce identical results to the branch base revision. There are a few caveats: the ice cavity routine: iscplhsb.F90, needs to be rewritten to avoid sums over the overlap regions; this will be done elsewhere and has merely been disabled on this branch. The work is not yet complete for the nogather option for the north-fold. The default MPI ALLGATHER option is working but do not activate ln_nogather until further notice.

  • Property svn:keywords set to Id
File size: 17.9 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !  2011-09  (M. Adani)  Original code: Drag Coefficient
7   !!         :  3.4  !  2012-10  (M. Adani)  Stokes Drift
8   !!            3.6  !  2014-09  (E. Clementi,P. Oddo) New Stokes Drift Computation
9   !!             -   !  2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                    + add sbc_wave_ini routine
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
15   !!   sbc_wave      : wave data from wave model in netcdf files
16   !!   sbc_wave_init : initialisation fo surface waves
17   !!----------------------------------------------------------------------
18   USE phycst         ! physical constants
19   USE oce            ! ocean variables
20   USE sbc_oce        ! Surface boundary condition: ocean fields
21   USE zdf_oce,  ONLY : ln_zdfqiao
22   USE bdy_oce        ! open boundary condition variables
23   USE domvvl         ! domain: variable volume layers
24   !
25   USE iom            ! I/O manager library
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! distribued memory computing library
28   USE fldread        ! read input fields
29   USE wrk_nemo       !
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_stokes      ! routine called in sbccpl
35   PUBLIC   sbc_wave        ! routine called in sbcmod
36   PUBLIC   sbc_wave_init   ! routine called in sbcmod
37   
38   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
39   LOGICAL, PUBLIC ::   cpl_hsig   = .FALSE.
40   LOGICAL, PUBLIC ::   cpl_phioc  = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_sdrftx = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrfty = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_wper   = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_wnum   = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_wstrf  = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_wdrag  = .FALSE.
47
48   INTEGER ::   jpfld    ! number of files to read for stokes drift
49   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
50   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
51   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
52   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
53
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_cd      ! structure of input fields (file informations, fields read) Drag Coefficient
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sd      ! structure of input fields (file informations, fields read) Stokes Drift
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_wn      ! structure of input fields (file informations, fields read) wave number for Qiao
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tauoc   ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
58   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave            !:
59   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw, wmp, wnum      !:
60   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave          !: 
61   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d               !:
62   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd              !: barotropic stokes drift divergence
63   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd        !: surface Stokes drift velocities at t-point
64   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd  , vsd  , wsd   !: Stokes drift velocities at u-, v- & w-points, resp.
65
66   !! * Substitutions
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE sbc_stokes( )
76      !!---------------------------------------------------------------------
77      !!                     ***  ROUTINE sbc_stokes  ***
78      !!
79      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
80      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
81      !!
82      !! ** Method  : - Calculate Stokes transport speed
83      !!              - Calculate horizontal divergence
84      !!              - Integrate the horizontal divergenze from the bottom
85      !! ** action 
86      !!---------------------------------------------------------------------
87      INTEGER  ::   jj, ji, jk   ! dummy loop argument
88      INTEGER  ::   ik           ! local integer
89      REAL(wp) ::  ztransp, zfac, ztemp, zsp0
90      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v
91      REAL(wp), DIMENSION(:,:)  , POINTER ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd   ! 2D workspace
92      REAL(wp), DIMENSION(:,:,:), POINTER ::   ze3divh                            ! 3D workspace
93      !!---------------------------------------------------------------------
94      !
95      CALL wrk_alloc( jpi,jpj,jpk,   ze3divh )
96      CALL wrk_alloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
97      !
98      !
99      zfac =  2.0_wp * rpi / 16.0_wp
100      DO jj = 1, jpj                ! exp. wave number at t-point    (Eq. (19) in Breivick et al. (2014) )
101         DO ji = 1, jpi
102               ! Stokes drift velocity estimated from Hs and Tmean
103               ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj) , 0.0000001_wp )
104               ! Stokes surface speed
105               zsp0 = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj) )
106               tsd2d(ji,jj) = zsp0
107               ! Wavenumber scale
108               zk_t(ji,jj) = ABS( zsp0 ) / MAX( ABS( 5.97_wp*ztransp ) , 0.0000001_wp )
109         END DO
110      END DO     
111      DO jj = 1, jpjm1              ! exp. wave number & Stokes drift velocity at u- & v-points
112         DO ji = 1, jpim1
113            zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
114            zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
115            !
116            zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
117            zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
118         END DO
119      END DO
120      !
121      !                       !==  horizontal Stokes Drift 3D velocity  ==!
122      DO jk = 1, jpkm1
123         DO jj = 2, jpjm1
124            DO ji = 2, jpim1
125               zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
126               zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
127               !                         
128               zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
129               zkh_v = zk_v(ji,jj) * zdep_v
130               !                                ! Depth attenuation
131               zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
132               zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
133               !
134               usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
135               vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
136            END DO
137         END DO
138      END DO   
139!!gm      CALL lbc_lnk( usd(:,:,:), 'U', vsd(:,:,:), 'V', -1. )
140      CALL lbc_lnk( usd(:,:,:), 'U', -1. )
141      CALL lbc_lnk( vsd(:,:,:), 'V', -1. )
142
143
144      !
145      !                       !==  vertical Stokes Drift 3D velocity  ==!
146      !
147      DO jk = 1, jpkm1               ! Horizontal e3*divergence
148         DO jj = 2, jpj
149            DO ji = fs_2, jpi
150               ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * usd(ji  ,jj,jk)    &
151                  &                 - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd(ji-1,jj,jk)    &
152                  &                 + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vsd(ji,jj  ,jk)    &
153                  &                 - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd(ji,jj-1,jk)  ) * r1_e1e2t(ji,jj)
154            END DO
155         END DO
156      END DO
157      !
158      IF( .NOT. AGRIF_Root() ) THEN
159         IF( nbondi ==  1 .OR. nbondi == 2 )   ze3divh(nlci-1,   :  ,:) = 0._wp      ! east
160         IF( nbondi == -1 .OR. nbondi == 2 )   ze3divh(  2   ,   :  ,:) = 0._wp      ! west
161         IF( nbondj ==  1 .OR. nbondj == 2 )   ze3divh(  :   ,nlcj-1,:) = 0._wp      ! north
162         IF( nbondj == -1 .OR. nbondj == 2 )   ze3divh(  :   ,  2   ,:) = 0._wp      ! south
163      ENDIF
164      !
165      CALL lbc_lnk( ze3divh, 'T', 1. )
166      !
167      IF( ln_linssh ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
168      ELSE                   ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
169      ENDIF
170      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
171         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
172      END DO
173      !
174      IF( ln_bdy ) THEN
175         DO jk = 1, jpkm1
176            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
177         END DO
178      ENDIF
179      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
180      div_sd(:,:) = 0._wp
181      DO jk = 1, jpkm1                                 !
182        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
183      END DO
184      !
185      CALL iom_put( "ustokes",  usd  )
186      CALL iom_put( "vstokes",  vsd  )
187      CALL iom_put( "wstokes",  wsd  )
188      !
189      CALL wrk_dealloc( jpi,jpj,jpk,   ze3divh )
190      CALL wrk_dealloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
191      !
192   END SUBROUTINE sbc_stokes
193
194
195   SUBROUTINE sbc_wave( kt )
196      !!---------------------------------------------------------------------
197      !!                     ***  ROUTINE sbc_wave  ***
198      !!
199      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
200      !!
201      !! ** Method  : - Read namelist namsbc_wave
202      !!              - Read Cd_n10 fields in netcdf files
203      !!              - Read stokes drift 2d in netcdf files
204      !!              - Read wave number in netcdf files
205      !!              - Compute 3d stokes drift using Breivik et al.,2014
206      !!                formulation
207      !! ** action 
208      !!---------------------------------------------------------------------
209      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
210      !!---------------------------------------------------------------------
211      !
212      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
213         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
214         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
215      ENDIF
216
217      IF( ln_tauoc .AND. .NOT. cpl_wstrf ) THEN    !==  Wave induced stress  ==!
218         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read wave norm stress from external forcing
219         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
220      ENDIF
221
222      IF( ln_sdw )  THEN                           !==  Computation of the 3d Stokes Drift  ==!
223         !
224         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
225            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
226            IF( jp_hsw > 0 )   hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1)   ! significant wave height
227            IF( jp_wmp > 0 )   wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
228            IF( jp_usd > 0 )   ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
229            IF( jp_vsd > 0 )   vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
230         ENDIF
231         !
232         ! Read also wave number if needed, so that it is available in coupling routines
233         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
234            CALL fld_read( kt, nn_fsbc, sf_wn )          ! read wave parameters from external forcing
235            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
236         ENDIF
237           
238         !                                         !==  Computation of the 3d Stokes Drift  ==!
239         !
240         IF( jpfld == 4 )   CALL sbc_stokes()            ! Calculate only if required fields are read
241         !                                               ! In coupled wave model-NEMO case the call is done after coupling
242         !
243      ENDIF
244      !
245   END SUBROUTINE sbc_wave
246
247
248   SUBROUTINE sbc_wave_init
249      !!---------------------------------------------------------------------
250      !!                     ***  ROUTINE sbc_wave_init  ***
251      !!
252      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
253      !!
254      !! ** Method  : - Read namelist namsbc_wave
255      !!              - Read Cd_n10 fields in netcdf files
256      !!              - Read stokes drift 2d in netcdf files
257      !!              - Read wave number in netcdf files
258      !!              - Compute 3d stokes drift using Breivik et al.,2014
259      !!                formulation
260      !! ** action 
261      !!---------------------------------------------------------------------
262      INTEGER ::   ierror, ios   ! local integer
263      INTEGER ::   ifpr
264      !!
265      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
266      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i     ! array of namelist informations on the fields to read
267      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
268                             &   sn_hsw, sn_wmp, sn_wnum, sn_tauoc      ! informations about the fields to be read
269      !
270      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wnum, sn_tauoc
271      !!---------------------------------------------------------------------
272      !
273      REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
274      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
275901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
276         
277      REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
278      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
279902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
280      IF(lwm) WRITE ( numond, namsbc_wave )
281      !
282      IF( ln_cdgw ) THEN
283         IF( .NOT. cpl_wdrag ) THEN
284            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
285            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
286            !
287                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
288            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
289            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
290         ENDIF
291         ALLOCATE( cdn_wave(jpi,jpj) )
292      ENDIF
293
294      IF( ln_tauoc ) THEN
295         IF( .NOT. cpl_wstrf ) THEN
296            ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
297            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
298            !
299                                    ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
300            IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
301            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
302         ENDIF
303         ALLOCATE( tauoc_wave(jpi,jpj) )
304      ENDIF
305
306      IF( ln_sdw ) THEN   ! Find out how many fields have to be read from file if not coupled
307         jpfld=0
308         jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0
309         IF( .NOT. cpl_sdrftx ) THEN
310            jpfld  = jpfld + 1
311            jp_usd = jpfld
312         ENDIF
313         IF( .NOT. cpl_sdrfty ) THEN
314            jpfld  = jpfld + 1
315            jp_vsd = jpfld
316         ENDIF
317         IF( .NOT. cpl_hsig ) THEN
318            jpfld  = jpfld + 1
319            jp_hsw = jpfld
320         ENDIF
321         IF( .NOT. cpl_wper ) THEN
322            jpfld  = jpfld + 1
323            jp_wmp = jpfld
324         ENDIF
325
326         ! Read from file only the non-coupled fields
327         IF( jpfld > 0 ) THEN
328            ALLOCATE( slf_i(jpfld) )
329            IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
330            IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
331            IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
332            IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
333            ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
334            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
335            !
336            DO ifpr= 1, jpfld
337               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
338               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
339            END DO
340            !
341            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
342         ENDIF
343         ALLOCATE( usd  (jpi,jpj,jpk), vsd  (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
344         ALLOCATE( hsw  (jpi,jpj)    , wmp  (jpi,jpj)     )
345         ALLOCATE( ut0sd(jpi,jpj)    , vt0sd(jpi,jpj)     )
346         ALLOCATE( div_sd(jpi,jpj) )
347         ALLOCATE( tsd2d (jpi,jpj) )
348         usd(:,:,:) = 0._wp
349         vsd(:,:,:) = 0._wp
350         wsd(:,:,:) = 0._wp
351         ! Wave number needed only if ln_zdfqiao=T
352         IF( .NOT. cpl_wnum ) THEN
353            ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
354            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wave structure' )
355                                   ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
356            IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
357            CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
358         ENDIF
359         ALLOCATE( wnum(jpi,jpj) )
360      ENDIF
361      !
362   END SUBROUTINE sbc_wave_init
363
364   !!======================================================================
365END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.