New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2017/dev_r8127_AGRIF_LIM3_GHOST/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8127_AGRIF_LIM3_GHOST/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8482

Last change on this file since 8482 was 8482, checked in by clem, 7 years ago

bug fix following #1937

  • Property svn:keywords set to Id
File size: 34.6 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! sea-ice variables
25   USE sbc_oce        ! Surface boundary condition: ocean fields
26   USE sbc_ice        ! Surface boundary condition: ice fields
27   USE thd_ice        ! thermodynamic sea-ice variables
28   USE limthd_dif     ! vertical diffusion
29   USE limthd_dh      ! ice-snow growth and melt
30   USE limthd_da      ! lateral melting
31   USE limthd_sal     ! ice salinity
32   USE limthd_ent     ! ice enthalpy redistribution
33   USE limthd_lac     ! lateral accretion
34   USE limitd_th      ! remapping thickness distribution
35   USE limtab         ! 1D <==> 2D transformation
36   USE limvar         !
37   USE limcons        ! conservation tests
38   USE limctl         ! control print
39   !
40   USE in_out_manager ! I/O manager
41   USE lbclnk         ! lateral boundary condition - MPP links
42   USE lib_mpp        ! MPP library
43   USE wrk_nemo       ! work arrays
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45   USE timing         ! Timing
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   lim_thd         ! called by limstp module
51   PUBLIC   lim_thd_init    ! called by sbc_lim_init
52
53   !! * Substitutions
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE lim_thd( kt )
63      !!-------------------------------------------------------------------
64      !!                ***  ROUTINE lim_thd  ***       
65      !! 
66      !! ** Purpose : This routine manages ice thermodynamics
67      !!         
68      !! ** Action : - Initialisation of some variables
69      !!             - Some preliminary computation (oceanic heat flux
70      !!               at the ice base, snow acc.,heat budget of the leads)
71      !!             - selection of the icy points and put them in an array
72      !!             - call lim_thd_dif  for vertical heat diffusion
73      !!             - call lim_thd_dh   for vertical ice growth and melt
74      !!             - call lim_thd_ent  for enthalpy remapping
75      !!             - call lim_thd_sal  for ice desalination
76      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
77      !!             - back to the geographic grid
78      !!     
79      !! ** References :
80      !!---------------------------------------------------------------------
81      INTEGER, INTENT(in) :: kt    ! number of iteration
82      !
83      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
84      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
85      REAL(wp) :: zfric_u, zqld, zqfr
86      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
87      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
88      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
89      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
90      !
91      !!-------------------------------------------------------------------
92
93      IF( nn_timing == 1 )   CALL timing_start('limthd')
94
95      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
96
97      IF( kt == nit000 .AND. lwp ) THEN
98         WRITE(numout,*)'' 
99         WRITE(numout,*)' lim_thd '
100         WRITE(numout,*)' ~~~~~~~~'
101      ENDIF
102     
103      ! conservation test
104      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
105
106      CALL lim_var_glo2eqv
107
108      !---------------------------------------------!
109      ! computation of friction velocity at T points
110      !---------------------------------------------!
111      IF( ln_limdyn ) THEN
112         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
113         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
114         DO jj = 2, jpjm1 
115            DO ji = fs_2, fs_jpim1
116               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
117                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
118                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
119            END DO
120         END DO
121      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
122         DO jj = 2, jpjm1
123            DO ji = fs_2, fs_jpim1
124               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
125                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
126                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
127            END DO
128         END DO
129      ENDIF
130      CALL lbc_lnk( zfric, 'T',  1. )
131      !
132      !----------------------------------!
133      ! Initialization and units change
134      !----------------------------------!
135      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
136
137      ! Change the units of heat content; from J/m2 to J/m3
138      DO jl = 1, jpl
139         DO jk = 1, nlay_i
140            DO jj = 1, jpj
141               DO ji = 1, jpi
142                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
143                  !Energy of melting q(S,T) [J.m-3]
144                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
145               END DO
146            END DO
147         END DO
148         DO jk = 1, nlay_s
149            DO jj = 1, jpj
150               DO ji = 1, jpi
151                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
152                  !Energy of melting q(S,T) [J.m-3]
153                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
154               END DO
155            END DO
156         END DO
157      END DO
158
159      !--------------------------------------------------------------------!
160      ! Partial computation of forcing for the thermodynamic sea ice model
161      !--------------------------------------------------------------------!
162      DO jj = 1, jpj
163         DO ji = 1, jpi
164            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
165            !
166            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
167            !           !  practically no "direct lateral ablation"
168            !           
169            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
170            !           !  temperature and turbulent mixing (McPhee, 1992)
171            !
172            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
173            zqld =  tmask(ji,jj,1) * rdt_ice *  &
174               &    ( pfrld(ji,jj) * qsr_oce(ji,jj) * frq_m(ji,jj) + pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
175
176            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
177            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
178
179            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
180            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
181            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
182            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
183            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
184            !                        the freezing point, so that we do not have SST < T_freeze
185            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
186
187            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
188            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
189
190            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
191            IF( zqld > 0._wp ) THEN
192               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
193               qlead(ji,jj) = 0._wp
194            ELSE
195               fhld (ji,jj) = 0._wp
196            ENDIF
197            !
198            ! Net heat flux on top of the ice-ocean [W.m-2]
199            ! ---------------------------------------------
200            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
201         END DO
202      END DO
203     
204      ! In case we bypass open-water ice formation
205      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
206      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
207      IF( .NOT. ln_limdH ) THEN
208         hfx_in(:,:) = pfrld(:,:) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
209         fhtur (:,:) = 0._wp
210         fhld  (:,:) = 0._wp
211      ENDIF
212
213      ! ---------------------------------------------------------------------
214      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
215      ! ---------------------------------------------------------------------
216      !     First  step here              :  non solar + precip - qlead - qturb
217      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
218      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
219      DO jj = 1, jpj
220         DO ji = 1, jpi
221            hfx_out(ji,jj) =   pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
222               &             - qlead(ji,jj) * r1_rdtice                         &  ! heat flux taken from the ocean where there is open water ice formation
223               &             - at_i(ji,jj) * fhtur(ji,jj)                       &  ! heat flux taken by turbulence
224               &             - at_i(ji,jj) *  fhld(ji,jj)                          ! heat flux taken during bottom growth/melt
225                                                                                   !    (fhld should be 0 while bott growth)
226         END DO
227      END DO
228
229      !------------------------------------------------------------------------------!
230      ! Thermodynamic computation (only on grid points covered by ice)
231      !------------------------------------------------------------------------------!
232
233      DO jl = 1, jpl      !loop over ice categories
234
235         ! select ice covered grid points
236         nbpb = 0
237         DO jj = 1, jpj
238            DO ji = 1, jpi
239               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
240                  nbpb      = nbpb  + 1
241                  npb(nbpb) = (jj - 1) * jpi + ji
242               ENDIF
243            END DO
244         END DO
245
246         ! debug point to follow
247         jiindex_1d = 0
248         IF( ln_limctl ) THEN
249            DO ji = mi0(iiceprt), mi1(iiceprt)
250               DO jj = mj0(jiceprt), mj1(jiceprt)
251                  jiindex_1d = (jj - 1) * jpi + ji
252                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
253               END DO
254            END DO
255         ENDIF
256
257         IF( lk_mpp )         CALL mpp_ini_ice( nbpb , numout )
258
259         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
260            !                                                               
261            s_i_new   (:) = 0._wp ; dh_s_tot (:) = 0._wp                     ! --- some init --- !
262            dh_i_surf (:) = 0._wp ; dh_i_bott(:) = 0._wp
263            dh_snowice(:) = 0._wp ; dh_i_sub (:) = 0._wp
264
265                              CALL lim_thd_1d2d( nbpb, jl, 1 )               ! --- Move to 1D arrays --- !
266            !
267            IF( ln_limdH )    CALL lim_thd_dif( 1, nbpb )                    ! --- Ice/Snow Temperature profile --- !
268            !
269            IF( ln_limdH )    CALL lim_thd_dh( 1, nbpb )                     ! --- Ice/Snow thickness --- !   
270            !
271            IF( ln_limdH )    CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) )  ! --- Ice enthalpy remapping --- !
272            !
273                              CALL lim_thd_sal( 1, nbpb )                    ! --- Ice salinity --- !   
274            !
275                              CALL lim_thd_temp( 1, nbpb )                   ! --- temperature update --- !
276            !
277            IF( ln_limdH ) THEN
278               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
279                              CALL lim_thd_lam( 1, nbpb )                    ! --- extra lateral melting if monocat --- !
280               END IF
281            END IF
282            !
283                              CALL lim_thd_1d2d( nbpb, jl, 2 )               ! --- Move to 2D arrays --- !
284            !
285            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
286         ENDIF
287         !
288      END DO !jl
289
290      IF( ln_limdA)           CALL lim_thd_da                                ! --- lateral melting --- !
291
292      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
293      DO jl = 1, jpl
294         DO jk = 1, nlay_i
295            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
296         END DO
297         DO jk = 1, nlay_s
298            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
299         END DO
300      END DO
301 
302      ! Change thickness to volume
303      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
304      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
305      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
306
307      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
308      DO jl  = 1, jpl
309         DO jj = 1, jpj
310            DO ji = 1, jpi
311               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
312               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
313            END DO
314         END DO
315      END DO
316
317      CALL lim_var_zapsmall
318
319      ! control checks
320      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
321      !
322      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
323
324      !------------------------------------------------!
325      !  Transport ice between thickness categories
326      !------------------------------------------------!
327      ! Given thermodynamic growth rates, transport ice between thickness categories.
328      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
329
330      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
331
332      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
333
334      !------------------------------------------------!
335      !  Add frazil ice growing in leads
336      !------------------------------------------------!
337      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
338
339      IF( ln_limdO )     CALL lim_thd_lac
340     
341      ! conservation test
342      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
343
344      ! Control print
345      IF( ln_ctl )       CALL lim_prt3D( 'limthd' )
346      !
347      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
348      !
349      IF( nn_timing == 1 )  CALL timing_stop('limthd')
350
351   END SUBROUTINE lim_thd 
352
353 
354   SUBROUTINE lim_thd_temp( kideb, kiut )
355      !!-----------------------------------------------------------------------
356      !!                   ***  ROUTINE lim_thd_temp ***
357      !!                 
358      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
359      !!
360      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
361      !!-------------------------------------------------------------------
362      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
363      !
364      INTEGER  ::   ji, jk   ! dummy loop indices
365      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
366      !!-------------------------------------------------------------------
367      ! Recover ice temperature
368      DO jk = 1, nlay_i
369         DO ji = kideb, kiut
370            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
371            ! Conversion q(S,T) -> T (second order equation)
372            zaaa          =  cpic
373            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
374            zccc          =  lfus * ( ztmelts - rt0 )
375            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
376            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
377           
378            ! mask temperature
379            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
380            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
381         END DO
382      END DO 
383      !
384   END SUBROUTINE lim_thd_temp
385
386
387   SUBROUTINE lim_thd_lam( kideb, kiut )
388      !!-----------------------------------------------------------------------
389      !!                   ***  ROUTINE lim_thd_lam ***
390      !!                 
391      !! ** Purpose :   Lateral melting in case monocategory
392      !!                          ( dA = A/2h dh )
393      !!-----------------------------------------------------------------------
394      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
395      !
396      INTEGER  ::   ji                 ! dummy loop indices
397      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
398      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
399      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
400      !!-----------------------------------------------------------------------
401      !
402      DO ji = kideb, kiut
403         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
404         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
405            zvi          = a_i_1d(ji) * ht_i_1d(ji)
406            zvs          = a_i_1d(ji) * ht_s_1d(ji)
407            ! lateral melting = concentration change
408            zhi_bef     = ht_i_1d(ji) - zdh_mel
409            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
410            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
411            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
412            ! adjust thickness
413            ht_i_1d(ji) = zvi / a_i_1d(ji)           
414            ht_s_1d(ji) = zvs / a_i_1d(ji)           
415            ! retrieve total concentration
416            at_i_1d(ji) = a_i_1d(ji)
417         END IF
418      END DO
419      !
420   END SUBROUTINE lim_thd_lam
421
422
423   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
424      !!-----------------------------------------------------------------------
425      !!                   ***  ROUTINE lim_thd_1d2d ***
426      !!                 
427      !! ** Purpose :   move arrays from 1d to 2d and the reverse
428      !!-----------------------------------------------------------------------
429      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
430      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
431      INTEGER, INTENT(in) ::   jl       ! ice cat
432      !
433      INTEGER             ::   jk       ! dummy loop indices
434      !!-----------------------------------------------------------------------
435      !
436      SELECT CASE( kn )
437      !
438      CASE( 1 )            ! from 2D to 1D
439         !
440         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
441         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
442         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
443         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
444         !
445         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
446         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
447         DO jk = 1, nlay_s
448            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
449            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
450         END DO
451         DO jk = 1, nlay_i
452            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
453            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
454            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
455         END DO
456         !
457         CALL tab_2d_1d( nbpb, qprec_ice_1d(1:nbpb), qprec_ice(:,:) , jpi, jpj, npb(1:nbpb) )
458         CALL tab_2d_1d( nbpb, qevap_ice_1d(1:nbpb), qevap_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
459         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
460         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
461         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
462         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
463         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
464         CALL tab_2d_1d( nbpb, evap_ice_1d (1:nbpb), evap_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
465         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
466         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
467         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
468         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
469         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
470         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
471         !
472         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
473         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
474         !
475         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
476         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
477         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
478         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
479         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
480         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
481         !
482         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
483         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
484         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
485         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
486         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
487         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
488         CALL tab_2d_1d( nbpb, sfx_sub_1d (1:nbpb), sfx_sub         , jpi, jpj,npb(1:nbpb) )
489         !
490         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
491         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
492         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
493         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
494         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
495         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
496         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
497         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
498         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
499         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
500         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
501         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
502         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
503         !
504      CASE( 2 )            ! from 1D to 2D
505         !
506         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
507         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
508         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
509         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
510         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
511         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
512         DO jk = 1, nlay_s
513            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
514            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
515         END DO
516         DO jk = 1, nlay_i
517            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
518            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
519            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
520         END DO
521         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
522         !
523         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
524         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
525         !
526         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
527         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
528         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
529         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
530         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
531         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
532         !
533         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
534         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
535         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
536         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
537         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
538         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
539         CALL tab_1d_2d( nbpb, sfx_sub       , npb, sfx_sub_1d(1:nbpb)   , jpi, jpj )       
540         !
541         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
542         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
543         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
544         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
545         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
546         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
547         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
548         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
549         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
550         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
551         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
552         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
553         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
554         !
555         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
556         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
557         !         
558      END SELECT
559      !
560   END SUBROUTINE lim_thd_1d2d
561
562
563   SUBROUTINE lim_thd_init
564      !!-----------------------------------------------------------------------
565      !!                   ***  ROUTINE lim_thd_init ***
566      !!                 
567      !! ** Purpose :   Physical constants and parameters linked to the ice
568      !!              thermodynamics
569      !!
570      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
571      !!              parameter values called at the first timestep (nit000)
572      !!
573      !! ** input   :   Namelist namicether
574      !!-------------------------------------------------------------------
575      INTEGER  ::   ios                 ! Local integer output status for namelist read
576      NAMELIST/namicethd/ rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon, ln_it_qnsice, nn_monocat, rn_cdsn,  &
577         &                ln_limdH, rn_betas,                                                                     &
578         &                ln_limdA, rn_beta, rn_dmin,                                                             &
579         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin
580      !!-------------------------------------------------------------------
581      !
582      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
583      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
584901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
585
586      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
587      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
588902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
589      IF(lwm) WRITE ( numoni, namicethd )
590      !
591      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
592         nn_monocat = 0
593         IF(lwp) WRITE(numout,*)
594         IF(lwp) WRITE(numout,*) '   nn_monocat forced to 0 as jpl>1, i.e. multi-category case is chosen'
595      ENDIF
596      !
597      IF(lwp) THEN                          ! control print
598         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
599         WRITE(numout,*) '~~~~~~~~~~~~~'
600         WRITE(numout,*)'   -- limthd_dif --'
601         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
602         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
603         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
604         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
605         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
606         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
607         WRITE(numout,*)'      thermal conductivity of the snow                        rn_cdsn      = ', rn_cdsn
608         WRITE(numout,*)'   -- limthd_dh --'
609         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
610         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
611         WRITE(numout,*)'   -- limthd_da --'
612         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
613         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
614         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
615         WRITE(numout,*)'   -- limthd_lac --'
616         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
617         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
618         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
619         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
620         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
621         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
622         WRITE(numout,*)'   -- limitd_th --'
623         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
624         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
625      ENDIF
626      !
627   END SUBROUTINE lim_thd_init
628
629#else
630   !!----------------------------------------------------------------------
631   !!   Default option         Dummy module          NO  LIM3 sea-ice model
632   !!----------------------------------------------------------------------
633#endif
634
635   !!======================================================================
636END MODULE limthd
Note: See TracBrowser for help on using the repository browser.