New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 8612

Last change on this file since 8612 was 8612, checked in by andmirek, 6 years ago

#1953 read single file restart with XIOS

  • Property svn:keywords set to Id
File size: 58.0 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE zdfbfr         ! bottom friction (only for rn_bfrz0)
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE phycst         ! physical constants
25   USE zdfmxl         ! mixed layer
26   USE sbcwave ,  ONLY: hsw   ! significant wave height
27   !
28   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
29   USE lib_mpp        ! MPP manager
30   USE wrk_nemo       ! work arrays
31   USE prtctl         ! Print control
32   USE in_out_manager ! I/O manager
33   USE iom            ! I/O manager library
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36   USE iom_def, ONLY : lxios_read
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   zdf_gls        ! routine called in step module
42   PUBLIC   zdf_gls_init   ! routine called in opa module
43   PUBLIC   gls_rst        ! routine called in step module
44
45   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
46   !
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
51
52   !                              !! ** Namelist  namzdf_gls  **
53   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
54   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
55   INTEGER  ::   nn_bc_surf        ! surface boundary condition (=0/1)
56   INTEGER  ::   nn_bc_bot         ! bottom boundary condition (=0/1)
57   INTEGER  ::   nn_z0_met         ! Method for surface roughness computation
58   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
59   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
60   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
61   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
62   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
63   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
64   REAL(wp) ::   rn_crban          ! Craig and Banner constant for surface breaking waves mixing
65   REAL(wp) ::   rn_hsro           ! Minimum surface roughness
66   REAL(wp) ::   rn_frac_hs        ! Fraction of wave height as surface roughness (if nn_z0_met > 1)
67
68   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
69   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
70   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
71   REAL(wp) ::   rghmin        = -0.28_wp
72   REAL(wp) ::   rgh0          =  0.0329_wp
73   REAL(wp) ::   rghcri        =  0.03_wp
74   REAL(wp) ::   ra1           =  0.92_wp
75   REAL(wp) ::   ra2           =  0.74_wp
76   REAL(wp) ::   rb1           = 16.60_wp
77   REAL(wp) ::   rb2           = 10.10_wp         
78   REAL(wp) ::   re2           =  1.33_wp         
79   REAL(wp) ::   rl1           =  0.107_wp
80   REAL(wp) ::   rl2           =  0.0032_wp
81   REAL(wp) ::   rl3           =  0.0864_wp
82   REAL(wp) ::   rl4           =  0.12_wp
83   REAL(wp) ::   rl5           = 11.9_wp
84   REAL(wp) ::   rl6           =  0.4_wp
85   REAL(wp) ::   rl7           =  0.0_wp
86   REAL(wp) ::   rl8           =  0.48_wp
87   REAL(wp) ::   rm1           =  0.127_wp
88   REAL(wp) ::   rm2           =  0.00336_wp
89   REAL(wp) ::   rm3           =  0.0906_wp
90   REAL(wp) ::   rm4           =  0.101_wp
91   REAL(wp) ::   rm5           = 11.2_wp
92   REAL(wp) ::   rm6           =  0.4_wp
93   REAL(wp) ::   rm7           =  0.0_wp
94   REAL(wp) ::   rm8           =  0.318_wp
95   REAL(wp) ::   rtrans        =  0.1_wp
96   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
97   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rfact_tke                  !     -           -           -        -
98   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rfact_psi                  !     -           -           -        -
99   REAL(wp) ::   rsbc_zs1, rsbc_zs2                               !     -           -           -        -
100   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
101   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
102   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
103   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
104   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
105
106   !! * Substitutions
107#  include "vectopt_loop_substitute.h90"
108   !!----------------------------------------------------------------------
109   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
110   !! $Id$
111   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
112   !!----------------------------------------------------------------------
113CONTAINS
114
115   INTEGER FUNCTION zdf_gls_alloc()
116      !!----------------------------------------------------------------------
117      !!                ***  FUNCTION zdf_gls_alloc  ***
118      !!----------------------------------------------------------------------
119      ALLOCATE( mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
120         &      ustars2(jpi,jpj) , ustarb2(jpi,jpj)   , STAT= zdf_gls_alloc )
121         !
122      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
123      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
124   END FUNCTION zdf_gls_alloc
125
126
127   SUBROUTINE zdf_gls( kt )
128      !!----------------------------------------------------------------------
129      !!                   ***  ROUTINE zdf_gls  ***
130      !!
131      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
132      !!              coefficients using the GLS turbulent closure scheme.
133      !!----------------------------------------------------------------------
134      INTEGER, INTENT(in) ::   kt ! ocean time step
135      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
136      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
137      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
138      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
139      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
140      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
141      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
142      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zkar
143      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
144      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
145      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
146      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
147      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
148      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
149      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi)
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   psi         ! psi at time now
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a    ! element of the first  matrix diagonal
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_b    ! element of the second matrix diagonal
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c    ! element of the third  matrix diagonal
154      !!--------------------------------------------------------------------
155      !
156      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
157      !
158      CALL wrk_alloc( jpi,jpj,       zdep, zkar, zflxs, zhsro )
159      CALL wrk_alloc( jpi,jpj,jpk,   eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi  )
160     
161      ! Preliminary computing
162
163      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
164
165      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
166         avt (:,:,:) = avt_k (:,:,:)
167         avm (:,:,:) = avm_k (:,:,:)
168         avmu(:,:,:) = avmu_k(:,:,:)
169         avmv(:,:,:) = avmv_k(:,:,:) 
170      ENDIF
171
172      ! Compute surface and bottom friction at T-points
173      DO jj = 2, jpjm1         
174         DO ji = fs_2, fs_jpim1   ! vector opt.         
175            !
176            ! surface friction
177            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
178            !   
179            ! bottom friction (explicit before friction)       
180            ! Note that we chose here not to bound the friction as in dynbfr)   
181            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &         
182               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )     
183            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &         
184               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )     
185            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)         
186         END DO         
187      END DO   
188
189      ! Set surface roughness length
190      SELECT CASE ( nn_z0_met )
191      !
192      CASE ( 0 )             ! Constant roughness         
193         zhsro(:,:) = rn_hsro
194      CASE ( 1 )             ! Standard Charnock formula
195         zhsro(:,:) = MAX(rsbc_zs1 * ustars2(:,:), rn_hsro)
196      CASE ( 2 )             ! Roughness formulae according to Rascle et al., Ocean Modelling (2008)
197         zdep(:,:)  = 30.*TANH(2.*0.3/(28.*SQRT(MAX(ustars2(:,:),rsmall))))             ! Wave age (eq. 10)
198         zhsro(:,:) = MAX(rsbc_zs2 * ustars2(:,:) * zdep(:,:)**1.5, rn_hsro) ! zhsro = rn_frac_hs * Hsw (eq. 11)
199      CASE ( 3 )             ! Roughness given by the wave model (coupled or read in file)
200         zhsro(:,:) = hsw(:,:)
201      END SELECT
202
203      ! Compute shear and dissipation rate
204      DO jk = 2, jpkm1
205         DO jj = 2, jpjm1
206            DO ji = fs_2, fs_jpim1   ! vector opt.
207               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
208                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
209                  &                            / (  e3uw_n(ji,jj,jk) * e3uw_b(ji,jj,jk) )
210               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
211                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
212                  &                            / (  e3vw_n(ji,jj,jk) * e3vw_b(ji,jj,jk) )
213               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
214            END DO
215         END DO
216      END DO
217      !
218      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
219      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
220
221      ! Save tke at before time step
222      eb  (:,:,:) = en  (:,:,:)
223      mxlb(:,:,:) = mxln(:,:,:)
224
225      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
226         DO jk = 2, jpkm1
227            DO jj = 2, jpjm1 
228               DO ji = fs_2, fs_jpim1   ! vector opt.
229                  zup   = mxln(ji,jj,jk) * gdepw_n(ji,jj,mbkt(ji,jj)+1)
230                  zdown = vkarmn * gdepw_n(ji,jj,jk) * ( -gdepw_n(ji,jj,jk) + gdepw_n(ji,jj,mbkt(ji,jj)+1) )
231                  zcoef = ( zup / MAX( zdown, rsmall ) )
232                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
233               END DO
234            END DO
235         END DO
236      ENDIF
237
238      !!---------------------------------!!
239      !!   Equation to prognostic k      !!
240      !!---------------------------------!!
241      !
242      ! Now Turbulent kinetic energy (output in en)
243      ! -------------------------------
244      ! Resolution of a tridiagonal linear system by a "methode de chasse"
245      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
246      ! The surface boundary condition are set after
247      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
248      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
249      ! Warning : after this step, en : right hand side of the matrix
250
251      DO jk = 2, jpkm1
252         DO jj = 2, jpjm1
253            DO ji = fs_2, fs_jpim1   ! vector opt.
254               !
255               ! shear prod. at w-point weightened by mask
256               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
257                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
258               !
259               ! stratif. destruction
260               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
261               !
262               ! shear prod. - stratif. destruction
263               diss = eps(ji,jj,jk)
264               !
265               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
266               !
267               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
268               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
269               !
270               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
271               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
272               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
273               ! Otherwise, this should be rsc_psi/rsc_psi0
274               IF( ln_sigpsi ) THEN
275                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
276                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
277                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
278               ELSE
279                  zwall_psi(ji,jj,jk) = 1._wp
280               ENDIF
281               !
282               ! building the matrix
283               zcof = rfact_tke * tmask(ji,jj,jk)
284               !
285               ! lower diagonal
286               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
287                  &                      / ( e3t_n(ji,jj,jk-1) * e3w_n(ji,jj,jk  ) )
288               !
289               ! upper diagonal
290               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
291                  &                      / ( e3t_n(ji,jj,jk  ) * e3w_n(ji,jj,jk) )
292               !
293               ! diagonal
294               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
295                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
296               !
297               ! right hand side in en
298               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
299            END DO
300         END DO
301      END DO
302      !
303      z_elem_b(:,:,jpk) = 1._wp
304      !
305      ! Set surface condition on zwall_psi (1 at the bottom)
306      zwall_psi(:,:,1) = zwall_psi(:,:,2)
307      zwall_psi(:,:,jpk) = 1.
308      !
309      ! Surface boundary condition on tke
310      ! ---------------------------------
311      !
312      SELECT CASE ( nn_bc_surf )
313      !
314      CASE ( 0 )             ! Dirichlet case
315      ! First level
316      en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
317      en(:,:,1) = MAX(en(:,:,1), rn_emin) 
318      z_elem_a(:,:,1) = en(:,:,1)
319      z_elem_c(:,:,1) = 0._wp
320      z_elem_b(:,:,1) = 1._wp
321      !
322      ! One level below
323      en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1 * ((zhsro(:,:)+gdepw_n(:,:,2)) &
324         &               / zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
325      en(:,:,2) = MAX(en(:,:,2), rn_emin )
326      z_elem_a(:,:,2) = 0._wp 
327      z_elem_c(:,:,2) = 0._wp
328      z_elem_b(:,:,2) = 1._wp
329      !
330      !
331      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
332      !
333      ! Dirichlet conditions at k=1
334      en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
335      en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
336      z_elem_a(:,:,1) = en(:,:,1)
337      z_elem_c(:,:,1) = 0._wp
338      z_elem_b(:,:,1) = 1._wp
339      !
340      ! at k=2, set de/dz=Fw
341      !cbr
342      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
343      z_elem_a(:,:,2) = 0._wp
344      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans*gdept_n(:,:,1)/zhsro(:,:)) ))
345      zflxs(:,:)      = rsbc_tke2 * ustars2(:,:)**1.5_wp * zkar(:,:) &
346          &                       * ((zhsro(:,:)+gdept_n(:,:,1)) / zhsro(:,:) )**(1.5_wp*ra_sf)
347
348      en(:,:,2) = en(:,:,2) + zflxs(:,:)/e3w_n(:,:,2)
349      !
350      !
351      END SELECT
352
353      ! Bottom boundary condition on tke
354      ! --------------------------------
355      !
356      SELECT CASE ( nn_bc_bot )
357      !
358      CASE ( 0 )             ! Dirichlet
359         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
360         !                      ! Balance between the production and the dissipation terms
361         DO jj = 2, jpjm1
362            DO ji = fs_2, fs_jpim1   ! vector opt.
363               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
364               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
365               !
366               ! Bottom level Dirichlet condition:
367               z_elem_a(ji,jj,ibot  ) = 0._wp
368               z_elem_c(ji,jj,ibot  ) = 0._wp
369               z_elem_b(ji,jj,ibot  ) = 1._wp
370               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
371               !
372               ! Just above last level, Dirichlet condition again
373               z_elem_a(ji,jj,ibotm1) = 0._wp
374               z_elem_c(ji,jj,ibotm1) = 0._wp
375               z_elem_b(ji,jj,ibotm1) = 1._wp
376               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
377            END DO
378         END DO
379         !
380      CASE ( 1 )             ! Neumman boundary condition
381         !                     
382         DO jj = 2, jpjm1
383            DO ji = fs_2, fs_jpim1   ! vector opt.
384               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
385               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
386               !
387               ! Bottom level Dirichlet condition:
388               z_elem_a(ji,jj,ibot) = 0._wp
389               z_elem_c(ji,jj,ibot) = 0._wp
390               z_elem_b(ji,jj,ibot) = 1._wp
391               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
392               !
393               ! Just above last level: Neumann condition
394               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
395               z_elem_c(ji,jj,ibotm1) = 0._wp
396            END DO
397         END DO
398         !
399      END SELECT
400
401      ! Matrix inversion (en prescribed at surface and the bottom)
402      ! ----------------------------------------------------------
403      !
404      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
405         DO jj = 2, jpjm1
406            DO ji = fs_2, fs_jpim1    ! vector opt.
407               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
408            END DO
409         END DO
410      END DO
411      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
412         DO jj = 2, jpjm1
413            DO ji = fs_2, fs_jpim1    ! vector opt.
414               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
415            END DO
416         END DO
417      END DO
418      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
419         DO jj = 2, jpjm1
420            DO ji = fs_2, fs_jpim1    ! vector opt.
421               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
422            END DO
423         END DO
424      END DO
425      !                                            ! set the minimum value of tke
426      en(:,:,:) = MAX( en(:,:,:), rn_emin )
427
428      !!----------------------------------------!!
429      !!   Solve prognostic equation for psi    !!
430      !!----------------------------------------!!
431
432      ! Set psi to previous time step value
433      !
434      SELECT CASE ( nn_clos )
435      !
436      CASE( 0 )               ! k-kl  (Mellor-Yamada)
437         DO jk = 2, jpkm1
438            DO jj = 2, jpjm1
439               DO ji = fs_2, fs_jpim1   ! vector opt.
440                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
441               END DO
442            END DO
443         END DO
444         !
445      CASE( 1 )               ! k-eps
446         DO jk = 2, jpkm1
447            DO jj = 2, jpjm1
448               DO ji = fs_2, fs_jpim1   ! vector opt.
449                  psi(ji,jj,jk)  = eps(ji,jj,jk)
450               END DO
451            END DO
452         END DO
453         !
454      CASE( 2 )               ! k-w
455         DO jk = 2, jpkm1
456            DO jj = 2, jpjm1
457               DO ji = fs_2, fs_jpim1   ! vector opt.
458                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
459               END DO
460            END DO
461         END DO
462         !
463      CASE( 3 )               ! generic
464         DO jk = 2, jpkm1
465            DO jj = 2, jpjm1
466               DO ji = fs_2, fs_jpim1   ! vector opt.
467                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
468               END DO
469            END DO
470         END DO
471         !
472      END SELECT
473      !
474      ! Now gls (output in psi)
475      ! -------------------------------
476      ! Resolution of a tridiagonal linear system by a "methode de chasse"
477      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
478      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
479      ! Warning : after this step, en : right hand side of the matrix
480
481      DO jk = 2, jpkm1
482         DO jj = 2, jpjm1
483            DO ji = fs_2, fs_jpim1   ! vector opt.
484               !
485               ! psi / k
486               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
487               !
488               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
489               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
490               !
491               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
492               !
493               ! shear prod. - stratif. destruction
494               prod = rpsi1 * zratio * shear(ji,jj,jk)
495               !
496               ! stratif. destruction
497               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
498               !
499               ! shear prod. - stratif. destruction
500               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
501               !
502               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
503               !
504               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
505               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
506               !                                                       
507               ! building the matrix
508               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
509               ! lower diagonal
510               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
511                  &                      / ( e3t_n(ji,jj,jk-1) * e3w_n(ji,jj,jk  ) )
512               ! upper diagonal
513               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
514                  &                      / ( e3t_n(ji,jj,jk  ) * e3w_n(ji,jj,jk) )
515               ! diagonal
516               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
517                  &                       + rdt * zdiss * tmask(ji,jj,jk)
518               !
519               ! right hand side in psi
520               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
521            END DO
522         END DO
523      END DO
524      !
525      z_elem_b(:,:,jpk) = 1._wp
526
527      ! Surface boundary condition on psi
528      ! ---------------------------------
529      !
530      SELECT CASE ( nn_bc_surf )
531      !
532      CASE ( 0 )             ! Dirichlet boundary conditions
533      !
534      ! Surface value
535      zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
536      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
537      z_elem_a(:,:,1) = psi(:,:,1)
538      z_elem_c(:,:,1) = 0._wp
539      z_elem_b(:,:,1) = 1._wp
540      !
541      ! One level below
542      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*gdepw_n(:,:,2)/zhsro(:,:) )))
543      zdep(:,:)       = (zhsro(:,:) + gdepw_n(:,:,2)) * zkar(:,:)
544      psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
545      z_elem_a(:,:,2) = 0._wp
546      z_elem_c(:,:,2) = 0._wp
547      z_elem_b(:,:,2) = 1._wp
548      !
549      !
550      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
551      !
552      ! Surface value: Dirichlet
553      zdep(:,:)       = zhsro(:,:) * rl_sf
554      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
555      z_elem_a(:,:,1) = psi(:,:,1)
556      z_elem_c(:,:,1) = 0._wp
557      z_elem_b(:,:,1) = 1._wp
558      !
559      ! Neumann condition at k=2
560      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
561      z_elem_a(:,:,2) = 0._wp
562      !
563      ! Set psi vertical flux at the surface:
564      zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*gdept_n(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
565      zdep(:,:) = ((zhsro(:,:) + gdept_n(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
566      zflxs(:,:) = (rnn + rsbc_tke1 * (rnn + rmm*ra_sf) * zdep(:,:))*(1._wp + rsbc_tke1*zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
567      zdep(:,:) =  rsbc_psi1 * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
568             & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + gdept_n(:,:,1))**(rnn-1.)
569      zflxs(:,:) = zdep(:,:) * zflxs(:,:)
570      psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / e3w_n(:,:,2)
571
572      !   
573      !
574      END SELECT
575
576      ! Bottom boundary condition on psi
577      ! --------------------------------
578      !
579      SELECT CASE ( nn_bc_bot )
580      !
581      !
582      CASE ( 0 )             ! Dirichlet
583         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * rn_bfrz0
584         !                      ! Balance between the production and the dissipation terms
585         DO jj = 2, jpjm1
586            DO ji = fs_2, fs_jpim1   ! vector opt.
587               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
588               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
589               zdep(ji,jj) = vkarmn * rn_bfrz0
590               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
591               z_elem_a(ji,jj,ibot) = 0._wp
592               z_elem_c(ji,jj,ibot) = 0._wp
593               z_elem_b(ji,jj,ibot) = 1._wp
594               !
595               ! Just above last level, Dirichlet condition again (GOTM like)
596               zdep(ji,jj) = vkarmn * ( rn_bfrz0 + e3t_n(ji,jj,ibotm1) )
597               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
598               z_elem_a(ji,jj,ibotm1) = 0._wp
599               z_elem_c(ji,jj,ibotm1) = 0._wp
600               z_elem_b(ji,jj,ibotm1) = 1._wp
601            END DO
602         END DO
603         !
604      CASE ( 1 )             ! Neumman boundary condition
605         !                     
606         DO jj = 2, jpjm1
607            DO ji = fs_2, fs_jpim1   ! vector opt.
608               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
609               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
610               !
611               ! Bottom level Dirichlet condition:
612               zdep(ji,jj) = vkarmn * rn_bfrz0
613               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
614               !
615               z_elem_a(ji,jj,ibot) = 0._wp
616               z_elem_c(ji,jj,ibot) = 0._wp
617               z_elem_b(ji,jj,ibot) = 1._wp
618               !
619               ! Just above last level: Neumann condition with flux injection
620               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
621               z_elem_c(ji,jj,ibotm1) = 0.
622               !
623               ! Set psi vertical flux at the bottom:
624               zdep(ji,jj) = rn_bfrz0 + 0.5_wp*e3t_n(ji,jj,ibotm1)
625               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
626                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
627               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / e3w_n(ji,jj,ibotm1)
628            END DO
629         END DO
630         !
631      END SELECT
632
633      ! Matrix inversion
634      ! ----------------
635      !
636      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
637         DO jj = 2, jpjm1
638            DO ji = fs_2, fs_jpim1    ! vector opt.
639               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
640            END DO
641         END DO
642      END DO
643      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
644         DO jj = 2, jpjm1
645            DO ji = fs_2, fs_jpim1    ! vector opt.
646               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
647            END DO
648         END DO
649      END DO
650      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
651         DO jj = 2, jpjm1
652            DO ji = fs_2, fs_jpim1    ! vector opt.
653               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
654            END DO
655         END DO
656      END DO
657
658      ! Set dissipation
659      !----------------
660
661      SELECT CASE ( nn_clos )
662      !
663      CASE( 0 )               ! k-kl  (Mellor-Yamada)
664         DO jk = 1, jpkm1
665            DO jj = 2, jpjm1
666               DO ji = fs_2, fs_jpim1   ! vector opt.
667                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / MAX( psi(ji,jj,jk), rn_epsmin)
668               END DO
669            END DO
670         END DO
671         !
672      CASE( 1 )               ! k-eps
673         DO jk = 1, jpkm1
674            DO jj = 2, jpjm1
675               DO ji = fs_2, fs_jpim1   ! vector opt.
676                  eps(ji,jj,jk) = psi(ji,jj,jk)
677               END DO
678            END DO
679         END DO
680         !
681      CASE( 2 )               ! k-w
682         DO jk = 1, jpkm1
683            DO jj = 2, jpjm1
684               DO ji = fs_2, fs_jpim1   ! vector opt.
685                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
686               END DO
687            END DO
688         END DO
689         !
690      CASE( 3 )               ! generic
691         zcoef = rc0**( 3._wp  + rpp/rnn )
692         zex1  =      ( 1.5_wp + rmm/rnn )
693         zex2  = -1._wp / rnn
694         DO jk = 1, jpkm1
695            DO jj = 2, jpjm1
696               DO ji = fs_2, fs_jpim1   ! vector opt.
697                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
698               END DO
699            END DO
700         END DO
701         !
702      END SELECT
703
704      ! Limit dissipation rate under stable stratification
705      ! --------------------------------------------------
706      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
707         DO jj = 2, jpjm1
708            DO ji = fs_2, fs_jpim1    ! vector opt.
709               ! limitation
710               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
711               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
712               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
713               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
714               IF (ln_length_lim) mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk) )
715            END DO
716         END DO
717      END DO 
718
719      !
720      ! Stability function and vertical viscosity and diffusivity
721      ! ---------------------------------------------------------
722      !
723      SELECT CASE ( nn_stab_func )
724      !
725      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
726         DO jk = 2, jpkm1
727            DO jj = 2, jpjm1
728               DO ji = fs_2, fs_jpim1   ! vector opt.
729                  ! zcof =  l²/q²
730                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
731                  ! Gh = -N²l²/q²
732                  gh = - rn2(ji,jj,jk) * zcof
733                  gh = MIN( gh, rgh0   )
734                  gh = MAX( gh, rghmin )
735                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
736                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
737                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
738                  !
739                  ! Store stability function in avmu and avmv
740                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
741                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
742               END DO
743            END DO
744         END DO
745         !
746      CASE ( 2, 3 )               ! Canuto stability functions
747         DO jk = 2, jpkm1
748            DO jj = 2, jpjm1
749               DO ji = fs_2, fs_jpim1   ! vector opt.
750                  ! zcof =  l²/q²
751                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
752                  ! Gh = -N²l²/q²
753                  gh = - rn2(ji,jj,jk) * zcof
754                  gh = MIN( gh, rgh0   )
755                  gh = MAX( gh, rghmin )
756                  gh = gh * rf6
757                  ! Gm =  M²l²/q² Shear number
758                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
759                  gm = MAX( shr * zcof , 1.e-10 )
760                  gm = gm * rf6
761                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
762                  ! Stability functions from Canuto
763                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
764                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
765                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
766                  !
767                  ! Store stability function in avmu and avmv
768                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
769                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
770               END DO
771            END DO
772         END DO
773         !
774      END SELECT
775
776      ! Boundary conditions on stability functions for momentum (Neumann):
777      ! Lines below are useless if GOTM style Dirichlet conditions are used
778
779      avmv(:,:,1) = avmv(:,:,2)
780
781      DO jj = 2, jpjm1
782         DO ji = fs_2, fs_jpim1   ! vector opt.
783            avmv(ji,jj,mbkt(ji,jj)+1) = avmv(ji,jj,mbkt(ji,jj))
784         END DO
785      END DO
786
787      ! Compute diffusivities/viscosities
788      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
789      DO jk = 1, jpk
790         DO jj = 2, jpjm1
791            DO ji = fs_2, fs_jpim1   ! vector opt.
792               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
793               zav           = zsqen * avmu(ji,jj,jk)
794               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
795               zav           = zsqen * avmv(ji,jj,jk)
796               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
797            END DO
798         END DO
799      END DO
800      !
801      ! Lateral boundary conditions (sign unchanged)
802      avt(:,:,1)  = 0._wp
803      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
804
805      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
806         DO jj = 2, jpjm1
807            DO ji = fs_2, fs_jpim1   ! vector opt.
808               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
809               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
810            END DO
811         END DO
812      END DO
813      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
814      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
815
816      IF(ln_ctl) THEN
817         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
818         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
819            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
820      ENDIF
821      !
822      avt_k (:,:,:) = avt (:,:,:)
823      avm_k (:,:,:) = avm (:,:,:)
824      avmu_k(:,:,:) = avmu(:,:,:)
825      avmv_k(:,:,:) = avmv(:,:,:)
826      !
827      CALL wrk_dealloc( jpi,jpj,       zdep, zkar, zflxs, zhsro )
828      CALL wrk_dealloc( jpi,jpj,jpk,   eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
829      !
830      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
831      !
832      !
833   END SUBROUTINE zdf_gls
834
835
836   SUBROUTINE zdf_gls_init
837      !!----------------------------------------------------------------------
838      !!                  ***  ROUTINE zdf_gls_init  ***
839      !!                     
840      !! ** Purpose :   Initialization of the vertical eddy diffivity and
841      !!      viscosity when using a gls turbulent closure scheme
842      !!
843      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
844      !!      called at the first timestep (nit000)
845      !!
846      !! ** input   :   Namlist namzdf_gls
847      !!
848      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
849      !!
850      !!----------------------------------------------------------------------
851      USE dynzdf_exp
852      USE trazdf_exp
853      !
854      INTEGER ::   jk    ! dummy loop indices
855      INTEGER ::   ios   ! Local integer output status for namelist read
856      REAL(wp)::   zcr   ! local scalar
857      !!
858      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
859         &            rn_clim_galp, ln_sigpsi, rn_hsro,      &
860         &            rn_crban, rn_charn, rn_frac_hs,        &
861         &            nn_bc_surf, nn_bc_bot, nn_z0_met,      &
862         &            nn_stab_func, nn_clos
863      !!----------------------------------------------------------
864      !
865      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
866      !
867      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
868      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
869901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
870
871      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
872      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
873902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
874      IF(lwm) WRITE ( numond, namzdf_gls )
875
876      IF(lwp) THEN                     !* Control print
877         WRITE(numout,*)
878         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
879         WRITE(numout,*) '~~~~~~~~~~~~'
880         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
881         WRITE(numout,*) '      minimum value of en                           rn_emin        = ', rn_emin
882         WRITE(numout,*) '      minimum value of eps                          rn_epsmin      = ', rn_epsmin
883         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim  = ', ln_length_lim
884         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp   = ', rn_clim_galp
885         WRITE(numout,*) '      TKE Surface boundary condition                nn_bc_surf     = ', nn_bc_surf
886         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_bc_bot      = ', nn_bc_bot
887         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi      = ', ln_sigpsi
888         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
889         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
890         WRITE(numout,*) '      Surface roughness formula                     nn_z0_met      = ', nn_z0_met
891         WRITE(numout,*) '      Wave height frac. (used if nn_z0_met=2)       rn_frac_hs     = ', rn_frac_hs
892         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
893         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
894         WRITE(numout,*) '      Surface roughness (m)                         rn_hsro        = ', rn_hsro
895         WRITE(numout,*) '      Bottom roughness (m) (nambfr namelist)        rn_bfrz0       = ', rn_bfrz0
896      ENDIF
897
898      !                                !* allocate gls arrays
899      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
900
901      !                                !* Check of some namelist values
902      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' )
903      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' )
904      IF( nn_z0_met < 0 .OR. nn_z0_met > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_z0_met is 0, 1, 2 or 3' )
905      IF( nn_z0_met == 3 .AND. .NOT.ln_wave ) CALL ctl_stop( 'zdf_gls_init: nn_z0_met=3 requires ln_wave=T' )
906      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_stab_func is 0, 1, 2 and 3' )
907      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_clos is 0, 1, 2 or 3' )
908
909      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
910      !
911      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
912         !
913         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
914         rpp     = 0._wp
915         rmm     = 1._wp
916         rnn     = 1._wp
917         rsc_tke = 1.96_wp
918         rsc_psi = 1.96_wp
919         rpsi1   = 0.9_wp
920         rpsi3p  = 1._wp
921         rpsi2   = 0.5_wp
922         !
923         SELECT CASE ( nn_stab_func )
924         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
925         CASE( 2 )      ;   rpsi3m = 2.62_wp       ! Canuto A stability functions
926         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
927         END SELECT
928         !
929      CASE( 1 )                              ! k-eps
930         !
931         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
932         rpp     =  3._wp
933         rmm     =  1.5_wp
934         rnn     = -1._wp
935         rsc_tke =  1._wp
936         rsc_psi =  1.2_wp  ! Schmidt number for psi
937         rpsi1   =  1.44_wp
938         rpsi3p  =  1._wp
939         rpsi2   =  1.92_wp
940         !
941         SELECT CASE ( nn_stab_func )
942         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
943         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
944         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
945         END SELECT
946         !
947      CASE( 2 )                              ! k-omega
948         !
949         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
950         rpp     = -1._wp
951         rmm     =  0.5_wp
952         rnn     = -1._wp
953         rsc_tke =  2._wp
954         rsc_psi =  2._wp
955         rpsi1   =  0.555_wp
956         rpsi3p  =  1._wp
957         rpsi2   =  0.833_wp
958         !
959         SELECT CASE ( nn_stab_func )
960         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
961         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
962         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
963         END SELECT
964         !
965      CASE( 3 )                              ! generic
966         !
967         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
968         rpp     = 2._wp
969         rmm     = 1._wp
970         rnn     = -0.67_wp
971         rsc_tke = 0.8_wp
972         rsc_psi = 1.07_wp
973         rpsi1   = 1._wp
974         rpsi3p  = 1._wp
975         rpsi2   = 1.22_wp
976         !
977         SELECT CASE ( nn_stab_func )
978         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
979         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
980         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
981         END SELECT
982         !
983      END SELECT
984
985      !
986      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
987      !
988      CASE ( 0 )                             ! Galperin stability functions
989         !
990         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
991         rc2     =  0._wp
992         rc3     =  0._wp
993         rc_diff =  1._wp
994         rc0     =  0.5544_wp
995         rcm_sf  =  0.9884_wp
996         rghmin  = -0.28_wp
997         rgh0    =  0.0233_wp
998         rghcri  =  0.02_wp
999         !
1000      CASE ( 1 )                             ! Kantha-Clayson stability functions
1001         !
1002         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1003         rc2     =  0.7_wp
1004         rc3     =  0.2_wp
1005         rc_diff =  1._wp
1006         rc0     =  0.5544_wp
1007         rcm_sf  =  0.9884_wp
1008         rghmin  = -0.28_wp
1009         rgh0    =  0.0233_wp
1010         rghcri  =  0.02_wp
1011         !
1012      CASE ( 2 )                             ! Canuto A stability functions
1013         !
1014         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1015         rs0 = 1.5_wp * rl1 * rl5*rl5
1016         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1017         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1018         rs4 = 2._wp * rl5
1019         rs5 = 2._wp * rl4
1020         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1021            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1022         rd0 = 3._wp * rl5*rl5
1023         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1024         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1025         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1026         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1027         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1028         rc0 = 0.5268_wp
1029         rf6 = 8._wp / (rc0**6._wp)
1030         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1031         rcm_sf  =  0.7310_wp
1032         rghmin  = -0.28_wp
1033         rgh0    =  0.0329_wp
1034         rghcri  =  0.03_wp
1035         !
1036      CASE ( 3 )                             ! Canuto B stability functions
1037         !
1038         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1039         rs0 = 1.5_wp * rm1 * rm5*rm5
1040         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1041         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1042         rs4 = 2._wp * rm5
1043         rs5 = 2._wp * rm4
1044         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1045         rd0 = 3._wp * rm5*rm5
1046         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1047         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1048         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1049         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1050         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1051         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1052         rf6 = 8._wp / ( rc0**6._wp )
1053         rc_diff = SQRT(2._wp)/(rc0**3.)
1054         rcm_sf  =  0.7470_wp
1055         rghmin  = -0.28_wp
1056         rgh0    =  0.0444_wp
1057         rghcri  =  0.0414_wp
1058         !
1059      END SELECT
1060   
1061      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1062      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1063      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1064      IF( ln_sigpsi ) THEN
1065         ra_sf = -1.5 ! Set kinetic energy slope, then deduce rsc_psi and rl_sf
1066         ! Verification: retrieve Burchard (2001) results by uncomenting the line below:
1067         ! Note that the results depend on the value of rn_cm_sf which is constant (=rc0) in his work
1068         ! ra_sf = -SQRT(2./3.*rc0**3./rn_cm_sf*rn_sc_tke)/vkarmn
1069         rsc_psi0 = rsc_tke/(24.*rpsi2)*(-1.+(4.*rnn + ra_sf*(1.+4.*rmm))**2./(ra_sf**2.))
1070      ELSE
1071         rsc_psi0 = rsc_psi
1072      ENDIF
1073 
1074      !                                !* Shear free turbulence parameters
1075      !
1076      ra_sf  = -4._wp*rnn*SQRT(rsc_tke) / ( (1._wp+4._wp*rmm)*SQRT(rsc_tke) &
1077               &                              - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1078
1079      IF ( rn_crban==0._wp ) THEN
1080         rl_sf = vkarmn
1081      ELSE
1082         rl_sf = rc0 * SQRT(rc0/rcm_sf) * SQRT( ( (1._wp + 4._wp*rmm + 8._wp*rmm**2_wp)*rsc_tke          &
1083                 &                                       + 12._wp * rsc_psi0*rpsi2 - (1._wp + 4._wp*rmm) &
1084                 &                                                *SQRT(rsc_tke*(rsc_tke                 &
1085                 &                                                   + 24._wp*rsc_psi0*rpsi2)) )         &
1086                 &                                         /(12._wp*rnn**2.)                             &
1087                 &                                       )
1088      ENDIF
1089
1090      !
1091      IF(lwp) THEN                     !* Control print
1092         WRITE(numout,*)
1093         WRITE(numout,*) 'Limit values'
1094         WRITE(numout,*) '~~~~~~~~~~~~'
1095         WRITE(numout,*) 'Parameter  m = ',rmm
1096         WRITE(numout,*) 'Parameter  n = ',rnn
1097         WRITE(numout,*) 'Parameter  p = ',rpp
1098         WRITE(numout,*) 'rpsi1   = ',rpsi1
1099         WRITE(numout,*) 'rpsi2   = ',rpsi2
1100         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1101         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1102         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1103         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1104         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1105         WRITE(numout,*) 'rc0     = ',rc0
1106         WRITE(numout,*)
1107         WRITE(numout,*) 'Shear free turbulence parameters:'
1108         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1109         WRITE(numout,*) 'ra_sf   = ',ra_sf
1110         WRITE(numout,*) 'rl_sf   = ',rl_sf
1111         WRITE(numout,*)
1112      ENDIF
1113
1114      !                                !* Constants initialization
1115      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1116      rc03  = rc02 * rc0
1117      rc04  = rc03 * rc0
1118      rsbc_tke1 = -3._wp/2._wp*rn_crban*ra_sf*rl_sf                      ! Dirichlet + Wave breaking
1119      rsbc_tke2 = rdt * rn_crban / rl_sf                                 ! Neumann + Wave breaking
1120      zcr = MAX(rsmall, rsbc_tke1**(1./(-ra_sf*3._wp/2._wp))-1._wp )
1121      rtrans = 0.2_wp / zcr                                              ! Ad. inverse transition length between log and wave layer
1122      rsbc_zs1  = rn_charn/grav                                          ! Charnock formula for surface roughness
1123      rsbc_zs2  = rn_frac_hs / 0.85_wp / grav * 665._wp                  ! Rascle formula for surface roughness
1124      rsbc_psi1 = -0.5_wp * rdt * rc0**(rpp-2._wp*rmm) / rsc_psi
1125      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi ! Neumann + NO Wave breaking
1126
1127      rfact_tke = -0.5_wp / rsc_tke * rdt                                ! Cst used for the Diffusion term of tke
1128      rfact_psi = -0.5_wp / rsc_psi * rdt                                ! Cst used for the Diffusion term of tke
1129
1130      !                                !* Wall proximity function
1131      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1132
1133      !                                !* set vertical eddy coef. to the background value
1134      DO jk = 1, jpk
1135         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1136         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1137         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1138         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1139      END DO
1140      !                             
1141      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1142      !
1143      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1144      !
1145   END SUBROUTINE zdf_gls_init
1146
1147
1148   SUBROUTINE gls_rst( kt, cdrw )
1149      !!---------------------------------------------------------------------
1150      !!                   ***  ROUTINE ts_rst  ***
1151      !!                     
1152      !! ** Purpose :   Read or write TKE file (en) in restart file
1153      !!
1154      !! ** Method  :   use of IOM library
1155      !!                if the restart does not contain TKE, en is either
1156      !!                set to rn_emin or recomputed (nn_igls/=0)
1157      !!----------------------------------------------------------------------
1158      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1159      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1160      !
1161      INTEGER ::   jit, jk   ! dummy loop indices
1162      INTEGER ::   id1, id2, id3, id4, id5, id6
1163      INTEGER ::   ji, jj, ikbu, ikbv
1164      REAL(wp)::   cbx, cby
1165      !!----------------------------------------------------------------------
1166      !
1167      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1168         !                                   ! ---------------
1169         IF( ln_rstart ) THEN                   !* Read the restart file
1170            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1171            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1172            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1173            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1174            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1175            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1176            !
1177            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1178               CALL iom_get( numror, jpdom_autoglo, 'en'    , en, lrxios = lxios_read     )
1179               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt, lrxios = lxios_read    )
1180               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm, lrxios = lxios_read    )
1181               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu, lrxios = lxios_read   )
1182               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv, lrxios = lxios_read   )
1183               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln, lrxios = lxios_read   )
1184            ELSE                       
1185               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1186               en  (:,:,:) = rn_emin
1187               mxln(:,:,:) = 0.05       
1188               avt_k (:,:,:) = avt (:,:,:)
1189               avm_k (:,:,:) = avm (:,:,:)
1190               avmu_k(:,:,:) = avmu(:,:,:)
1191               avmv_k(:,:,:) = avmv(:,:,:)
1192               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1193            ENDIF
1194         ELSE                                   !* Start from rest
1195            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1196            en  (:,:,:) = rn_emin
1197            mxln(:,:,:) = 0.05       
1198         ENDIF
1199         !
1200      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1201         !                                   ! -------------------
1202         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1203         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     ) 
1204         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1205         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1206         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k ) 
1207         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1208         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1209         !
1210      ENDIF
1211      !
1212   END SUBROUTINE gls_rst
1213
1214#else
1215   !!----------------------------------------------------------------------
1216   !!   Dummy module :                                        NO TKE scheme
1217   !!----------------------------------------------------------------------
1218   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1219CONTAINS
1220   SUBROUTINE zdf_gls_init           ! Empty routine
1221      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1222   END SUBROUTINE zdf_gls_init
1223   SUBROUTINE zdf_gls( kt )          ! Empty routine
1224      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1225   END SUBROUTINE zdf_gls
1226   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1227      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1228      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1229      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1230   END SUBROUTINE gls_rst
1231#endif
1232
1233   !!======================================================================
1234END MODULE zdfgls
1235
Note: See TracBrowser for help on using the repository browser.