New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icedyn.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/icedyn.F90 @ 8563

Last change on this file since 8563 was 8563, checked in by clem, 7 years ago

change variable names (ht_s => h_s & ht_i => h_i)

File size: 14.6 KB
Line 
1MODULE icedyn
2   !!======================================================================
3   !!                     ***  MODULE  icedyn  ***
4   !!   Sea-Ice dynamics : master routine for sea ice dynamics
5   !!======================================================================
6   !! history :  4.0  ! 2017-09  (C. Rousset)  original code
7   !!----------------------------------------------------------------------
8#if defined key_lim3
9   !!----------------------------------------------------------------------
10   !!   'key_lim3'                                       ESIM sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_dyn       : dynamics of sea ice
13   !!   ice_dyn_init  : initialization and namelist read
14   !!----------------------------------------------------------------------
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain
17   USE ice            ! sea-ice: variables
18   USE icedyn_rhg     ! sea-ice: rheology
19   USE icedyn_adv     ! sea-ice: advection
20   USE icedyn_rdgrft  ! sea-ice: ridging/rafting
21   USE icecor         ! sea-ice: corrections
22   USE icevar         ! sea-ice: operations
23   !
24   USE in_out_manager ! I/O manager
25   USE iom            ! I/O manager library
26   USE lib_mpp        ! MPP library
27   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
28   USE lbclnk         ! lateral boundary conditions (or mpp links)
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   ice_dyn        ! called by icestp.F90
35   PUBLIC   ice_dyn_init   ! called by icestp.F90
36   
37   INTEGER ::              nice_dyn   ! choice of the type of dynamics
38   !                                        ! associated indices:
39   INTEGER, PARAMETER ::   np_dynFULL    = 1   ! full ice dynamics               (rheology + advection + ridging/rafting + correction)
40   INTEGER, PARAMETER ::   np_dynRHGADV1 = 2   ! no ridging/rafting              (rheology + advection                   + correction)
41   INTEGER, PARAMETER ::   np_dynRHGADV2 = 3   ! pure dynamics                   (rheology + advection)
42   INTEGER, PARAMETER ::   np_dynADV     = 4   ! only advection w prescribed vel.(rn_uvice + advection)
43   !
44   ! ** namelist (namdyn) **
45   LOGICAL  ::   ln_dynFULL       ! full ice dynamics               (rheology + advection + ridging/rafting + correction)
46   LOGICAL  ::   ln_dynRHGADV     ! no ridge/raft & no corrections  (rheology + advection)
47   LOGICAL  ::   ln_dynADV        ! only advection w prescribed vel.(rn_uvice + advection)
48   REAL(wp) ::   rn_uice          !    prescribed u-vel (case np_dynADV)
49   REAL(wp) ::   rn_vice          !    prescribed v-vel (case np_dynADV)
50   
51   !! * Substitutions
52#  include "vectopt_loop_substitute.h90"
53   !!----------------------------------------------------------------------
54   !! NEMO/ICE 4.0 , NEMO Consortium (2017)
55   !! $Id: icedyn.F90 8378 2017-07-26 13:55:59Z clem $
56   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60   SUBROUTINE ice_dyn( kt )
61      !!-------------------------------------------------------------------
62      !!               ***  ROUTINE ice_dyn  ***
63      !!               
64      !! ** Purpose :   this routine manages sea ice dynamics
65      !!
66      !! ** Action : - Initialisation of some variables
67      !!             - call ice_rhg
68      !!--------------------------------------------------------------------
69      INTEGER, INTENT(in) ::   kt     ! ice time step
70      !!
71      INTEGER ::   ji, jj, jl         ! dummy loop indices
72      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zhmax
73      !!--------------------------------------------------------------------
74      !
75      IF( nn_timing == 1 )   CALL timing_start('icedyn')
76      !
77      IF( kt == nit000 .AND. lwp ) THEN
78         WRITE(numout,*)
79         WRITE(numout,*)'ice_dyn: sea-ice dynamics'
80         WRITE(numout,*)'~~~~~~~'
81      ENDIF
82
83      !                     
84      IF( ln_landfast ) THEN            !-- Landfast ice parameterization: define max bottom friction
85         tau_icebfr(:,:) = 0._wp
86         DO jl = 1, jpl
87            WHERE( h_i(:,:,jl) > ht_n(:,:) * rn_gamma )   tau_icebfr(:,:) = tau_icebfr(:,:) + a_i(:,:,jl) * rn_icebfr
88         END DO
89         IF( iom_use('tau_icebfr') )   CALL iom_put( 'tau_icebfr', tau_icebfr ) 
90      ENDIF
91
92      zhmax(:,:,:) = h_i_b(:,:,:)      !-- Record max of the surrounding 9-pts ice thick. (for CALL Hbig)
93      DO jl = 1, jpl
94         DO jj = 2, jpjm1
95            DO ji = 2, jpim1
96!!gm use of MAXVAL here is very probably less efficient than expending the 9 values
97               zhmax(ji,jj,jl) = MAX( epsi20, MAXVAL( h_i_b(ji-1:ji+1,jj-1:jj+1,jl) ) )
98            END DO
99         END DO
100      END DO
101      CALL lbc_lnk( zhmax(:,:,:), 'T', 1. )
102      !
103      !
104      SELECT CASE( nice_dyn )           !-- Set which dynamics is running
105
106      CASE ( np_dynFULL )          !==  all dynamical processes  ==!
107         CALL ice_dyn_rhg   ( kt )                            ! -- rheology 
108         CALL ice_dyn_adv   ( kt )   ;   CALL Hbig( zhmax )   ! -- advection of ice + correction on ice thickness
109         CALL ice_dyn_rdgrft( kt )                            ! -- ridging/rafting
110         CALL ice_cor       ( kt , 1 )                        ! -- Corrections
111
112      CASE ( np_dynRHGADV1 )       !==  no ridge/raft ==!   (mono cat. case 2)
113         CALL ice_dyn_rhg   ( kt )                            ! -- rheology 
114         CALL ice_dyn_adv   ( kt )                            ! -- advection of ice
115         CALL Hpiling                                         ! -- simple pile-up (replaces ridging/rafting)
116         CALL ice_cor       ( kt , 1 )                        ! -- Corrections
117
118      CASE ( np_dynRHGADV2 )       !==  no ridge/raft & no corrections ==!
119         CALL ice_dyn_rhg   ( kt )                            ! -- rheology 
120         CALL ice_dyn_adv   ( kt )                            ! -- advection of ice
121         CALL Hpiling                                         ! -- simple pile-up (replaces ridging/rafting)
122
123      CASE ( np_dynADV )           !==  pure advection ==!   (prescribed velocities)
124         u_ice(:,:) = rn_uice * umask(:,:,1)
125         v_ice(:,:) = rn_vice * vmask(:,:,1)
126         !!CALL RANDOM_NUMBER(u_ice(:,:))
127         !!CALL RANDOM_NUMBER(v_ice(:,:))
128         CALL ice_dyn_adv   ( kt )                            ! -- advection of ice
129
130      END SELECT
131      !
132      IF( nn_timing == 1 )   CALL timing_stop('icedyn')
133      !
134   END SUBROUTINE ice_dyn
135
136   SUBROUTINE Hbig( phmax )
137      !!-------------------------------------------------------------------
138      !!                  ***  ROUTINE Hbig  ***
139      !!
140      !! ** Purpose : Thickness correction in case advection scheme creates
141      !!              abnormally tick ice
142      !!
143      !! ** Method  : 1- check whether ice thickness resulting from advection is
144      !!                 larger than the surrounding 9-points before advection
145      !!                 and reduce it if a) divergence or b) convergence & at_i>0.8
146      !!              2- bound ice thickness with hi_max (99m)
147      !!
148      !! ** input   : Max thickness of the surrounding 9-points
149      !!-------------------------------------------------------------------
150      REAL(wp), DIMENSION(:,:,:), INTENT(in) ::   phmax   ! max ice thick from surrounding 9-pts
151      !
152      INTEGER  ::   ji, jj, jl         ! dummy loop indices
153      REAL(wp) ::   zh, zdv
154      !!-------------------------------------------------------------------
155      !
156      CALL ice_var_zapsmall                       !-- zap small areas
157      !
158      DO jl = 1, jpl
159         DO jj = 1, jpj
160            DO ji = 1, jpi
161               IF ( v_i(ji,jj,jl) > 0._wp ) THEN  !-- bound to hmax
162                  !
163                  zh  = v_i (ji,jj,jl) / a_i(ji,jj,jl)
164                  zdv = v_i(ji,jj,jl) - v_i_b(ji,jj,jl) 
165                  !
166                  IF ( ( zdv >  0.0 .AND. zh > phmax(ji,jj,jl) .AND. at_i_b(ji,jj) < 0.80 ) .OR. &
167                     & ( zdv <= 0.0 .AND. zh > phmax(ji,jj,jl) ) ) THEN
168                     a_i (ji,jj,jl) = v_i(ji,jj,jl) / MIN( phmax(ji,jj,jl), hi_max(jpl) )   !-- bound h_i to hi_max (99 m)
169                  ENDIF
170                  !
171               ENDIF
172            END DO
173         END DO
174      END DO
175           
176      IF ( nn_pnd_scheme > 0 ) THEN               !-- correct pond fraction to avoid a_ip > a_i
177         WHERE( a_ip(:,:,:) > a_i(:,:,:) )   a_ip(:,:,:) = a_i(:,:,:)
178      ENDIF
179      !
180   END SUBROUTINE Hbig
181
182   SUBROUTINE Hpiling
183      !!-------------------------------------------------------------------
184      !!                  ***  ROUTINE Hpiling  ***
185      !!
186      !! ** Purpose : Simple conservative piling comparable with 1-cat models
187      !!
188      !! ** Method  : pile-up ice when no ridging/rafting
189      !!
190      !! ** input   : a_i
191      !!-------------------------------------------------------------------
192      INTEGER ::   jl         ! dummy loop indices
193      !!-------------------------------------------------------------------
194      !
195      CALL ice_var_zapsmall                       !-- zap small areas
196      !
197      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
198      DO jl = 1, jpl
199         WHERE( at_i(:,:) > epsi20 )
200            a_i(:,:,jl) = a_i(:,:,jl) * (  1._wp + MIN( rn_amax_2d(:,:) - at_i(:,:) , 0._wp ) / at_i(:,:)  )
201         END WHERE
202      END DO
203      !
204   END SUBROUTINE Hpiling
205
206   SUBROUTINE ice_dyn_init
207      !!-------------------------------------------------------------------
208      !!                  ***  ROUTINE ice_dyn_init  ***
209      !!
210      !! ** Purpose : Physical constants and parameters linked to the ice
211      !!      dynamics
212      !!
213      !! ** Method  :  Read the namdyn namelist and check the ice-dynamic
214      !!       parameter values called at the first timestep (nit000)
215      !!
216      !! ** input   :   Namelist namdyn
217      !!-------------------------------------------------------------------
218      INTEGER ::   ios, ioptio   ! Local integer output status for namelist read
219      !!
220      NAMELIST/namdyn/ ln_dynFULL, ln_dynRHGADV, ln_dynADV, rn_uice, rn_vice,  &
221         &             rn_ishlat  ,                                            &
222         &             ln_landfast, rn_gamma , rn_icebfr, rn_lfrelax
223      !!-------------------------------------------------------------------
224      !
225      REWIND( numnam_ice_ref )         ! Namelist namdyn in reference namelist : Ice dynamics
226      READ  ( numnam_ice_ref, namdyn, IOSTAT = ios, ERR = 901)
227901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn in reference namelist', lwp )
228      !
229      REWIND( numnam_ice_cfg )         ! Namelist namdyn in configuration namelist : Ice dynamics
230      READ  ( numnam_ice_cfg, namdyn, IOSTAT = ios, ERR = 902 )
231902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn in configuration namelist', lwp )
232      IF(lwm) WRITE ( numoni, namdyn )
233      !
234      IF(lwp) THEN                     ! control print
235         WRITE(numout,*)
236         WRITE(numout,*) 'ice_dyn_init: ice parameters for ice dynamics '
237         WRITE(numout,*) '~~~~~~~~~~~~'
238         WRITE(numout,*) '   Namelist namdyn:'
239         WRITE(numout,*) '      Full ice dynamics      (rhg + adv + ridge/raft + corr)  ln_dynFULL   = ', ln_dynFULL
240         WRITE(numout,*) '      No ridge/raft & No cor (rhg + adv)                      ln_dynRHGADV = ', ln_dynRHGADV
241         WRITE(numout,*) '      Advection only         (rn_uvice + adv)                 ln_dynADV    = ', ln_dynADV
242         WRITE(numout,*) '           with prescribed velocity given by '
243         WRITE(numout,*) '               a uniform field               (u,v)_ice = (rn_uice,rn_vice) = (', rn_uice,',', rn_vice,')'
244         WRITE(numout,*) '      lateral boundary condition for sea ice dynamics         rn_ishlat    = ', rn_ishlat
245         WRITE(numout,*) '      Landfast: param (T or F)                                ln_landfast  = ', ln_landfast
246         WRITE(numout,*) '         fraction of ocean depth that ice must reach          rn_gamma     = ', rn_gamma
247         WRITE(numout,*) '         maximum bottom stress per unit area of contact       rn_icebfr    = ', rn_icebfr
248         WRITE(numout,*) '         relax time scale (s-1) to reach static friction      rn_lfrelax   = ', rn_lfrelax
249      ENDIF
250      !                             !== set the choice of ice dynamics ==!
251      ioptio = 0 
252      !      !--- full dynamics                               (rheology + advection + ridging/rafting + correction)
253      IF( ln_dynFULL .AND. nn_monocat /= 2 ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynFULL      ;   ENDIF
254      !      !--- dynamics without ridging/rafting            (rheology + advection                   + correction)
255      IF( ln_dynFULL .AND. nn_monocat == 2 ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynRHGADV1   ;   ENDIF
256      !      !--- dynamics without ridging/rafting and corr   (rheology + advection)
257      IF( ln_dynRHGADV                     ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynRHGADV2   ;   ENDIF
258      !      !--- advection only with prescribed ice velocities (from namelist)
259      IF( ln_dynADV                        ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynADV       ;   ENDIF
260      !
261      IF( ioptio /= 1 )    CALL ctl_stop( 'ice_dyn_init: one and only one ice dynamics option has to be defined ' )
262      !
263      !                                      !--- Lateral boundary conditions
264      IF     (      rn_ishlat == 0.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  free-slip'
265      ELSEIF (      rn_ishlat == 2.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  no-slip'
266      ELSEIF ( 0. < rn_ishlat .AND. rn_ishlat < 2. ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  partial-slip'
267      ELSEIF ( 2. < rn_ishlat                      ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  strong-slip'
268      ENDIF
269      !                                      !--- NO Landfast ice : set to zero once for all
270      IF( .NOT. ln_landfast )   tau_icebfr(:,:) = 0._wp
271      !
272      CALL ice_dyn_rdgrft_init          ! set ice ridging/rafting parameters
273      CALL ice_dyn_rhg_init             ! set ice rheology parameters
274      CALL ice_dyn_adv_init             ! set ice advection parameters
275      !
276   END SUBROUTINE ice_dyn_init
277
278#else
279   !!----------------------------------------------------------------------
280   !!   Default option         Empty module           NO ESIM sea-ice model
281   !!----------------------------------------------------------------------
282#endif 
283
284   !!======================================================================
285END MODULE icedyn
Note: See TracBrowser for help on using the repository browser.