New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 8612

Last change on this file since 8612 was 8612, checked in by andmirek, 6 years ago

#1953 read single file restart with XIOS

  • Property svn:keywords set to Id
File size: 32.8 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_init      : read namsbc namelist
21   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
22   !!   sbc_final     : Finalize CICE ice model (if used)
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean dynamics and tracers
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE trc_oce        ! shared ocean-passive tracers variables
29   USE sbc_ice        ! Surface boundary condition: ice fields
30   USE sbcdcy         ! surface boundary condition: diurnal cycle
31   USE sbcssm         ! surface boundary condition: sea-surface mean variables
32   USE sbcflx         ! surface boundary condition: flux formulation
33   USE sbcblk         ! surface boundary condition: bulk formulation
34   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
35   USE sbcice_lim     ! surface boundary condition: LIM 3.0 sea-ice model
36   USE sbcice_lim_2   ! surface boundary condition: LIM 2.0 sea-ice model
37   USE sbcice_cice    ! surface boundary condition: CICE    sea-ice model
38   USE sbcisf         ! surface boundary condition: ice-shelf
39   USE sbccpl         ! surface boundary condition: coupled formulation
40   USE cpl_oasis3     ! OASIS routines for coupling
41   USE sbcssr         ! surface boundary condition: sea surface restoring
42   USE sbcrnf         ! surface boundary condition: runoffs
43   USE sbcapr         ! surface boundary condition: atmo pressure
44   USE sbcisf         ! surface boundary condition: ice shelf
45   USE sbcfwb         ! surface boundary condition: freshwater budget
46   USE icbstp         ! Icebergs
47   USE traqsr         ! active tracers: light penetration
48   USE sbcwave        ! Wave module
49   USE bdy_oce   , ONLY: ln_bdy
50   USE usrdef_sbc     ! user defined: surface boundary condition
51   USE usrdef_closea  ! user defined: closed sea
52   !
53   USE prtctl         ! Print control                    (prt_ctl routine)
54   USE iom            ! IOM library
55   USE in_out_manager ! I/O manager
56   USE lib_mpp        ! MPP library
57   USE timing         ! Timing
58
59   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
60   USE iom_def, ONLY : lxios_read
61
62   IMPLICIT NONE
63   PRIVATE
64
65   PUBLIC   sbc        ! routine called by step.F90
66   PUBLIC   sbc_init   ! routine called by opa.F90
67
68   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
69
70   !!----------------------------------------------------------------------
71   !! NEMO/OPA 4.0 , NEMO-consortium (2016)
72   !! $Id$
73   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   SUBROUTINE sbc_init
78      !!---------------------------------------------------------------------
79      !!                    ***  ROUTINE sbc_init ***
80      !!
81      !! ** Purpose :   Initialisation of the ocean surface boundary computation
82      !!
83      !! ** Method  :   Read the namsbc namelist and set derived parameters
84      !!                Call init routines for all other SBC modules that have one
85      !!
86      !! ** Action  : - read namsbc parameters
87      !!              - nsbc: type of sbc
88      !!----------------------------------------------------------------------
89      INTEGER ::   ios, icpt                         ! local integer
90      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
91      !!
92      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
93         &             ln_usr   , ln_flx   , ln_blk       ,                          &
94         &             ln_cpl   , ln_mixcpl, nn_components, nn_limflx,               &
95         &             nn_ice   , nn_ice_embd,                                       &
96         &             ln_traqsr, ln_dm2dc ,                                         &
97         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_isf    , ln_apr_dyn ,     &
98         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauoc  , ln_stcor   ,     &
99         &             nn_lsm
100      !!----------------------------------------------------------------------
101      !
102      IF(lwp) THEN
103         WRITE(numout,*)
104         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
105         WRITE(numout,*) '~~~~~~~~ '
106      ENDIF
107      !
108      !                       !**  read Surface Module namelist
109      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
110      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
111901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
112      !
113      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
114      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
115902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
116      IF(lwm) WRITE( numond, namsbc )
117      !
118      !                             !* overwrite namelist parameter using CPP key information
119#if defined key_agrif
120      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
121         IF( lk_lim2 )   nn_ice      = 2
122         IF( lk_lim3 )   nn_ice      = 3
123         IF( lk_cice )   nn_ice      = 4
124      ENDIF
125#else
126      IF( lk_lim2 )   nn_ice      = 2
127      IF( lk_lim3 )   nn_ice      = 3
128      IF( lk_cice )   nn_ice      = 4
129#endif
130      !
131      IF(lwp) THEN                  !* Control print
132         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
133         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
134         WRITE(numout,*) '      Type of air-sea fluxes : '
135         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
136         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
137         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
138         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
139         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
140         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
141!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
142         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
143         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
144         WRITE(numout,*) '         Multicategory heat flux formulation (LIM3) nn_limflx     = ', nn_limflx
145         WRITE(numout,*) '      Sea-ice : '
146         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
147         WRITE(numout,*) '         ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd   = ', nn_ice_embd
148         WRITE(numout,*) '      Misc. options of sbc : '
149         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
150         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
151         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
152         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
153         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
154         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
155         WRITE(numout,*) '         iceshelf formulation                       ln_isf        = ', ln_isf
156         WRITE(numout,*) '         closed sea (=0/1) (set in namdom)          nn_closea     = ', nn_closea
157         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
158         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
159         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
160         WRITE(numout,*) '               wave modified ocean stress           ln_tauoc      = ', ln_tauoc
161         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
162         WRITE(numout,*) '               neutral drag coefficient (CORE, MFS) ln_cdgw       = ', ln_cdgw
163      ENDIF
164      !
165      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
166         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
167         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
168         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
169      ENDIF
170      !                       !**  check option consistency
171      !
172      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
173      SELECT CASE( nn_components )
174      CASE( jp_iam_nemo )
175         IF(lwp) WRITE(numout,*) '   NEMO configured as a single executable (i.e. including both OPA and Surface module'
176      CASE( jp_iam_opa  )
177         IF(lwp) WRITE(numout,*) '   Multi executable configuration. Here, OPA component'
178         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
179         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
180         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
181      CASE( jp_iam_sas  )
182         IF(lwp) WRITE(numout,*) '   Multi executable configuration. Here, SAS component'
183         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
184         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
185      CASE DEFAULT
186         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
187      END SELECT
188      !                             !* coupled options
189      IF( ln_cpl ) THEN
190         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
191            &                                  '           required to defined key_oasis3' )
192      ENDIF
193      IF( ln_mixcpl ) THEN
194         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
195            &                                  '           required to defined key_oasis3' )
196         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
197         IF( nn_components /= jp_iam_nemo )    &
198            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
199            &                                   '          not yet working with sas-opa coupling via oasis' )
200      ENDIF
201      !                             !* sea-ice
202      SELECT CASE( nn_ice )
203      CASE( 0 )                        !- no ice in the domain
204      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
205      CASE( 2 )                        !- LIM2 ice model
206         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : LIM2 sea-ice model requires ln_blk or ln_cpl = T' )
207      CASE( 3 )                        !- LIM3 ice model
208         IF( nn_ice_embd == 0            )   CALL ctl_stop( 'sbc_init : LIM3 sea-ice models require nn_ice_embd = 1 or 2' )
209      CASE( 4 )                        !- CICE ice model
210         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' )
211         IF( nn_ice_embd == 0            )   CALL ctl_stop( 'sbc_init : CICE sea-ice models require nn_ice_embd = 1 or 2' )
212         IF( lk_agrif                    )   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
213      CASE DEFAULT                     !- not supported
214      END SELECT
215      !
216      IF( nn_ice == 3 ) THEN           !- LIM3 case: multi-category flux option
217         IF(lwp) WRITE(numout,*)
218         SELECT CASE( nn_limflx )         ! LIM3 Multi-category heat flux formulation
219         CASE ( -1 )
220            IF(lwp) WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
221            IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
222         CASE ( 0  )
223            IF(lwp) WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
224         CASE ( 1  )
225            IF(lwp) WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
226            IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
227         CASE ( 2  )
228            IF(lwp) WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
229            IF( .NOT.ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' )
230         CASE DEFAULT
231            CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' )
232         END SELECT
233      ELSE                             ! other sea-ice model
234         IF( nn_limflx >= 0  )   CALL ctl_warn( 'sbc_init : multi-category flux option (nn_limflx) only available in LIM3' )
235      ENDIF
236      !
237      !                       !**  allocate and set required variables
238      !
239      !                             !* allocate sbc arrays
240      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
241      !
242      IF( .NOT.ln_isf ) THEN        !* No ice-shelf in the domain : allocate and set to zero
243         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
244         fwfisf  (:,:)   = 0._wp   ;   risf_tsc  (:,:,:) = 0._wp
245         fwfisf_b(:,:)   = 0._wp   ;   risf_tsc_b(:,:,:) = 0._wp
246      END IF
247      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
248         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
249      ENDIF
250      !
251      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
252      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
253
254      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
255
256      !                          ! Choice of the Surface Boudary Condition (set nsbc)
257      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
258         nday_qsr = -1   ! allow initialization at the 1st call
259         IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa )   &
260            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' )
261      ENDIF
262      !                             !* Choice of the Surface Boudary Condition
263      !                             (set nsbc)
264      !
265      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
266      ll_opa      = nn_components == jp_iam_opa
267      ll_not_nemo = nn_components /= jp_iam_nemo
268      icpt = 0
269      !
270      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
271      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
272      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
273      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
274      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
275      !
276      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
277      !
278      IF(lwp) THEN                     !- print the choice of surface flux formulation
279         WRITE(numout,*)
280         SELECT CASE( nsbc )
281         CASE( jp_usr     )   ;   WRITE(numout,*) '   user defined formulation'
282         CASE( jp_flx     )   ;   WRITE(numout,*) '      ===>>   flux formulation'
283         CASE( jp_blk     )   ;   WRITE(numout,*) '      ===>>   bulk formulation'
284         CASE( jp_purecpl )   ;   WRITE(numout,*) '      ===>>   pure coupled formulation'
285!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
286         CASE( jp_none    )   ;   WRITE(numout,*) '      ===>>   OPA coupled to SAS via oasis'
287            IF( ln_mixcpl )       WRITE(numout,*) '                  + forced-coupled mixed formulation'
288         END SELECT
289         IF( ll_not_nemo  )       WRITE(numout,*) '                  + OASIS coupled SAS'
290      ENDIF
291      !
292      !                             !* OASIS initialization
293      !
294      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
295      !                                              !                      (2) the use of nn_fsbc
296      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
297      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
298      IF( nn_components /= jp_iam_nemo ) THEN
299         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
300         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
301         !
302         IF(lwp)THEN
303            WRITE(numout,*)
304            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
305            WRITE(numout,*)
306         ENDIF
307      ENDIF
308      !
309      !                             !* check consistency between model timeline and nn_fsbc
310      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
311          MOD( nstock             , nn_fsbc) /= 0 ) THEN
312         WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
313            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
314         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
315      ENDIF
316      !
317      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
318         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
319      !
320      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
321         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
322      !
323   
324      !                       !**  associated modules : initialization
325      !
326                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
327      !
328      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
329
330      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
331      !
332      IF( ln_isf      )   CALL sbc_isf_init               ! Compute iceshelves
333      !
334                          CALL sbc_rnf_init            ! Runof initialization
335      !
336      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
337      !
338      IF( nn_ice == 3 )   CALL sbc_lim_init            ! LIM3 initialization
339      !
340      IF( nn_ice == 4 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
341      !
342      IF( ln_wave     )   CALL sbc_wave_init              ! surface wave initialisation
343      !
344   END SUBROUTINE sbc_init
345
346
347   SUBROUTINE sbc( kt )
348      !!---------------------------------------------------------------------
349      !!                    ***  ROUTINE sbc  ***
350      !!
351      !! ** Purpose :   provide at each time-step the ocean surface boundary
352      !!                condition (momentum, heat and freshwater fluxes)
353      !!
354      !! ** Method  :   blah blah  to be written ?????????
355      !!                CAUTION : never mask the surface stress field (tke sbc)
356      !!
357      !! ** Action  : - set the ocean surface boundary condition at before and now
358      !!                time step, i.e.
359      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
360      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
361      !!              - updte the ice fraction : fr_i
362      !!----------------------------------------------------------------------
363      INTEGER, INTENT(in) ::   kt   ! ocean time step
364      !
365      LOGICAL ::   ll_sas, ll_opa   ! local logical
366      !!---------------------------------------------------------------------
367      !
368      IF( nn_timing == 1 )  CALL timing_start('sbc')
369      !
370      !                                            ! ---------------------------------------- !
371      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
372         !                                         ! ---------------------------------------- !
373         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
374         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
375         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
376         emp_b (:,:) = emp (:,:)
377         sfx_b (:,:) = sfx (:,:)
378         IF ( ln_rnf ) THEN
379            rnf_b    (:,:  ) = rnf    (:,:  )
380            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
381         ENDIF
382         IF( ln_isf )  THEN
383            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
384            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
385         ENDIF
386        !
387      ENDIF
388      !                                            ! ---------------------------------------- !
389      !                                            !        forcing field computation         !
390      !                                            ! ---------------------------------------- !
391      !
392      ll_sas = nn_components == jp_iam_sas               ! component flags
393      ll_opa = nn_components == jp_iam_opa
394      !
395      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
396      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
397
398      !
399      !                                            !==  sbc formulation  ==!
400      !                                                   
401      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
402      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
403      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
404      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
405      CASE( jp_blk     )
406         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
407                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
408                               !
409      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
410      CASE( jp_none    )
411         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
412      END SELECT
413      IF ( ln_wave .AND. ln_tauoc) THEN                                 ! Wave stress subctracted
414            utau(:,:) = utau(:,:)*tauoc_wave(:,:)
415            vtau(:,:) = vtau(:,:)*tauoc_wave(:,:)
416            taum(:,:) = taum(:,:)*tauoc_wave(:,:)
417      !
418            SELECT CASE( nsbc )
419            CASE(  0,1,2,3,5,-1 )  ;
420                IF(lwp .AND. kt == nit000 ) WRITE(numout,*) 'WARNING: You are subtracting the wave stress to the ocean. &
421                        & If not requested select ln_tauoc=.false'
422            END SELECT
423      !
424      END IF
425      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
426
427      !
428      !                                            !==  Misc. Options  ==!
429      !
430      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
431      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
432      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
433      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
434      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
435      END SELECT
436
437      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
438
439      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
440
441      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
442
443      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
444
445      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
446
447      ! treatment of closed sea in the model domain   (update freshwater fluxes)
448      ! Should not be ran if ln_diurnal_only
449      IF( .NOT.ln_diurnal_only .AND. nn_closea == 1 )   CALL sbc_clo( kt, cn_cfg, nn_cfg )   
450
451!RBbug do not understand why see ticket 667
452!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
453      CALL lbc_lnk( emp, 'T', 1. )
454      !
455      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
456         !                                             ! ---------------------------------------- !
457         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
458            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
459            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
460            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, lrxios = lxios_read )   ! before i-stress  (U-point)
461            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, lrxios = lxios_read )   ! before j-stress  (V-point)
462            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b, lrxios = lxios_read  )   ! before non solar heat flux (T-point)
463            ! The 3D heat content due to qsr forcing is treated in traqsr
464            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, lrxios = lxios_read  ) ! before     solar heat flux (T-point)
465            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, lrxios = lxios_read  )    ! before     freshwater flux (T-point)
466            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
467            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
468               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, lrxios = lxios_read )  ! before salt flux (T-point)
469            ELSE
470               sfx_b (:,:) = sfx(:,:)
471            ENDIF
472         ELSE                                                   !* no restart: set from nit000 values
473            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
474            utau_b(:,:) = utau(:,:)
475            vtau_b(:,:) = vtau(:,:)
476            qns_b (:,:) = qns (:,:)
477            emp_b (:,:) = emp (:,:)
478            sfx_b (:,:) = sfx (:,:)
479         ENDIF
480      ENDIF
481      !                                                ! ---------------------------------------- !
482      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
483         !                                             ! ---------------------------------------- !
484         IF(lwp) WRITE(numout,*)
485         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
486            &                    'at it= ', kt,' date= ', ndastp
487         IF(lwp) WRITE(numout,*) '~~~~'
488         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
489         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
490         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
491         ! The 3D heat content due to qsr forcing is treated in traqsr
492         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
493         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
494         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx  )
495      ENDIF
496      !                                                ! ---------------------------------------- !
497      !                                                !        Outputs and control print         !
498      !                                                ! ---------------------------------------- !
499      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
500         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
501         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
502         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
503         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
504         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
505         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
506         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
507         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
508         CALL iom_put( "taum"  , taum       )                   ! wind stress module
509         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
510      ENDIF
511      !
512      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
513      CALL iom_put( "vtau", vtau )   ! j-wind stress
514      !
515      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
516         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask, ovlap=1 )
517         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 )
518         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 )
519         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
520         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
521         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
522         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
523         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
524         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
525            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
526      ENDIF
527
528      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
529      !
530      IF( nn_timing == 1 )  CALL timing_stop('sbc')
531      !
532   END SUBROUTINE sbc
533
534
535   SUBROUTINE sbc_final
536      !!---------------------------------------------------------------------
537      !!                    ***  ROUTINE sbc_final  ***
538      !!
539      !! ** Purpose :   Finalize CICE (if used)
540      !!---------------------------------------------------------------------
541      !
542      IF( nn_ice == 4 )   CALL cice_sbc_final
543      !
544   END SUBROUTINE sbc_final
545
546   !!======================================================================
547END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.