New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8342

Last change on this file since 8342 was 8342, checked in by clem, 7 years ago

simplify the code
  • Property svn:keywords set to Id
File size: 36.3 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! sea-ice variables
25   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
26   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
27      &                 fr1_i0, fr2_i0, nn_limflx
28   USE thd_ice        ! thermodynamic sea-ice variables
29   USE limthd_dif     ! vertical diffusion
30   USE limthd_dh      ! ice-snow growth and melt
31   USE limthd_da      ! lateral melting
32   USE limthd_sal     ! ice salinity
33   USE limthd_ent     ! ice enthalpy redistribution
34   USE limthd_lac     ! lateral accretion
35   USE limitd_th      ! remapping thickness distribution
36   USE limtab         ! 1D <==> 2D transformation
37   USE limvar         !
38   USE limcons        ! conservation tests
39   USE limctl         ! control print
40   !
41   USE in_out_manager ! I/O manager
42   USE lbclnk         ! lateral boundary condition - MPP links
43   USE lib_mpp        ! MPP library
44   USE wrk_nemo       ! work arrays
45   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
46   USE timing         ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   lim_thd         ! called by limstp module
52   PUBLIC   lim_thd_init    ! called by ice_init
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
86      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
87      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
88      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
89      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
90      !
91      !!-------------------------------------------------------------------
92
93      IF( nn_timing == 1 )   CALL timing_start('limthd')
94
95      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
96
97      IF( kt == nit000 .AND. lwp ) THEN
98         WRITE(numout,*)'' 
99         WRITE(numout,*)' lim_thd '
100         WRITE(numout,*)' ~~~~~~~~'
101      ENDIF
102     
103      ! conservation test
104      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
105
106      CALL lim_var_glo2eqv
107
108      !---------------------------------------------!
109      ! computation of friction velocity at T points
110      !---------------------------------------------!
111      IF( ln_limdyn ) THEN
112         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
113         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
114         DO jj = 2, jpjm1 
115            DO ji = fs_2, fs_jpim1
116               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
117                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
118                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
119            END DO
120         END DO
121      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
122         DO jj = 2, jpjm1
123            DO ji = fs_2, fs_jpim1
124               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
125                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
126                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
127            END DO
128         END DO
129      ENDIF
130      CALL lbc_lnk( zfric, 'T',  1. )
131      !
132      ftr_ice(:,:,:) = 0._wp  ! initialization (part of solar radiation transmitted through the ice)
133
134      !--------------------------------------------------------------------!
135      ! Partial computation of forcing for the thermodynamic sea ice model
136      !--------------------------------------------------------------------!
137      DO jj = 1, jpj
138         DO ji = 1, jpi
139            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
140            !
141            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
142            !           !  practically no "direct lateral ablation"
143            !           
144            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
145            !           !  temperature and turbulent mixing (McPhee, 1992)
146            !
147            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
148            zqld =  tmask(ji,jj,1) * rdt_ice *  &
149               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
150               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
151
152            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
153            ! includes supercooling potential energy (>0) or "above-freezing" energy (<0)
154            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
155
156            ! --- Above-freezing sensible heat content (J/m2 grid)
157            zqfr_neg = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * MIN( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0._wp )
158
159            ! --- Sensible ocean-to-ice heat flux (W/m2)
160            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
161            fhtur(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
162
163            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
164            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
165            !                        the freezing point, so that we do not have SST < T_freeze
166            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
167
168            !-- Energy Budget of the leads (J.m-2), source of lateral accretion. Must be < 0 to form ice
169            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
170
171            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
172            IF( zqld > 0._wp ) THEN
173               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
174               qlead(ji,jj) = 0._wp
175            ELSE
176               fhld (ji,jj) = 0._wp
177            ENDIF
178            !
179            ! Net heat flux on top of the ice-ocean [W.m-2]
180            ! ---------------------------------------------
181            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
182         END DO
183      END DO
184     
185      ! In case we bypass open-water ice formation
186      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
187      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
188      IF( .NOT. ln_limdH )  hfx_in(:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
189      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
190
191      ! ---------------------------------------------------------------------
192      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
193      ! ---------------------------------------------------------------------
194      !     First  step here              :  non solar + precip - qlead - qturb
195      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
196      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
197      DO jj = 1, jpj
198         DO ji = 1, jpi
199            hfx_out(ji,jj) = ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
200               &             - qlead(ji,jj) * r1_rdtice                                    &  ! heat flux taken from the ocean where there is open water ice formation
201               &             - at_i(ji,jj) * fhtur(ji,jj)                                  &  ! heat flux taken by turbulence
202               &             - at_i(ji,jj) *  fhld(ji,jj)                                     ! heat flux taken during bottom growth/melt
203                                                                                              !    (fhld should be 0 while bott growth)
204         END DO
205      END DO
206
207      !------------------------------------------------------------------------------!
208      ! Thermodynamic computation (only on grid points covered by ice)
209      !------------------------------------------------------------------------------!
210
211      DO jl = 1, jpl      !loop over ice categories
212
213         ! select ice covered grid points
214         nidx = 0 ; idxice(:) = 0
215         DO jj = 1, jpj
216            DO ji = 1, jpi
217               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
218                  nidx         = nidx  + 1
219                  idxice(nidx) = (jj - 1) * jpi + ji
220               ENDIF
221            END DO
222         END DO
223
224         ! debug point to follow
225         jiindex_1d = 0
226         IF( ln_limctl ) THEN
227            DO ji = mi0(iiceprt), mi1(iiceprt)
228               DO jj = mj0(jiceprt), mj1(jiceprt)
229                  jiindex_1d = (jj - 1) * jpi + ji
230                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
231               END DO
232            END DO
233         ENDIF
234
235         IF( lk_mpp )         CALL mpp_ini_ice( nidx , numout )
236
237         IF( nidx > 0 ) THEN  ! If there is no ice, do nothing.
238            !                                                               
239            s_i_new   (:) = 0._wp ; dh_s_tot (:) = 0._wp                     ! --- some init --- !
240            dh_i_surf (:) = 0._wp ; dh_i_bott(:) = 0._wp
241            dh_snowice(:) = 0._wp ; dh_i_sub (:) = 0._wp
242
243                              CALL lim_thd_1d2d( jl, 1 )               ! --- Move to 1D arrays --- !
244            !
245            DO jk = 1, nlay_i                                                ! --- Change units from J/m2 to J/m3 --- !
246               WHERE( ht_i_1d(:)>0._wp ) e_i_1d(:,jk) = e_i_1d(:,jk) / (ht_i_1d(:) * a_i_1d(:)) * nlay_i
247            ENDDO
248            DO jk = 1, nlay_s
249               WHERE( ht_s_1d(:)>0._wp ) e_s_1d(:,jk) = e_s_1d(:,jk) / (ht_s_1d(:) * a_i_1d(:)) * nlay_s
250            ENDDO
251            !
252            IF( ln_limdH )    CALL lim_thd_dif                    ! --- Ice/Snow Temperature profile --- !
253            !
254            IF( ln_limdH )    CALL lim_thd_dh                     ! --- Ice/Snow thickness --- !   
255            !
256            IF( ln_limdH )    CALL lim_thd_ent( e_i_1d(1:nidx,:) )  ! --- Ice enthalpy remapping --- !
257            !
258                              CALL lim_thd_sal                    ! --- Ice salinity --- !   
259            !
260                              CALL lim_thd_temp                   ! --- temperature update --- !
261            !
262            IF( ln_limdH ) THEN
263               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
264                              CALL lim_thd_lam                    ! --- extra lateral melting if monocat --- !
265               END IF
266            END IF
267            !
268            DO jk = 1, nlay_i                                                ! --- Change units from J/m3 to J/m2 --- !
269               e_i_1d(:,jk) = e_i_1d(:,jk) * ht_i_1d(:) * a_i_1d(:) * r1_nlay_i
270            ENDDO
271            DO jk = 1, nlay_s
272               e_s_1d(:,jk) = e_s_1d(:,jk) * ht_s_1d(:) * a_i_1d(:) * r1_nlay_s
273            ENDDO
274            !
275                              CALL lim_thd_1d2d( jl, 2 )               ! --- Move to 2D arrays --- !
276            !
277            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
278         ENDIF
279         !
280      END DO
281      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
282
283      ! Change thickness to volume
284      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
285      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
286      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
287      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
288
289      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_thd_da', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
290      IF( ln_limdA)           CALL lim_thd_da                                ! --- lateral melting --- !
291
292      ! Change thickness to volume
293      at_i(:,:)    = SUM( a_i(:,:,:), dim=3 )
294      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
295      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
296      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
297      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_thd_da', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
298
299      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
300      DO jl  = 1, jpl
301         DO jj = 1, jpj
302            DO ji = 1, jpi
303               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
304               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
305            END DO
306         END DO
307      END DO
308
309      CALL lim_var_zapsmall
310
311      ! control checks
312      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
313      !
314
315      !------------------------------------------------!
316      !  Transport ice between thickness categories
317      !------------------------------------------------!
318      ! Given thermodynamic growth rates, transport ice between thickness categories.
319      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
320
321      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
322
323      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
324
325      !------------------------------------------------!
326      !  Add frazil ice growing in leads
327      !------------------------------------------------!
328      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
329
330      IF( ln_limdO )     CALL lim_thd_lac
331     
332      ! conservation test
333      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
334
335      ! Control print
336      IF( ln_ctl )       CALL lim_prt3D( 'limthd' )
337      !
338      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
339      !
340      IF( nn_timing == 1 )  CALL timing_stop('limthd')
341
342   END SUBROUTINE lim_thd 
343
344 
345   SUBROUTINE lim_thd_temp
346      !!-----------------------------------------------------------------------
347      !!                   ***  ROUTINE lim_thd_temp ***
348      !!                 
349      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
350      !!
351      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
352      !!-------------------------------------------------------------------
353      INTEGER  ::   ji, jk   ! dummy loop indices
354      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
355      !!-------------------------------------------------------------------
356      ! Recover ice temperature
357      DO jk = 1, nlay_i
358         DO ji = 1, nidx
359            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
360            ! Conversion q(S,T) -> T (second order equation)
361            zaaa          =  cpic
362            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + e_i_1d(ji,jk) * r1_rhoic - lfus
363            zccc          =  lfus * ( ztmelts - rt0 )
364            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
365            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
366           
367            ! mask temperature
368            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
369            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
370         END DO
371      END DO 
372      !
373   END SUBROUTINE lim_thd_temp
374
375
376   SUBROUTINE lim_thd_lam
377      !!-----------------------------------------------------------------------
378      !!                   ***  ROUTINE lim_thd_lam ***
379      !!                 
380      !! ** Purpose :   Lateral melting in case monocategory
381      !!                          ( dA = A/2h dh )
382      !!-----------------------------------------------------------------------
383      INTEGER  ::   ji                 ! dummy loop indices
384      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
385      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
386      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
387      !!-----------------------------------------------------------------------
388      !
389      DO ji = 1, nidx
390         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
391         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
392            zvi          = a_i_1d(ji) * ht_i_1d(ji)
393            zvs          = a_i_1d(ji) * ht_s_1d(ji)
394            ! lateral melting = concentration change
395            zhi_bef     = ht_i_1d(ji) - zdh_mel
396            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
397            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
398            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
399            ! adjust thickness
400            ht_i_1d(ji) = zvi / a_i_1d(ji)           
401            ht_s_1d(ji) = zvs / a_i_1d(ji)           
402            ! retrieve total concentration
403            at_i_1d(ji) = a_i_1d(ji)
404         END IF
405      END DO
406      !
407   END SUBROUTINE lim_thd_lam
408
409
410   SUBROUTINE lim_thd_1d2d( jl, kn )
411      !!-----------------------------------------------------------------------
412      !!                   ***  ROUTINE lim_thd_1d2d ***
413      !!                 
414      !! ** Purpose :   move arrays from 1d to 2d and the reverse
415      !!-----------------------------------------------------------------------
416      INTEGER, INTENT(in) ::   jl       ! ice cat
417      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
418      !
419      INTEGER             ::   jk       ! dummy loop indices
420      !!-----------------------------------------------------------------------
421      !
422      SELECT CASE( kn )
423      !
424      CASE( 1 )            ! from 2D to 1D
425         !
426         CALL tab_2d_1d( nidx, idxice(1:nidx), at_i_1d(1:nidx), at_i             )
427         CALL tab_2d_1d( nidx, idxice(1:nidx), a_i_1d (1:nidx), a_i(:,:,jl)      )
428         CALL tab_2d_1d( nidx, idxice(1:nidx), ht_i_1d(1:nidx), ht_i(:,:,jl)     )
429         CALL tab_2d_1d( nidx, idxice(1:nidx), ht_s_1d(1:nidx), ht_s(:,:,jl)     )
430         CALL tab_2d_1d( nidx, idxice(1:nidx), t_su_1d(1:nidx), t_su(:,:,jl)     )
431         CALL tab_2d_1d( nidx, idxice(1:nidx), sm_i_1d(1:nidx), sm_i(:,:,jl)     )
432         DO jk = 1, nlay_s
433            CALL tab_2d_1d( nidx, idxice(1:nidx), t_s_1d(1:nidx,jk), t_s(:,:,jk,jl)   )
434            CALL tab_2d_1d( nidx, idxice(1:nidx), e_s_1d(1:nidx,jk), e_s(:,:,jk,jl)   )
435         END DO
436         DO jk = 1, nlay_i
437            CALL tab_2d_1d( nidx, idxice(1:nidx), t_i_1d(1:nidx,jk), t_i(:,:,jk,jl)   )
438            CALL tab_2d_1d( nidx, idxice(1:nidx), e_i_1d(1:nidx,jk), e_i(:,:,jk,jl)   )
439            CALL tab_2d_1d( nidx, idxice(1:nidx), s_i_1d(1:nidx,jk), s_i(:,:,jk,jl)   )
440         END DO
441         !
442         CALL tab_2d_1d( nidx, idxice(1:nidx), qprec_ice_1d(1:nidx), qprec_ice        )
443         CALL tab_2d_1d( nidx, idxice(1:nidx), qevap_ice_1d(1:nidx), qevap_ice(:,:,jl)  )
444         CALL tab_2d_1d( nidx, idxice(1:nidx), qsr_ice_1d  (1:nidx), qsr_ice(:,:,jl)  )
445         CALL tab_2d_1d( nidx, idxice(1:nidx), fr1_i0_1d   (1:nidx), fr1_i0           )
446         CALL tab_2d_1d( nidx, idxice(1:nidx), fr2_i0_1d   (1:nidx), fr2_i0           )
447         CALL tab_2d_1d( nidx, idxice(1:nidx), qns_ice_1d  (1:nidx), qns_ice(:,:,jl)  )
448         CALL tab_2d_1d( nidx, idxice(1:nidx), ftr_ice_1d  (1:nidx), ftr_ice(:,:,jl)  )
449         CALL tab_2d_1d( nidx, idxice(1:nidx), evap_ice_1d (1:nidx), evap_ice(:,:,jl) )
450         CALL tab_2d_1d( nidx, idxice(1:nidx), dqns_ice_1d (1:nidx), dqns_ice(:,:,jl) )
451         CALL tab_2d_1d( nidx, idxice(1:nidx), t_bo_1d     (1:nidx), t_bo             )
452         CALL tab_2d_1d( nidx, idxice(1:nidx), sprecip_1d  (1:nidx), sprecip          ) 
453         CALL tab_2d_1d( nidx, idxice(1:nidx), fhtur_1d    (1:nidx), fhtur            )
454         CALL tab_2d_1d( nidx, idxice(1:nidx), fhld_1d     (1:nidx), fhld             )
455         !
456         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sni_1d(1:nidx), wfx_snw_sni   )
457         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sum_1d(1:nidx), wfx_snw_sum   )
458         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sub_1d    (1:nidx), wfx_sub       )
459         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sub_1d(1:nidx), wfx_snw_sub   )
460         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_ice_sub_1d(1:nidx), wfx_ice_sub   )
461         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_err_sub_1d(1:nidx), wfx_err_sub   )
462         !
463         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_bog_1d (1:nidx), wfx_bog          )
464         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_bom_1d (1:nidx), wfx_bom          )
465         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sum_1d (1:nidx), wfx_sum          )
466         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sni_1d (1:nidx), wfx_sni          )
467         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_res_1d (1:nidx), wfx_res          )
468         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_spr_1d (1:nidx), wfx_spr          )
469         !
470         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bog_1d (1:nidx), sfx_bog          )
471         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bom_1d (1:nidx), sfx_bom          )
472         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sum_1d (1:nidx), sfx_sum          )
473         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sni_1d (1:nidx), sfx_sni          )
474         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bri_1d (1:nidx), sfx_bri          )
475         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_res_1d (1:nidx), sfx_res          )
476         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sub_1d (1:nidx), sfx_sub          )
477         !
478         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_thd_1d (1:nidx), hfx_thd          )
479         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_spr_1d (1:nidx), hfx_spr          )
480         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_sum_1d (1:nidx), hfx_sum          )
481         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_bom_1d (1:nidx), hfx_bom          )
482         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_bog_1d (1:nidx), hfx_bog          )
483         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_dif_1d (1:nidx), hfx_dif          )
484         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_opw_1d (1:nidx), hfx_opw          )
485         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_snw_1d (1:nidx), hfx_snw          )
486         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_sub_1d (1:nidx), hfx_sub          )
487         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_1d (1:nidx), hfx_err          )
488         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_res_1d (1:nidx), hfx_res          )
489         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_dif_1d(1:nidx), hfx_err_dif   )
490         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_rem_1d(1:nidx), hfx_err_rem   )
491         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_out_1d (1:nidx), hfx_out          )
492         !
493         ! SIMIP diagnostics
494         CALL tab_2d_1d( nidx, idxice(1:nidx), diag_fc_bo_1d(1:nidx), diag_fc_bo   )
495         CALL tab_2d_1d( nidx, idxice(1:nidx), diag_fc_su_1d(1:nidx), diag_fc_su   )
496         ! ocean surface fields
497         CALL tab_2d_1d( nidx, idxice(1:nidx), sst_1d(1:nidx), sst_m )
498         CALL tab_2d_1d( nidx, idxice(1:nidx), sss_1d(1:nidx), sss_m )
499         !
500      CASE( 2 )            ! from 1D to 2D
501         !
502         CALL tab_1d_2d( nidx, idxice(1:nidx), at_i_1d(1:nidx), at_i             )
503         CALL tab_1d_2d( nidx, idxice(1:nidx), a_i_1d (1:nidx), a_i(:,:,jl)      )
504         CALL tab_1d_2d( nidx, idxice(1:nidx), ht_i_1d(1:nidx), ht_i(:,:,jl)     )
505         CALL tab_1d_2d( nidx, idxice(1:nidx), ht_s_1d(1:nidx), ht_s(:,:,jl)     )
506         CALL tab_1d_2d( nidx, idxice(1:nidx), t_su_1d(1:nidx), t_su(:,:,jl)     )
507         CALL tab_1d_2d( nidx, idxice(1:nidx), sm_i_1d(1:nidx), sm_i(:,:,jl)     )
508         DO jk = 1, nlay_s
509            CALL tab_1d_2d( nidx, idxice(1:nidx), t_s_1d(1:nidx,jk), t_s(:,:,jk,jl)   )
510            CALL tab_1d_2d( nidx, idxice(1:nidx), e_s_1d(1:nidx,jk), e_s(:,:,jk,jl)   )
511         END DO
512         DO jk = 1, nlay_i
513            CALL tab_1d_2d( nidx, idxice(1:nidx), t_i_1d(1:nidx,jk), t_i(:,:,jk,jl)   )
514            CALL tab_1d_2d( nidx, idxice(1:nidx), e_i_1d(1:nidx,jk), e_i(:,:,jk,jl)   )
515            CALL tab_1d_2d( nidx, idxice(1:nidx), s_i_1d(1:nidx,jk), s_i(:,:,jk,jl)   )
516         END DO
517         !
518         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sni_1d(1:nidx), wfx_snw_sni   )
519         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sum_1d(1:nidx), wfx_snw_sum   )
520         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sub_1d    (1:nidx), wfx_sub       )
521         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sub_1d(1:nidx), wfx_snw_sub   )
522         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_ice_sub_1d(1:nidx), wfx_ice_sub   )
523         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_err_sub_1d(1:nidx), wfx_err_sub   )
524         !
525         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_bog_1d (1:nidx), wfx_bog          )
526         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_bom_1d (1:nidx), wfx_bom          )
527         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sum_1d (1:nidx), wfx_sum          )
528         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sni_1d (1:nidx), wfx_sni          )
529         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_res_1d (1:nidx), wfx_res          )
530         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_spr_1d (1:nidx), wfx_spr          )
531         !
532         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bog_1d (1:nidx), sfx_bog          )
533         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bom_1d (1:nidx), sfx_bom          )
534         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sum_1d (1:nidx), sfx_sum          )
535         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sni_1d (1:nidx), sfx_sni          )
536         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bri_1d (1:nidx), sfx_bri          )
537         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_res_1d (1:nidx), sfx_res          )
538         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sub_1d (1:nidx), sfx_sub          )
539
540         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_thd_1d (1:nidx), hfx_thd          )
541         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_spr_1d (1:nidx), hfx_spr          )
542         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_sum_1d (1:nidx), hfx_sum          )
543         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_bom_1d (1:nidx), hfx_bom          )
544         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_bog_1d (1:nidx), hfx_bog          )
545         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_dif_1d (1:nidx), hfx_dif          )
546         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_opw_1d (1:nidx), hfx_opw          )
547         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_snw_1d (1:nidx), hfx_snw          )
548         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_sub_1d (1:nidx), hfx_sub          )
549         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_1d (1:nidx), hfx_err          )
550         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_res_1d (1:nidx), hfx_res          )
551         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_dif_1d(1:nidx), hfx_err_dif   )
552         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_rem_1d(1:nidx), hfx_err_rem   )
553         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_out_1d (1:nidx), hfx_out          )
554
555         CALL tab_1d_2d( nidx, idxice(1:nidx), qns_ice_1d  (1:nidx), qns_ice(:,:,jl)  )
556         CALL tab_1d_2d( nidx, idxice(1:nidx), ftr_ice_1d  (1:nidx), ftr_ice(:,:,jl)  )
557         !
558         !
559         ! SIMIP diagnostics         
560         CALL tab_1d_2d( nidx, idxice(1:nidx), t_si_1d      (1:nidx), t_si(:,:,jl)      )
561         CALL tab_1d_2d( nidx, idxice(1:nidx), diag_fc_bo_1d(1:nidx), diag_fc_bo        )
562         CALL tab_1d_2d( nidx, idxice(1:nidx), diag_fc_su_1d(1:nidx), diag_fc_su        )
563      END SELECT
564      !
565   END SUBROUTINE lim_thd_1d2d
566
567
568   SUBROUTINE lim_thd_init
569      !!-----------------------------------------------------------------------
570      !!                   ***  ROUTINE lim_thd_init ***
571      !!                 
572      !! ** Purpose :   Physical constants and parameters linked to the ice
573      !!              thermodynamics
574      !!
575      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
576      !!              parameter values called at the first timestep (nit000)
577      !!
578      !! ** input   :   Namelist namicether
579      !!-------------------------------------------------------------------
580      INTEGER  ::   ios                 ! Local integer output status for namelist read
581      NAMELIST/namicethd/ rn_kappa_i, nn_ice_thcon, ln_dqnsice, rn_cdsn,                                  &
582         &                ln_limdH, rn_betas,                                                             &
583         &                ln_limdA, rn_beta, rn_dmin,                                                     &
584         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin,   &
585         &                nn_limflx
586      !!-------------------------------------------------------------------
587      !
588      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
589      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
590901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
591
592      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
593      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
594902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
595      IF(lwm) WRITE ( numoni, namicethd )
596      !
597      !
598      IF(lwp) THEN                          ! control print
599         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
600         WRITE(numout,*) '~~~~~~~~~~~~~'
601         WRITE(numout,*)'   -- limthd_dif --'
602         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
603         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
604         WRITE(numout,*)'      change the surface non-solar flux with Tsu or not       ln_dqnsice   = ', ln_dqnsice
605         WRITE(numout,*)'      thermal conductivity of the snow                        rn_cdsn      = ', rn_cdsn
606         WRITE(numout,*)'   -- limthd_dh --'
607         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
608         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
609         WRITE(numout,*)'   -- limthd_da --'
610         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
611         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
612         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
613         WRITE(numout,*)'   -- limthd_lac --'
614         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
615         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
616         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
617         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
618         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
619         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
620         WRITE(numout,*)'   -- limitd_th --'
621         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
622         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
623         WRITE(numout,*)'   -- icestp --'
624         WRITE(numout,*)'      Multicategory heat flux formulation                     nn_limflx    = ', nn_limflx
625      ENDIF
626      !
627      IF ( rn_hnewice < rn_himin )   CALL ctl_stop( 'STOP', 'lim_thd_init : rn_hnewice should be >= rn_himin' )
628      !
629      IF(lwp) WRITE(numout,*)
630      SELECT CASE( nn_limflx )         ! LIM3 Multi-category heat flux formulation
631      CASE ( -1 )
632         IF(lwp) WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
633         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
634      CASE ( 0  )
635         IF(lwp) WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
636      CASE ( 1  )
637         IF(lwp) WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
638         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
639      CASE ( 2  )
640         IF(lwp) WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
641         IF( .NOT. ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' )
642      CASE DEFAULT
643         CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' )
644      END SELECT
645      !
646   END SUBROUTINE lim_thd_init
647
648#else
649   !!----------------------------------------------------------------------
650   !!   Default option         Dummy module          NO  LIM3 sea-ice model
651   !!----------------------------------------------------------------------
652#endif
653
654   !!======================================================================
655END MODULE limthd
Note: See TracBrowser for help on using the repository browser.