source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/icedyn_adv_umx.F90 @ 8554

Last change on this file since 8554 was 8534, checked in by clem, 3 years ago

changes in style - part6 - pure cosmetics

File size: 34.0 KB
Line 
1MODULE icedyn_adv_umx
2   !!==============================================================================
3   !!                       ***  MODULE  icedyn_adv_umx  ***
4   !! sea-ice : advection using the ULTIMATE-MACHO scheme
5   !!==============================================================================
6   !! History :  3.6  !  2014-11  (C. Rousset, G. Madec)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_lim3
9   !!----------------------------------------------------------------------
10   !!   'key_lim3'                                       ESIM sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_dyn_adv_umx   : update the tracer trend with the 3D advection trends using a TVD scheme
13   !!   ultimate_x(_y)    : compute a tracer value at velocity points using ULTIMATE scheme at various orders
14   !!   macho             : ???
15   !!   nonosc_2d         : compute monotonic tracer fluxes by a non-oscillatory algorithm
16   !!----------------------------------------------------------------------
17   USE phycst         ! physical constant
18   USE dom_oce        ! ocean domain
19   USE sbc_oce , ONLY : nn_fsbc   ! update frequency of surface boundary condition
20   USE ice            ! sea-ice variables
21   !
22   USE in_out_manager ! I/O manager
23   USE lib_mpp        ! MPP library
24   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
25   USE lbclnk         ! lateral boundary conditions (or mpp links)
26   USE timing         ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ice_dyn_adv_umx   ! called by icedyn_adv.F90
32     
33   REAL(wp) ::   z1_6   = 1._wp /   6._wp   ! =1/6
34   REAL(wp) ::   z1_120 = 1._wp / 120._wp   ! =1/120
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/ICE 4.0 , NEMO Consortium (2017)
40   !! $Id: icedyn_adv_umx.F90 4499 2014-02-18 15:14:31Z timgraham $
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ice_dyn_adv_umx( k_order, kt, pu_ice, pv_ice,  &
46      &                    pato_i, pv_i, pv_s, psmv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_dyn_adv_umx  ***
49      !!
50      !! **  Purpose :   Compute the now trend due to total advection of
51      !!                 tracers and add it to the general trend of tracer equations
52      !!                 using an "Ultimate-Macho" scheme
53      !!
54      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
55      !!----------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the scheme (1-5 or 20)
57      INTEGER                     , INTENT(in   ) ::   kt         ! time step
58      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pu_ice     ! ice i-velocity
59      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pv_ice     ! ice j-velocity
60      REAL(wp), DIMENSION(:,:)    , INTENT(inout) ::   pato_i     ! open water area
61      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_i       ! ice volume
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_s       ! snw volume
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   psmv_i     ! salt content
64      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   poa_i      ! age content
65      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_i       ! ice concentration
66      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_ip      ! melt pond fraction
67      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_ip      ! melt pond volume
68      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_s       ! snw heat content
69      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_i       ! ice heat content
70      !
71      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
72      INTEGER  ::   initad                  ! number of sub-timestep for the advection
73      REAL(wp) ::   zcfl , zusnit, zdt      !   -      -
74      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zudy, zvdx, zcu_box, zcv_box
75      !!----------------------------------------------------------------------
76      !
77      IF( kt == nit000 .AND. lwp )   WRITE(numout,*) '-- ice_dyn_adv_umx: Ultimate-Macho advection scheme'
78      !
79      ALLOCATE( zudy(jpi,jpj) , zvdx(jpi,jpj) , zcu_box(jpi,jpj) , zcv_box(jpi,jpj) )
80      !
81      ! --- If ice drift field is too fast, use an appropriate time step for advection (CFL test for stability) --- !       
82      zcfl  =            MAXVAL( ABS( pu_ice(:,:) ) * rdt_ice * r1_e1u(:,:) )
83      zcfl  = MAX( zcfl, MAXVAL( ABS( pv_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) )
84      IF( lk_mpp )   CALL mpp_max( zcfl )
85
86      IF( zcfl > 0.5 ) THEN   ;   initad = 2   ;   zusnit = 0.5_wp
87      ELSE                    ;   initad = 1   ;   zusnit = 1.0_wp
88      ENDIF
89
90      zdt = rdt_ice / REAL(initad)
91
92      ! --- transport --- !
93      zudy(:,:) = pu_ice(:,:) * e2u(:,:)
94      zvdx(:,:) = pv_ice(:,:) * e1v(:,:)
95
96      ! --- define velocity for advection: u*grad(H) --- !
97      DO jj = 2, jpjm1
98         DO ji = fs_2, fs_jpim1
99            IF    ( pu_ice(ji,jj) * pu_ice(ji-1,jj) <= 0._wp ) THEN   ;   zcu_box(ji,jj) = 0._wp
100            ELSEIF( pu_ice(ji,jj)                   >  0._wp ) THEN   ;   zcu_box(ji,jj) = pu_ice(ji-1,jj)
101            ELSE                                                      ;   zcu_box(ji,jj) = pu_ice(ji  ,jj)
102            ENDIF
103
104            IF    ( pv_ice(ji,jj) * pv_ice(ji,jj-1) <= 0._wp ) THEN   ;   zcv_box(ji,jj) = 0._wp
105            ELSEIF( pv_ice(ji,jj)                   >  0._wp ) THEN   ;   zcv_box(ji,jj) = pv_ice(ji,jj-1)
106            ELSE                                                      ;   zcv_box(ji,jj) = pv_ice(ji,jj  )
107            ENDIF
108         END DO
109      END DO
110
111      !---------------!
112      !== advection ==!
113      !---------------!
114      DO jt = 1, initad
115         CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pato_i(:,:) )             ! Open water area
116         DO jl = 1, jpl
117            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pa_i(:,:,jl) )         ! Ice area
118            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_i(:,:,jl) )         ! Ice  volume
119            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, psmv_i(:,:,jl) )       ! Salt content
120            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, poa_i (:,:,jl) )       ! Age content
121            DO jk = 1, nlay_i
122               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pe_i(:,:,jk,jl) )   ! Ice  heat content
123            END DO
124            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_s(:,:,jl) )         ! Snow volume
125            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pe_s(:,:,1,jl) )       ! Snow heat content
126            IF ( nn_pnd_scheme > 0 ) THEN
127               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pa_ip(:,:,jl) )     ! Melt pond fraction
128               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_ip(:,:,jl) )     ! Melt pond volume
129            ENDIF
130         END DO
131      END DO
132      !
133      DEALLOCATE( zudy, zvdx, zcu_box, zcv_box )
134      !
135   END SUBROUTINE ice_dyn_adv_umx
136   
137   SUBROUTINE adv_umx( k_order, kt, pdt, puc, pvc, pubox, pvbox, ptc )
138      !!----------------------------------------------------------------------
139      !!                  ***  ROUTINE adv_umx  ***
140      !!
141      !! **  Purpose :   Compute the now trend due to total advection of
142      !!       tracers and add it to the general trend of tracer equations
143      !!
144      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
145      !!       corrected flux (monotonic correction)
146      !!       note: - this advection scheme needs a leap-frog time scheme
147      !!
148      !! ** Action : - pt  the after advective tracer
149      !!----------------------------------------------------------------------
150      INTEGER                     , INTENT(in   ) ::   k_order        ! order of the ULTIMATE scheme
151      INTEGER                     , INTENT(in   ) ::   kt             ! number of iteration
152      REAL(wp)                    , INTENT(in   ) ::   pdt            ! tracer time-step
153      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc  , pvc     ! 2 ice velocity components => u*e2
154      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
155      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   ptc            ! tracer content field
156      !
157      INTEGER  ::   ji, jj           ! dummy loop indices 
158      REAL(wp) ::   ztra             ! local scalar
159      REAL(wp) ::   zfp_ui, zfp_vj   !   -      -
160      REAL(wp) ::   zfm_ui, zfm_vj   !   -      -
161      REAL(wp), DIMENSION(jpi,jpj) ::   zfu_ups, zfu_ho, zt_u, zt_ups
162      REAL(wp), DIMENSION(jpi,jpj) ::   zfv_ups, zfv_ho, zt_v, ztrd
163      !!----------------------------------------------------------------------
164      !
165      !  upstream advection with initial mass fluxes & intermediate update
166      ! --------------------------------------------------------------------
167      DO jj = 1, jpjm1         ! upstream tracer flux in the i and j direction
168         DO ji = 1, fs_jpim1   ! vector opt.
169            zfp_ui = puc(ji,jj) + ABS( puc(ji,jj) )
170            zfm_ui = puc(ji,jj) - ABS( puc(ji,jj) )
171            zfp_vj = pvc(ji,jj) + ABS( pvc(ji,jj) )
172            zfm_vj = pvc(ji,jj) - ABS( pvc(ji,jj) )
173            zfu_ups(ji,jj) = 0.5_wp * ( zfp_ui * ptc(ji,jj) + zfm_ui * ptc(ji+1,jj  ) )
174            zfv_ups(ji,jj) = 0.5_wp * ( zfp_vj * ptc(ji,jj) + zfm_vj * ptc(ji  ,jj+1) )
175         END DO
176      END DO
177     
178      DO jj = 2, jpjm1            ! total intermediate advective trends
179         DO ji = fs_2, fs_jpim1   ! vector opt.
180            ztra = - (   zfu_ups(ji,jj) - zfu_ups(ji-1,jj  )   &
181               &       + zfv_ups(ji,jj) - zfv_ups(ji  ,jj-1)   ) * r1_e1e2t(ji,jj)
182            !
183            ztrd(ji,jj) =                         ztra                         ! upstream trend [ -div(uh) or -div(uhT) ] 
184            zt_ups (ji,jj) = ( ptc(ji,jj) + pdt * ztra ) * tmask(ji,jj,1)      ! guess after content field with monotonic scheme
185         END DO
186      END DO
187      CALL lbc_lnk( zt_ups, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
188     
189      ! High order (_ho) fluxes
190      ! -----------------------
191      SELECT CASE( k_order )
192      CASE ( 20 )                          ! centered second order
193         DO jj = 2, jpjm1
194            DO ji = fs_2, fs_jpim1   ! vector opt.
195               zfu_ho(ji,jj) = 0.5 * puc(ji,jj) * ( ptc(ji,jj) + ptc(ji+1,jj) )
196               zfv_ho(ji,jj) = 0.5 * pvc(ji,jj) * ( ptc(ji,jj) + ptc(ji,jj+1) )
197            END DO
198         END DO
199         !
200      CASE ( 1:5 )                      ! 1st to 5th order ULTIMATE-MACHO scheme
201         CALL macho( k_order, kt, pdt, ptc, puc, pvc, pubox, pvbox, zt_u, zt_v )
202         !
203         DO jj = 2, jpjm1
204            DO ji = fs_2, fs_jpim1   ! vector opt.
205               zfu_ho(ji,jj) = puc(ji,jj) * zt_u(ji,jj)
206               zfv_ho(ji,jj) = pvc(ji,jj) * zt_v(ji,jj)
207            END DO
208         END DO
209         !
210      END SELECT
211         
212      ! antidiffusive flux : high order minus low order
213      ! --------------------------------------------------
214      DO jj = 2, jpjm1
215         DO ji = fs_2, fs_jpim1   ! vector opt.
216            zfu_ho(ji,jj) = zfu_ho(ji,jj) - zfu_ups(ji,jj)
217            zfv_ho(ji,jj) = zfv_ho(ji,jj) - zfv_ups(ji,jj)
218         END DO
219      END DO
220      CALL lbc_lnk_multi( zfu_ho, 'U', -1., zfv_ho, 'V', -1. )         ! Lateral bondary conditions
221     
222      ! monotonicity algorithm
223      ! -------------------------
224      CALL nonosc_2d( ptc, zfu_ho, zfv_ho, zt_ups, pdt )
225     
226      ! final trend with corrected fluxes
227      ! ------------------------------------
228      DO jj = 2, jpjm1
229         DO ji = fs_2, fs_jpim1   ! vector opt. 
230            ztra       = ztrd(ji,jj)  - (  zfu_ho(ji,jj) - zfu_ho(ji-1,jj  )   &
231               &                         + zfv_ho(ji,jj) - zfv_ho(ji  ,jj-1) ) * r1_e1e2t(ji,jj) 
232            ptc(ji,jj) = ptc(ji,jj) + pdt * ztra
233         END DO
234      END DO
235      CALL lbc_lnk( ptc(:,:) , 'T',  1. )
236      !
237   END SUBROUTINE adv_umx
238
239
240   SUBROUTINE macho( k_order, kt, pdt, ptc, puc, pvc, pubox, pvbox, pt_u, pt_v )
241      !!---------------------------------------------------------------------
242      !!                    ***  ROUTINE ultimate_x  ***
243      !!     
244      !! **  Purpose :   compute 
245      !!
246      !! **  Method  :   ... ???
247      !!                 TIM = transient interpolation Modeling
248      !!
249      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
250      !!----------------------------------------------------------------------
251      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the ULTIMATE scheme
252      INTEGER                     , INTENT(in   ) ::   kt         ! number of iteration
253      REAL(wp)                    , INTENT(in   ) ::   pdt        ! tracer time-step
254      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   ptc        ! tracer fields
255      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc, pvc   ! 2 ice velocity components
256      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
257      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_u, pt_v ! tracer at u- and v-points
258      !
259      INTEGER  ::   ji, jj    ! dummy loop indices
260      REAL(wp) ::   zc_box    !   -      -
261      REAL(wp), DIMENSION(jpi,jpj) :: zzt
262      !!----------------------------------------------------------------------
263      !
264!!      IF( nn_timing == 1 )  CALL timing_start('macho')
265      !
266      IF( MOD( (kt - 1) / nn_fsbc , 2 ) == 0 ) THEN         !==  odd ice time step:  adv_x then adv_y  ==!
267         !
268         !                                                           !--  ultimate interpolation of pt at u-point  --!
269         CALL ultimate_x( k_order, pdt, ptc, puc, pt_u )
270         !
271         !                                                           !--  advective form update in zzt  --!
272         DO jj = 2, jpjm1
273            DO ji = fs_2, fs_jpim1   ! vector opt.
274               zzt(ji,jj) = ptc(ji,jj) - pubox(ji,jj) * pdt * ( pt_u(ji,jj) - pt_u(ji-1,jj) ) * r1_e1t(ji,jj)  &
275                  &                    - ptc  (ji,jj) * pdt * ( puc (ji,jj) - puc (ji-1,jj) ) * r1_e1e2t(ji,jj)
276               zzt(ji,jj) = zzt(ji,jj) * tmask(ji,jj,1)
277            END DO
278         END DO
279         CALL lbc_lnk( zzt, 'T', 1. )
280         !
281         !                                                           !--  ultimate interpolation of pt at v-point  --!
282         CALL ultimate_y( k_order, pdt, zzt, pvc, pt_v )
283         !
284      ELSE                                                  !==  even ice time step:  adv_y then adv_x  ==!
285         !
286         !                                                           !--  ultimate interpolation of pt at v-point  --!
287         CALL ultimate_y( k_order, pdt, ptc, pvc, pt_v )
288         !
289         !                                                           !--  advective form update in zzt  --!
290         DO jj = 2, jpjm1
291            DO ji = fs_2, fs_jpim1
292               zzt(ji,jj) = ptc(ji,jj) - pvbox(ji,jj) * pdt * ( pt_v(ji,jj) - pt_v(ji,jj-1) ) * r1_e2t(ji,jj)  &
293                  &                    - ptc  (ji,jj) * pdt * ( pvc (ji,jj) - pvc (ji,jj-1) ) * r1_e1e2t(ji,jj)
294               zzt(ji,jj) = zzt(ji,jj) * tmask(ji,jj,1)
295            END DO
296         END DO
297         CALL lbc_lnk( zzt, 'T', 1. )
298         !
299         !                                                           !--  ultimate interpolation of pt at u-point  --!
300         CALL ultimate_x( k_order, pdt, zzt, puc, pt_u )
301         !     
302      ENDIF     
303      !
304!!      IF( nn_timing == 1 )  CALL timing_stop('macho')
305      !
306   END SUBROUTINE macho
307
308
309   SUBROUTINE ultimate_x( k_order, pdt, pt, puc, pt_u )
310      !!---------------------------------------------------------------------
311      !!                    ***  ROUTINE ultimate_x  ***
312      !!     
313      !! **  Purpose :   compute 
314      !!
315      !! **  Method  :   ... ???
316      !!                 TIM = transient interpolation Modeling
317      !!
318      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
319      !!----------------------------------------------------------------------
320      INTEGER                     , INTENT(in   ) ::   k_order   ! ocean time-step index
321      REAL(wp)                    , INTENT(in   ) ::   pdt       ! tracer time-step
322      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc       ! ice i-velocity component
323      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pt        ! tracer fields
324      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_u      ! tracer at u-point
325      !
326      INTEGER  ::   ji, jj       ! dummy loop indices
327      REAL(wp) ::   zcu, zdx2, zdx4    !   -      -
328      REAL(wp), DIMENSION(jpi,jpj) :: ztu1, ztu2, ztu3, ztu4
329      !!----------------------------------------------------------------------
330      !
331!!      IF( nn_timing == 1 )  CALL timing_start('ultimate_x')
332      !
333      !                                                     !--  Laplacian in i-direction  --!
334      DO jj = 2, jpjm1         ! First derivative (gradient)
335         DO ji = 1, fs_jpim1
336            ztu1(ji,jj) = ( pt(ji+1,jj) - pt(ji,jj) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
337         END DO
338         !                     ! Second derivative (Laplacian)
339         DO ji = fs_2, fs_jpim1
340            ztu2(ji,jj) = ( ztu1(ji,jj) - ztu1(ji-1,jj) ) * r1_e1t(ji,jj)
341         END DO
342      END DO
343      CALL lbc_lnk( ztu2, 'T', 1. )
344      !
345      !                                                     !--  BiLaplacian in i-direction  --!
346      DO jj = 2, jpjm1         ! Third derivative
347         DO ji = 1, fs_jpim1
348            ztu3(ji,jj) = ( ztu2(ji+1,jj) - ztu2(ji,jj) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
349         END DO
350         !                     ! Fourth derivative
351         DO ji = fs_2, fs_jpim1
352            ztu4(ji,jj) = ( ztu3(ji,jj) - ztu3(ji-1,jj) ) * r1_e1t(ji,jj)
353         END DO
354      END DO
355      CALL lbc_lnk( ztu4, 'T', 1. )
356      !
357      !
358      SELECT CASE (k_order )
359      !
360      CASE( 1 )                                                   !==  1st order central TIM  ==! (Eq. 21)
361         !       
362         DO jj = 1, jpj
363            DO ji = 1, fs_jpim1   ! vector opt.
364               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj) + pt(ji,jj)   &
365                  &                                    - SIGN( 1._wp, puc(ji,jj) ) * ( pt(ji+1,jj) - pt(ji,jj) ) )
366            END DO
367         END DO
368         !
369      CASE( 2 )                                                   !==  2nd order central TIM  ==! (Eq. 23)
370         !
371         DO jj = 1, jpj
372            DO ji = 1, fs_jpim1   ! vector opt.
373               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
374               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (                                   pt(ji+1,jj) + pt(ji,jj)   &
375                  &                                               -              zcu   * ( pt(ji+1,jj) - pt(ji,jj) ) ) 
376            END DO
377         END DO
378         CALL lbc_lnk( pt_u(:,:) , 'U',  1. )
379         
380      CASE( 3 )                                                   !==  3rd order central TIM  ==! (Eq. 24)
381         !
382         DO jj = 1, jpj
383            DO ji = 1, fs_jpim1   ! vector opt.
384               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
385               zdx2 = e1u(ji,jj) * e1u(ji,jj)
386!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
387               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (         (                         pt  (ji+1,jj) + pt  (ji,jj)        &
388                  &                                               -              zcu   * ( pt  (ji+1,jj) - pt  (ji,jj) )  )   &
389                  &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                         ztu2(ji+1,jj) + ztu2(ji,jj)        &
390                  &                                               - SIGN( 1._wp, zcu ) * ( ztu2(ji+1,jj) - ztu2(ji,jj) )  )   )
391            END DO
392         END DO
393         !
394      CASE( 4 )                                                   !==  4th order central TIM  ==! (Eq. 27)
395         !
396         DO jj = 1, jpj
397            DO ji = 1, fs_jpim1   ! vector opt.
398               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
399               zdx2 = e1u(ji,jj) * e1u(ji,jj)
400!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
401               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (         (                   pt  (ji+1,jj) + pt  (ji,jj)        &
402                  &                                               -          zcu * ( pt  (ji+1,jj) - pt  (ji,jj) )  )   &
403                  &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                   ztu2(ji+1,jj) + ztu2(ji,jj)        &
404                  &                                               - 0.5_wp * zcu * ( ztu2(ji+1,jj) - ztu2(ji,jj) )  )   )
405            END DO
406         END DO
407         !
408      CASE( 5 )                                                   !==  5th order central TIM  ==! (Eq. 29)
409         !
410         DO jj = 1, jpj
411            DO ji = 1, fs_jpim1   ! vector opt.
412               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
413               zdx2 = e1u(ji,jj) * e1u(ji,jj)
414!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
415               zdx4 = zdx2 * zdx2
416               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (               (                   pt  (ji+1,jj) + pt  (ji,jj)       &
417                  &                                                     -          zcu * ( pt  (ji+1,jj) - pt  (ji,jj) ) )   &
418                  &        + z1_6   * zdx2 * ( zcu*zcu - 1._wp ) *     (                   ztu2(ji+1,jj) + ztu2(ji,jj)       &
419                  &                                                     - 0.5_wp * zcu * ( ztu2(ji+1,jj) - ztu2(ji,jj) ) )   &
420                  &        + z1_120 * zdx4 * ( zcu*zcu - 1._wp ) * ( zcu*zcu - 4._wp ) * ( ztu4(ji+1,jj) + ztu4(ji,jj)       &
421                  &                                               - SIGN( 1._wp, zcu ) * ( ztu4(ji+1,jj) - ztu4(ji,jj) ) ) )
422            END DO
423         END DO
424         !
425      END SELECT
426      !
427!!      IF( nn_timing == 1 )  CALL timing_stop('ultimate_x')
428      !
429   END SUBROUTINE ultimate_x
430   
431 
432   SUBROUTINE ultimate_y( k_order, pdt, pt, pvc, pt_v )
433      !!---------------------------------------------------------------------
434      !!                    ***  ROUTINE ultimate_y  ***
435      !!     
436      !! **  Purpose :   compute 
437      !!
438      !! **  Method  :   ... ???
439      !!                 TIM = transient interpolation Modeling
440      !!
441      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
442      !!----------------------------------------------------------------------
443      INTEGER                     , INTENT(in   ) ::   k_order   ! ocean time-step index
444      REAL(wp)                    , INTENT(in   ) ::   pdt       ! tracer time-step
445      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pvc       ! ice j-velocity component
446      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pt        ! tracer fields
447      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_v      ! tracer at v-point
448      !
449      INTEGER  ::   ji, jj       ! dummy loop indices
450      REAL(wp) ::   zcv, zdy2, zdy4    !   -      -
451      REAL(wp), DIMENSION(jpi,jpj) :: ztv1, ztv2, ztv3, ztv4
452      !!----------------------------------------------------------------------
453      !
454!!      IF( nn_timing == 1 )  CALL timing_start('ultimate_y')
455      !
456      !                                                     !--  Laplacian in j-direction  --!
457      DO jj = 1, jpjm1         ! First derivative (gradient)
458         DO ji = fs_2, fs_jpim1
459            ztv1(ji,jj) = ( pt(ji,jj+1) - pt(ji,jj) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
460         END DO
461      END DO
462      DO jj = 2, jpjm1         ! Second derivative (Laplacian)
463         DO ji = fs_2, fs_jpim1
464            ztv2(ji,jj) = ( ztv1(ji,jj) - ztv1(ji,jj-1) ) * r1_e2t(ji,jj)
465         END DO
466      END DO
467      CALL lbc_lnk( ztv2, 'T', 1. )
468      !
469      !                                                     !--  BiLaplacian in j-direction  --!
470      DO jj = 1, jpjm1         ! First derivative
471         DO ji = fs_2, fs_jpim1
472            ztv3(ji,jj) = ( ztv2(ji,jj+1) - ztv2(ji,jj) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
473         END DO
474      END DO
475      DO jj = 2, jpjm1         ! Second derivative
476         DO ji = fs_2, fs_jpim1
477            ztv4(ji,jj) = ( ztv3(ji,jj) - ztv3(ji,jj-1) ) * r1_e2t(ji,jj)
478         END DO
479      END DO
480      CALL lbc_lnk( ztv4, 'T', 1. )
481      !
482      !
483      SELECT CASE (k_order )
484      !
485      CASE( 1 )                                                !==  1st order central TIM  ==! (Eq. 21)
486         DO jj = 1, jpjm1
487            DO ji = 1, jpi
488               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt(ji,jj+1) + pt(ji,jj) )  &
489                  &                                     - SIGN( 1._wp, pvc(ji,jj) ) * ( pt(ji,jj+1) - pt(ji,jj) ) )
490            END DO
491         END DO
492         !
493      CASE( 2 )                                                !==  2nd order central TIM  ==! (Eq. 23)
494         DO jj = 1, jpjm1
495            DO ji = 1, jpi
496               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
497               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (        ( pt(ji,jj+1) + pt(ji,jj) )  &
498                  &                                     - zcv * ( pt(ji,jj+1) - pt(ji,jj) ) )
499            END DO
500         END DO
501         CALL lbc_lnk( pt_v(:,:) , 'V',  1. )
502         !
503      CASE( 3 )                                                !==  3rd order central TIM  ==! (Eq. 24)
504         DO jj = 1, jpjm1
505            DO ji = 1, jpi
506               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
507               zdy2 = e2v(ji,jj) * e2v(ji,jj)
508!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
509               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                                 ( pt  (ji,jj+1) + pt  (ji,jj)       &
510                  &                                     -                        zcv   * ( pt  (ji,jj+1) - pt  (ji,jj) ) )   &
511                  &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                         ztv2(ji,jj+1) + ztv2(ji,jj)       &
512                  &                                               - SIGN( 1._wp, zcv ) * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) ) )
513            END DO
514         END DO
515         !
516      CASE( 4 )                                                !==  4th order central TIM  ==! (Eq. 27)
517         DO jj = 1, jpjm1
518            DO ji = 1, jpi
519               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
520               zdy2 = e2v(ji,jj) * e2v(ji,jj)
521!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
522               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                           ( pt  (ji,jj+1) + pt  (ji,jj)       &
523                  &                                               -          zcv * ( pt  (ji,jj+1) - pt  (ji,jj) ) )   &
524                  &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                   ztv2(ji,jj+1) + ztv2(ji,jj)       &
525                  &                                               - 0.5_wp * zcv * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) ) )
526            END DO
527         END DO
528         !
529      CASE( 5 )                                                !==  5th order central TIM  ==! (Eq. 29)
530         DO jj = 1, jpjm1
531            DO ji = 1, jpi
532               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
533               zdy2 = e2v(ji,jj) * e2v(ji,jj)
534!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
535               zdy4 = zdy2 * zdy2
536               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                                 ( pt  (ji,jj+1) + pt  (ji,jj)      &
537                  &                                                     -          zcv * ( pt  (ji,jj+1) - pt  (ji,jj) ) )  &
538                  &        + z1_6   * zdy2 * ( zcv*zcv - 1._wp ) *     (                   ztv2(ji,jj+1) + ztv2(ji,jj)      &
539                  &                                                     - 0.5_wp * zcv * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) )  &
540                  &        + z1_120 * zdy4 * ( zcv*zcv - 1._wp ) * ( zcv*zcv - 4._wp ) * ( ztv4(ji,jj+1) + ztv4(ji,jj)      &
541                  &                                               - SIGN( 1._wp, zcv ) * ( ztv4(ji,jj+1) - ztv4(ji,jj) ) ) )
542            END DO
543         END DO
544         !
545      END SELECT
546      !
547!!      IF( nn_timing == 1 )  CALL timing_stop('ultimate_y')
548      !
549   END SUBROUTINE ultimate_y
550   
551 
552   SUBROUTINE nonosc_2d( pbef, paa, pbb, paft, pdt )
553      !!---------------------------------------------------------------------
554      !!                    ***  ROUTINE nonosc  ***
555      !!     
556      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
557      !!       scheme and the before field by a nonoscillatory algorithm
558      !!
559      !! **  Method  :   ... ???
560      !!       warning : pbef and paft must be masked, but the boundaries
561      !!       conditions on the fluxes are not necessary zalezak (1979)
562      !!       drange (1995) multi-dimensional forward-in-time and upstream-
563      !!       in-space based differencing for fluid
564      !!----------------------------------------------------------------------
565      REAL(wp)                     , INTENT(in   ) ::   pdt          ! tracer time-step
566      REAL(wp), DIMENSION (jpi,jpj), INTENT(in   ) ::   pbef, paft   ! before & after field
567      REAL(wp), DIMENSION (jpi,jpj), INTENT(inout) ::   paa, pbb     ! monotonic fluxes in the 2 directions
568      !
569      INTEGER  ::   ji, jj    ! dummy loop indices
570      INTEGER  ::   ikm1      ! local integer
571      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zsml, z1_dt   ! local scalars
572      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
573      REAL(wp), DIMENSION(jpi,jpj) :: zbetup, zbetdo, zbup, zbdo, zmsk, zdiv
574      !!----------------------------------------------------------------------
575      !
576!!      IF( nn_timing == 1 )  CALL timing_start('nonosc_2d')
577      !
578      zbig = 1.e+40_wp
579      zsml = 1.e-15_wp
580
581      ! clem test
582      DO jj = 2, jpjm1
583         DO ji = fs_2, fs_jpim1   ! vector opt. 
584            zdiv(ji,jj) =  - (  paa(ji,jj) - paa(ji-1,jj  )   &
585               &              + pbb(ji,jj) - pbb(ji  ,jj-1) ) 
586         END DO
587      END DO
588      CALL lbc_lnk( zdiv, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
589
590      ! Determine ice masks for before and after tracers
591      WHERE( pbef(:,:) == 0._wp .AND. paft(:,:) == 0._wp .AND. zdiv(:,:) == 0._wp )   ;   zmsk(:,:) = 0._wp
592      ELSEWHERE                                                                       ;   zmsk(:,:) = 1._wp * tmask(:,:,1)
593      END WHERE
594
595      ! Search local extrema
596      ! --------------------
597      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
598!      zbup(:,:) = MAX( pbef(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) ),   &
599!         &             paft(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) )  )
600!      zbdo(:,:) = MIN( pbef(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) ),   &
601!         &             paft(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) )  )
602      zbup(:,:) = MAX( pbef(:,:) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) ),   &
603         &             paft(:,:) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) )  )
604      zbdo(:,:) = MIN( pbef(:,:) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) ),   &
605         &             paft(:,:) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) )  )
606
607      z1_dt = 1._wp / pdt
608      DO jj = 2, jpjm1
609         DO ji = fs_2, fs_jpim1   ! vector opt.
610            !
611            zup  = MAX(   zbup(ji,jj), zbup(ji-1,jj  ), zbup(ji+1,jj  ),   &        ! search max/min in neighbourhood
612               &                       zbup(ji  ,jj-1), zbup(ji  ,jj+1)    )
613            zdo  = MIN(   zbdo(ji,jj), zbdo(ji-1,jj  ), zbdo(ji+1,jj  ),   &
614               &                       zbdo(ji  ,jj-1), zbdo(ji  ,jj+1)    )
615               !
616            zpos = MAX( 0., paa(ji-1,jj  ) ) - MIN( 0., paa(ji  ,jj  ) )   &        ! positive/negative  part of the flux
617               & + MAX( 0., pbb(ji  ,jj-1) ) - MIN( 0., pbb(ji  ,jj  ) )
618            zneg = MAX( 0., paa(ji  ,jj  ) ) - MIN( 0., paa(ji-1,jj  ) )   &
619               & + MAX( 0., pbb(ji  ,jj  ) ) - MIN( 0., pbb(ji  ,jj-1) )
620               !
621            zbt = e1e2t(ji,jj) * z1_dt                                   ! up & down beta terms
622            zbetup(ji,jj) = ( zup         - paft(ji,jj) ) / ( zpos + zsml ) * zbt
623            zbetdo(ji,jj) = ( paft(ji,jj) - zdo         ) / ( zneg + zsml ) * zbt
624         END DO
625      END DO
626      CALL lbc_lnk_multi( zbetup, 'T', 1., zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
627
628      ! monotonic flux in the i & j direction (paa & pbb)
629      ! -------------------------------------
630      DO jj = 2, jpjm1
631         DO ji = fs_2, fs_jpim1   ! vector opt.
632            zau = MIN( 1._wp , zbetdo(ji,jj) , zbetup(ji+1,jj) )
633            zbu = MIN( 1._wp , zbetup(ji,jj) , zbetdo(ji+1,jj) )
634            zcu = 0.5  + SIGN( 0.5 , paa(ji,jj) )
635            !
636            zav = MIN( 1._wp , zbetdo(ji,jj) , zbetup(ji,jj+1) )
637            zbv = MIN( 1._wp , zbetup(ji,jj) , zbetdo(ji,jj+1) )
638            zcv = 0.5  + SIGN( 0.5 , pbb(ji,jj) )
639            !
640            paa(ji,jj) = paa(ji,jj) * ( zcu * zau + ( 1._wp - zcu) * zbu )
641            pbb(ji,jj) = pbb(ji,jj) * ( zcv * zav + ( 1._wp - zcv) * zbv )
642            !
643         END DO
644      END DO
645      CALL lbc_lnk_multi( paa, 'U', -1., pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
646      !
647!!      IF( nn_timing == 1 )  CALL timing_stop('nonosc_2d')
648      !
649   END SUBROUTINE nonosc_2d
650
651#else
652   !!----------------------------------------------------------------------
653   !!   Default option           Dummy module         NO ESIM sea-ice model
654   !!----------------------------------------------------------------------
655#endif
656
657   !!======================================================================
658END MODULE icedyn_adv_umx
Note: See TracBrowser for help on using the repository browser.