source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/icerhg.F90 @ 8518

MODULE icerhg
   !!======================================================================
   !!                     ***  MODULE  icerhg  ***
   !!   Sea-Ice dynamics :  
   !!======================================================================
   !! history :  1.0  ! 2002-08  (C. Ethe, G. Madec)  original VP code 
   !!            3.0  ! 2007-03  (MA Morales Maqueda, S. Bouillon, M. Vancoppenolle)  LIM3: EVP-Cgrid
   !!            3.5  ! 2011-02  (G. Madec) dynamical allocation
   !!----------------------------------------------------------------------
#if defined key_lim3
   !!----------------------------------------------------------------------
   !!   'key_lim3'                                       LIM3 sea-ice model
   !!----------------------------------------------------------------------
   !!    ice_rhg      : computes ice velocities
   !!    ice_rhg_init : initialization and namelist read
   !!----------------------------------------------------------------------
   USE phycst         ! physical constants
   USE dom_oce        ! ocean space and time domain
   USE ice            ! sea-ice: variables
   USE icerhg_evp     ! sea-ice: EVP rheology
   USE icectl         ! sea-ice: control prints
   !
   USE lbclnk         ! lateral boundary conditions - MPP exchanges
   USE lib_mpp        ! MPP library
   USE in_out_manager ! I/O manager
   USE lib_fortran    ! glob_sum
   USE timing         ! Timing

   IMPLICIT NONE
   PRIVATE

   PUBLIC   ice_rhg        ! called by icestp.F90
   PUBLIC   ice_rhg_init   ! called by icestp.F90

   INTEGER ::              nice_rhg   ! choice of the type of rheology
   !                                        ! associated indices:
   INTEGER, PARAMETER ::   np_rhgEVP = 1   ! EVP rheology
!! INTEGER, PARAMETER ::   np_rhgEAP = 2   ! EAP rheology

   ! ** namelist (namrhg) **
   LOGICAL ::   ln_rhg_EVP       ! EVP rheology
   !
   !! * Substitutions
#  include "vectopt_loop_substitute.h90"
   !!----------------------------------------------------------------------
   !! NEMO/ICE 4.0 , NEMO Consortium (2017)
   !! $Id: icerhg.F90 8378 2017-07-26 13:55:59Z clem $
   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
   !!----------------------------------------------------------------------
CONTAINS

   SUBROUTINE ice_rhg( kt )
      !!-------------------------------------------------------------------
      !!               ***  ROUTINE ice_rhg  ***
      !!               
      !! ** Purpose :   compute ice velocity
      !!
      !! ** Action  : comupte - ice velocity (u_ice, v_ice)
      !!                      - 3 components of the stress tensor (stress1_i, stress2_i, stress12_i)
      !!                      - shear, divergence and delta (shear_i, divu_i, delta_i)
      !!--------------------------------------------------------------------
      INTEGER, INTENT(in) ::   kt     ! ice time step
      !!--------------------------------------------------------------------
      ! controls
      IF( nn_timing == 1 )   CALL timing_start('icerhg')                                                             ! timing
      IF( ln_icediachk   )   CALL ice_cons_hsm(0, 'icerhg', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
      !
      IF( kt == nit000 .AND. lwp ) THEN
         WRITE(numout,*)
         WRITE(numout,*)'ice_rhg: sea-ice rheology'
         WRITE(numout,*)'~~~~~~~'
      ENDIF

      ! --------
      ! Rheology
      ! --------   
      SELECT CASE( nice_rhg )
      !                                !------------------------!
      CASE( np_rhgEVP )                ! Elasto-Viscous-Plastic !
         !                             !------------------------!
         CALL ice_rhg_evp( kt, stress1_i, stress2_i, stress12_i, u_ice, v_ice, shear_i, divu_i, delta_i )
         !         
      END SELECT
      !
      IF( lrst_ice ) THEN                       !* write EVP fields in the restart file
         IF( ln_rhg_EVP )   CALL rhg_evp_rst( 'WRITE', kt )
      ENDIF
      !
      ! controls
      IF( ln_icediachk   )   CALL ice_cons_hsm(1, 'icerhg', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
      IF( ln_ctl         )   CALL ice_prt3D   ('icerhg')                                                             ! prints
      IF( nn_timing == 1 )   CALL timing_stop ('icerhg')                                                             ! timing
      !
   END SUBROUTINE ice_rhg

   SUBROUTINE ice_rhg_init
      !!-------------------------------------------------------------------
      !!                  ***  ROUTINE ice_rhg_init  ***
      !!
      !! ** Purpose : Physical constants and parameters linked to the ice
      !!      dynamics
      !!
      !! ** Method  :  Read the namice_rhg namelist and check the ice-dynamic
      !!       parameter values called at the first timestep (nit000)
      !!
      !! ** input   :   Namelist namice_rhg
      !!-------------------------------------------------------------------
      INTEGER ::   ios, ioptio   ! Local integer output status for namelist read
      !!
      NAMELIST/namice_rhg/  ln_rhg_EVP, rn_creepl, rn_ecc , nn_nevp, rn_relast
      !!-------------------------------------------------------------------
      !
      REWIND( numnam_ice_ref )         ! Namelist namice_rhg in reference namelist : Ice dynamics
      READ  ( numnam_ice_ref, namice_rhg, IOSTAT = ios, ERR = 901)
901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namice_rhg in reference namelist', lwp )
      !
      REWIND( numnam_ice_cfg )         ! Namelist namice_rhg in configuration namelist : Ice dynamics
      READ  ( numnam_ice_cfg, namice_rhg, IOSTAT = ios, ERR = 902 )
902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namice_rhg in configuration namelist', lwp )
      IF(lwm) WRITE ( numoni, namice_rhg )
      !
      IF(lwp) THEN                     ! control print
         WRITE(numout,*)
         WRITE(numout,*) 'ice_rhg_init: ice parameters for ice dynamics '
         WRITE(numout,*) '~~~~~~~~~~~~'
         WRITE(numout,*) '   Namelist namice_rhg'
         WRITE(numout,*) '      rheology EVP (icerhg_evp)                                   ln_rhg_EVP    = ', ln_rhg_EVP
         WRITE(numout,*) '         creep limit                                              rn_creepl     = ', rn_creepl
         WRITE(numout,*) '         eccentricity of the elliptical yield curve               rn_ecc        = ', rn_ecc
         WRITE(numout,*) '         number of iterations for subcycling                      nn_nevp       = ', nn_nevp
         WRITE(numout,*) '         ratio of elastic timescale over ice time step            rn_relast     = ', rn_relast
      ENDIF
      !
      !                             !== set the choice of ice advection ==!
      ioptio = 0 
      IF( ln_rhg_EVP ) THEN   ;   ioptio = ioptio + 1   ;   nice_rhg = np_rhgEVP    ;   ENDIF
!!    IF( ln_rhg_EAP ) THEN   ;   ioptio = ioptio + 1   ;   nice_rhg = np_rhgEAP    ;   ENDIF
      IF( ioptio /= 1 )   CALL ctl_stop( 'ice_rhg_init: choose one and only one ice rheology' )
      !
      IF( ln_rhg_EVP )   CALL rhg_evp_rst( 'READ' )  !* read or initialize all required files
      !
   END SUBROUTINE ice_rhg_init

#else
   !!----------------------------------------------------------------------
   !!   Default option         Empty module          NO LIM-3 sea-ice model
   !!----------------------------------------------------------------------
#endif 

   !!======================================================================
END MODULE icerhg