| 1 | MODULE iceupdate |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE iceupdate *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! ice_update_alloc : allocate the iceupdate arrays |
|---|
| 21 | !! ice_update_init : initialisation |
|---|
| 22 | !! ice_update_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! ice_update_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE oce , ONLY : sshn, sshb |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE ice ! LIM sea-ice variables |
|---|
| 30 | USE sbc_ice , ONLY : emp_oce, qns_oce, qsr_oce, qemp_oce, emp_ice, qsr_ice, qemp_ice, qevap_ice, alb_ice, tn_ice, cldf_ice, & |
|---|
| 31 | & snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 32 | USE sbc_oce , ONLY : nn_fsbc, ln_ice_embd, sfx, fr_i, qsr_tot, qns, qsr, fmmflx, emp, taum, utau, vtau |
|---|
| 33 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 34 | USE icealb ! albedo parameters |
|---|
| 35 | USE traqsr ! add penetration of solar flux in the calculation of heat budget |
|---|
| 36 | USE domvvl ! Variable volume |
|---|
| 37 | USE icectl ! |
|---|
| 38 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 39 | ! |
|---|
| 40 | USE in_out_manager ! I/O manager |
|---|
| 41 | USE iom ! xIO server |
|---|
| 42 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 43 | USE lib_mpp ! MPP library |
|---|
| 44 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 45 | USE timing ! Timing |
|---|
| 46 | |
|---|
| 47 | IMPLICIT NONE |
|---|
| 48 | PRIVATE |
|---|
| 49 | |
|---|
| 50 | PUBLIC ice_update_init ! called by ice_init |
|---|
| 51 | PUBLIC ice_update_flx ! called by ice_stp |
|---|
| 52 | PUBLIC ice_update_tau ! called by ice_stp |
|---|
| 53 | |
|---|
| 54 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 57 | |
|---|
| 58 | !! * Substitutions |
|---|
| 59 | # include "vectopt_loop_substitute.h90" |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 62 | !! $Id: iceupdate.F90 8411 2017-08-07 16:09:12Z clem $ |
|---|
| 63 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | CONTAINS |
|---|
| 66 | |
|---|
| 67 | INTEGER FUNCTION ice_update_alloc() |
|---|
| 68 | !!------------------------------------------------------------------- |
|---|
| 69 | !! *** ROUTINE ice_update_alloc *** |
|---|
| 70 | !!------------------------------------------------------------------- |
|---|
| 71 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 72 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=ice_update_alloc) |
|---|
| 73 | ! |
|---|
| 74 | IF( lk_mpp ) CALL mpp_sum( ice_update_alloc ) |
|---|
| 75 | IF( ice_update_alloc /= 0 ) CALL ctl_warn('ice_update_alloc: failed to allocate arrays') |
|---|
| 76 | END FUNCTION ice_update_alloc |
|---|
| 77 | |
|---|
| 78 | |
|---|
| 79 | SUBROUTINE ice_update_flx( kt ) |
|---|
| 80 | !!------------------------------------------------------------------- |
|---|
| 81 | !! *** ROUTINE ice_update_flx *** |
|---|
| 82 | !! |
|---|
| 83 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 84 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 85 | !! |
|---|
| 86 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 87 | !! at the ice-ocean interface. |
|---|
| 88 | !! - Update the ocean sbc |
|---|
| 89 | !! |
|---|
| 90 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 91 | !! - qns : sea heat flux: non solar |
|---|
| 92 | !! - emp : freshwater budget: volume flux |
|---|
| 93 | !! - sfx : salt flux |
|---|
| 94 | !! - fr_i : ice fraction |
|---|
| 95 | !! - tn_ice : sea-ice surface temperature |
|---|
| 96 | !! - alb_ice : sea-ice albedo (recomputed only for coupled mode) |
|---|
| 97 | !! |
|---|
| 98 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 99 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 100 | !! These refs are now obsolete since everything has been revised |
|---|
| 101 | !! The ref should be Rousset et al., 2015 |
|---|
| 102 | !!--------------------------------------------------------------------- |
|---|
| 103 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 104 | ! |
|---|
| 105 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 106 | REAL(wp) :: zqmass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 107 | REAL(wp) :: zqsr ! New solar flux received by the ocean |
|---|
| 108 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalb_cs, zalb_os ! 3D workspace |
|---|
| 109 | !!--------------------------------------------------------------------- |
|---|
| 110 | IF( nn_timing == 1 ) CALL timing_start('ice_update_flx') |
|---|
| 111 | |
|---|
| 112 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 113 | WRITE(numout,*) |
|---|
| 114 | WRITE(numout,*)'ice_update_flx' |
|---|
| 115 | WRITE(numout,*)'~~~~~~~~~~~~~~' |
|---|
| 116 | ENDIF |
|---|
| 117 | |
|---|
| 118 | ! --- case we bypass ice thermodynamics --- ! |
|---|
| 119 | IF( .NOT. ln_limthd ) THEN ! we suppose ice is impermeable => ocean is isolated from atmosphere |
|---|
| 120 | hfx_in (:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:) |
|---|
| 121 | hfx_out (:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:) |
|---|
| 122 | ftr_ice (:,:,:) = 0._wp |
|---|
| 123 | emp_ice (:,:) = 0._wp |
|---|
| 124 | qemp_ice (:,:) = 0._wp |
|---|
| 125 | qevap_ice(:,:,:) = 0._wp |
|---|
| 126 | ENDIF |
|---|
| 127 | |
|---|
| 128 | DO jj = 1, jpj |
|---|
| 129 | DO ji = 1, jpi |
|---|
| 130 | |
|---|
| 131 | !------------------------------------------! |
|---|
| 132 | ! heat flux at the ocean surface ! |
|---|
| 133 | !------------------------------------------! |
|---|
| 134 | ! Solar heat flux reaching the ocean = zqsr (W.m-2) |
|---|
| 135 | !--------------------------------------------------- |
|---|
| 136 | zqsr = qsr_tot(ji,jj) |
|---|
| 137 | DO jl = 1, jpl |
|---|
| 138 | zqsr = zqsr - a_i_b(ji,jj,jl) * ( qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) |
|---|
| 139 | END DO |
|---|
| 140 | |
|---|
| 141 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 142 | !--------------------------------------------------- |
|---|
| 143 | zqmass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 144 | hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr |
|---|
| 145 | |
|---|
| 146 | ! Add the residual from heat diffusion equation and sublimation (W.m-2) |
|---|
| 147 | !---------------------------------------------------------------------- |
|---|
| 148 | hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) + & |
|---|
| 149 | & ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) ) |
|---|
| 150 | |
|---|
| 151 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 152 | !---------------------------------------------------------------------------- |
|---|
| 153 | qsr(ji,jj) = zqsr |
|---|
| 154 | qns(ji,jj) = hfx_out(ji,jj) - zqsr |
|---|
| 155 | |
|---|
| 156 | ! Mass flux at the atm. surface |
|---|
| 157 | !----------------------------------- |
|---|
| 158 | wfx_sub(ji,jj) = wfx_snw_sub(ji,jj) + wfx_ice_sub(ji,jj) |
|---|
| 159 | |
|---|
| 160 | ! Mass flux at the ocean surface |
|---|
| 161 | !------------------------------------ |
|---|
| 162 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 163 | ! ------------------------------------------------------------------------------------- |
|---|
| 164 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 165 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 166 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 167 | ! Associated to Ice formation AND Ice melting |
|---|
| 168 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 169 | ! |
|---|
| 170 | ! mass flux from ice/ocean |
|---|
| 171 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) & |
|---|
| 172 | + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) |
|---|
| 173 | |
|---|
| 174 | IF ( ln_pnd_fw ) wfx_ice(ji,jj) = wfx_ice(ji,jj) + wfx_pnd(ji,jj) |
|---|
| 175 | |
|---|
| 176 | ! add the snow melt water to snow mass flux to the ocean |
|---|
| 177 | wfx_snw(ji,jj) = wfx_snw_sni(ji,jj) + wfx_snw_dyn(ji,jj) + wfx_snw_sum(ji,jj) |
|---|
| 178 | |
|---|
| 179 | ! mass flux at the ocean/ice interface |
|---|
| 180 | fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) ) ! F/M mass flux save at least for biogeochemical model |
|---|
| 181 | emp(ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 182 | |
|---|
| 183 | |
|---|
| 184 | ! Salt flux at the ocean surface |
|---|
| 185 | !------------------------------------------ |
|---|
| 186 | sfx(ji,jj) = sfx_bog(ji,jj) + sfx_bom(ji,jj) + sfx_sum(ji,jj) + sfx_sni(ji,jj) + sfx_opw(ji,jj) & |
|---|
| 187 | & + sfx_res(ji,jj) + sfx_dyn(ji,jj) + sfx_bri(ji,jj) + sfx_sub(ji,jj) + sfx_lam(ji,jj) |
|---|
| 188 | |
|---|
| 189 | ! Mass of snow and ice per unit area |
|---|
| 190 | !---------------------------------------- |
|---|
| 191 | ! save mass from the previous ice time step |
|---|
| 192 | snwice_mass_b(ji,jj) = snwice_mass(ji,jj) |
|---|
| 193 | ! new mass per unit area |
|---|
| 194 | snwice_mass (ji,jj) = tmask(ji,jj,1) * ( rhosn * vt_s(ji,jj) + rhoic * vt_i(ji,jj) ) |
|---|
| 195 | ! time evolution of snow+ice mass |
|---|
| 196 | snwice_fmass (ji,jj) = ( snwice_mass(ji,jj) - snwice_mass_b(ji,jj) ) * r1_rdtice |
|---|
| 197 | |
|---|
| 198 | END DO |
|---|
| 199 | END DO |
|---|
| 200 | |
|---|
| 201 | !-----------------------------------------------! |
|---|
| 202 | ! Storing the transmitted variables ! |
|---|
| 203 | !-----------------------------------------------! |
|---|
| 204 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 205 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 206 | |
|---|
| 207 | !------------------------------------------------------------------------! |
|---|
| 208 | ! Snow/ice albedo (only if sent to coupler, useless in forced mode) ! |
|---|
| 209 | !------------------------------------------------------------------------! |
|---|
| 210 | CALL ice_alb( t_su, ht_i, ht_s, a_ip_frac, h_ip, ln_pnd_rad, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 211 | |
|---|
| 212 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 213 | |
|---|
| 214 | ! conservation test |
|---|
| 215 | IF( ln_limdiachk .AND. .NOT. ln_bdy) CALL ice_cons_final( 'iceupdate' ) |
|---|
| 216 | |
|---|
| 217 | ! control prints |
|---|
| 218 | IF( ln_limctl ) CALL ice_prt( kt, iiceprt, jiceprt, 3, ' - Final state ice_update - ' ) |
|---|
| 219 | IF( ln_ctl ) CALL ice_prt3D( 'iceupdate' ) |
|---|
| 220 | |
|---|
| 221 | IF( nn_timing == 1 ) CALL timing_stop('ice_update_flx') |
|---|
| 222 | |
|---|
| 223 | END SUBROUTINE ice_update_flx |
|---|
| 224 | |
|---|
| 225 | |
|---|
| 226 | SUBROUTINE ice_update_tau( kt , pu_oce, pv_oce ) |
|---|
| 227 | !!------------------------------------------------------------------- |
|---|
| 228 | !! *** ROUTINE ice_update_tau *** |
|---|
| 229 | !! |
|---|
| 230 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 231 | !! |
|---|
| 232 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 233 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 234 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 235 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 236 | !! - update the modulus of stress at ocean surface |
|---|
| 237 | !! taum = (1-a) * taum + a * tmod_io * | U_ice-U_oce | |
|---|
| 238 | !! * at each ocean time step (every kt): |
|---|
| 239 | !! compute linearized ice-ocean stresses as |
|---|
| 240 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 241 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 242 | !! |
|---|
| 243 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 244 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 245 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 246 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 247 | !! |
|---|
| 248 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 249 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 250 | !!--------------------------------------------------------------------- |
|---|
| 251 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 252 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 253 | ! |
|---|
| 254 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 255 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 256 | REAL(wp) :: zat_v, zvtau_ice, zv_t, zrhoco ! - - |
|---|
| 257 | !!--------------------------------------------------------------------- |
|---|
| 258 | |
|---|
| 259 | IF( nn_timing == 1 ) CALL timing_start('ice_update_tau') |
|---|
| 260 | |
|---|
| 261 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 262 | WRITE(numout,*) |
|---|
| 263 | WRITE(numout,*)'ice_update_tau' |
|---|
| 264 | WRITE(numout,*)'~~~~~~~~~~~~~~' |
|---|
| 265 | ENDIF |
|---|
| 266 | |
|---|
| 267 | zrhoco = rau0 * rn_cio |
|---|
| 268 | ! |
|---|
| 269 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 270 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 271 | DO ji = fs_2, fs_jpim1 |
|---|
| 272 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 273 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 274 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 275 | ! ! |U_ice-U_oce|^2 |
|---|
| 276 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 277 | ! ! update the ocean stress modulus |
|---|
| 278 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt |
|---|
| 279 | tmod_io(ji,jj) = zrhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 280 | END DO |
|---|
| 281 | END DO |
|---|
| 282 | CALL lbc_lnk_multi( taum, 'T', 1., tmod_io, 'T', 1. ) |
|---|
| 283 | ! |
|---|
| 284 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 285 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 286 | ! |
|---|
| 287 | ENDIF |
|---|
| 288 | ! |
|---|
| 289 | ! !== every ocean time-step ==! |
|---|
| 290 | ! |
|---|
| 291 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 292 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 293 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 294 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 295 | ! ! linearized quadratic drag formulation |
|---|
| 296 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 297 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 298 | ! ! stresses at the ocean surface |
|---|
| 299 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 300 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 301 | END DO |
|---|
| 302 | END DO |
|---|
| 303 | CALL lbc_lnk_multi( utau, 'U', -1., vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 304 | ! |
|---|
| 305 | IF( nn_timing == 1 ) CALL timing_stop('ice_update_tau') |
|---|
| 306 | ! |
|---|
| 307 | END SUBROUTINE ice_update_tau |
|---|
| 308 | |
|---|
| 309 | |
|---|
| 310 | SUBROUTINE ice_update_init |
|---|
| 311 | !!------------------------------------------------------------------- |
|---|
| 312 | !! *** ROUTINE ice_update_init *** |
|---|
| 313 | !! |
|---|
| 314 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 315 | !! the temporal evolution of key variables |
|---|
| 316 | !! |
|---|
| 317 | !! ** input : Namelist namicedia |
|---|
| 318 | !!------------------------------------------------------------------- |
|---|
| 319 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 320 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 321 | !!------------------------------------------------------------------- |
|---|
| 322 | ! |
|---|
| 323 | IF(lwp) WRITE(numout,*) |
|---|
| 324 | IF(lwp) WRITE(numout,*) 'ice_update_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 325 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~ ' |
|---|
| 326 | |
|---|
| 327 | ! ! allocate ice_update array |
|---|
| 328 | IF( ice_update_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'ice_update_init : unable to allocate standard arrays' ) |
|---|
| 329 | ! |
|---|
| 330 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 331 | sice_0(:,:) = sice |
|---|
| 332 | ! ! decrease ocean & ice reference salinities in the Baltic Sea area |
|---|
| 333 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 334 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 335 | soce_0(:,:) = 4._wp |
|---|
| 336 | sice_0(:,:) = 2._wp |
|---|
| 337 | END WHERE |
|---|
| 338 | ! |
|---|
| 339 | IF( .NOT. ln_rstart ) THEN |
|---|
| 340 | ! |
|---|
| 341 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) ! snow+ice mass |
|---|
| 342 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 343 | ! |
|---|
| 344 | IF( ln_ice_embd ) THEN ! embedded sea-ice: deplete the initial ssh below sea-ice area |
|---|
| 345 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 346 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 347 | |
|---|
| 348 | !!gm I really don't like this stuff here... Find a way to put that elsewhere or differently |
|---|
| 349 | !!gm |
|---|
| 350 | IF( .NOT.ln_linssh ) THEN |
|---|
| 351 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 352 | e3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 353 | e3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 354 | END DO |
|---|
| 355 | e3t_a(:,:,:) = e3t_b(:,:,:) |
|---|
| 356 | ! Reconstruction of all vertical scale factors at now and before time-steps |
|---|
| 357 | ! ========================================================================= |
|---|
| 358 | ! Horizontal scale factor interpolations |
|---|
| 359 | ! -------------------------------------- |
|---|
| 360 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3u_b(:,:,:), 'U' ) |
|---|
| 361 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3v_b(:,:,:), 'V' ) |
|---|
| 362 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3u_n(:,:,:), 'U' ) |
|---|
| 363 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3v_n(:,:,:), 'V' ) |
|---|
| 364 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3f_n(:,:,:), 'F' ) |
|---|
| 365 | ! Vertical scale factor interpolations |
|---|
| 366 | ! ------------------------------------ |
|---|
| 367 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3w_n (:,:,:), 'W' ) |
|---|
| 368 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3uw_n(:,:,:), 'UW' ) |
|---|
| 369 | CALL dom_vvl_interpol( e3v_n(:,:,:), e3vw_n(:,:,:), 'VW' ) |
|---|
| 370 | CALL dom_vvl_interpol( e3u_b(:,:,:), e3uw_b(:,:,:), 'UW' ) |
|---|
| 371 | CALL dom_vvl_interpol( e3v_b(:,:,:), e3vw_b(:,:,:), 'VW' ) |
|---|
| 372 | ! t- and w- points depth |
|---|
| 373 | ! ---------------------- |
|---|
| 374 | !!gm not sure of that.... |
|---|
| 375 | gdept_n(:,:,1) = 0.5_wp * e3w_n(:,:,1) |
|---|
| 376 | gdepw_n(:,:,1) = 0.0_wp |
|---|
| 377 | gde3w_n(:,:,1) = gdept_n(:,:,1) - sshn(:,:) |
|---|
| 378 | DO jk = 2, jpk |
|---|
| 379 | gdept_n(:,:,jk) = gdept_n(:,:,jk-1) + e3w_n(:,:,jk) |
|---|
| 380 | gdepw_n(:,:,jk) = gdepw_n(:,:,jk-1) + e3t_n(:,:,jk-1) |
|---|
| 381 | gde3w_n(:,:,jk) = gdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 382 | END DO |
|---|
| 383 | ENDIF |
|---|
| 384 | ENDIF |
|---|
| 385 | ENDIF ! .NOT. ln_rstart |
|---|
| 386 | ! |
|---|
| 387 | END SUBROUTINE ice_update_init |
|---|
| 388 | |
|---|
| 389 | #endif |
|---|
| 390 | |
|---|
| 391 | !!====================================================================== |
|---|
| 392 | END MODULE iceupdate |
|---|
