| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE oce , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE ice ! LIM sea-ice variables |
|---|
| 30 | USE sbc_ice , ONLY : emp_oce, qns_oce, qsr_oce, qemp_oce, emp_ice, qsr_ice, qemp_ice, qevap_ice, alb_ice, tn_ice, cldf_ice |
|---|
| 31 | USE sbc_oce , ONLY : nn_fsbc, ln_ice_embd, sfx, fr_i, qsr_tot, qns, qsr, fmmflx, emp, taum, utau, vtau |
|---|
| 32 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 33 | USE albedoice ! albedo parameters |
|---|
| 34 | USE traqsr ! add penetration of solar flux in the calculation of heat budget |
|---|
| 35 | USE domvvl ! Variable volume |
|---|
| 36 | USE limctl ! |
|---|
| 37 | USE limcons ! |
|---|
| 38 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 39 | ! |
|---|
| 40 | USE in_out_manager ! I/O manager |
|---|
| 41 | USE iom ! xIO server |
|---|
| 42 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 43 | USE lib_mpp ! MPP library |
|---|
| 44 | USE wrk_nemo ! work arrays |
|---|
| 45 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 46 | |
|---|
| 47 | IMPLICIT NONE |
|---|
| 48 | PRIVATE |
|---|
| 49 | |
|---|
| 50 | PUBLIC lim_sbc_init ! called by ice_init |
|---|
| 51 | PUBLIC lim_sbc_flx ! called by ice_stp |
|---|
| 52 | PUBLIC lim_sbc_tau ! called by ice_stp |
|---|
| 53 | |
|---|
| 54 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 57 | |
|---|
| 58 | !! * Substitutions |
|---|
| 59 | # include "vectopt_loop_substitute.h90" |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 62 | !! $Id$ |
|---|
| 63 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | CONTAINS |
|---|
| 66 | |
|---|
| 67 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 68 | !!------------------------------------------------------------------- |
|---|
| 69 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 70 | !!------------------------------------------------------------------- |
|---|
| 71 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 72 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 73 | ! |
|---|
| 74 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 75 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 76 | END FUNCTION lim_sbc_alloc |
|---|
| 77 | |
|---|
| 78 | |
|---|
| 79 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 80 | !!------------------------------------------------------------------- |
|---|
| 81 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 82 | !! |
|---|
| 83 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 84 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 85 | !! |
|---|
| 86 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 87 | !! at the ice-ocean interface. |
|---|
| 88 | !! - Update the ocean sbc |
|---|
| 89 | !! |
|---|
| 90 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 91 | !! - qns : sea heat flux: non solar |
|---|
| 92 | !! - emp : freshwater budget: volume flux |
|---|
| 93 | !! - sfx : salt flux |
|---|
| 94 | !! - fr_i : ice fraction |
|---|
| 95 | !! - tn_ice : sea-ice surface temperature |
|---|
| 96 | !! - alb_ice : sea-ice albedo (recomputed only for coupled mode) |
|---|
| 97 | !! |
|---|
| 98 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 99 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 100 | !! These refs are now obsolete since everything has been revised |
|---|
| 101 | !! The ref should be Rousset et al., 2015 |
|---|
| 102 | !!--------------------------------------------------------------------- |
|---|
| 103 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 104 | ! |
|---|
| 105 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 106 | REAL(wp) :: zqmass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 107 | REAL(wp) :: zqsr ! New solar flux received by the ocean |
|---|
| 108 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_cs, zalb_os ! 3D workspace |
|---|
| 109 | REAL(wp), POINTER, DIMENSION(:,:) :: zalb ! 2D workspace |
|---|
| 110 | !!--------------------------------------------------------------------- |
|---|
| 111 | |
|---|
| 112 | ! --- case we bypass ice thermodynamics --- ! |
|---|
| 113 | IF( .NOT. ln_limthd ) THEN ! we suppose ice is impermeable => ocean is isolated from atmosphere |
|---|
| 114 | hfx_in (:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:) |
|---|
| 115 | hfx_out (:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:) |
|---|
| 116 | ftr_ice (:,:,:) = 0._wp |
|---|
| 117 | emp_ice (:,:) = 0._wp |
|---|
| 118 | qemp_ice (:,:) = 0._wp |
|---|
| 119 | qevap_ice(:,:,:) = 0._wp |
|---|
| 120 | ENDIF |
|---|
| 121 | |
|---|
| 122 | ! albedo output |
|---|
| 123 | CALL wrk_alloc( jpi,jpj, zalb ) |
|---|
| 124 | |
|---|
| 125 | zalb(:,:) = 0._wp |
|---|
| 126 | WHERE ( at_i_b <= epsi06 ) ; zalb(:,:) = rn_alb_oce |
|---|
| 127 | ELSEWHERE ; zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b |
|---|
| 128 | END WHERE |
|---|
| 129 | IF( iom_use('icealb' ) ) CALL iom_put( "icealb" , zalb(:,:) ) ! ice albedo output |
|---|
| 130 | |
|---|
| 131 | zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b ) |
|---|
| 132 | IF( iom_use('albedo' ) ) CALL iom_put( "albedo" , zalb(:,:) ) ! surface albedo output |
|---|
| 133 | |
|---|
| 134 | CALL wrk_dealloc( jpi,jpj, zalb ) |
|---|
| 135 | |
|---|
| 136 | DO jj = 1, jpj |
|---|
| 137 | DO ji = 1, jpi |
|---|
| 138 | |
|---|
| 139 | !------------------------------------------! |
|---|
| 140 | ! heat flux at the ocean surface ! |
|---|
| 141 | !------------------------------------------! |
|---|
| 142 | ! Solar heat flux reaching the ocean = zqsr (W.m-2) |
|---|
| 143 | !--------------------------------------------------- |
|---|
| 144 | zqsr = qsr_tot(ji,jj) |
|---|
| 145 | DO jl = 1, jpl |
|---|
| 146 | zqsr = zqsr - a_i_b(ji,jj,jl) * ( qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) |
|---|
| 147 | END DO |
|---|
| 148 | |
|---|
| 149 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 150 | !--------------------------------------------------- |
|---|
| 151 | zqmass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 152 | hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr |
|---|
| 153 | |
|---|
| 154 | ! Add the residual from heat diffusion equation and sublimation (W.m-2) |
|---|
| 155 | !---------------------------------------------------------------------- |
|---|
| 156 | hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) + & |
|---|
| 157 | & ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) ) |
|---|
| 158 | |
|---|
| 159 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 160 | !---------------------------------------------------------------------------- |
|---|
| 161 | qsr(ji,jj) = zqsr |
|---|
| 162 | qns(ji,jj) = hfx_out(ji,jj) - zqsr |
|---|
| 163 | |
|---|
| 164 | !------------------------------------------! |
|---|
| 165 | ! mass flux at the ocean surface ! |
|---|
| 166 | !------------------------------------------! |
|---|
| 167 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 168 | ! ------------------------------------------------------------------------------------- |
|---|
| 169 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 170 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 171 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 172 | ! Associated to Ice formation AND Ice melting |
|---|
| 173 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 174 | ! |
|---|
| 175 | ! mass flux from ice/ocean |
|---|
| 176 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) & |
|---|
| 177 | + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) |
|---|
| 178 | |
|---|
| 179 | IF ( ln_pnd_fw ) & |
|---|
| 180 | wfx_ice(ji,jj) = wfx_ice(ji,jj) + wfx_pnd(ji,jj) |
|---|
| 181 | |
|---|
| 182 | ! add the snow melt water to snow mass flux to the ocean |
|---|
| 183 | wfx_snw(ji,jj) = wfx_snw(ji,jj) + wfx_snw_sum(ji,jj) |
|---|
| 184 | |
|---|
| 185 | ! mass flux at the ocean/ice interface |
|---|
| 186 | fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) ) ! F/M mass flux save at least for biogeochemical model |
|---|
| 187 | emp(ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 188 | END DO |
|---|
| 189 | END DO |
|---|
| 190 | |
|---|
| 191 | !------------------------------------------! |
|---|
| 192 | ! salt flux at the ocean surface ! |
|---|
| 193 | !------------------------------------------! |
|---|
| 194 | sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:) & |
|---|
| 195 | & + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:) + sfx_sub(:,:) + sfx_lam(:,:) |
|---|
| 196 | |
|---|
| 197 | !----------------------------------------! |
|---|
| 198 | ! mass of snow and ice per unit area ! |
|---|
| 199 | !----------------------------------------! |
|---|
| 200 | ! save mass from the previous ice time step |
|---|
| 201 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 202 | ! new mass per unit area |
|---|
| 203 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 204 | ! time evolution of snow+ice mass |
|---|
| 205 | snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice |
|---|
| 206 | |
|---|
| 207 | !-----------------------------------------------! |
|---|
| 208 | ! Storing the transmitted variables ! |
|---|
| 209 | !-----------------------------------------------! |
|---|
| 210 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 211 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 212 | |
|---|
| 213 | !------------------------------------------------------------------------! |
|---|
| 214 | ! Snow/ice albedo (only if sent to coupler, useless in forced mode) ! |
|---|
| 215 | !------------------------------------------------------------------------! |
|---|
| 216 | CALL wrk_alloc( jpi,jpj,jpl, zalb_cs, zalb_os ) |
|---|
| 217 | CALL albedo_ice( t_su, ht_i, ht_s, a_ip_frac, h_ip, ln_pnd_rad, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 218 | |
|---|
| 219 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 220 | CALL wrk_dealloc( jpi,jpj,jpl, zalb_cs, zalb_os ) |
|---|
| 221 | |
|---|
| 222 | ! conservation test |
|---|
| 223 | IF( ln_limdiachk .AND. .NOT. ln_bdy) CALL lim_cons_final( 'limsbc' ) |
|---|
| 224 | |
|---|
| 225 | ! control prints |
|---|
| 226 | IF( ln_limctl ) CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' ) |
|---|
| 227 | IF( ln_ctl ) CALL lim_prt3D( 'limsbc' ) |
|---|
| 228 | |
|---|
| 229 | END SUBROUTINE lim_sbc_flx |
|---|
| 230 | |
|---|
| 231 | |
|---|
| 232 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 233 | !!------------------------------------------------------------------- |
|---|
| 234 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 235 | !! |
|---|
| 236 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 237 | !! |
|---|
| 238 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 239 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 240 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 241 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 242 | !! - update the modulus of stress at ocean surface |
|---|
| 243 | !! taum = (1-a) * taum + a * tmod_io * | U_ice-U_oce | |
|---|
| 244 | !! * at each ocean time step (every kt): |
|---|
| 245 | !! compute linearized ice-ocean stresses as |
|---|
| 246 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 247 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 248 | !! |
|---|
| 249 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 250 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 251 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 252 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 253 | !! |
|---|
| 254 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 255 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 256 | !!--------------------------------------------------------------------- |
|---|
| 257 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 258 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 259 | ! |
|---|
| 260 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 261 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 262 | REAL(wp) :: zat_v, zvtau_ice, zv_t, zrhoco ! - - |
|---|
| 263 | !!--------------------------------------------------------------------- |
|---|
| 264 | zrhoco = rau0 * rn_cio |
|---|
| 265 | ! |
|---|
| 266 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 267 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 268 | DO ji = fs_2, fs_jpim1 |
|---|
| 269 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 270 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 271 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 272 | ! ! |U_ice-U_oce|^2 |
|---|
| 273 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 274 | ! ! update the ocean stress modulus |
|---|
| 275 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt |
|---|
| 276 | tmod_io(ji,jj) = zrhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 277 | END DO |
|---|
| 278 | END DO |
|---|
| 279 | CALL lbc_lnk_multi( taum, 'T', 1., tmod_io, 'T', 1. ) |
|---|
| 280 | ! |
|---|
| 281 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 282 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 283 | ! |
|---|
| 284 | ENDIF |
|---|
| 285 | ! |
|---|
| 286 | ! !== every ocean time-step ==! |
|---|
| 287 | ! |
|---|
| 288 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 289 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 290 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 291 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 292 | ! ! linearized quadratic drag formulation |
|---|
| 293 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 294 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 295 | ! ! stresses at the ocean surface |
|---|
| 296 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 297 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 298 | END DO |
|---|
| 299 | END DO |
|---|
| 300 | CALL lbc_lnk_multi( utau, 'U', -1., vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 301 | ! |
|---|
| 302 | ! |
|---|
| 303 | END SUBROUTINE lim_sbc_tau |
|---|
| 304 | |
|---|
| 305 | |
|---|
| 306 | SUBROUTINE lim_sbc_init |
|---|
| 307 | !!------------------------------------------------------------------- |
|---|
| 308 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 309 | !! |
|---|
| 310 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 311 | !! the temporal evolution of key variables |
|---|
| 312 | !! |
|---|
| 313 | !! ** input : Namelist namicedia |
|---|
| 314 | !!------------------------------------------------------------------- |
|---|
| 315 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 316 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 317 | !!------------------------------------------------------------------- |
|---|
| 318 | ! |
|---|
| 319 | IF(lwp) WRITE(numout,*) |
|---|
| 320 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 321 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 322 | |
|---|
| 323 | ! ! allocate lim_sbc array |
|---|
| 324 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 325 | ! |
|---|
| 326 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 327 | sice_0(:,:) = sice |
|---|
| 328 | ! ! decrease ocean & ice reference salinities in the Baltic Sea area |
|---|
| 329 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 330 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 331 | soce_0(:,:) = 4._wp |
|---|
| 332 | sice_0(:,:) = 2._wp |
|---|
| 333 | END WHERE |
|---|
| 334 | ! |
|---|
| 335 | IF( .NOT. ln_rstart ) THEN |
|---|
| 336 | ! |
|---|
| 337 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) ! snow+ice mass |
|---|
| 338 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 339 | ! |
|---|
| 340 | IF( ln_ice_embd ) THEN ! embedded sea-ice: deplete the initial ssh below sea-ice area |
|---|
| 341 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 342 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 343 | |
|---|
| 344 | !!gm I really don't like this stuff here... Find a way to put that elsewhere or differently |
|---|
| 345 | !!gm |
|---|
| 346 | IF( .NOT.ln_linssh ) THEN |
|---|
| 347 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 348 | e3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 349 | e3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 350 | END DO |
|---|
| 351 | e3t_a(:,:,:) = e3t_b(:,:,:) |
|---|
| 352 | ! Reconstruction of all vertical scale factors at now and before time-steps |
|---|
| 353 | ! ========================================================================= |
|---|
| 354 | ! Horizontal scale factor interpolations |
|---|
| 355 | ! -------------------------------------- |
|---|
| 356 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3u_b(:,:,:), 'U' ) |
|---|
| 357 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3v_b(:,:,:), 'V' ) |
|---|
| 358 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3u_n(:,:,:), 'U' ) |
|---|
| 359 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3v_n(:,:,:), 'V' ) |
|---|
| 360 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3f_n(:,:,:), 'F' ) |
|---|
| 361 | ! Vertical scale factor interpolations |
|---|
| 362 | ! ------------------------------------ |
|---|
| 363 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3w_n (:,:,:), 'W' ) |
|---|
| 364 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3uw_n(:,:,:), 'UW' ) |
|---|
| 365 | CALL dom_vvl_interpol( e3v_n(:,:,:), e3vw_n(:,:,:), 'VW' ) |
|---|
| 366 | CALL dom_vvl_interpol( e3u_b(:,:,:), e3uw_b(:,:,:), 'UW' ) |
|---|
| 367 | CALL dom_vvl_interpol( e3v_b(:,:,:), e3vw_b(:,:,:), 'VW' ) |
|---|
| 368 | ! t- and w- points depth |
|---|
| 369 | ! ---------------------- |
|---|
| 370 | !!gm not sure of that.... |
|---|
| 371 | gdept_n(:,:,1) = 0.5_wp * e3w_n(:,:,1) |
|---|
| 372 | gdepw_n(:,:,1) = 0.0_wp |
|---|
| 373 | gde3w_n(:,:,1) = gdept_n(:,:,1) - sshn(:,:) |
|---|
| 374 | DO jk = 2, jpk |
|---|
| 375 | gdept_n(:,:,jk) = gdept_n(:,:,jk-1) + e3w_n(:,:,jk) |
|---|
| 376 | gdepw_n(:,:,jk) = gdepw_n(:,:,jk-1) + e3t_n(:,:,jk-1) |
|---|
| 377 | gde3w_n(:,:,jk) = gdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 378 | END DO |
|---|
| 379 | ENDIF |
|---|
| 380 | ENDIF |
|---|
| 381 | ENDIF ! .NOT. ln_rstart |
|---|
| 382 | ! |
|---|
| 383 | END SUBROUTINE lim_sbc_init |
|---|
| 384 | |
|---|
| 385 | #else |
|---|
| 386 | !!---------------------------------------------------------------------- |
|---|
| 387 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 388 | !!---------------------------------------------------------------------- |
|---|
| 389 | CONTAINS |
|---|
| 390 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 391 | END SUBROUTINE lim_sbc |
|---|
| 392 | #endif |
|---|
| 393 | |
|---|
| 394 | !!====================================================================== |
|---|
| 395 | END MODULE limsbc |
|---|
