New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
agrif_lim3_update.F90 in branches/2017/dev_r8127_AGRIF_LIM3_GHOST/NEMOGCM/NEMO/NST_SRC – NEMO

source: branches/2017/dev_r8127_AGRIF_LIM3_GHOST/NEMOGCM/NEMO/NST_SRC/agrif_lim3_update.F90 @ 8129

Last change on this file since 8129 was 8129, checked in by clem, 7 years ago

make those things work: ghostcells>1 + nn_ice(child)=0 + fix timing
File size: 9.1 KB
Line 
1#define TWO_WAY
2
3MODULE agrif_lim3_update
4   !!=====================================================================================
5   !!                       ***  MODULE agrif_lim3_update ***
6   !! Nesting module :  update surface ocean boundary condition over ice from a child grid
7   !! Sea-Ice model  :  LIM 3.6 Sea ice model time-stepping
8   !!=====================================================================================
9   !! History :  2.0   !  04-2008  (F. Dupont)  initial version
10   !!            3.4   !  08-2012  (R. Benshila, C. Herbaut) update and EVP
11   !!            3.6   !  05-2016  (C. Rousset)  Add LIM3 compatibility
12   !!----------------------------------------------------------------------
13#if defined key_agrif && defined key_lim3
14   !!----------------------------------------------------------------------
15   !!   'key_lim3'  :                                 LIM 3.6 sea-ice model
16   !!   'key_agrif' :                                 AGRIF library
17   !!----------------------------------------------------------------------
18   !!   agrif_update_lim3  : update sea-ice on boundaries or total
19   !!                        child domain for velocities and ice properties
20   !!   update_tra_ice     : sea-ice properties
21   !!   update_u_ice       : zonal      ice velocity
22   !!   update_v_ice       : meridional ice velocity
23   !!----------------------------------------------------------------------
24   USE dom_oce
25   USE sbc_oce
26   USE agrif_oce
27   USE ice
28   USE agrif_ice 
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC agrif_update_lim3
34
35   !!----------------------------------------------------------------------
36   !! NEMO/NST 3.6 , LOCEAN-IPSL (2016)
37   !! $Id: agrif_lim3_update.F90 6204 2016-01-04 13:47:06Z cetlod $
38   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40
41CONTAINS
42
43   SUBROUTINE agrif_update_lim3( kt )
44      !!----------------------------------------------------------------------
45      !!                     *** ROUTINE agrif_update_lim3 ***
46      !! ** Method  :   Call the hydrostaticupdate pressure at the boundary or the entire domain
47      !!
48      !! ** Action : - Update (u_ice,v_ice) and ice tracers
49      !!----------------------------------------------------------------------
50      INTEGER, INTENT(in) :: kt
51      !!
52      !!----------------------------------------------------------------------
53      !
54      !! clem: I think the update should take place each time the ocean sees the surface forcings
55      !!       (but maybe I am wrong and we should update every rhot time steps)
56      IF( ( MOD( (kt-nit000)/nn_fsbc + 1, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) /=0 ) .AND. (kt /= 0) ) RETURN ! do not update if nb of child time steps differ from time refinement
57                                                                                                                           ! i.e. update only at the parent time step
58      IF( nn_ice == 0 ) RETURN   ! clem2017: do not update if child domain does not have ice
59      !
60      Agrif_UseSpecialValueInUpdate = .TRUE.
61      Agrif_SpecialValueFineGrid = -9999.
62# if defined TWO_WAY
63      IF( MOD(nbcline,nbclineupdate) == 0) THEN ! update the whole basin at each nbclineupdate (=nn_cln_update) baroclinic parent time steps
64                                                ! nbcline is incremented (+1) at the end of each parent time step from 0 (1st time step)
65         CALL Agrif_Update_Variable( tra_ice_id , procname = update_tra_ice  )
66         CALL Agrif_Update_Variable( u_ice_id   , procname = update_u_ice    )
67         CALL Agrif_Update_Variable( v_ice_id   , procname = update_v_ice    )
68      ELSE                                      ! update only the boundaries defined par locupdate
69         CALL Agrif_Update_Variable( tra_ice_id , locupdate=(/0,2/), procname = update_tra_ice  )
70         CALL Agrif_Update_Variable( u_ice_id   , locupdate=(/0,1/), procname = update_u_ice    )
71         CALL Agrif_Update_Variable( v_ice_id   , locupdate=(/0,1/), procname = update_v_ice    )
72      ENDIF
73# endif
74      Agrif_UseSpecialValueInUpdate = .FALSE.
75      !
76   END SUBROUTINE agrif_update_lim3
77
78
79   !!------------------
80   !! Local subroutines
81   !!------------------
82   SUBROUTINE update_tra_ice( ptab, i1, i2, j1, j2, k1, k2, before )
83      !!-----------------------------------------------------------------------
84      !!                        *** ROUTINE update_tra_ice ***
85      !! ** Method  : Compute the mass properties on the fine grid and recover
86      !!              the properties per mass on the coarse grid
87      !!-----------------------------------------------------------------------
88      INTEGER , INTENT(in) :: i1, i2, j1, j2, k1, k2
89      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2), INTENT(inout) :: ptab
90      LOGICAL , INTENT(in) :: before
91      !!
92      INTEGER  :: jk, jl, jm
93      !!-----------------------------------------------------------------------
94      ! it is ok not to multiply by e1*e2 since we conserve tracers here (same as in the ocean).
95      IF( before ) THEN
96         jm = 1
97         DO jl = 1, jpl
98            ptab(:,:,jm) = a_i  (i1:i2,j1:j2,jl) ; jm = jm + 1
99            ptab(:,:,jm) = v_i  (i1:i2,j1:j2,jl) ; jm = jm + 1
100            ptab(:,:,jm) = v_s  (i1:i2,j1:j2,jl) ; jm = jm + 1
101            ptab(:,:,jm) = smv_i(i1:i2,j1:j2,jl) ; jm = jm + 1
102            ptab(:,:,jm) = oa_i (i1:i2,j1:j2,jl) ; jm = jm + 1
103            DO jk = 1, nlay_s
104               ptab(:,:,jm) = e_s(i1:i2,j1:j2,jk,jl) ; jm = jm + 1
105            ENDDO
106            DO jk = 1, nlay_i
107               ptab(:,:,jm) = e_i(i1:i2,j1:j2,jk,jl) ; jm = jm + 1
108            ENDDO
109         ENDDO
110
111         DO jk = k1, k2
112            WHERE( tmask(i1:i2,j1:j2,1) == 0. )  ptab(:,:,jk) = -9999.
113         ENDDO
114                 
115      ELSE
116         jm = 1
117         DO jl = 1, jpl
118            a_i  (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
119            v_i  (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
120            v_s  (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
121            smv_i(i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
122            oa_i (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
123            DO jk = 1, nlay_s
124               e_s(i1:i2,j1:j2,jk,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
125            ENDDO
126            DO jk = 1, nlay_i
127               e_i(i1:i2,j1:j2,jk,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
128            ENDDO
129         ENDDO
130
131         ! integrated values
132         vt_i (i1:i2,j1:j2) = SUM( v_i(i1:i2,j1:j2,:), dim=3 )
133         vt_s (i1:i2,j1:j2) = SUM( v_s(i1:i2,j1:j2,:), dim=3 )
134         at_i (i1:i2,j1:j2) = SUM( a_i(i1:i2,j1:j2,:), dim=3 )
135         et_s(i1:i2,j1:j2)  = SUM( SUM( e_s(i1:i2,j1:j2,:,:), dim=4 ), dim=3 )
136         et_i(i1:i2,j1:j2)  = SUM( SUM( e_i(i1:i2,j1:j2,:,:), dim=4 ), dim=3 )
137         
138      ENDIF
139      !
140   END SUBROUTINE update_tra_ice
141
142
143   SUBROUTINE update_u_ice( ptab, i1, i2, j1, j2, before )
144      !!-----------------------------------------------------------------------
145      !!                        *** ROUTINE update_u_ice ***
146      !! ** Method  : Update the fluxes and recover the properties (C-grid)
147      !!-----------------------------------------------------------------------
148      INTEGER , INTENT(in) :: i1, i2, j1, j2
149      REAL(wp), DIMENSION(i1:i2,j1:j2), INTENT(inout) :: ptab
150      LOGICAL , INTENT(in) :: before
151      !!
152      REAL(wp) :: zrhoy
153      !!-----------------------------------------------------------------------
154      !
155      IF( before ) THEN
156         zrhoy = Agrif_Rhoy()
157         ptab(:,:) = e2u(i1:i2,j1:j2) * u_ice(i1:i2,j1:j2) * zrhoy
158         WHERE( umask(i1:i2,j1:j2,1) == 0. )  ptab(:,:) = -9999.
159      ELSE
160         u_ice(i1:i2,j1:j2) = ptab(:,:) / e2u(i1:i2,j1:j2) * umask(i1:i2,j1:j2,1)
161      ENDIF
162      !
163   END SUBROUTINE update_u_ice
164
165
166   SUBROUTINE update_v_ice( ptab, i1, i2, j1, j2, before )
167      !!-----------------------------------------------------------------------
168      !!                    *** ROUTINE update_v_ice ***
169      !! ** Method  : Update the fluxes and recover the properties (C-grid)
170      !!-----------------------------------------------------------------------
171      INTEGER , INTENT(in) :: i1,i2,j1,j2
172      REAL(wp), DIMENSION(i1:i2,j1:j2),  INTENT(inout) :: ptab
173      LOGICAL , INTENT(in) :: before
174      !!
175      REAL(wp) :: zrhox
176      !!-----------------------------------------------------------------------
177      !
178      IF( before ) THEN
179         zrhox = Agrif_Rhox()
180         ptab(:,:) = e1v(i1:i2,j1:j2) * v_ice(i1:i2,j1:j2) * zrhox
181         WHERE( vmask(i1:i2,j1:j2,1) == 0. )  ptab(:,:) = -9999.
182      ELSE
183         v_ice(i1:i2,j1:j2) = ptab(:,:) / e1v(i1:i2,j1:j2) * vmask(i1:i2,j1:j2,1)
184      ENDIF
185      !
186   END SUBROUTINE update_v_ice
187
188#else
189CONTAINS
190   SUBROUTINE agrif_lim3_update_empty
191      !!---------------------------------------------
192      !!   *** ROUTINE agrif_lim3_update_empty ***
193      !!---------------------------------------------
194      WRITE(*,*)  'agrif_lim3_update : You should not have seen this print! error?'
195   END SUBROUTINE agrif_lim3_update_empty
196#endif
197END MODULE agrif_lim3_update
Note: See TracBrowser for help on using the repository browser.