New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcblk_algo_ecmwf.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/OPA_SRC/SBC/sbcblk_algo_ecmwf.F90 @ 8585

Last change on this file since 8585 was 8585, checked in by clem, 6 years ago

add option Lupkes2015 for ice-atm drag

File size: 20.8 KB
RevLine 
[6723]1MODULE sbcblk_algo_ecmwf
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_algo_ecmwf  ***
4   !! Computes turbulent components of surface fluxes
5   !!         according to the method in IFS of the ECMWF model
6   !!
7   !!   * bulk transfer coefficients C_D, C_E and C_H
8   !!   * air temp. and spec. hum. adjusted from zt (2m) to zu (10m) if needed
9   !!   * the effective bulk wind speed at 10m U_blk
10   !!   => all these are used in bulk formulas in sbcblk.F90
11   !!
12   !!    Using the bulk formulation/param. of IFS of ECMWF (cycle 31r2)
13   !!         based on IFS doc (avaible online on the ECMWF's website)
14   !!
15   !!
16   !!       Routine turb_ecmwf maintained and developed in AeroBulk
17   !!                     (http://aerobulk.sourceforge.net/)
18   !!
19   !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
20   !!----------------------------------------------------------------------
[6727]21   !! History :  4.0  !  2016-02  (L.Brodeau)   Original code
[6723]22   !!----------------------------------------------------------------------
[6727]23
24   !!----------------------------------------------------------------------
[6723]25   !!   turb_ecmwf  : computes the bulk turbulent transfer coefficients
26   !!                   adjusts t_air and q_air from zt to zu m
27   !!                   returns the effective bulk wind speed at 10m
28   !!----------------------------------------------------------------------
29   USE oce             ! ocean dynamics and tracers
30   USE dom_oce         ! ocean space and time domain
31   USE phycst          ! physical constants
32   USE iom             ! I/O manager library
33   USE lib_mpp         ! distribued memory computing library
34   USE wrk_nemo        ! work arrays
35   USE timing          ! Timing
36   USE in_out_manager  ! I/O manager
37   USE prtctl          ! Print control
38   USE sbcwave, ONLY   :  cdn_wave ! wave module
39#if defined key_lim3 || defined key_cice
40   USE sbc_ice         ! Surface boundary condition: ice fields
41#endif
42   USE lib_fortran     ! to use key_nosignedzero
43
44   USE sbc_oce         ! Surface boundary condition: ocean fields
45
46   IMPLICIT NONE
47   PRIVATE
48
[6727]49   PUBLIC ::   TURB_ECMWF   ! called by sbcblk.F90
[6723]50
51   !                   !! ECMWF own values for given constants, taken form IFS documentation...
52   REAL(wp), PARAMETER ::   charn0 = 0.018    ! Charnock constant (pretty high value here !!!
53   !                                          !    =>  Usually 0.011 for moderate winds)
54   REAL(wp), PARAMETER ::   zi0     = 1000.   ! scale height of the atmospheric boundary layer...1
55   REAL(wp), PARAMETER ::   Beta0    = 1.     ! gustiness parameter ( = 1.25 in COAREv3)
56   REAL(wp), PARAMETER ::   rctv0    = 0.608  ! constant to obtain virtual temperature...
57   REAL(wp), PARAMETER ::   Cp_dry = 1005.0   ! Specic heat of dry air, constant pressure      [J/K/kg]
58   REAL(wp), PARAMETER ::   Cp_vap = 1860.0   ! Specic heat of water vapor, constant pressure  [J/K/kg]
59   REAL(wp), PARAMETER ::   alpha_M = 0.11    ! For roughness length (smooth surface term)
60   REAL(wp), PARAMETER ::   alpha_H = 0.40    ! (Chapter 3, p.34, IFS doc Cy31r1)
61   REAL(wp), PARAMETER ::   alpha_Q = 0.62    !
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE TURB_ECMWF( zt, zu, sst, t_zt, ssq , q_zt , U_zu,   &
[8585]66      &                   Cd, Ch, Ce , t_zu, q_zu, U_blk,         &
67      &                   Cdn, Chn, Cen                           )
[6723]68      !!----------------------------------------------------------------------------------
69      !!                      ***  ROUTINE  turb_ecmwf  ***
70      !!
71      !!            2015: L. Brodeau (brodeau@gmail.com)
72      !!
73      !! ** Purpose :   Computes turbulent transfert coefficients of surface
74      !!                fluxes according to IFS doc. (cycle 31)
75      !!                If relevant (zt /= zu), adjust temperature and humidity from height zt to zu
76      !!
77      !! ** Method : Monin Obukhov Similarity Theory
78      !!
79      !! INPUT :
80      !! -------
81      !!    *  zt   : height for temperature and spec. hum. of air            [m]
82      !!    *  zu   : height for wind speed (generally 10m)                   [m]
83      !!    *  U_zu : scalar wind speed at 10m                                [m/s]
84      !!    *  sst  : SST                                                     [K]
85      !!    *  t_zt : potential air temperature at zt                         [K]
86      !!    *  ssq  : specific humidity at saturation at SST                  [kg/kg]
87      !!    *  q_zt : specific humidity of air at zt                          [kg/kg]
88      !!
89      !!
90      !! OUTPUT :
91      !! --------
92      !!    *  Cd     : drag coefficient
93      !!    *  Ch     : sensible heat coefficient
94      !!    *  Ce     : evaporation coefficient
95      !!    *  t_zu   : pot. air temperature adjusted at wind height zu       [K]
96      !!    *  q_zu   : specific humidity of air        //                    [kg/kg]
97      !!    *  U_blk  : bulk wind at 10m                                      [m/s]
98      !!
99      !!
100      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
101      !!----------------------------------------------------------------------------------
102      REAL(wp), INTENT(in   )                     ::   zt       ! height for t_zt and q_zt                    [m]
103      REAL(wp), INTENT(in   )                     ::   zu       ! height for U_zu                             [m]
104      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   sst      ! sea surface temperature                [Kelvin]
105      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   t_zt     ! potential air temperature              [Kelvin]
106      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   ssq      ! sea surface specific humidity           [kg/kg]
107      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_zt     ! specific air humidity                   [kg/kg]
108      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   U_zu     ! relative wind module at zu                [m/s]
109      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cd       ! transfer coefficient for momentum         (tau)
110      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ch       ! transfer coefficient for sensible heat (Q_sens)
111      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ce       ! transfert coefficient for evaporation   (Q_lat)
112      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   t_zu     ! pot. air temp. adjusted at zu               [K]
113      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   q_zu     ! spec. humidity adjusted at zu           [kg/kg]
114      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   U_blk    ! bulk wind at 10m                          [m/s]
[8585]115      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cdn, Chn, Cen ! neutral transfer coefficients
[6723]116      !
117      INTEGER :: j_itt
118      LOGICAL ::   l_zt_equal_zu = .FALSE.      ! if q and t are given at same height as U
119      INTEGER , PARAMETER ::   nb_itt = 4       ! number of itterations
120      !
121      REAL(wp), DIMENSION(:,:), POINTER  ::   u_star, t_star, q_star,   &
122         &  dt_zu, dq_zu,    &
123         &  znu_a,           & !: Nu_air, Viscosity of air
124         &  Linv,            & !: 1/L (inverse of Monin Obukhov length...
125         &  z0, z0t, z0q
126      REAL(wp), DIMENSION(:,:), POINTER ::   func_m, func_h
127      REAL(wp), DIMENSION(:,:), POINTER ::   ztmp0, ztmp1, ztmp2
128      !!----------------------------------------------------------------------------------
129      !
130      IF( nn_timing == 1 )   CALL timing_start('turb_ecmwf')
131      !
132      CALL wrk_alloc( jpi,jpj,   u_star, t_star, q_star, func_m, func_h, dt_zu, dq_zu, Linv )
133      CALL wrk_alloc( jpi,jpj,   znu_a, z0, z0t, z0q, ztmp0, ztmp1, ztmp2 )
134      !
135      ! Identical first gess as in COARE, with IFS parameter values though
136      !
137      l_zt_equal_zu = .FALSE.
138      IF( ABS(zu - zt) < 0.01 )   l_zt_equal_zu = .TRUE.    ! testing "zu == zt" is risky with double precision
139
140
141      !! First guess of temperature and humidity at height zu:
142      t_zu = MAX( t_zt , 0.0  )   ! who knows what's given on masked-continental regions...
143      q_zu = MAX( q_zt , 1.e-6)   !               "
144
145      !! Pot. temp. difference (and we don't want it to be 0!)
146      dt_zu = t_zu - sst   ;   dt_zu = SIGN( MAX(ABS(dt_zu),1.e-6), dt_zu )
147      dq_zu = q_zu - ssq   ;   dq_zu = SIGN( MAX(ABS(dq_zu),1.e-9), dq_zu )
148
149      znu_a = visc_air(t_zt) ! Air viscosity (m^2/s) at zt given from temperature in (K)
150
151      ztmp2 = 0.5 * 0.5  ! initial guess for wind gustiness contribution
152      U_blk = SQRT(U_zu*U_zu + ztmp2)
153
154      ! z0     = 0.0001
155      ztmp2   = 10000.     ! optimization: ztmp2 == 1/z0
156      ztmp0   = LOG(zu*ztmp2)
157      ztmp1   = LOG(10.*ztmp2)
158      u_star = 0.035*U_blk*ztmp1/ztmp0       ! (u* = 0.035*Un10)
159
160      z0     = charn0*u_star*u_star/grav + 0.11*znu_a/u_star
161      z0t    = 0.1*EXP(vkarmn/(0.00115/(vkarmn/ztmp1)))   !  WARNING: 1/z0t !
162
163      Cd     = (vkarmn/ztmp0)**2    ! first guess of Cd
164
165      ztmp0 = vkarmn*vkarmn/LOG(zt*z0t)/Cd
166
167      ztmp2 = Ri_bulk( zu, t_zu, dt_zu, q_zu, dq_zu, U_blk )   ! Ribu = Bulk Richardson number
168
169      !! First estimate of zeta_u, depending on the stability, ie sign of Ribu (ztmp2):
170      ztmp1 = 0.5 + SIGN( 0.5 , ztmp2 )
171      func_m = ztmp0*ztmp2 ! temporary array !!
172      !!             Ribu < 0                                 Ribu > 0   Beta = 1.25
173      func_h = (1.-ztmp1)*(func_m/(1.+ztmp2/(-zu/(zi0*0.004*Beta0**3)))) &  ! temporary array !!! func_h == zeta_u
174         &  +     ztmp1*(func_m*(1. + 27./9.*ztmp2/ztmp0))
175
176      !! First guess M-O stability dependent scaling params.(u*,t*,q*) to estimate z0 and z/L
177      ztmp0   =        vkarmn/(LOG(zu*z0t) - psi_h_ecmwf(func_h))
178
179      u_star = U_blk*vkarmn/(LOG(zu) - LOG(z0)  - psi_m_ecmwf(func_h))
180      t_star = dt_zu*ztmp0
181      q_star = dq_zu*ztmp0
182
183      ! What's need to be done if zt /= zu:
184      IF( .NOT. l_zt_equal_zu ) THEN
185         !
186         !! First update of values at zu (or zt for wind)
187         ztmp0 = psi_h_ecmwf(func_h) - psi_h_ecmwf(zt*func_h/zu)    ! zt*func_h/zu == zeta_t
188         ztmp1 = log(zt/zu) + ztmp0
189         t_zu = t_zt - t_star/vkarmn*ztmp1
190         q_zu = q_zt - q_star/vkarmn*ztmp1
191         q_zu = (0.5 + sign(0.5,q_zu))*q_zu !Makes it impossible to have negative humidity :
192
193         dt_zu = t_zu - sst  ; dt_zu = SIGN( MAX(ABS(dt_zu),1.E-6), dt_zu )
194         dq_zu = q_zu - ssq  ; dq_zu = SIGN( MAX(ABS(dq_zu),1.E-9), dq_zu )
195         !
196      ENDIF
197
198
199      !! => that was same first guess as in COARE...
200
201
202      !! First guess of inverse of Monin-Obukov length (1/L) :
203      ztmp0 = (1. + rctv0*q_zu)  ! the factor to apply to temp. to get virt. temp...
204      Linv  =  grav*vkarmn*(t_star*ztmp0 + rctv0*t_zu*q_star) / ( u_star*u_star * t_zu*ztmp0 )
205
206      !! Functions such as  u* = U_blk*vkarmn/func_m
207      ztmp1 = zu + z0
208      ztmp0 = ztmp1*Linv
209      func_m = LOG(ztmp1) -LOG(z0) - psi_m_ecmwf(ztmp0) + psi_m_ecmwf(z0*Linv)
210      func_h = LOG(ztmp1*z0t) - psi_h_ecmwf(ztmp0) + psi_h_ecmwf(1./z0t*Linv)
211
212
213      !! ITERATION BLOCK
214      !! ***************
215
216      DO j_itt = 1, nb_itt
217
218         !! Bulk Richardson Number at z=zu (Eq. 3.25)
219         ztmp0 = Ri_bulk(zu, t_zu, dt_zu, q_zu, dq_zu, U_blk)
220
221         !! New estimate of the inverse of the Monin-Obukhon length (Linv == zeta/zu) :
222         Linv = ztmp0*func_m*func_m/func_h / zu     ! From Eq. 3.23, Chap.3, p.33, IFS doc - Cy31r1
223
224         !! Update func_m with new Linv:
225         ztmp1 = zu + z0
226         func_m = LOG(ztmp1) -LOG(z0) - psi_m_ecmwf(ztmp1*Linv) + psi_m_ecmwf(z0*Linv)
227
228         !! Need to update roughness lengthes:
229         u_star = U_blk*vkarmn/func_m
230         ztmp2  = u_star*u_star
231         ztmp1  = znu_a/u_star
232         z0    = alpha_M*ztmp1 + charn0*ztmp2/grav
233         z0t    = alpha_H*ztmp1                              ! eq.3.26, Chap.3, p.34, IFS doc - Cy31r1
234         z0q    = alpha_Q*ztmp1
235
236         !! Update wind at 10m taking into acount convection-related wind gustiness:
237         ! Only true when unstable (L<0) => when ztmp0 < 0 => - !!!
238         ztmp2 = ztmp2 * (MAX(-zi0*Linv/vkarmn,0.))**(2./3.) ! => w*^2  (combining Eq. 3.8 and 3.18, hap.3, IFS doc - Cy31r1)
239         !! => equivalent using Beta=1 (gustiness parameter, 1.25 for COARE, also zi0=600 in COARE..)
240         U_blk = MAX(sqrt(U_zu*U_zu + ztmp2), 0.2)              ! eq.3.17, Chap.3, p.32, IFS doc - Cy31r1
241         ! => 0.2 prevents U_blk to be 0 in stable case when U_zu=0.
242
243
244         !! Need to update "theta" and "q" at zu in case they are given at different heights
245         !! as well the air-sea differences:
246         IF( .NOT. l_zt_equal_zu ) THEN
247
248            !! Arrays func_m and func_h are free for a while so using them as temporary arrays...
249            func_h = psi_h_ecmwf((zu+z0)*Linv) ! temporary array !!!
250            func_m = psi_h_ecmwf((zt+z0)*Linv) ! temporary array !!!
251
252            ztmp2  = psi_h_ecmwf(z0t*Linv)
253            ztmp0  = func_h - ztmp2
254            ztmp1  = vkarmn/(LOG(zu+z0) - LOG(z0t) - ztmp0)
255            t_star = dt_zu*ztmp1
256            ztmp2  = ztmp0 - func_m + ztmp2
257            ztmp1  = LOG(zt/zu) + ztmp2
258            t_zu   = t_zt - t_star/vkarmn*ztmp1
259
260            ztmp2  = psi_h_ecmwf(z0q*Linv)
261            ztmp0  = func_h - ztmp2
262            ztmp1  = vkarmn/(LOG(zu+z0) - LOG(z0q) - ztmp0)
263            q_star = dq_zu*ztmp1
264            ztmp2  = ztmp0 - func_m + ztmp2
265            ztmp1  = log(zt/zu) + ztmp2
266            q_zu   = q_zt - q_star/vkarmn*ztmp1
267
268            dt_zu = t_zu - sst ;  dt_zu = SIGN( MAX(ABS(dt_zu),1.E-6), dt_zu )
269            dq_zu = q_zu - ssq ;  dq_zu = SIGN( MAX(ABS(dq_zu),1.E-9), dq_zu )
[8585]270
[6723]271         END IF
272
273         !! Updating because of updated z0 and z0t and new Linv...
274         ztmp1 = zu + z0
275         ztmp0 = ztmp1*Linv
[8585]276         func_m = log(ztmp1) - LOG(z0 ) - psi_m_ecmwf(ztmp0) + psi_m_ecmwf(z0 *Linv)
[6723]277         func_h = log(ztmp1) - LOG(z0t) - psi_h_ecmwf(ztmp0) + psi_h_ecmwf(z0t*Linv)
278
279      END DO
280
281      Cd = vkarmn*vkarmn/(func_m*func_m)
282      Ch = vkarmn*vkarmn/(func_m*func_h)
283      ztmp1 = log((zu + z0)/z0q) - psi_h_ecmwf((zu + z0)*Linv) + psi_h_ecmwf(z0q*Linv)   ! func_q
284      Ce = vkarmn*vkarmn/(func_m*ztmp1)
285
[8585]286      ztmp1 = zu + z0
287      Cdn = vkarmn*vkarmn / (log(ztmp1/z0 )*log(ztmp1/z0 ))
288      Chn = vkarmn*vkarmn / (log(ztmp1/z0t)*log(ztmp1/z0t))
289      Cen = vkarmn*vkarmn / (log(ztmp1/z0q)*log(ztmp1/z0q))
290
[6723]291      CALL wrk_dealloc( jpi,jpj,   u_star, t_star, q_star, func_m, func_h, dt_zu, dq_zu, Linv )
292      CALL wrk_dealloc( jpi,jpj,   znu_a, z0, z0t, z0q, ztmp0, ztmp1, ztmp2 )
293      !
294      IF( nn_timing == 1 )   CALL timing_stop('turb_ecmwf')
295      !
296   END SUBROUTINE TURB_ECMWF
297
298
299   FUNCTION psi_m_ecmwf( pzeta )
300      !!----------------------------------------------------------------------------------
301      !! Universal profile stability function for momentum
302      !!     ECMWF / as in IFS cy31r1 documentation, available online
303      !!     at ecmwf.int
304      !!
305      !! pzeta : stability paramenter, z/L where z is altitude measurement
306      !!         and L is M-O length
307      !!
308      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
309      !!----------------------------------------------------------------------------------
310      REAL(wp), DIMENSION(jpi,jpj) :: psi_m_ecmwf
311      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta
312      !
313      INTEGER  ::   ji, jj    ! dummy loop indices
314      REAL(wp) :: zzeta, zx, ztmp, psi_unst, psi_stab, stab
315      !!----------------------------------------------------------------------------------
316      !
317      DO jj = 1, jpj
318         DO ji = 1, jpi
319            !
320            zzeta = MIN( pzeta(ji,jj) , 5. ) !! Very stable conditions (L positif and big!):
321            !
322            ! Unstable (Paulson 1970):
323            !   eq.3.20, Chap.3, p.33, IFS doc - Cy31r1
324            zx = SQRT(ABS(1. - 16.*zzeta))
325            ztmp = 1. + SQRT(zx)
326            ztmp = ztmp*ztmp
327            psi_unst = LOG( 0.125*ztmp*(1. + zx) )   &
328               &       -2.*ATAN( SQRT(zx) ) + 0.5*rpi
329            !
330            ! Unstable:
331            ! eq.3.22, Chap.3, p.33, IFS doc - Cy31r1
332            psi_stab = -2./3.*(zzeta - 5./0.35)*EXP(-0.35*zzeta) &
333               &       - zzeta - 2./3.*5./0.35
334            !
335            ! Combining:
336            stab = 0.5 + SIGN(0.5, zzeta) ! zzeta > 0 => stab = 1
337            !
338            psi_m_ecmwf(ji,jj) = (1. - stab) * psi_unst & ! (zzeta < 0) Unstable
339               &                +      stab  * psi_stab   ! (zzeta > 0) Stable
340            !
341         END DO
342      END DO
343      !
344   END FUNCTION psi_m_ecmwf
345
346   
347   FUNCTION psi_h_ecmwf( pzeta )
348      !!----------------------------------------------------------------------------------
349      !! Universal profile stability function for temperature and humidity
350      !!     ECMWF / as in IFS cy31r1 documentation, available online
351      !!     at ecmwf.int
352      !!
353      !! pzeta : stability paramenter, z/L where z is altitude measurement
354      !!         and L is M-O length
355      !!
356      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
357      !!----------------------------------------------------------------------------------
358      REAL(wp), DIMENSION(jpi,jpj) :: psi_h_ecmwf
359      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta
360      !
361      INTEGER  ::   ji, jj     ! dummy loop indices
362      REAL(wp) ::  zzeta, zx, psi_unst, psi_stab, stab
363      !!----------------------------------------------------------------------------------
364      !
365      DO jj = 1, jpj
366         DO ji = 1, jpi
367            !
368            zzeta = MIN(pzeta(ji,jj) , 5.)   ! Very stable conditions (L positif and big!):
369            !
370            zx  = ABS(1. - 16.*zzeta)**.25        ! this is actually (1/phi_m)**2  !!!
371            !                                     ! eq.3.19, Chap.3, p.33, IFS doc - Cy31r1
372            ! Unstable (Paulson 1970) :
373            psi_unst = 2.*LOG(0.5*(1. + zx*zx))   ! eq.3.20, Chap.3, p.33, IFS doc - Cy31r1
374            !
375            ! Stable:
376            psi_stab = -2./3.*(zzeta - 5./0.35)*EXP(-0.35*zzeta) & ! eq.3.22, Chap.3, p.33, IFS doc - Cy31r1
377               &       - ABS(1. + 2./3.*zzeta)**1.5 - 2./3.*5./0.35 + 1. 
378            ! LB: added ABS() to avoid NaN values when unstable, which contaminates the unstable solution...
379            !
380            stab = 0.5 + SIGN(0.5, zzeta) ! zzeta > 0 => stab = 1
381            !
382            !
383            psi_h_ecmwf(ji,jj) = (1. - stab) * psi_unst &   ! (zzeta < 0) Unstable
384               &                +    stab    * psi_stab     ! (zzeta > 0) Stable
385            !
386         END DO
387      END DO
388      !
389   END FUNCTION psi_h_ecmwf
390
391
392   FUNCTION Ri_bulk( pz, ptz, pdt, pqz, pdq, pub )
393      !!----------------------------------------------------------------------------------
394      !! Bulk Richardson number (Eq. 3.25 IFS doc)
395      !!
396      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
397      !!----------------------------------------------------------------------------------
398      REAL(wp), DIMENSION(jpi,jpj) ::   Ri_bulk   !
399      !
400      REAL(wp)                    , INTENT(in) ::   pz    ! height above the sea        [m]
401      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   ptz   ! air temperature at pz m     [K]
402      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pdt   ! ptz - sst                   [K]
403      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pqz   ! air temperature at pz m [kg/kg]
404      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pdq   ! pqz - ssq               [kg/kg]
405      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pub   ! bulk wind speed           [m/s]
406      !!----------------------------------------------------------------------------------
407      !
408      Ri_bulk =   grav*pz/(pub*pub)                                          &
409         &      * ( pdt/(ptz - 0.5_wp*(pdt + grav*pz/(Cp_dry+Cp_vap*pqz)))   &
410         &          + rctv0*pdq )
411      !
412   END FUNCTION Ri_bulk
413
414
415   FUNCTION visc_air(ptak)
416      !!----------------------------------------------------------------------------------
417      !! Air kinetic viscosity (m^2/s) given from temperature in degrees...
418      !!
419      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
420      !!----------------------------------------------------------------------------------
421      REAL(wp), DIMENSION(jpi,jpj)             ::   visc_air   !
422      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   ptak       ! air temperature in (K)
423      !
424      INTEGER  ::   ji, jj      ! dummy loop indices
425      REAL(wp) ::   ztc, ztc2   ! local scalar
426      !!----------------------------------------------------------------------------------
427      !
428      DO jj = 1, jpj
429         DO ji = 1, jpi
430            ztc  = ptak(ji,jj) - rt0   ! air temp, in deg. C
431            ztc2 = ztc*ztc
432            visc_air(ji,jj) = 1.326e-5*(1. + 6.542E-3*ztc + 8.301e-6*ztc2 - 4.84e-9*ztc2*ztc)
433         END DO
434      END DO
435      !
436   END FUNCTION visc_air
437
438   !!======================================================================
439END MODULE sbcblk_algo_ecmwf
Note: See TracBrowser for help on using the repository browser.