New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iceadv_umx.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/iceadv_umx.F90 @ 8518

Last change on this file since 8518 was 8518, checked in by clem, 7 years ago

changes in style - part6 - commits of the day
File size: 34.1 KB
Line 
1MODULE iceadv_umx
2   !!==============================================================================
3   !!                       ***  MODULE  iceadv_umx  ***
4   !! LIM sea-ice model : sea-ice advection using the ULTIMATE-MACHO scheme
5   !!==============================================================================
6   !! History :  3.6  !  2014-11  (C. Rousset, G. Madec)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_lim3
9   !!----------------------------------------------------------------------
10   !!   'key_lim3'                                    LIM 3.0 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_adv_umx   : update the tracer trend with the 3D advection trends using a TVD scheme
13   !!   ultimate_x(_y): compute a tracer value at velocity points using ULTIMATE scheme at various orders
14   !!   macho         : ???
15   !!   nonosc_2d     : compute monotonic tracer fluxes by a non-oscillatory algorithm
16   !!----------------------------------------------------------------------
17   USE phycst         ! physical constant
18   USE dom_oce        ! ocean domain
19   USE sbc_oce , ONLY : nn_fsbc   ! update frequency of surface boundary condition
20   USE ice            ! sea-ice variables
21   !
22   USE in_out_manager ! I/O manager
23   USE lbclnk         ! lateral boundary conditions -- MPP exchanges
24   USE lib_mpp        ! MPP library
25   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
26   USE timing         ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ice_adv_umx    ! called by iceadv.F90
32     
33   REAL(wp) ::   z1_6   = 1._wp /   6._wp   ! =1/6
34   REAL(wp) ::   z1_120 = 1._wp / 120._wp   ! =1/120
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/ICE 4.0 , NEMO Consortium (2017)
40   !! $Id: iceadv_umx.F90 4499 2014-02-18 15:14:31Z timgraham $
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ice_adv_umx( k_order, kt, pu_ice, pv_ice,  &
46      &                    pato_i, pv_i, pv_s, psmv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_adv_umx  ***
49      !!
50      !! **  Purpose :   Compute the now trend due to total advection of
51      !!                 tracers and add it to the general trend of tracer equations
52      !!                 using an "Ultimate-Macho" scheme
53      !!
54      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
55      !!----------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the scheme (1-5 or 20)
57      INTEGER                     , INTENT(in   ) ::   kt         ! time step
58      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pu_ice     ! ice i-velocity
59      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pv_ice     ! ice j-velocity
60      REAL(wp), DIMENSION(:,:)    , INTENT(inout) ::   pato_i     ! open water area
61      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_i       ! ice volume
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_s       ! snw volume
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   psmv_i     ! salt content
64      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   poa_i      ! age content
65      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_i       ! ice concentration
66      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_ip      ! melt pond fraction
67      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_ip      ! melt pond volume
68      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_s       ! snw heat content
69      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_i       ! ice heat content
70      !
71      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
72      INTEGER  ::   initad                  ! number of sub-timestep for the advection
73      REAL(wp) ::   zcfl , zusnit, zdt      !   -      -
74      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zudy, zvdx, zcu_box, zcv_box
75      !!----------------------------------------------------------------------
76      !
77      IF( kt == nit000 .AND. lwp )   WRITE(numout,*) '-- ice_adv_umx: Ultimate-Macho advection scheme'
78      !
79      ALLOCATE( zudy(jpi,jpj) , zvdx(jpi,jpj) , zcu_box(jpi,jpj) , zcv_box(jpi,jpj) )
80      !
81      ! --- If ice drift field is too fast, use an appropriate time step for advection (CFL test for stability) --- !       
82      zcfl  =            MAXVAL( ABS( pu_ice(:,:) ) * rdt_ice * r1_e1u(:,:) )
83      zcfl  = MAX( zcfl, MAXVAL( ABS( pv_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) )
84      IF( lk_mpp )   CALL mpp_max( zcfl )
85
86      IF( zcfl > 0.5 ) THEN   ;   initad = 2   ;   zusnit = 0.5_wp
87      ELSE                    ;   initad = 1   ;   zusnit = 1.0_wp
88      ENDIF
89
90      zdt = rdt_ice / REAL(initad)
91
92      ! --- transport --- !
93      zudy(:,:) = pu_ice(:,:) * e2u(:,:)
94      zvdx(:,:) = pv_ice(:,:) * e1v(:,:)
95
96      ! --- define velocity for advection: u*grad(H) --- !
97      DO jj = 2, jpjm1
98         DO ji = fs_2, fs_jpim1
99            IF    ( pu_ice(ji,jj) * pu_ice(ji-1,jj) <= 0._wp ) THEN   ;   zcu_box(ji,jj) = 0._wp
100            ELSEIF( pu_ice(ji,jj)                   >  0._wp ) THEN   ;   zcu_box(ji,jj) = pu_ice(ji-1,jj)
101            ELSE                                                      ;   zcu_box(ji,jj) = pu_ice(ji  ,jj)
102            ENDIF
103
104            IF    ( pv_ice(ji,jj) * pv_ice(ji,jj-1) <= 0._wp ) THEN   ;   zcv_box(ji,jj) = 0._wp
105            ELSEIF( pv_ice(ji,jj)                   >  0._wp ) THEN   ;   zcv_box(ji,jj) = pv_ice(ji,jj-1)
106            ELSE                                                      ;   zcv_box(ji,jj) = pv_ice(ji,jj  )
107            ENDIF
108         END DO
109      END DO
110
111      !---------------!
112      !== advection ==!
113      !---------------!
114      DO jt = 1, initad
115         CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pato_i(:,:) )             ! Open water area
116         DO jl = 1, jpl
117            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pa_i(:,:,jl) )         ! Ice area
118            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_i(:,:,jl) )         ! Ice  volume
119            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, psmv_i(:,:,jl) )       ! Salt content
120            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, poa_i (:,:,jl) )       ! Age content
121            DO jk = 1, nlay_i
122               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pe_i(:,:,jk,jl) )   ! Ice  heat content
123            END DO
124            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_s(:,:,jl) )         ! Snow volume
125            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pe_s(:,:,1,jl) )       ! Snow heat content
126            IF ( nn_pnd_scheme > 0 ) THEN
127               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pa_ip(:,:,jl) )     ! Melt pond fraction
128               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_ip(:,:,jl) )     ! Melt pond volume
129            ENDIF
130         END DO
131      END DO
132      !
133      DEALLOCATE( zudy, zvdx, zcu_box, zcv_box )
134      !
135   END SUBROUTINE ice_adv_umx
136   
137   SUBROUTINE adv_umx( k_order, kt, pdt, puc, pvc, pubox, pvbox, ptc )
138      !!----------------------------------------------------------------------
139      !!                  ***  ROUTINE adv_umx  ***
140      !!
141      !! **  Purpose :   Compute the now trend due to total advection of
142      !!       tracers and add it to the general trend of tracer equations
143      !!
144      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
145      !!       corrected flux (monotonic correction)
146      !!       note: - this advection scheme needs a leap-frog time scheme
147      !!
148      !! ** Action : - pt  the after advective tracer
149      !!----------------------------------------------------------------------
150      INTEGER                     , INTENT(in   ) ::   k_order        ! order of the ULTIMATE scheme
151      INTEGER                     , INTENT(in   ) ::   kt             ! number of iteration
152      REAL(wp)                    , INTENT(in   ) ::   pdt            ! tracer time-step
153      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc  , pvc     ! 2 ice velocity components => u*e2
154      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
155      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   ptc            ! tracer content field
156      !
157      INTEGER  ::   ji, jj           ! dummy loop indices 
158      REAL(wp) ::   ztra             ! local scalar
159      REAL(wp) ::   zfp_ui, zfp_vj   !   -      -
160      REAL(wp) ::   zfm_ui, zfm_vj   !   -      -
161      REAL(wp), DIMENSION(jpi,jpj) ::   zfu_ups, zfu_ho, zt_u, zt_ups
162      REAL(wp), DIMENSION(jpi,jpj) ::   zfv_ups, zfv_ho, zt_v, ztrd
163      !!----------------------------------------------------------------------
164      !
165      IF( nn_timing == 1 )  CALL timing_start('ice_adv_umx')
166      !
167      !  upstream advection with initial mass fluxes & intermediate update
168      ! --------------------------------------------------------------------
169      DO jj = 1, jpjm1         ! upstream tracer flux in the i and j direction
170         DO ji = 1, fs_jpim1   ! vector opt.
171            zfp_ui = puc(ji,jj) + ABS( puc(ji,jj) )
172            zfm_ui = puc(ji,jj) - ABS( puc(ji,jj) )
173            zfp_vj = pvc(ji,jj) + ABS( pvc(ji,jj) )
174            zfm_vj = pvc(ji,jj) - ABS( pvc(ji,jj) )
175            zfu_ups(ji,jj) = 0.5_wp * ( zfp_ui * ptc(ji,jj) + zfm_ui * ptc(ji+1,jj  ) )
176            zfv_ups(ji,jj) = 0.5_wp * ( zfp_vj * ptc(ji,jj) + zfm_vj * ptc(ji  ,jj+1) )
177         END DO
178      END DO
179     
180      DO jj = 2, jpjm1            ! total intermediate advective trends
181         DO ji = fs_2, fs_jpim1   ! vector opt.
182            ztra = - (   zfu_ups(ji,jj) - zfu_ups(ji-1,jj  )   &
183               &       + zfv_ups(ji,jj) - zfv_ups(ji  ,jj-1)   ) * r1_e1e2t(ji,jj)
184            !
185            ztrd(ji,jj) =                         ztra                         ! upstream trend [ -div(uh) or -div(uhT) ] 
186            zt_ups (ji,jj) = ( ptc(ji,jj) + pdt * ztra ) * tmask(ji,jj,1)      ! guess after content field with monotonic scheme
187         END DO
188      END DO
189      CALL lbc_lnk( zt_ups, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
190     
191      ! High order (_ho) fluxes
192      ! -----------------------
193      SELECT CASE( k_order )
194      CASE ( 20 )                          ! centered second order
195         DO jj = 2, jpjm1
196            DO ji = fs_2, fs_jpim1   ! vector opt.
197               zfu_ho(ji,jj) = 0.5 * puc(ji,jj) * ( ptc(ji,jj) + ptc(ji+1,jj) )
198               zfv_ho(ji,jj) = 0.5 * pvc(ji,jj) * ( ptc(ji,jj) + ptc(ji,jj+1) )
199            END DO
200         END DO
201         !
202      CASE ( 1:5 )                      ! 1st to 5th order ULTIMATE-MACHO scheme
203         CALL macho( k_order, kt, pdt, ptc, puc, pvc, pubox, pvbox, zt_u, zt_v )
204         !
205         DO jj = 2, jpjm1
206            DO ji = fs_2, fs_jpim1   ! vector opt.
207               zfu_ho(ji,jj) = puc(ji,jj) * zt_u(ji,jj)
208               zfv_ho(ji,jj) = pvc(ji,jj) * zt_v(ji,jj)
209            END DO
210         END DO
211         !
212      END SELECT
213         
214      ! antidiffusive flux : high order minus low order
215      ! --------------------------------------------------
216      DO jj = 2, jpjm1
217         DO ji = fs_2, fs_jpim1   ! vector opt.
218            zfu_ho(ji,jj) = zfu_ho(ji,jj) - zfu_ups(ji,jj)
219            zfv_ho(ji,jj) = zfv_ho(ji,jj) - zfv_ups(ji,jj)
220         END DO
221      END DO
222      CALL lbc_lnk_multi( zfu_ho, 'U', -1., zfv_ho, 'V', -1. )         ! Lateral bondary conditions
223     
224      ! monotonicity algorithm
225      ! -------------------------
226      CALL nonosc_2d( ptc, zfu_ho, zfv_ho, zt_ups, pdt )
227     
228      ! final trend with corrected fluxes
229      ! ------------------------------------
230      DO jj = 2, jpjm1
231         DO ji = fs_2, fs_jpim1   ! vector opt. 
232            ztra       = ztrd(ji,jj)  - (  zfu_ho(ji,jj) - zfu_ho(ji-1,jj  )   &
233               &                         + zfv_ho(ji,jj) - zfv_ho(ji  ,jj-1) ) * r1_e1e2t(ji,jj) 
234            ptc(ji,jj) = ptc(ji,jj) + pdt * ztra
235         END DO
236      END DO
237      CALL lbc_lnk( ptc(:,:) , 'T',  1. )
238      !
239      IF( nn_timing == 1 )  CALL timing_stop('ice_adv_umx')
240      !
241   END SUBROUTINE adv_umx
242
243
244   SUBROUTINE macho( k_order, kt, pdt, ptc, puc, pvc, pubox, pvbox, pt_u, pt_v )
245      !!---------------------------------------------------------------------
246      !!                    ***  ROUTINE ultimate_x  ***
247      !!     
248      !! **  Purpose :   compute 
249      !!
250      !! **  Method  :   ... ???
251      !!                 TIM = transient interpolation Modeling
252      !!
253      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
254      !!----------------------------------------------------------------------
255      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the ULTIMATE scheme
256      INTEGER                     , INTENT(in   ) ::   kt         ! number of iteration
257      REAL(wp)                    , INTENT(in   ) ::   pdt        ! tracer time-step
258      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   ptc        ! tracer fields
259      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc, pvc   ! 2 ice velocity components
260      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
261      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_u, pt_v ! tracer at u- and v-points
262      !
263      INTEGER  ::   ji, jj    ! dummy loop indices
264      REAL(wp) ::   zc_box    !   -      -
265      REAL(wp), DIMENSION(jpi,jpj) :: zzt
266      !!----------------------------------------------------------------------
267      !
268      IF( nn_timing == 1 )  CALL timing_start('macho')
269      !
270      IF( MOD( (kt - 1) / nn_fsbc , 2 ) == 0 ) THEN         !==  odd ice time step:  adv_x then adv_y  ==!
271         !
272         !                                                           !--  ultimate interpolation of pt at u-point  --!
273         CALL ultimate_x( k_order, pdt, ptc, puc, pt_u )
274         !
275         !                                                           !--  advective form update in zzt  --!
276         DO jj = 2, jpjm1
277            DO ji = fs_2, fs_jpim1   ! vector opt.
278               zzt(ji,jj) = ptc(ji,jj) - pubox(ji,jj) * pdt * ( pt_u(ji,jj) - pt_u(ji-1,jj) ) * r1_e1t(ji,jj)  &
279                  &                    - ptc  (ji,jj) * pdt * ( puc (ji,jj) - puc (ji-1,jj) ) * r1_e1e2t(ji,jj)
280               zzt(ji,jj) = zzt(ji,jj) * tmask(ji,jj,1)
281            END DO
282         END DO
283         CALL lbc_lnk( zzt, 'T', 1. )
284         !
285         !                                                           !--  ultimate interpolation of pt at v-point  --!
286         CALL ultimate_y( k_order, pdt, zzt, pvc, pt_v )
287         !
288      ELSE                                                  !==  even ice time step:  adv_y then adv_x  ==!
289         !
290         !                                                           !--  ultimate interpolation of pt at v-point  --!
291         CALL ultimate_y( k_order, pdt, ptc, pvc, pt_v )
292         !
293         !                                                           !--  advective form update in zzt  --!
294         DO jj = 2, jpjm1
295            DO ji = fs_2, fs_jpim1
296               zzt(ji,jj) = ptc(ji,jj) - pvbox(ji,jj) * pdt * ( pt_v(ji,jj) - pt_v(ji,jj-1) ) * r1_e2t(ji,jj)  &
297                  &                    - ptc  (ji,jj) * pdt * ( pvc (ji,jj) - pvc (ji,jj-1) ) * r1_e1e2t(ji,jj)
298               zzt(ji,jj) = zzt(ji,jj) * tmask(ji,jj,1)
299            END DO
300         END DO
301         CALL lbc_lnk( zzt, 'T', 1. )
302         !
303         !                                                           !--  ultimate interpolation of pt at u-point  --!
304         CALL ultimate_x( k_order, pdt, zzt, puc, pt_u )
305         !     
306      ENDIF     
307      !
308      IF( nn_timing == 1 )  CALL timing_stop('macho')
309      !
310   END SUBROUTINE macho
311
312
313   SUBROUTINE ultimate_x( k_order, pdt, pt, puc, pt_u )
314      !!---------------------------------------------------------------------
315      !!                    ***  ROUTINE ultimate_x  ***
316      !!     
317      !! **  Purpose :   compute 
318      !!
319      !! **  Method  :   ... ???
320      !!                 TIM = transient interpolation Modeling
321      !!
322      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
323      !!----------------------------------------------------------------------
324      INTEGER                     , INTENT(in   ) ::   k_order   ! ocean time-step index
325      REAL(wp)                    , INTENT(in   ) ::   pdt       ! tracer time-step
326      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc       ! ice i-velocity component
327      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pt        ! tracer fields
328      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_u      ! tracer at u-point
329      !
330      INTEGER  ::   ji, jj       ! dummy loop indices
331      REAL(wp) ::   zcu, zdx2, zdx4    !   -      -
332      REAL(wp), DIMENSION(jpi,jpj) :: ztu1, ztu2, ztu3, ztu4
333      !!----------------------------------------------------------------------
334      !
335      IF( nn_timing == 1 )  CALL timing_start('ultimate_x')
336      !
337      !                                                     !--  Laplacian in i-direction  --!
338      DO jj = 2, jpjm1         ! First derivative (gradient)
339         DO ji = 1, fs_jpim1
340            ztu1(ji,jj) = ( pt(ji+1,jj) - pt(ji,jj) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
341         END DO
342         !                     ! Second derivative (Laplacian)
343         DO ji = fs_2, fs_jpim1
344            ztu2(ji,jj) = ( ztu1(ji,jj) - ztu1(ji-1,jj) ) * r1_e1t(ji,jj)
345         END DO
346      END DO
347      CALL lbc_lnk( ztu2, 'T', 1. )
348      !
349      !                                                     !--  BiLaplacian in i-direction  --!
350      DO jj = 2, jpjm1         ! Third derivative
351         DO ji = 1, fs_jpim1
352            ztu3(ji,jj) = ( ztu2(ji+1,jj) - ztu2(ji,jj) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
353         END DO
354         !                     ! Fourth derivative
355         DO ji = fs_2, fs_jpim1
356            ztu4(ji,jj) = ( ztu3(ji,jj) - ztu3(ji-1,jj) ) * r1_e1t(ji,jj)
357         END DO
358      END DO
359      CALL lbc_lnk( ztu4, 'T', 1. )
360      !
361      !
362      SELECT CASE (k_order )
363      !
364      CASE( 1 )                                                   !==  1st order central TIM  ==! (Eq. 21)
365         !       
366         DO jj = 1, jpj
367            DO ji = 1, fs_jpim1   ! vector opt.
368               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj) + pt(ji,jj)   &
369                  &                                    - SIGN( 1._wp, puc(ji,jj) ) * ( pt(ji+1,jj) - pt(ji,jj) ) )
370            END DO
371         END DO
372         !
373      CASE( 2 )                                                   !==  2nd order central TIM  ==! (Eq. 23)
374         !
375         DO jj = 1, jpj
376            DO ji = 1, fs_jpim1   ! vector opt.
377               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
378               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (                                   pt(ji+1,jj) + pt(ji,jj)   &
379                  &                                               -              zcu   * ( pt(ji+1,jj) - pt(ji,jj) ) ) 
380            END DO
381         END DO
382         CALL lbc_lnk( pt_u(:,:) , 'U',  1. )
383         ! 
384      CASE( 3 )                                                   !==  3rd order central TIM  ==! (Eq. 24)
385         !
386         DO jj = 1, jpj
387            DO ji = 1, fs_jpim1   ! vector opt.
388               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
389               zdx2 = e1u(ji,jj) * e1u(ji,jj)
390!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
391               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (         (                         pt  (ji+1,jj) + pt  (ji,jj)        &
392                  &                                               -              zcu   * ( pt  (ji+1,jj) - pt  (ji,jj) )  )   &
393                  &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                         ztu2(ji+1,jj) + ztu2(ji,jj)        &
394                  &                                               - SIGN( 1._wp, zcu ) * ( ztu2(ji+1,jj) - ztu2(ji,jj) )  )   )
395            END DO
396         END DO
397         !
398      CASE( 4 )                                                   !==  4th order central TIM  ==! (Eq. 27)
399         !
400         DO jj = 1, jpj
401            DO ji = 1, fs_jpim1   ! vector opt.
402               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
403               zdx2 = e1u(ji,jj) * e1u(ji,jj)
404!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
405               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (         (                   pt  (ji+1,jj) + pt  (ji,jj)        &
406                  &                                               -          zcu * ( pt  (ji+1,jj) - pt  (ji,jj) )  )   &
407                  &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                   ztu2(ji+1,jj) + ztu2(ji,jj)        &
408                  &                                               - 0.5_wp * zcu * ( ztu2(ji+1,jj) - ztu2(ji,jj) )  )   )
409            END DO
410         END DO
411         !
412      CASE( 5 )                                                   !==  5th order central TIM  ==! (Eq. 29)
413         !
414         DO jj = 1, jpj
415            DO ji = 1, fs_jpim1   ! vector opt.
416               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
417               zdx2 = e1u(ji,jj) * e1u(ji,jj)
418!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
419               zdx4 = zdx2 * zdx2
420               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (               (                   pt  (ji+1,jj) + pt  (ji,jj)       &
421                  &                                                     -          zcu * ( pt  (ji+1,jj) - pt  (ji,jj) ) )   &
422                  &        + z1_6   * zdx2 * ( zcu*zcu - 1._wp ) *     (                   ztu2(ji+1,jj) + ztu2(ji,jj)       &
423                  &                                                     - 0.5_wp * zcu * ( ztu2(ji+1,jj) - ztu2(ji,jj) ) )   &
424                  &        + z1_120 * zdx4 * ( zcu*zcu - 1._wp ) * ( zcu*zcu - 4._wp ) * ( ztu4(ji+1,jj) + ztu4(ji,jj)       &
425                  &                                               - SIGN( 1._wp, zcu ) * ( ztu4(ji+1,jj) - ztu4(ji,jj) ) ) )
426            END DO
427         END DO
428         !
429      END SELECT
430      !
431      IF( nn_timing == 1 )  CALL timing_stop('ultimate_x')
432      !
433   END SUBROUTINE ultimate_x
434   
435 
436   SUBROUTINE ultimate_y( k_order, pdt, pt, pvc, pt_v )
437      !!---------------------------------------------------------------------
438      !!                    ***  ROUTINE ultimate_y  ***
439      !!     
440      !! **  Purpose :   compute 
441      !!
442      !! **  Method  :   ... ???
443      !!                 TIM = transient interpolation Modeling
444      !!
445      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
446      !!----------------------------------------------------------------------
447      INTEGER                     , INTENT(in   ) ::   k_order   ! ocean time-step index
448      REAL(wp)                    , INTENT(in   ) ::   pdt       ! tracer time-step
449      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pvc       ! ice j-velocity component
450      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pt        ! tracer fields
451      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_v      ! tracer at v-point
452      !
453      INTEGER  ::   ji, jj       ! dummy loop indices
454      REAL(wp) ::   zcv, zdy2, zdy4    !   -      -
455      REAL(wp), DIMENSION(jpi,jpj) :: ztv1, ztv2, ztv3, ztv4
456      !!----------------------------------------------------------------------
457      !
458      IF( nn_timing == 1 )  CALL timing_start('ultimate_y')
459      !
460      !                                                     !--  Laplacian in j-direction  --!
461      DO jj = 1, jpjm1         ! First derivative (gradient)
462         DO ji = fs_2, fs_jpim1
463            ztv1(ji,jj) = ( pt(ji,jj+1) - pt(ji,jj) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
464         END DO
465      END DO
466      DO jj = 2, jpjm1         ! Second derivative (Laplacian)
467         DO ji = fs_2, fs_jpim1
468            ztv2(ji,jj) = ( ztv1(ji,jj) - ztv1(ji,jj-1) ) * r1_e2t(ji,jj)
469         END DO
470      END DO
471      CALL lbc_lnk( ztv2, 'T', 1. )
472      !
473      !                                                     !--  BiLaplacian in j-direction  --!
474      DO jj = 1, jpjm1         ! First derivative
475         DO ji = fs_2, fs_jpim1
476            ztv3(ji,jj) = ( ztv2(ji,jj+1) - ztv2(ji,jj) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
477         END DO
478      END DO
479      DO jj = 2, jpjm1         ! Second derivative
480         DO ji = fs_2, fs_jpim1
481            ztv4(ji,jj) = ( ztv3(ji,jj) - ztv3(ji,jj-1) ) * r1_e2t(ji,jj)
482         END DO
483      END DO
484      CALL lbc_lnk( ztv4, 'T', 1. )
485      !
486      !
487      SELECT CASE (k_order )
488      !
489      CASE( 1 )                                                !==  1st order central TIM  ==! (Eq. 21)
490         DO jj = 1, jpjm1
491            DO ji = 1, jpi
492               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt(ji,jj+1) + pt(ji,jj) )  &
493                  &                                     - SIGN( 1._wp, pvc(ji,jj) ) * ( pt(ji,jj+1) - pt(ji,jj) ) )
494            END DO
495         END DO
496         !
497      CASE( 2 )                                                !==  2nd order central TIM  ==! (Eq. 23)
498         DO jj = 1, jpjm1
499            DO ji = 1, jpi
500               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
501               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (        ( pt(ji,jj+1) + pt(ji,jj) )  &
502                  &                                     - zcv * ( pt(ji,jj+1) - pt(ji,jj) ) )
503            END DO
504         END DO
505         CALL lbc_lnk( pt_v(:,:) , 'V',  1. )
506         !
507      CASE( 3 )                                                !==  3rd order central TIM  ==! (Eq. 24)
508         DO jj = 1, jpjm1
509            DO ji = 1, jpi
510               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
511               zdy2 = e2v(ji,jj) * e2v(ji,jj)
512!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
513               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                                 ( pt  (ji,jj+1) + pt  (ji,jj)       &
514                  &                                     -                        zcv   * ( pt  (ji,jj+1) - pt  (ji,jj) ) )   &
515                  &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                         ztv2(ji,jj+1) + ztv2(ji,jj)       &
516                  &                                               - SIGN( 1._wp, zcv ) * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) ) )
517            END DO
518         END DO
519         !
520      CASE( 4 )                                                !==  4th order central TIM  ==! (Eq. 27)
521         DO jj = 1, jpjm1
522            DO ji = 1, jpi
523               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
524               zdy2 = e2v(ji,jj) * e2v(ji,jj)
525!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
526               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                           ( pt  (ji,jj+1) + pt  (ji,jj)       &
527                  &                                               -          zcv * ( pt  (ji,jj+1) - pt  (ji,jj) ) )   &
528                  &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                   ztv2(ji,jj+1) + ztv2(ji,jj)       &
529                  &                                               - 0.5_wp * zcv * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) ) )
530            END DO
531         END DO
532         !
533      CASE( 5 )                                                !==  5th order central TIM  ==! (Eq. 29)
534         DO jj = 1, jpjm1
535            DO ji = 1, jpi
536               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
537               zdy2 = e2v(ji,jj) * e2v(ji,jj)
538!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
539               zdy4 = zdy2 * zdy2
540               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                                 ( pt  (ji,jj+1) + pt  (ji,jj)      &
541                  &                                                     -          zcv * ( pt  (ji,jj+1) - pt  (ji,jj) ) )  &
542                  &        + z1_6   * zdy2 * ( zcv*zcv - 1._wp ) *     (                   ztv2(ji,jj+1) + ztv2(ji,jj)      &
543                  &                                                     - 0.5_wp * zcv * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) )  &
544                  &        + z1_120 * zdy4 * ( zcv*zcv - 1._wp ) * ( zcv*zcv - 4._wp ) * ( ztv4(ji,jj+1) + ztv4(ji,jj)      &
545                  &                                               - SIGN( 1._wp, zcv ) * ( ztv4(ji,jj+1) - ztv4(ji,jj) ) ) )
546            END DO
547         END DO
548         !
549      END SELECT
550      !
551      IF( nn_timing == 1 )  CALL timing_stop('ultimate_y')
552      !
553   END SUBROUTINE ultimate_y
554   
555 
556   SUBROUTINE nonosc_2d( pbef, paa, pbb, paft, pdt )
557      !!---------------------------------------------------------------------
558      !!                    ***  ROUTINE nonosc  ***
559      !!     
560      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
561      !!       scheme and the before field by a nonoscillatory algorithm
562      !!
563      !! **  Method  :   ... ???
564      !!       warning : pbef and paft must be masked, but the boundaries
565      !!       conditions on the fluxes are not necessary zalezak (1979)
566      !!       drange (1995) multi-dimensional forward-in-time and upstream-
567      !!       in-space based differencing for fluid
568      !!----------------------------------------------------------------------
569      REAL(wp)                     , INTENT(in   ) ::   pdt          ! tracer time-step
570      REAL(wp), DIMENSION (jpi,jpj), INTENT(in   ) ::   pbef, paft   ! before & after field
571      REAL(wp), DIMENSION (jpi,jpj), INTENT(inout) ::   paa, pbb     ! monotonic fluxes in the 2 directions
572      !
573      INTEGER  ::   ji, jj    ! dummy loop indices
574      INTEGER  ::   ikm1      ! local integer
575      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zsml, z1_dt   ! local scalars
576      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
577      REAL(wp), DIMENSION(jpi,jpj) :: zbetup, zbetdo, zbup, zbdo, zmsk, zdiv
578      !!----------------------------------------------------------------------
579      !
580      IF( nn_timing == 1 )  CALL timing_start('nonosc_2d')
581      !
582      zbig = 1.e+40_wp
583      zsml = 1.e-15_wp
584
585      ! clem test
586      DO jj = 2, jpjm1
587         DO ji = fs_2, fs_jpim1   ! vector opt. 
588            zdiv(ji,jj) =  - (  paa(ji,jj) - paa(ji-1,jj  )   &
589               &              + pbb(ji,jj) - pbb(ji  ,jj-1) ) 
590         END DO
591      END DO
592      CALL lbc_lnk( zdiv, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
593
594      ! Determine ice masks for before and after tracers
595      WHERE( pbef(:,:) == 0._wp .AND. paft(:,:) == 0._wp .AND. zdiv(:,:) == 0._wp )   ;   zmsk(:,:) = 0._wp
596      ELSEWHERE                                                                       ;   zmsk(:,:) = 1._wp * tmask(:,:,1)
597      END WHERE
598
599      ! Search local extrema
600      ! --------------------
601      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
602!      zbup(:,:) = MAX( pbef(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) ),   &
603!         &             paft(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) )  )
604!      zbdo(:,:) = MIN( pbef(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) ),   &
605!         &             paft(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) )  )
606      zbup(:,:) = MAX( pbef(:,:) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) ),   &
607         &             paft(:,:) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) )  )
608      zbdo(:,:) = MIN( pbef(:,:) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) ),   &
609         &             paft(:,:) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) )  )
610
611      z1_dt = 1._wp / pdt
612      DO jj = 2, jpjm1
613         DO ji = fs_2, fs_jpim1   ! vector opt.
614            !
615            zup  = MAX(   zbup(ji,jj), zbup(ji-1,jj  ), zbup(ji+1,jj  ),   &        ! search max/min in neighbourhood
616               &                       zbup(ji  ,jj-1), zbup(ji  ,jj+1)    )
617            zdo  = MIN(   zbdo(ji,jj), zbdo(ji-1,jj  ), zbdo(ji+1,jj  ),   &
618               &                       zbdo(ji  ,jj-1), zbdo(ji  ,jj+1)    )
619               !
620            zpos = MAX( 0., paa(ji-1,jj  ) ) - MIN( 0., paa(ji  ,jj  ) )   &        ! positive/negative  part of the flux
621               & + MAX( 0., pbb(ji  ,jj-1) ) - MIN( 0., pbb(ji  ,jj  ) )
622            zneg = MAX( 0., paa(ji  ,jj  ) ) - MIN( 0., paa(ji-1,jj  ) )   &
623               & + MAX( 0., pbb(ji  ,jj  ) ) - MIN( 0., pbb(ji  ,jj-1) )
624               !
625            zbt = e1e2t(ji,jj) * z1_dt                                   ! up & down beta terms
626            zbetup(ji,jj) = ( zup         - paft(ji,jj) ) / ( zpos + zsml ) * zbt
627            zbetdo(ji,jj) = ( paft(ji,jj) - zdo         ) / ( zneg + zsml ) * zbt
628         END DO
629      END DO
630      CALL lbc_lnk_multi( zbetup, 'T', 1., zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
631
632      ! monotonic flux in the i & j direction (paa & pbb)
633      ! -------------------------------------
634      DO jj = 2, jpjm1
635         DO ji = fs_2, fs_jpim1   ! vector opt.
636            zau = MIN( 1._wp , zbetdo(ji,jj) , zbetup(ji+1,jj) )
637            zbu = MIN( 1._wp , zbetup(ji,jj) , zbetdo(ji+1,jj) )
638            zcu = 0.5  + SIGN( 0.5 , paa(ji,jj) )
639            !
640            zav = MIN( 1._wp , zbetdo(ji,jj) , zbetup(ji,jj+1) )
641            zbv = MIN( 1._wp , zbetup(ji,jj) , zbetdo(ji,jj+1) )
642            zcv = 0.5  + SIGN( 0.5 , pbb(ji,jj) )
643            !
644            paa(ji,jj) = paa(ji,jj) * ( zcu * zau + ( 1._wp - zcu) * zbu )
645            pbb(ji,jj) = pbb(ji,jj) * ( zcv * zav + ( 1._wp - zcv) * zbv )
646            !
647         END DO
648      END DO
649      CALL lbc_lnk_multi( paa, 'U', -1., pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
650      !
651      IF( nn_timing == 1 )  CALL timing_stop('nonosc_2d')
652      !
653   END SUBROUTINE nonosc_2d
654
655#else
656   !!----------------------------------------------------------------------
657   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
658   !!----------------------------------------------------------------------
659#endif
660
661   !!======================================================================
662END MODULE iceadv_umx
Note: See TracBrowser for help on using the repository browser.