New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcapr.F90 in branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/SBC/sbcapr.F90 @ 8612

Last change on this file since 8612 was 8612, checked in by andmirek, 6 years ago

#1953 read single file restart with XIOS

  • Property svn:keywords set to Id
File size: 9.4 KB
Line 
1MODULE sbcapr
2   !!======================================================================
3   !!                       ***  MODULE  sbcapr  ***
4   !! Surface module :   atmospheric pressure forcing
5   !!======================================================================
6   !! History :  3.3  !   2010-09  (J. Chanut, C. Bricaud, G. Madec)  Original code
7   !!----------------------------------------------------------------------
8   
9   !!----------------------------------------------------------------------
10   !!   sbc_apr        : read atmospheric pressure in netcdf files
11   !!----------------------------------------------------------------------
12   USE dom_oce         ! ocean space and time domain
13   USE sbc_oce         ! surface boundary condition
14   USE phycst          ! physical constants
15   !
16   USE fldread         ! read input fields
17   USE in_out_manager  ! I/O manager
18   USE lib_fortran     ! distribued memory computing library
19   USE iom             ! IOM library
20   USE lib_mpp         ! MPP library
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   sbc_apr       ! routine called in sbcmod
26   PUBLIC   sbc_apr_init  ! routine called in sbcmod
27   
28   !                                !!* namsbc_apr namelist (Atmospheric PRessure) *
29   LOGICAL, PUBLIC ::   ln_apr_obc   !: inverse barometer added to OBC ssh data
30   LOGICAL, PUBLIC ::   ln_ref_apr   !: ref. pressure: global mean Patm (F) or a constant (F)
31   REAL(wp)        ::   rn_pref      !  reference atmospheric pressure   [N/m2]
32
33   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   ssh_ib    ! Inverse barometer now    sea surface height   [m]
34   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   ssh_ibb   ! Inverse barometer before sea surface height   [m]
35   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   apr       ! atmospheric pressure at kt                 [N/m2]
36   
37   REAL(wp) ::   tarea                ! whole domain mean masked ocean surface
38   REAL(wp) ::   r1_grau              ! = 1.e0 / (grav * rau0)
39   
40   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_apr   ! structure of input fields (file informations, fields read)
41
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_apr_init
50      !!---------------------------------------------------------------------
51      !!                     ***  ROUTINE sbc_apr  ***
52      !!
53      !! ** Purpose :   read atmospheric pressure fields in netcdf files.
54      !!
55      !! ** Method  : - Read namelist namsbc_apr
56      !!              - Read Patm fields in netcdf files
57      !!              - Compute reference atmospheric pressure
58      !!              - Compute inverse barometer ssh
59      !! ** action  :   apr      : atmospheric pressure at kt
60      !!                ssh_ib   : inverse barometer ssh at kt
61      !!---------------------------------------------------------------------
62      INTEGER            ::   ierror  ! local integer
63      INTEGER            ::   ios     ! Local integer output status for namelist read
64      !!
65      CHARACTER(len=100) ::  cn_dir   ! Root directory for location of ssr files
66      TYPE(FLD_N)        ::  sn_apr   ! informations about the fields to be read
67      LOGICAL            ::  lxios_read ! read restart using XIOS?
68      !!
69      NAMELIST/namsbc_apr/ cn_dir, sn_apr, ln_ref_apr, rn_pref, ln_apr_obc
70      !!----------------------------------------------------------------------
71      REWIND( numnam_ref )              ! Namelist namsbc_apr in reference namelist : File for atmospheric pressure forcing
72      READ  ( numnam_ref, namsbc_apr, IOSTAT = ios, ERR = 901)
73901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_apr in reference namelist', lwp )
74
75      REWIND( numnam_cfg )              ! Namelist namsbc_apr in configuration namelist : File for atmospheric pressure forcing
76      READ  ( numnam_cfg, namsbc_apr, IOSTAT = ios, ERR = 902 )
77902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_apr in configuration namelist', lwp )
78      IF(lwm) WRITE ( numond, namsbc_apr )
79      !
80      ALLOCATE( sf_apr(1), STAT=ierror )           !* allocate and fill sf_sst (forcing structure) with sn_sst
81      IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_apr: unable to allocate sf_apr structure' )
82      !
83      CALL fld_fill( sf_apr, (/ sn_apr /), cn_dir, 'sbc_apr', 'Atmospheric pressure ', 'namsbc_apr' )
84                                ALLOCATE( sf_apr(1)%fnow(jpi,jpj,1)   )
85      IF( sn_apr%ln_tint )   ALLOCATE( sf_apr(1)%fdta(jpi,jpj,1,2) )
86                             ALLOCATE( ssh_ib(jpi,jpj) , ssh_ibb(jpi,jpj) )
87                             ALLOCATE( apr (jpi,jpj) )
88      !
89      IF( lwp )THEN                                 !* control print
90         WRITE(numout,*)
91         WRITE(numout,*) '   Namelist namsbc_apr : Atmospheric PRessure as extrenal forcing'
92         WRITE(numout,*) '      ref. pressure: global mean Patm (T) or a constant (F)  ln_ref_apr = ', ln_ref_apr
93      ENDIF
94      !
95      IF( ln_ref_apr ) THEN                        !* Compute whole inner domain mean masked ocean surface
96         tarea = glob_sum( e1e2t(:,:) )
97         IF(lwp) WRITE(numout,*) '         Variable ref. Patm computed over a ocean surface of ', tarea*1e-6, 'km2'
98      ELSE
99         IF(lwp) WRITE(numout,*) '         Reference Patm used : ', rn_pref, ' N/m2'
100      ENDIF
101      !
102      r1_grau = 1.e0 / (grav * rau0)               !* constant for optimization
103      !
104      !                                            !* control check
105      IF ( ln_apr_obc  ) THEN
106         IF(lwp) WRITE(numout,*) '         Inverse barometer added to OBC ssh data'
107      ENDIF
108!jc: stop below should rather be a warning
109      IF( ln_apr_obc .AND. .NOT.ln_apr_dyn   )   &
110            CALL ctl_warn( 'sbc_apr: use inverse barometer ssh at open boundary ONLY requires ln_apr_dyn=T' )
111      !
112   END SUBROUTINE sbc_apr_init
113
114   SUBROUTINE sbc_apr( kt )
115      !!---------------------------------------------------------------------
116      !!                     ***  ROUTINE sbc_apr  ***
117      !!
118      !! ** Purpose :   read atmospheric pressure fields in netcdf files.
119      !!
120      !! ** Method  : - Read namelist namsbc_apr
121      !!              - Read Patm fields in netcdf files
122      !!              - Compute reference atmospheric pressure
123      !!              - Compute inverse barometer ssh
124      !! ** action  :   apr      : atmospheric pressure at kt
125      !!                ssh_ib   : inverse barometer ssh at kt
126      !!---------------------------------------------------------------------
127      INTEGER, INTENT(in)::   kt   ! ocean time step
128      !
129      !!----------------------------------------------------------------------
130
131      !                                         ! ========================== !
132      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    At each sbc time-step   !
133         !                                      ! ===========+++============ !
134         !
135         IF( kt /= nit000 )   ssh_ibb(:,:) = ssh_ib(:,:)    !* Swap of ssh_ib fields
136         !
137         CALL fld_read( kt, nn_fsbc, sf_apr )               !* input Patm provided at kt + nn_fsbc/2
138         !
139         !                                                  !* update the reference atmospheric pressure (if necessary)
140         IF( ln_ref_apr )   rn_pref = glob_sum( sf_apr(1)%fnow(:,:,1) * e1e2t(:,:) ) / tarea
141         !
142         !                                                  !* Patm related forcing at kt
143         ssh_ib(:,:) = - ( sf_apr(1)%fnow(:,:,1) - rn_pref ) * r1_grau    ! equivalent ssh (inverse barometer)
144         apr   (:,:) =     sf_apr(1)%fnow(:,:,1)                        ! atmospheric pressure
145         !
146         CALL iom_put( "ssh_ib", ssh_ib )                   !* output the inverse barometer ssh
147      ENDIF
148
149      !                                         ! ---------------------------------------- !
150      IF( kt == nit000 ) THEN                   !   set the forcing field at nit000 - 1    !
151         !                                      ! ---------------------------------------- !
152         !                                            !* Restart: read in restart file
153         IF( ln_rstart .AND. iom_varid( numror, 'ssh_ibb', ldstop = .FALSE. ) > 0 ) THEN
154            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb read in the restart file'
155            CALL iom_get( numror, jpdom_autoglo, 'ssh_ibb', ssh_ibb, lrxios = lxios_read )   ! before inv. barometer ssh
156            !
157         ELSE                                         !* no restart: set from nit000 values
158            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb set to nit000 values'
159            ssh_ibb(:,:) = ssh_ib(:,:)
160         ENDIF
161      ENDIF
162      !                                         ! ---------------------------------------- !
163      IF( lrst_oce ) THEN                       !      Write in the ocean restart file     !
164         !                                      ! ---------------------------------------- !
165         IF(lwp) WRITE(numout,*)
166         IF(lwp) WRITE(numout,*) 'sbc_apr : ssh_ib written in ocean restart file at it= ', kt,' date= ', ndastp
167         IF(lwp) WRITE(numout,*) '~~~~'
168         CALL iom_rstput( kt, nitrst, numrow, 'ssh_ibb' , ssh_ib )
169      ENDIF
170      !
171   END SUBROUTINE sbc_apr
172     
173   !!======================================================================
174END MODULE sbcapr
Note: See TracBrowser for help on using the repository browser.