New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcstp.F90 in branches/2017/dev_r8126_ROBUST08_no_ghost/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/2017/dev_r8126_ROBUST08_no_ghost/NEMOGCM/NEMO/TOP_SRC/trcstp.F90 @ 8809

Last change on this file since 8809 was 7812, checked in by cetlod, 7 years ago

trunk : minor bugfix

  • Property svn:keywords set to Id
File size: 10.4 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!----------------------------------------------------------------------
8#if defined key_top
9   !!----------------------------------------------------------------------
10   !!   trc_stp      : passive tracer system time-stepping
11   !!----------------------------------------------------------------------
12   USE oce_trc          ! ocean dynamics and active tracers variables
13   USE sbc_oce
14   USE trc
15   USE trctrp           ! passive tracers transport
16   USE trcsms           ! passive tracers sources and sinks
17   USE trcwri
18   USE trcrst
19   USE trdtrc_oce
20   USE trdmxl_trc
21   USE prtctl_trc       ! Print control for debbuging
22   USE iom
23   USE in_out_manager
24   USE trcsub
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   trc_stp    ! called by step
30
31   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr ! save qsr during TOP time-step
32   REAL(wp) :: rdt_sampl
33   INTEGER  :: nb_rec_per_day, ktdcy
34   REAL(wp) :: rsecfst, rseclast
35   LOGICAL  :: llnew
36
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE trc_stp( kt )
45      !!-------------------------------------------------------------------
46      !!                     ***  ROUTINE trc_stp  ***
47      !!                     
48      !! ** Purpose : Time loop of opa for passive tracer
49      !!
50      !! ** Method  :
51      !!              Compute the passive tracers trends
52      !!              Update the passive tracers
53      !!-------------------------------------------------------------------
54      INTEGER, INTENT( in ) ::  kt      ! ocean time-step index
55      INTEGER               ::  jk, jn  ! dummy loop indices
56      REAL(wp)              ::  ztrai
57      CHARACTER (len=25)    ::  charout 
58
59      !!-------------------------------------------------------------------
60      !
61      IF( nn_timing == 1 )   CALL timing_start('trc_stp')
62      !
63      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
64         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
65      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
66         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
67      ENDIF
68      !
69      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
70      !
71      IF( .NOT.ln_linssh ) THEN                                           ! update ocean volume due to ssh temporal evolution
72         DO jk = 1, jpk
73            cvol(:,:,jk) = e1e2t(:,:) * e3t_n(:,:,jk) * tmask(:,:,jk)
74         END DO
75         areatot         = glob_sum( cvol(:,:,:) )
76      ENDIF
77      !
78      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
79      !   
80      IF( nn_dttrc /= 1 )   CALL trc_sub_stp( kt )  ! averaging physical variables for sub-stepping
81      !   
82      IF( MOD( kt , nn_dttrc ) == 0 ) THEN      ! only every nn_dttrc time step
83         !
84         IF(ln_ctl) THEN
85            WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
86            CALL prt_ctl_trc_info(charout)
87         ENDIF
88         !
89         tra(:,:,:,:) = 0.e0
90         !
91                                   CALL trc_rst_opn  ( kt )       ! Open tracer restart file
92         IF( lrst_trc )            CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
93                                   CALL trc_wri      ( kt )       ! output of passive tracers with iom I/O manager
94                                   CALL trc_sms      ( kt )       ! tracers: sinks and sources
95                                   CALL trc_trp      ( kt )       ! transport of passive tracers
96         IF( kt == nittrc000 ) THEN
97            CALL iom_close( numrtr )       ! close input tracer restart file
98            IF(lwm) CALL FLUSH( numont )   ! flush namelist output
99         ENDIF
100         IF( lrst_trc )            CALL trc_rst_wri  ( kt )       ! write tracer restart file
101         IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt )       ! trends: Mixed-layer
102         !
103         IF( nn_dttrc /= 1   )     CALL trc_sub_reset( kt )       ! resetting physical variables when sub-stepping
104         !
105      ENDIF
106      !
107      ztrai = 0._wp                                                   !  content of all tracers
108      DO jn = 1, jptra
109         ztrai = ztrai + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
110      END DO
111      IF( lwp ) WRITE(numstr,9300) kt,  ztrai / areatot
1129300  FORMAT(i10,D23.16)
113      !
114      IF( nn_timing == 1 )   CALL timing_stop('trc_stp')
115      !
116   END SUBROUTINE trc_stp
117
118   SUBROUTINE trc_mean_qsr( kt )
119      !!----------------------------------------------------------------------
120      !!             ***  ROUTINE trc_mean_qsr  ***
121      !!
122      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
123      !!               of diurnal cycle
124      !!
125      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
126      !!              is greater than 1 hour ) and then, compute the  mean with
127      !!              a moving average over 24 hours.
128      !!              In coupled mode, the sampling is done at every coupling frequency
129      !!----------------------------------------------------------------------
130      INTEGER, INTENT(in) ::   kt
131      INTEGER  :: jn
132      REAL(wp) :: zkt, zrec
133      CHARACTER(len=1)               ::   cl1                      ! 1 character
134      CHARACTER(len=2)               ::   cl2                      ! 2 characters
135
136      IF( kt == nittrc000 ) THEN
137         IF( ln_cpl )  THEN 
138            rdt_sampl = rday / ncpl_qsr_freq
139            nb_rec_per_day = ncpl_qsr_freq
140         ELSE 
141            rdt_sampl = MAX( 3600., rdttrc )
142            nb_rec_per_day = INT( rday / rdt_sampl )
143         ENDIF
144         !
145         IF( lwp ) THEN
146            WRITE(numout,*) 
147            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
148            WRITE(numout,*) 
149         ENDIF
150         !
151         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
152         !
153         !                                            !* Restart: read in restart file
154         IF( ln_rsttr .AND. nn_rsttr /= 0 .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0  &
155           &                              .AND. iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0  &
156           &                              .AND. iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0  &
157           &                              .AND. iom_varid( numrtr, 'nrdcy'    , ldstop = .FALSE. ) > 0  ) THEN
158
159            CALL iom_get( numrtr, 'ktdcy', zkt ) 
160            rsecfst = INT( zkt ) * rdttrc
161            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
162            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
163            CALL iom_get( numrtr, 'nrdcy', zrec )   !  Number of record per days
164            IF( INT( zrec ) == nb_rec_per_day ) THEN
165               DO jn = 1, nb_rec_per_day 
166                  IF( jn <= 9 )  THEN
167                    WRITE(cl1,'(i1)') jn
168                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
169                  ELSE
170                    WRITE(cl2,'(i2.2)') jn
171                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
172                  ENDIF
173              ENDDO
174            ELSE
175               DO jn = 1, nb_rec_per_day
176                  qsr_arr(:,:,jn) = qsr_mean(:,:)
177               ENDDO
178            ENDIF
179         ELSE                                         !* no restart: set from nit000 values
180            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
181            rsecfst  = kt * rdttrc
182            !
183            qsr_mean(:,:) = qsr(:,:)
184            DO jn = 1, nb_rec_per_day
185               qsr_arr(:,:,jn) = qsr_mean(:,:)
186            ENDDO
187         ENDIF
188         !
189      ENDIF
190      !
191      rseclast = kt * rdttrc
192      !
193      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
194      IF( llnew ) THEN
195          ktdcy = kt
196          IF( lwp .AND. kt < nittrc000 + 100 ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', ktdcy, &
197             &                      ' time = ', rseclast/3600.,'hours '
198          rsecfst = rseclast
199          DO jn = 1, nb_rec_per_day - 1
200             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
201          ENDDO
202          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
203          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
204      ENDIF
205      !
206      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
207         IF(lwp) WRITE(numout,*)
208         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
209         IF(lwp) WRITE(numout,*) '~~~~~~~'
210         zkt  = REAL( ktdcy, wp )
211         zrec = REAL( nb_rec_per_day, wp )
212         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt  )
213         CALL iom_rstput( kt, nitrst, numrtw, 'nrdcy', zrec )
214          DO jn = 1, nb_rec_per_day 
215             IF( jn <= 9 )  THEN
216               WRITE(cl1,'(i1)') jn
217               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
218             ELSE
219               WRITE(cl2,'(i2.2)') jn
220               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
221             ENDIF
222         ENDDO
223         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
224      ENDIF
225      !
226   END SUBROUTINE trc_mean_qsr
227
228#else
229   !!----------------------------------------------------------------------
230   !!   Default key                                     NO passive tracers
231   !!----------------------------------------------------------------------
232CONTAINS
233   SUBROUTINE trc_stp( kt )        ! Empty routine
234      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
235   END SUBROUTINE trc_stp
236#endif
237
238   !!======================================================================
239END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.