New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icedyn.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/icedyn.F90 @ 8518

Last change on this file since 8518 was 8518, checked in by clem, 7 years ago

changes in style - part6 - commits of the day
File size: 14.3 KB
RevLine 
[8516]1MODULE icedyn
2   !!======================================================================
3   !!                     ***  MODULE  icedyn  ***
4   !!   Sea-Ice dynamics : 
5   !!======================================================================
6   !! history :  4.0  ! 2017-09  (C. Rousset)  original code
7   !!----------------------------------------------------------------------
8#if defined key_lim3
9   !!----------------------------------------------------------------------
10   !!   'key_lim3'                                       LIM3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_dyn       : dynamics of sea ice
13   !!   ice_dyn_init  : initialisation of sea-ice dynamics
14   !!----------------------------------------------------------------------
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain
17   USE ice            ! sea-ice: variables
18   USE icerhg         ! sea-ice: rheology
19   USE iceadv         ! sea-ice: advection
20   USE icerdgrft      ! sea-ice: ridging/rafting
21   USE icecor         ! sea-ice: corrections
22   USE icevar         ! sea-ice: operations
23   !
24   USE lbclnk         ! lateral boundary conditions - MPP exchanges
25   USE lib_mpp        ! MPP library
26   USE in_out_manager ! I/O manager
27   USE lib_fortran    ! glob_sum
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   ice_dyn        ! called by icestp.F90
34   PUBLIC   ice_dyn_init   ! called by icestp.F90
35   
[8517]36   INTEGER ::              nice_dyn   ! choice of the type of dynamics
[8516]37   !                                        ! associated indices:
[8517]38   INTEGER, PARAMETER ::   np_dynFULL    = 1   ! full ice dynamics               (rheology + advection + ridging/rafting + correction)
39   INTEGER, PARAMETER ::   np_dynRHGADV1 = 2   ! no ridging/rafting              (rheology + advection                   + correction)
40   INTEGER, PARAMETER ::   np_dynRHGADV2 = 3   ! pure dynamics                   (rheology + advection)
41   INTEGER, PARAMETER ::   np_dynADV     = 4   ! only advection w prescribed vel.(rn_uvice + advection)
42   !
43   ! ** namelist (namdyn) **
[8518]44   LOGICAL  ::   ln_dynFULL       ! full ice dynamics               (rheology + advection + ridging/rafting + correction)
45   LOGICAL  ::   ln_dynRHGADV     ! no ridge/raft & no corrections  (rheology + advection)
46   LOGICAL  ::   ln_dynADV        ! only advection w prescribed vel.(rn_uvice + advection)
47   REAL(wp) ::   rn_uice          !    prescribed u-vel (case np_dynADV)
48   REAL(wp) ::   rn_vice          !    prescribed v-vel (case np_dynADV)
[8517]49   
[8516]50   !! * Substitutions
51#  include "vectopt_loop_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/ICE 4.0 , NEMO Consortium (2017)
54   !! $Id: icedyn.F90 8378 2017-07-26 13:55:59Z clem $
55   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE ice_dyn( kt )
60      !!-------------------------------------------------------------------
61      !!               ***  ROUTINE ice_dyn  ***
62      !!               
63      !! ** Purpose :   this routine manages sea ice dynamics
64      !!
65      !! ** Action : - Initialisation of some variables
66      !!             - call ice_rhg
67      !!--------------------------------------------------------------------
68      INTEGER, INTENT(in) ::   kt     ! ice time step
69      !!
[8517]70      INTEGER ::   ji, jj, jl         ! dummy loop indices
71      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zhmax
[8516]72      !!--------------------------------------------------------------------
73      !
74      IF( nn_timing == 1 )  CALL timing_start('icedyn')
75      !
76      IF( kt == nit000 .AND. lwp ) THEN
77         WRITE(numout,*)
78         WRITE(numout,*)'ice_dyn: sea-ice dynamics'
79         WRITE(numout,*)'~~~~~~~'
80      ENDIF
81
82      !                     
[8517]83      IF( ln_landfast ) THEN            !-- Landfast ice parameterization: define max bottom friction
[8516]84         tau_icebfr(:,:) = 0._wp
85         DO jl = 1, jpl
86            WHERE( ht_i(:,:,jl) > ht_n(:,:) * rn_gamma )   tau_icebfr(:,:) = tau_icebfr(:,:) + a_i(:,:,jl) * rn_icebfr
87         END DO
88      ENDIF
89
[8517]90      zhmax(:,:,:) = ht_i_b(:,:,:)      !-- Record max of the surrounding 9-pts ice thick. (for CALL Hbig)
91      DO jl = 1, jpl
92         DO jj = 2, jpjm1
93            DO ji = 2, jpim1
94!!gm use of MAXVAL here is very probably less efficient than expending the 9 values
95               zhmax(ji,jj,jl) = MAX( epsi20, MAXVAL( ht_i_b(ji-1:ji+1,jj-1:jj+1,jl) ) )
96            END DO
97         END DO
98      END DO
99      CALL lbc_lnk( zhmax(:,:,:), 'T', 1. )
100      !
101      !
102      SELECT CASE( nice_dyn )           !-- Set which dynamics is running
[8516]103
104      CASE ( np_dynFULL )          !==  all dynamical processes  ==!
[8517]105         CALL ice_rhg   ( kt )                            ! -- rheology 
106         CALL ice_adv   ( kt )   ;   CALL Hbig( zhmax )   ! -- advection of ice + correction on ice thickness
107         CALL ice_rdgrft( kt )                            ! -- ridging/rafting
108         CALL ice_cor   ( kt , 1 )                        ! -- Corrections
[8516]109
[8517]110      CASE ( np_dynRHGADV1 )       !==  no ridge/raft ==!   (mono cat. case 2)
111         CALL ice_rhg   ( kt )                            ! -- rheology 
112         CALL ice_adv   ( kt )                            ! -- advection of ice
113         CALL Hpiling                                     ! -- simple pile-up (replaces ridging/rafting)
114         CALL ice_cor   ( kt , 1 )                        ! -- Corrections
[8516]115
[8517]116      CASE ( np_dynRHGADV2 )       !==  no ridge/raft & no corrections ==!
117         CALL ice_rhg   ( kt )                            ! -- rheology 
118         CALL ice_adv   ( kt )                            ! -- advection of ice
119         CALL Hpiling                                     ! -- simple pile-up (replaces ridging/rafting)
[8516]120
[8517]121      CASE ( np_dynADV )           !==  pure advection ==!   (prescribed velocities)
[8516]122         u_ice(:,:) = rn_uice * umask(:,:,1)
123         v_ice(:,:) = rn_vice * vmask(:,:,1)
124         !!CALL RANDOM_NUMBER(u_ice(:,:))
125         !!CALL RANDOM_NUMBER(v_ice(:,:))
[8517]126         CALL ice_adv   ( kt )                            ! -- advection of ice
[8516]127
128      END SELECT
129      !
130      IF( nn_timing == 1 )   CALL timing_stop('icedyn')
131      !
132   END SUBROUTINE ice_dyn
133
[8517]134   SUBROUTINE Hbig( phmax )
135      !!-------------------------------------------------------------------
136      !!                  ***  ROUTINE Hbig  ***
137      !!
138      !! ** Purpose : Thickness correction in case advection scheme creates
139      !!              abnormally tick ice
140      !!
141      !! ** Method  : 1- check whether ice thickness resulting from advection is
142      !!                 larger than the surrounding 9-points before advection
143      !!                 and reduce it if a) divergence or b) convergence & at_i>0.8
144      !!              2- bound ice thickness with hi_max (99m)
145      !!
146      !! ** input   : Max thickness of the surrounding 9-points
147      !!-------------------------------------------------------------------
148      REAL(wp), DIMENSION(:,:,:), INTENT(in) ::   phmax   ! max ice thick from surrounding 9-pts
149      !
150      INTEGER  ::   ji, jj, jl         ! dummy loop indices
151      REAL(wp) ::   zh, zdv
152      !!-------------------------------------------------------------------
153      !
154      CALL ice_var_zapsmall                       !-- zap small areas
155      !
156      DO jl = 1, jpl
157         DO jj = 1, jpj
158            DO ji = 1, jpi
159               IF ( v_i(ji,jj,jl) > 0._wp ) THEN  !-- bound to hmax
160                  !
161                  zh  = v_i (ji,jj,jl) / a_i(ji,jj,jl)
162                  zdv = v_i(ji,jj,jl) - v_i_b(ji,jj,jl) 
163                  !
164                  IF ( ( zdv >  0.0 .AND. zh > phmax(ji,jj,jl) .AND. at_i_b(ji,jj) < 0.80 ) .OR. &
165                     & ( zdv <= 0.0 .AND. zh > phmax(ji,jj,jl) ) ) THEN
166                     a_i (ji,jj,jl) = v_i(ji,jj,jl) / MIN( phmax(ji,jj,jl), hi_max(jpl) )   !-- bound ht_i to hi_max (99 m)
167                  ENDIF
168                  !
169               ENDIF
170            END DO
171         END DO
172      END DO
173           
174      IF ( nn_pnd_scheme > 0 ) THEN               !-- correct pond fraction to avoid a_ip > a_i
175         WHERE( a_ip(:,:,:) > a_i(:,:,:) )   a_ip(:,:,:) = a_i(:,:,:)
176      ENDIF
177      !
178   END SUBROUTINE Hbig
[8516]179
[8517]180   SUBROUTINE Hpiling
181      !!-------------------------------------------------------------------
182      !!                  ***  ROUTINE Hpiling  ***
183      !!
184      !! ** Purpose : Simple conservative piling comparable with 1-cat models
185      !!
186      !! ** Method  : pile-up ice when no ridging/rafting
187      !!
188      !! ** input   : a_i
189      !!-------------------------------------------------------------------
190      INTEGER ::   jl         ! dummy loop indices
191      !!-------------------------------------------------------------------
192      !
193      CALL ice_var_zapsmall                       !-- zap small areas
194      !
195      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
196      DO jl = 1, jpl
197         WHERE( at_i(:,:) > epsi20 )
198            a_i(:,:,jl) = a_i(:,:,jl) * (  1._wp + MIN( rn_amax_2d(:,:) - at_i(:,:) , 0._wp ) / at_i(:,:)  )
199         END WHERE
200      END DO
201      !
202   END SUBROUTINE Hpiling
203
[8516]204   SUBROUTINE ice_dyn_init
205      !!-------------------------------------------------------------------
206      !!                  ***  ROUTINE ice_dyn_init  ***
207      !!
208      !! ** Purpose : Physical constants and parameters linked to the ice
209      !!      dynamics
210      !!
211      !! ** Method  :  Read the namice_dyn namelist and check the ice-dynamic
212      !!       parameter values called at the first timestep (nit000)
213      !!
214      !! ** input   :   Namelist namice_dyn
215      !!-------------------------------------------------------------------
[8517]216      INTEGER ::   ios, ioptio   ! Local integer output status for namelist read
[8516]217      !!
[8517]218      NAMELIST/namice_dyn/ ln_dynFULL, ln_dynRHGADV, ln_dynADV, rn_uice, rn_vice,  &
[8516]219         &                 rn_ishlat  , rn_cio   ,                         &
220         &                 ln_landfast, rn_gamma , rn_icebfr, rn_lfrelax
221      !!-------------------------------------------------------------------
222      !
223      REWIND( numnam_ice_ref )         ! Namelist namice_dyn in reference namelist : Ice dynamics
224      READ  ( numnam_ice_ref, namice_dyn, IOSTAT = ios, ERR = 901)
225901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namice_dyn in reference namelist', lwp )
226      !
227      REWIND( numnam_ice_cfg )         ! Namelist namice_dyn in configuration namelist : Ice dynamics
228      READ  ( numnam_ice_cfg, namice_dyn, IOSTAT = ios, ERR = 902 )
229902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namice_dyn in configuration namelist', lwp )
230      IF(lwm) WRITE ( numoni, namice_dyn )
231      !
232      IF(lwp) THEN                     ! control print
233         WRITE(numout,*)
234         WRITE(numout,*) 'ice_dyn_init: ice parameters for ice dynamics '
235         WRITE(numout,*) '~~~~~~~~~~~~'
236         WRITE(numout,*) '   Namelist namice_dyn'
[8517]237         WRITE(numout,*) '      Full ice dynamics      (rhg + adv + ridge/raft + corr)  ln_dynFULL   = ', ln_dynFULL
238         WRITE(numout,*) '      No ridge/raft & No cor (rhg + adv)                      ln_dynRHGADV = ', ln_dynRHGADV
239         WRITE(numout,*) '      Advection only         (rn_uvice + adv)                 ln_dynADV    = ', ln_dynADV
240         WRITE(numout,*) '           with prescribed velocity given by '
[8516]241         WRITE(numout,*) '               a uniform field               (u,v)_ice = (rn_uice,rn_vice) = (', rn_uice,',', rn_vice,')'
242         WRITE(numout,*) '      lateral boundary condition for sea ice dynamics        rn_ishlat     = ', rn_ishlat
243         WRITE(numout,*) '      drag coefficient for oceanic stress                    rn_cio        = ', rn_cio
244         WRITE(numout,*) '      Landfast: param (T or F)                               ln_landfast   = ', ln_landfast
245         WRITE(numout,*) '         fraction of ocean depth that ice must reach         rn_gamma      = ', rn_gamma
246         WRITE(numout,*) '         maximum bottom stress per unit area of contact      rn_icebfr     = ', rn_icebfr
247         WRITE(numout,*) '         relax time scale (s-1) to reach static friction     rn_lfrelax    = ', rn_lfrelax
248      ENDIF
249      !                             !== set the choice of ice dynamics ==!
[8517]250      ioptio = 0 
251      !      !--- full dynamics                               (rheology + advection + ridging/rafting + correction)
252      IF( ln_dynFULL .AND. nn_monocat /= 2 ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynFULL      ;   ENDIF
253      !      !--- dynamics without ridging/rafting            (rheology + advection                   + correction)
254      IF( ln_dynFULL .AND. nn_monocat == 2 ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynRHGADV1   ;   ENDIF
255      !      !--- dynamics without ridging/rafting and corr   (rheology + advection)
256      IF( ln_dynRHGADV                     ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynRHGADV2   ;   ENDIF
257      !      !--- advection only with prescribed ice velocities (from namelist)
258      IF( ln_dynADV                        ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynADV       ;   ENDIF
[8516]259      !
[8517]260      IF( ioptio /= 1 )    CALL ctl_stop( 'ice_dyn_init: one and only one ice dynamics option has to be defined ' )
261      !
[8516]262      !                                      !--- Lateral boundary conditions
263      IF     (      rn_ishlat == 0.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  free-slip'
264      ELSEIF (      rn_ishlat == 2.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  no-slip'
265      ELSEIF ( 0. < rn_ishlat .AND. rn_ishlat < 2. ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  partial-slip'
266      ELSEIF ( 2. < rn_ishlat                      ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  strong-slip'
267      ENDIF
268      !                                      !--- NO Landfast ice : set to zero once for all
269      IF( .NOT. ln_landfast )   tau_icebfr(:,:) = 0._wp 
270      !
271   END SUBROUTINE ice_dyn_init
272
273#else
274   !!----------------------------------------------------------------------
275   !!   Default option         Empty module          NO LIM-3 sea-ice model
276   !!----------------------------------------------------------------------
277#endif 
278
279   !!======================================================================
280END MODULE icedyn
Note: See TracBrowser for help on using the repository browser.