New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iceadv.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/iceadv.F90 @ 8512

Last change on this file since 8512 was 8512, checked in by clem, 7 years ago

changes in style - part5 - reaching the end

File size: 14.5 KB
Line 
1MODULE iceadv
2   !!======================================================================
3   !!                       ***  MODULE iceadv   ***
4   !! LIM transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6   !! History : LIM-2 ! 2000-01 (M.A. Morales Maqueda, H. Goosse, and T. Fichefet)  Original code
7   !!            3.0  ! 2005-11 (M. Vancoppenolle)   Multi-layer sea ice, salinity variations
8   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
9   !!----------------------------------------------------------------------
10#if defined key_lim3
11   !!----------------------------------------------------------------------
12   !!   'key_lim3'                                       LIM3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   ice_adv       : advection/diffusion process of sea ice
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constant
17   USE dom_oce        ! ocean domain
18   USE sbc_oce , ONLY : nn_fsbc   ! frequency of sea-ice call
19   USE ice            ! sea-ice: variables
20   USE icevar         ! sea-ice: operations
21   USE iceadv_prather ! sea-ice: advection scheme (Prather)
22   USE iceadv_umx     ! sea-ice: advection scheme (ultimate-macho)
23   USE icectl         ! sea-ice: control prints
24   !
25   USE in_out_manager ! I/O manager
26   USE lbclnk         ! lateral boundary conditions -- MPP exchanges
27   USE lib_mpp        ! MPP library
28   USE prtctl         ! Print control
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30   USE timing         ! Timing
31   USE iom            !
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   ice_adv        ! called by icestp
37   PUBLIC   ice_adv_init   ! called by icestp
38
39   INTEGER, PUBLIC ::              nice_dyn   ! choice of the type of advection scheme
40   !                                  ! associated indices:
41   INTEGER, PUBLIC, PARAMETER ::   np_dynNO   = 0   ! no ice dynamics and ice advection
42   INTEGER, PUBLIC, PARAMETER ::   np_dynFULL = 1   ! full ice dynamics  (rheology + advection + ridging/rafting + correction)
43   INTEGER, PUBLIC, PARAMETER ::   np_dyn     = 2   ! no ridging/rafting (rheology + advection                   + correction)
44   INTEGER, PUBLIC, PARAMETER ::   np_dynPURE = 3   ! pure dynamics      (rheology + advection)
45
46   !! * Substitution
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/ICE 4.0 , NEMO Consortium (2017)
50   !! $Id: iceadv.F90 8373 2017-07-25 17:44:54Z clem $
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE ice_adv( kt ) 
56      !!----------------------------------------------------------------------
57      !!                   ***  ROUTINE ice_adv ***
58      !!                   
59      !! ** purpose : advection of sea ice
60      !!
61      !! ** method  : variables included in the process are scalar,   
62      !!     other values are considered as second order.
63      !!     For advection, one can choose between
64      !!     a) an Ultimate-Macho scheme (whose order is defined by nn_UMx) => ln_adv_UMx
65      !!     b) and a second order Prather scheme => ln_adv_Pra
66      !!
67      !! ** action :
68      !!----------------------------------------------------------------------
69      INTEGER, INTENT(in) ::   kt   ! number of iteration
70      !
71      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
72      INTEGER  ::   initad                  ! number of sub-timestep for the advection
73      REAL(wp) ::   zcfl , zusnit           !   -      -
74      CHARACTER(len=80) :: cltmp
75      !
76      REAL(wp) ::    zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b
77      REAL(wp) ::    zdv
78      REAL(wp), DIMENSION(jpi,jpj)           ::   zatold, zeiold, zesold, zsmvold 
79      REAL(wp), DIMENSION(jpi,jpj,jpl)       ::   zhimax, zviold, zvsold
80      !!---------------------------------------------------------------------
81      IF( nn_timing == 1 )  CALL timing_start('iceadv')
82 
83      IF( kt == nit000 .AND. lwp ) THEN
84         WRITE(numout,*)
85         WRITE(numout,*) 'ice_adv: sea-ice advection'
86         WRITE(numout,*) '~~~~~~~'
87      ENDIF
88     
89      CALL ice_var_agg( 1 ) ! integrated values + ato_i
90
91      ! conservation test
92      IF( ln_limdiachk )   CALL ice_cons_hsm(0, 'iceadv', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
93     
94      ! store old values for diag
95      zviold (:,:,:) = v_i(:,:,:)
96      zvsold (:,:,:) = v_s(:,:,:)
97      zsmvold(:,:)   = SUM( smv_i(:,:,:), dim=3 )
98      zeiold (:,:)   = et_i(:,:)
99      zesold (:,:)   = et_s(:,:)
100
101      ! Thickness correction init.
102      zatold(:,:) = at_i
103      WHERE( a_i(:,:,:) >= epsi20 )
104         ht_i(:,:,:) = v_i(:,:,:) / a_i(:,:,:)
105         ht_s(:,:,:) = v_s(:,:,:) / a_i(:,:,:)
106      ELSEWHERE
107         ht_i(:,:,:) = 0._wp
108         ht_s(:,:,:) = 0._wp         
109      END WHERE
110         
111      ! Record max of the surrounding ice thicknesses for correction in case advection creates ice too thick
112      zhimax(:,:,:) = ht_i(:,:,:) + ht_s(:,:,:)
113      DO jl = 1, jpl
114         DO jj = 2, jpjm1
115            DO ji = 2, jpim1
116!!gm use of MAXVAL here is very probably less efficient than expending the 9 values
117               zhimax(ji,jj,jl) = MAX( epsi20, MAXVAL( ht_i(ji-1:ji+1,jj-1:jj+1,jl) + ht_s(ji-1:ji+1,jj-1:jj+1,jl) ) )
118            END DO
119         END DO
120      END DO
121      CALL lbc_lnk( zhimax(:,:,:), 'T', 1. )
122     
123      !----------
124      ! Advection
125      !----------
126      IF( ln_adv_UMx ) THEN                    !-- ULTIMATE-MACHO scheme
127         CALL ice_adv_umx( kt, u_ice, v_ice,  &
128            &              ato_i, v_i, v_s, smv_i, oa_i, a_i, a_ip, v_ip, e_s, e_i )
129         
130      ELSEIF( ln_adv_Pra ) THEN                !-- PRATHER scheme
131         CALL ice_adv_prather( kt, u_ice, v_ice,  &
132            &                  ato_i, v_i, v_s, smv_i, oa_i, a_i, a_ip, v_ip, e_s, e_i )
133         
134      ENDIF
135
136      ! total ice fraction
137      at_i(:,:) = a_i(:,:,1)
138      DO jl = 2, jpl
139         at_i(:,:) = at_i(:,:) + a_i(:,:,jl)
140      END DO
141     
142      !------------
143      ! diagnostics
144      !------------
145      DO jj = 1, jpj
146         DO ji = 1, jpi
147            diag_trp_ei (ji,jj) = ( SUM( e_i  (ji,jj,1:nlay_i,:) ) -  zeiold(ji,jj) ) * r1_rdtice
148            diag_trp_es (ji,jj) = ( SUM( e_s  (ji,jj,1:nlay_s,:) ) -  zesold(ji,jj) ) * r1_rdtice
149            diag_trp_smv(ji,jj) = ( SUM( smv_i(ji,jj,:)          ) - zsmvold(ji,jj) ) * r1_rdtice
150            diag_trp_vi (ji,jj) =   SUM(   v_i(ji,jj,:)            -  zviold(ji,jj,:) ) * r1_rdtice
151            diag_trp_vs (ji,jj) =   SUM(   v_s(ji,jj,:)            -  zvsold(ji,jj,:) ) * r1_rdtice
152         END DO
153      END DO
154      IF( iom_use('icetrp') )   CALL iom_put( "icetrp" , diag_trp_vi * rday  )         ! ice volume transport
155      IF( iom_use('snwtrp') )   CALL iom_put( "snwtrp" , diag_trp_vs * rday  )         ! snw volume transport
156      IF( iom_use('saltrp') )   CALL iom_put( "saltrp" , diag_trp_smv * rday * rhoic ) ! salt content transport
157      IF( iom_use('deitrp') )   CALL iom_put( "deitrp" , diag_trp_ei         )         ! advected ice enthalpy (W/m2)
158      IF( iom_use('destrp') )   CALL iom_put( "destrp" , diag_trp_es         )         ! advected snw enthalpy (W/m2)
159     
160      !--------------------------------------
161      ! Thickness correction in case too high
162      !--------------------------------------
163      IF( nn_icedyn == 2 ) THEN
164         !
165         CALL ice_var_zapsmall                       !-- zap small areas
166         !
167         DO jl = 1, jpl
168            DO jj = 1, jpj
169               DO ji = 1, jpi
170                  IF ( v_i(ji,jj,jl) > 0._wp ) THEN  !-- bound to zhimax
171                     !
172                     ht_i  (ji,jj,jl) = v_i (ji,jj,jl) / a_i(ji,jj,jl)
173                     ht_s  (ji,jj,jl) = v_s (ji,jj,jl) / a_i(ji,jj,jl)
174                     zdv = v_i(ji,jj,jl) + v_s(ji,jj,jl) - zviold(ji,jj,jl) - zvsold(ji,jj,jl) 
175                     !
176                     IF ( ( zdv >  0.0 .AND. (ht_i(ji,jj,jl)+ht_s(ji,jj,jl)) > zhimax(ji,jj,jl) .AND. zatold(ji,jj) < 0.80 ) .OR. &
177                        & ( zdv <= 0.0 .AND. (ht_i(ji,jj,jl)+ht_s(ji,jj,jl)) > zhimax(ji,jj,jl) ) ) THEN
178                        a_i (ji,jj,jl) = ( v_i(ji,jj,jl) + v_s(ji,jj,jl) ) / zhimax(ji,jj,jl)
179                        ht_i(ji,jj,jl) =   v_i(ji,jj,jl) / a_i(ji,jj,jl)
180                     ENDIF
181                     !
182                  ENDIF
183               END DO
184            END DO
185         END DO
186                 
187         WHERE( ht_i(:,:,jpl) > hi_max(jpl) )        !-- bound ht_i to hi_max (99 m)
188            ht_i(:,:,jpl) = hi_max(jpl)
189            a_i (:,:,jpl) = v_i(:,:,jpl) / hi_max(jpl)
190         END WHERE
191
192         IF ( nn_pnd_scheme > 0 ) THEN               !-- correct pond fraction to avoid a_ip > a_i
193            WHERE( a_ip(:,:,:) > a_i(:,:,:) )   a_ip(:,:,:) = a_i(:,:,:)
194         ENDIF
195         !
196      ENDIF
197         
198      !------------------------------------------------------------
199      ! Impose a_i < amax if no ridging/rafting or in mono-category
200      !------------------------------------------------------------
201      IF( l_piling ) THEN                            !-- simple conservative piling, comparable with 1-cat models
202         at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
203         DO jl = 1, jpl
204            WHERE( at_i(:,:) > epsi20 )
205               a_i(:,:,jl) = a_i(:,:,jl) * (  1._wp + MIN( rn_amax_2d(:,:) - at_i(:,:) , 0._wp ) / at_i(:,:)  )
206            END WHERE
207         END DO
208      ENDIF
209     
210      ! agglomerate variables
211      vt_i(:,:) = SUM( v_i(:,:,:), dim=3 )
212      vt_s(:,:) = SUM( v_s(:,:,:), dim=3 )
213      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
214
215      ! MV MP 2016 (remove once we get rid of a_i_frac and ht_i)
216      IF ( nn_pnd_scheme > 0 ) THEN
217          at_ip(:,:) = SUM( a_ip(:,:,:), dim = 3 )
218          vt_ip(:,:) = SUM( v_ip(:,:,:), dim = 3 )
219      ENDIF
220      ! END MP 2016
221     
222      ! open water = 1 if at_i=0
223      WHERE( at_i == 0._wp ) ato_i = 1._wp 
224     
225      ! conservation test
226      IF( ln_limdiachk )   CALL ice_cons_hsm(1, 'iceadv', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
227       
228      ! --------------
229      ! control prints
230      ! --------------
231      IF( ln_limctl )   CALL ice_prt( kt, iiceprt, jiceprt,-1, ' - ice dyn & trp - ' )
232      !
233      IF( nn_timing == 1 )  CALL timing_stop('iceadv')
234      !
235   END SUBROUTINE ice_adv
236
237
238   SUBROUTINE ice_adv_init
239      !!-------------------------------------------------------------------
240      !!                  ***  ROUTINE ice_adv_init  ***
241      !!
242      !! ** Purpose : Physical constants and parameters linked to the ice
243      !!      dynamics
244      !!
245      !! ** Method  :  Read the namice_adv namelist and check the ice-dynamic
246      !!       parameter values called at the first timestep (nit000)
247      !!
248      !! ** input   :   Namelist namice_adv
249      !!-------------------------------------------------------------------
250      INTEGER ::   ios   ! Local integer output status for namelist read
251      !!
252      NAMELIST/namice_adv/ ln_icedyn, nn_icedyn, rn_uice, rn_vice, ln_adv_Pra, ln_adv_UMx, nn_UMx
253      !!-------------------------------------------------------------------
254      !
255      REWIND( numnam_ice_ref )         ! Namelist namice_adv in reference namelist : Ice dynamics
256      READ  ( numnam_ice_ref, namice_adv, IOSTAT = ios, ERR = 901)
257901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namice_adv in reference namelist', lwp )
258      !
259      REWIND( numnam_ice_cfg )         ! Namelist namice_adv in configuration namelist : Ice dynamics
260      READ  ( numnam_ice_cfg, namice_adv, IOSTAT = ios, ERR = 902 )
261902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namice_adv in configuration namelist', lwp )
262      IF(lwm) WRITE ( numoni, namice_adv )
263      !
264      IF(lwp) THEN                     ! control print
265         WRITE(numout,*)
266         WRITE(numout,*) 'ice_adv_init : ice parameters for ice dynamics '
267         WRITE(numout,*) '~~~~~~~~~~~~'
268         WRITE(numout,*) '   Namelist namice_adv'
269         WRITE(numout,*) '      Ice dynamics       (T) or not (F)                         ln_icedyn  = ', ln_icedyn
270         WRITE(numout,*) '         associated switch                                      nn_icedyn  = ', nn_icedyn
271         WRITE(numout,*) '            =2 all processes (default option)'
272         WRITE(numout,*) '            =1 advection only (no ridging/rafting)'
273         WRITE(numout,*) '            =0 advection only with prescribed velocity given by '
274         WRITE(numout,*) '               a uniform field               (u,v)_ice = (rn_uice,rn_vice) = (', rn_uice,',', rn_vice,')'
275         WRITE(numout,*) '      advection scheme for ice transport (limtrp)'
276         WRITE(numout,*) '         type of advection scheme (Prather)                     ln_adv_Pra = ', ln_adv_Pra 
277         WRITE(numout,*) '         type of advection scheme (Ulimate-Macho)               ln_adv_UMx = ', ln_adv_UMx 
278         WRITE(numout,*) '            order of the Ultimate-Macho scheme                      nn_UMx = ', nn_UMx
279      ENDIF
280      !
281      !                             ! set the choice of ice dynamics
282      IF( lk_c1d .OR. .NOT. ln_icedyn ) THEN
283         nice_dyn = np_dynNO                    !--- no dynamics
284      ELSE
285         SELECT CASE( nn_icedyn )
286         CASE( 2 )                   
287            IF( nn_monocat /= 2 ) THEN          !--- full dynamics (rheology + advection + ridging/rafting + correction)
288               nice_dyn = np_dynFULL
289            ELSE
290               nice_dyn = np_dyn                !--- dynamics without ridging/rafting
291            ENDIF
292         CASE( 0 , 1 )                          !--- dynamics without ridging/rafting and correction
293            nice_dyn = np_dynPURE
294         END SELECT
295      ENDIF
296      !                                         !--- simple conservative piling, comparable with LIM2
297      l_piling = nn_icedyn == 1 .OR. ( nn_monocat == 2  .AND.  jpl == 1 )
298      !
299      IF ( ( ln_adv_Pra .AND. ln_adv_UMx ) .OR. ( .NOT.ln_adv_Pra .AND. .NOT.ln_adv_UMx ) ) THEN
300         CALL ctl_stop( 'ice_adv_init: choose one and only one ice advection scheme (ln_adv_Pra or ln_adv_UMx)' )
301      ENDIF
302      !
303   END SUBROUTINE ice_adv_init
304
305#else
306   !!----------------------------------------------------------------------
307   !!   Default option         Empty Module                No sea-ice model
308   !!----------------------------------------------------------------------
309#endif
310
311   !!======================================================================
312END MODULE iceadv
313
Note: See TracBrowser for help on using the repository browser.