New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 8612

Last change on this file since 8612 was 8612, checked in by andmirek, 6 years ago

#1953 read single file restart with XIOS

  • Property svn:keywords set to Id
File size: 14.5 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diurnal_bulk
30   
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   rst_opn         ! routine called by step module
35   PUBLIC   rst_write       ! routine called by step module
36   PUBLIC   rst_read        ! routine called by istate module
37   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!                     
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      !!
60      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
61      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
62      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
63      !!----------------------------------------------------------------------
64      !
65      IF( kt == nit000 ) THEN   ! default definitions
66         lrst_oce = .FALSE.   
67         IF( ln_rst_list ) THEN
68            nrst_lst = 1
69            nitrst = nstocklist( nrst_lst )
70         ELSE
71            nitrst = nitend
72         ENDIF
73      ENDIF
74
75      ! frequency-based restart dumping (nn_stock)
76      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
77         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
78         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
79         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
80      ENDIF
81      ! to get better performances with NetCDF format:
82      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
83      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
84      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
85         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
86            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
87            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
88            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
89            ENDIF
90            ! create the file
91            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
92            clpath = TRIM(cn_ocerst_outdir)
93            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
94            IF(lwp) THEN
95               WRITE(numout,*)
96               SELECT CASE ( jprstlib )
97               CASE DEFAULT         ;   WRITE(numout,*)                            &
98                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
99               END SELECT
100               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
101               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
102               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
103               ENDIF
104            ENDIF
105            !
106            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
107            lrst_oce = .TRUE.
108         ENDIF
109      ENDIF
110      !
111   END SUBROUTINE rst_opn
112
113
114   SUBROUTINE rst_write( kt )
115      !!---------------------------------------------------------------------
116      !!                   ***  ROUTINE rstwrite  ***
117      !!                     
118      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
119      !!
120      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
121      !!              file, save fields which are necessary for restart
122      !!----------------------------------------------------------------------
123      INTEGER, INTENT(in) ::   kt   ! ocean time-step
124      !!----------------------------------------------------------------------
125
126                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics and tracer time step
127
128      IF ( .NOT. ln_diurnal_only ) THEN
129                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
130                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
131                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
132                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
133                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
134                     !
135                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
136                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
137                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
138                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
139                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
140                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
141
142                  ! extra variable needed for the ice sheet coupling
143                  IF ( ln_iscpl ) THEN
144                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask     ) ! need to extrapolate T/S
145                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask     ) ! need to correct barotropic velocity
146                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask     ) ! need to correct barotropic velocity
147                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask    ) ! need to correct barotropic velocity
148                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:) )   ! need to compute temperature correction
149                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:) )   ! need to compute bt conservation
150                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:) )   ! need to compute bt conservation
151                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:) ) ! need to compute extrapolation if vvl
152                  END IF
153      ENDIF
154     
155      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst    ) 
156
157      IF( kt == nitrst ) THEN
158         CALL iom_close( numrow )     ! close the restart file (only at last time step)
159!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
160!!gm  not sure what to do here   ===>>>  ask to Sebastian
161         lrst_oce = .FALSE.
162            IF( ln_rst_list ) THEN
163               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
164               nitrst = nstocklist( nrst_lst )
165            ENDIF
166            lrst_oce = .FALSE.
167      ENDIF
168      !
169   END SUBROUTINE rst_write
170
171
172   SUBROUTINE rst_read_open
173      !!----------------------------------------------------------------------
174      !!                   ***  ROUTINE rst_read_open  ***
175      !!
176      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
177      !!
178      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
179      !!                the file has already been opened
180      !!----------------------------------------------------------------------
181      INTEGER        ::   jlibalt = jprstlib
182      LOGICAL        ::   llok
183      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
184      !!----------------------------------------------------------------------
185      !
186      IF( numror <= 0 ) THEN
187         IF(lwp) THEN                                             ! Contol prints
188            WRITE(numout,*)
189            SELECT CASE ( jprstlib )
190            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
191            END SELECT
192            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
193            WRITE(numout,*) '~~~~~~~~'
194         ENDIF
195         lxios_sini = .FALSE.
196         clpath = TRIM(cn_ocerst_indir)
197         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
198         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
199! are we using XIOS to read the data? Part above will have to modified once XIOS
200! can handle checking if variable is in the restart file (there will be no need to open
201! restart)
202         IF(.NOT.lxios_set) lxios_read = lxios_read.AND.lxios_sini
203         IF( lxios_read) THEN
204           rxios_context = 'nemo_rst'
205         if(.NOT.lxios_set) then
206             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
207             CALL iom_init( rxios_context )
208             lxios_set = .TRUE.
209         endif
210         ENDIF
211         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lxios_read) THEN
212            CALL iom_init( rxios_context )
213            IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
214            lxios_set = .TRUE.
215         ENDIF
216      ENDIF
217
218   END SUBROUTINE rst_read_open
219
220
221   SUBROUTINE rst_read
222      !!----------------------------------------------------------------------
223      !!                   ***  ROUTINE rst_read  ***
224      !!
225      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
226      !!
227      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
228      !!----------------------------------------------------------------------
229      REAL(wp) ::   zrdt
230      INTEGER  ::   jk
231      TYPE(xios_duration):: dtime
232      integer::ni,nj,nk
233      !!----------------------------------------------------------------------
234
235      CALL rst_read_open           ! open restart for reading (if not already opened)
236
237      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
238      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
239         CALL iom_get( numror, 'rdt', zrdt, lrxios = lxios_read )
240         IF( zrdt /= rdt )   neuler = 0
241      ENDIF
242
243      ! Diurnal DSST
244      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, lrxios = lxios_read ) 
245      IF ( ln_diurnal_only ) THEN
246         IF(lwp) WRITE( numout, * ) &
247         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
248         rhop = rau0
249         CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,1,jp_tem), lrxios = lxios_read ) 
250         RETURN
251      ENDIF 
252     
253      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
254         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub, lrxios = lxios_read                )   ! before fields
255         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb, lrxios = lxios_read                )
256         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem), lrxios = lxios_read )
257         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal), lrxios = lxios_read )
258         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb, lrxios = lxios_read              )
259      ELSE
260         neuler = 0
261      ENDIF
262      !
263      CALL iom_get( numror, jpdom_autoglo, 'un'     , un, lrxios = lxios_read )   ! now    fields
264      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn, lrxios = lxios_read )
265      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem), lrxios = lxios_read )
266      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal), lrxios = lxios_read )
267      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn, lrxios = lxios_read )
268      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
269         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, lrxios = lxios_read )   ! now    potential density
270      ELSE
271         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
272      ENDIF
273      !
274      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
275         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
276         ub   (:,:,:)   = un   (:,:,:)
277         vb   (:,:,:)   = vn   (:,:,:)
278         sshb (:,:)     = sshn (:,:)
279         !
280         IF( .NOT.ln_linssh ) THEN
281            DO jk = 1, jpk
282               e3t_b(:,:,jk) = e3t_n(:,:,jk)
283            END DO
284         ENDIF
285         !
286      ENDIF
287      !
288   END SUBROUTINE rst_read
289
290   !!=====================================================================
291END MODULE restart
Note: See TracBrowser for help on using the repository browser.