| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE oce , ONLY : sshn, sshb |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE ice ! LIM sea-ice variables |
|---|
| 30 | USE sbc_ice , ONLY : emp_oce, qns_oce, qsr_oce, qemp_oce, emp_ice, qsr_ice, qemp_ice, qevap_ice, alb_ice, tn_ice, cldf_ice, & |
|---|
| 31 | & snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 32 | USE sbc_oce , ONLY : nn_fsbc, ln_ice_embd, sfx, fr_i, qsr_tot, qns, qsr, fmmflx, emp, taum, utau, vtau |
|---|
| 33 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 34 | USE albedoice ! albedo parameters |
|---|
| 35 | USE traqsr ! add penetration of solar flux in the calculation of heat budget |
|---|
| 36 | USE domvvl ! Variable volume |
|---|
| 37 | USE limctl ! |
|---|
| 38 | USE limcons ! |
|---|
| 39 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 40 | ! |
|---|
| 41 | USE in_out_manager ! I/O manager |
|---|
| 42 | USE iom ! xIO server |
|---|
| 43 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 44 | USE lib_mpp ! MPP library |
|---|
| 45 | USE wrk_nemo ! work arrays |
|---|
| 46 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 47 | |
|---|
| 48 | IMPLICIT NONE |
|---|
| 49 | PRIVATE |
|---|
| 50 | |
|---|
| 51 | PUBLIC lim_sbc_init ! called by ice_init |
|---|
| 52 | PUBLIC lim_sbc_flx ! called by ice_stp |
|---|
| 53 | PUBLIC lim_sbc_tau ! called by ice_stp |
|---|
| 54 | |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 57 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 58 | |
|---|
| 59 | !! * Substitutions |
|---|
| 60 | # include "vectopt_loop_substitute.h90" |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 63 | !! $Id$ |
|---|
| 64 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | CONTAINS |
|---|
| 67 | |
|---|
| 68 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 69 | !!------------------------------------------------------------------- |
|---|
| 70 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 71 | !!------------------------------------------------------------------- |
|---|
| 72 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 73 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 74 | ! |
|---|
| 75 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 76 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 77 | END FUNCTION lim_sbc_alloc |
|---|
| 78 | |
|---|
| 79 | |
|---|
| 80 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 81 | !!------------------------------------------------------------------- |
|---|
| 82 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 83 | !! |
|---|
| 84 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 85 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 86 | !! |
|---|
| 87 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 88 | !! at the ice-ocean interface. |
|---|
| 89 | !! - Update the ocean sbc |
|---|
| 90 | !! |
|---|
| 91 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 92 | !! - qns : sea heat flux: non solar |
|---|
| 93 | !! - emp : freshwater budget: volume flux |
|---|
| 94 | !! - sfx : salt flux |
|---|
| 95 | !! - fr_i : ice fraction |
|---|
| 96 | !! - tn_ice : sea-ice surface temperature |
|---|
| 97 | !! - alb_ice : sea-ice albedo (recomputed only for coupled mode) |
|---|
| 98 | !! |
|---|
| 99 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 100 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 101 | !! These refs are now obsolete since everything has been revised |
|---|
| 102 | !! The ref should be Rousset et al., 2015 |
|---|
| 103 | !!--------------------------------------------------------------------- |
|---|
| 104 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 105 | ! |
|---|
| 106 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 107 | REAL(wp) :: zqmass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 108 | REAL(wp) :: zqsr ! New solar flux received by the ocean |
|---|
| 109 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_cs, zalb_os ! 3D workspace |
|---|
| 110 | REAL(wp), POINTER, DIMENSION(:,:) :: zalb ! 2D workspace |
|---|
| 111 | !!--------------------------------------------------------------------- |
|---|
| 112 | |
|---|
| 113 | ! --- case we bypass ice thermodynamics --- ! |
|---|
| 114 | IF( .NOT. ln_limthd ) THEN ! we suppose ice is impermeable => ocean is isolated from atmosphere |
|---|
| 115 | hfx_in (:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:) |
|---|
| 116 | hfx_out (:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:) |
|---|
| 117 | ftr_ice (:,:,:) = 0._wp |
|---|
| 118 | emp_ice (:,:) = 0._wp |
|---|
| 119 | qemp_ice (:,:) = 0._wp |
|---|
| 120 | qevap_ice(:,:,:) = 0._wp |
|---|
| 121 | ENDIF |
|---|
| 122 | |
|---|
| 123 | ! albedo output |
|---|
| 124 | CALL wrk_alloc( jpi,jpj, zalb ) |
|---|
| 125 | |
|---|
| 126 | zalb(:,:) = 0._wp |
|---|
| 127 | WHERE ( at_i_b <= epsi06 ) ; zalb(:,:) = rn_alb_oce |
|---|
| 128 | ELSEWHERE ; zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b |
|---|
| 129 | END WHERE |
|---|
| 130 | IF( iom_use('icealb' ) ) CALL iom_put( "icealb" , zalb(:,:) ) ! ice albedo output |
|---|
| 131 | |
|---|
| 132 | zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b ) |
|---|
| 133 | IF( iom_use('albedo' ) ) CALL iom_put( "albedo" , zalb(:,:) ) ! surface albedo output |
|---|
| 134 | |
|---|
| 135 | CALL wrk_dealloc( jpi,jpj, zalb ) |
|---|
| 136 | |
|---|
| 137 | DO jj = 1, jpj |
|---|
| 138 | DO ji = 1, jpi |
|---|
| 139 | |
|---|
| 140 | !------------------------------------------! |
|---|
| 141 | ! heat flux at the ocean surface ! |
|---|
| 142 | !------------------------------------------! |
|---|
| 143 | ! Solar heat flux reaching the ocean = zqsr (W.m-2) |
|---|
| 144 | !--------------------------------------------------- |
|---|
| 145 | zqsr = qsr_tot(ji,jj) |
|---|
| 146 | DO jl = 1, jpl |
|---|
| 147 | zqsr = zqsr - a_i_b(ji,jj,jl) * ( qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) |
|---|
| 148 | END DO |
|---|
| 149 | |
|---|
| 150 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 151 | !--------------------------------------------------- |
|---|
| 152 | zqmass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 153 | hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr |
|---|
| 154 | |
|---|
| 155 | ! Add the residual from heat diffusion equation and sublimation (W.m-2) |
|---|
| 156 | !---------------------------------------------------------------------- |
|---|
| 157 | hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) + & |
|---|
| 158 | & ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) ) |
|---|
| 159 | |
|---|
| 160 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 161 | !---------------------------------------------------------------------------- |
|---|
| 162 | qsr(ji,jj) = zqsr |
|---|
| 163 | qns(ji,jj) = hfx_out(ji,jj) - zqsr |
|---|
| 164 | |
|---|
| 165 | !------------------------------------------! |
|---|
| 166 | ! mass flux at the ocean surface ! |
|---|
| 167 | !------------------------------------------! |
|---|
| 168 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 169 | ! ------------------------------------------------------------------------------------- |
|---|
| 170 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 171 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 172 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 173 | ! Associated to Ice formation AND Ice melting |
|---|
| 174 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 175 | ! |
|---|
| 176 | ! mass flux from ice/ocean |
|---|
| 177 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) & |
|---|
| 178 | + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) |
|---|
| 179 | |
|---|
| 180 | IF ( ln_pnd_fw ) & |
|---|
| 181 | wfx_ice(ji,jj) = wfx_ice(ji,jj) + wfx_pnd(ji,jj) |
|---|
| 182 | |
|---|
| 183 | ! add the snow melt water to snow mass flux to the ocean |
|---|
| 184 | wfx_snw(ji,jj) = wfx_snw(ji,jj) + wfx_snw_sum(ji,jj) |
|---|
| 185 | |
|---|
| 186 | ! mass flux at the ocean/ice interface |
|---|
| 187 | fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) ) ! F/M mass flux save at least for biogeochemical model |
|---|
| 188 | emp(ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 189 | END DO |
|---|
| 190 | END DO |
|---|
| 191 | |
|---|
| 192 | !------------------------------------------! |
|---|
| 193 | ! salt flux at the ocean surface ! |
|---|
| 194 | !------------------------------------------! |
|---|
| 195 | sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:) & |
|---|
| 196 | & + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:) + sfx_sub(:,:) + sfx_lam(:,:) |
|---|
| 197 | |
|---|
| 198 | !----------------------------------------! |
|---|
| 199 | ! mass of snow and ice per unit area ! |
|---|
| 200 | !----------------------------------------! |
|---|
| 201 | ! save mass from the previous ice time step |
|---|
| 202 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 203 | ! new mass per unit area |
|---|
| 204 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 205 | ! time evolution of snow+ice mass |
|---|
| 206 | snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice |
|---|
| 207 | |
|---|
| 208 | !-----------------------------------------------! |
|---|
| 209 | ! Storing the transmitted variables ! |
|---|
| 210 | !-----------------------------------------------! |
|---|
| 211 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 212 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 213 | |
|---|
| 214 | !------------------------------------------------------------------------! |
|---|
| 215 | ! Snow/ice albedo (only if sent to coupler, useless in forced mode) ! |
|---|
| 216 | !------------------------------------------------------------------------! |
|---|
| 217 | CALL wrk_alloc( jpi,jpj,jpl, zalb_cs, zalb_os ) |
|---|
| 218 | CALL albedo_ice( t_su, ht_i, ht_s, a_ip_frac, h_ip, ln_pnd_rad, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 219 | |
|---|
| 220 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 221 | CALL wrk_dealloc( jpi,jpj,jpl, zalb_cs, zalb_os ) |
|---|
| 222 | |
|---|
| 223 | ! conservation test |
|---|
| 224 | IF( ln_limdiachk .AND. .NOT. ln_bdy) CALL lim_cons_final( 'limsbc' ) |
|---|
| 225 | |
|---|
| 226 | ! control prints |
|---|
| 227 | IF( ln_limctl ) CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' ) |
|---|
| 228 | IF( ln_ctl ) CALL lim_prt3D( 'limsbc' ) |
|---|
| 229 | |
|---|
| 230 | END SUBROUTINE lim_sbc_flx |
|---|
| 231 | |
|---|
| 232 | |
|---|
| 233 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 234 | !!------------------------------------------------------------------- |
|---|
| 235 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 236 | !! |
|---|
| 237 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 238 | !! |
|---|
| 239 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 240 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 241 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 242 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 243 | !! - update the modulus of stress at ocean surface |
|---|
| 244 | !! taum = (1-a) * taum + a * tmod_io * | U_ice-U_oce | |
|---|
| 245 | !! * at each ocean time step (every kt): |
|---|
| 246 | !! compute linearized ice-ocean stresses as |
|---|
| 247 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 248 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 249 | !! |
|---|
| 250 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 251 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 252 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 253 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 254 | !! |
|---|
| 255 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 256 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 257 | !!--------------------------------------------------------------------- |
|---|
| 258 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 259 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 260 | ! |
|---|
| 261 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 262 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 263 | REAL(wp) :: zat_v, zvtau_ice, zv_t, zrhoco ! - - |
|---|
| 264 | !!--------------------------------------------------------------------- |
|---|
| 265 | zrhoco = rau0 * rn_cio |
|---|
| 266 | ! |
|---|
| 267 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 268 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 269 | DO ji = fs_2, fs_jpim1 |
|---|
| 270 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 271 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 272 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 273 | ! ! |U_ice-U_oce|^2 |
|---|
| 274 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 275 | ! ! update the ocean stress modulus |
|---|
| 276 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt |
|---|
| 277 | tmod_io(ji,jj) = zrhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 278 | END DO |
|---|
| 279 | END DO |
|---|
| 280 | CALL lbc_lnk_multi( taum, 'T', 1., tmod_io, 'T', 1. ) |
|---|
| 281 | ! |
|---|
| 282 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 283 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 284 | ! |
|---|
| 285 | ENDIF |
|---|
| 286 | ! |
|---|
| 287 | ! !== every ocean time-step ==! |
|---|
| 288 | ! |
|---|
| 289 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 290 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 291 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 292 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 293 | ! ! linearized quadratic drag formulation |
|---|
| 294 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 295 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 296 | ! ! stresses at the ocean surface |
|---|
| 297 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 298 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 299 | END DO |
|---|
| 300 | END DO |
|---|
| 301 | CALL lbc_lnk_multi( utau, 'U', -1., vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 302 | ! |
|---|
| 303 | ! |
|---|
| 304 | END SUBROUTINE lim_sbc_tau |
|---|
| 305 | |
|---|
| 306 | |
|---|
| 307 | SUBROUTINE lim_sbc_init |
|---|
| 308 | !!------------------------------------------------------------------- |
|---|
| 309 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 310 | !! |
|---|
| 311 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 312 | !! the temporal evolution of key variables |
|---|
| 313 | !! |
|---|
| 314 | !! ** input : Namelist namicedia |
|---|
| 315 | !!------------------------------------------------------------------- |
|---|
| 316 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 317 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 318 | !!------------------------------------------------------------------- |
|---|
| 319 | ! |
|---|
| 320 | IF(lwp) WRITE(numout,*) |
|---|
| 321 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 322 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 323 | |
|---|
| 324 | ! ! allocate lim_sbc array |
|---|
| 325 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 326 | ! |
|---|
| 327 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 328 | sice_0(:,:) = sice |
|---|
| 329 | ! ! decrease ocean & ice reference salinities in the Baltic Sea area |
|---|
| 330 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 331 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 332 | soce_0(:,:) = 4._wp |
|---|
| 333 | sice_0(:,:) = 2._wp |
|---|
| 334 | END WHERE |
|---|
| 335 | ! |
|---|
| 336 | IF( .NOT. ln_rstart ) THEN |
|---|
| 337 | ! |
|---|
| 338 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) ! snow+ice mass |
|---|
| 339 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 340 | ! |
|---|
| 341 | IF( ln_ice_embd ) THEN ! embedded sea-ice: deplete the initial ssh below sea-ice area |
|---|
| 342 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 343 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 344 | |
|---|
| 345 | !!gm I really don't like this stuff here... Find a way to put that elsewhere or differently |
|---|
| 346 | !!gm |
|---|
| 347 | IF( .NOT.ln_linssh ) THEN |
|---|
| 348 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 349 | e3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 350 | e3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 351 | END DO |
|---|
| 352 | e3t_a(:,:,:) = e3t_b(:,:,:) |
|---|
| 353 | ! Reconstruction of all vertical scale factors at now and before time-steps |
|---|
| 354 | ! ========================================================================= |
|---|
| 355 | ! Horizontal scale factor interpolations |
|---|
| 356 | ! -------------------------------------- |
|---|
| 357 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3u_b(:,:,:), 'U' ) |
|---|
| 358 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3v_b(:,:,:), 'V' ) |
|---|
| 359 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3u_n(:,:,:), 'U' ) |
|---|
| 360 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3v_n(:,:,:), 'V' ) |
|---|
| 361 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3f_n(:,:,:), 'F' ) |
|---|
| 362 | ! Vertical scale factor interpolations |
|---|
| 363 | ! ------------------------------------ |
|---|
| 364 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3w_n (:,:,:), 'W' ) |
|---|
| 365 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3uw_n(:,:,:), 'UW' ) |
|---|
| 366 | CALL dom_vvl_interpol( e3v_n(:,:,:), e3vw_n(:,:,:), 'VW' ) |
|---|
| 367 | CALL dom_vvl_interpol( e3u_b(:,:,:), e3uw_b(:,:,:), 'UW' ) |
|---|
| 368 | CALL dom_vvl_interpol( e3v_b(:,:,:), e3vw_b(:,:,:), 'VW' ) |
|---|
| 369 | ! t- and w- points depth |
|---|
| 370 | ! ---------------------- |
|---|
| 371 | !!gm not sure of that.... |
|---|
| 372 | gdept_n(:,:,1) = 0.5_wp * e3w_n(:,:,1) |
|---|
| 373 | gdepw_n(:,:,1) = 0.0_wp |
|---|
| 374 | gde3w_n(:,:,1) = gdept_n(:,:,1) - sshn(:,:) |
|---|
| 375 | DO jk = 2, jpk |
|---|
| 376 | gdept_n(:,:,jk) = gdept_n(:,:,jk-1) + e3w_n(:,:,jk) |
|---|
| 377 | gdepw_n(:,:,jk) = gdepw_n(:,:,jk-1) + e3t_n(:,:,jk-1) |
|---|
| 378 | gde3w_n(:,:,jk) = gdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 379 | END DO |
|---|
| 380 | ENDIF |
|---|
| 381 | ENDIF |
|---|
| 382 | ENDIF ! .NOT. ln_rstart |
|---|
| 383 | ! |
|---|
| 384 | END SUBROUTINE lim_sbc_init |
|---|
| 385 | |
|---|
| 386 | #else |
|---|
| 387 | !!---------------------------------------------------------------------- |
|---|
| 388 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 389 | !!---------------------------------------------------------------------- |
|---|
| 390 | CONTAINS |
|---|
| 391 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 392 | END SUBROUTINE lim_sbc |
|---|
| 393 | #endif |
|---|
| 394 | |
|---|
| 395 | !!====================================================================== |
|---|
| 396 | END MODULE limsbc |
|---|
