New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/SAS_SRC – NEMO

source: branches/2017/dev_r8600_xios_read/NEMOGCM/NEMO/SAS_SRC/daymod.F90 @ 8612

Last change on this file since 8612 was 8612, checked in by andmirek, 6 years ago

#1953 read single file restart with XIOS

  • Property svn:keywords set to Id
File size: 20.1 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean :   management of the model calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!                 ! 2015-11  (D. Lea) Allow non-zero initial time of day
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   day        : calendar
18   !!----------------------------------------------------------------------
19   !!                    ----------- WARNING -----------
20   !!                    -------------------------------
21   !!   sbcmod assume that the time step is dividing the number of second of
22   !!   in a day, i.e. ===> MOD( rday, rdt ) == 0
23   !!   except when user defined forcing is used (see sbcmod.F90)
24   !!----------------------------------------------------------------------
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE ioipsl  , ONLY :   ymds2ju      ! for calendar
28   USE trc_oce , ONLY :   l_offline   ! offline flag
29   !
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE iom            !
33   USE timing         ! Timing
34   USE restart        ! restart
35   USE iom_def, ONLY : lxios_read
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   day        ! called by step.F90
40   PUBLIC   day_init   ! called by istate.F90
41   PUBLIC   day_mth    ! Needed by TAM
42
43   INTEGER, PUBLIC ::   nsecd, nsecd05, ndt, ndt05   !: (PUBLIC for TAM)
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 4.0 , NEMO Consortium (2016)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE day_init
53      !!----------------------------------------------------------------------
54      !!                   ***  ROUTINE day_init  ***
55      !!
56      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
57      !!                because day will be called at the beginning of step
58      !!
59      !! ** Action  : - nyear        : current year
60      !!              - nmonth       : current month of the year nyear
61      !!              - nday         : current day of the month nmonth
62      !!              - nday_year    : current day of the year nyear
63      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
64      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
65      !!              - nsec_day     : current time step counted in second since 00h of the current day
66      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
67      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
68      !!----------------------------------------------------------------------
69      INTEGER  ::   inbday, idweek   ! local integers
70      REAL(wp) ::   zjul             ! local scalar
71      !!----------------------------------------------------------------------
72      !
73      ! max number of seconds between each restart
74      IF( REAL( nitend - nit000 + 1 ) * rdt > REAL( HUGE( nsec1jan000 ) ) ) THEN
75         CALL ctl_stop( 'The number of seconds between each restart exceeds the integer 4 max value: 2^31-1. ',   &
76            &           'You must do a restart at higher frequency (or remove this stop and recompile the code in I8)' )
77      ENDIF
78      nsecd   = NINT( rday       )
79      nsecd05 = NINT( 0.5 * rday )
80      ndt     = NINT(       rdt  )
81      ndt05   = NINT( 0.5 * rdt  )
82
83      IF( .NOT. l_offline )   CALL day_rst( nit000, 'READ' )
84
85      ! set the calandar from ndastp (read in restart file and namelist)
86      nyear   =   ndastp / 10000
87      nmonth  = ( ndastp - (nyear * 10000) ) / 100
88      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 )
89
90      nhour   =   nn_time0 / 100
91      nminute = ( nn_time0 - nhour * 100 )
92
93      CALL ymds2ju( nyear, nmonth, nday, nhour*3600._wp+nminute*60._wp, fjulday ) 
94      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
95      IF( nn_time0*3600 - ndt05 .lt. 0 ) fjulday = fjulday + 1.                    ! move back to the day at nit000 (and not at nit000 - 1)
96
97      nsec1jan000 = 0
98      CALL day_mth
99
100      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
101         nmonth = nmonth - 1
102         nday = nmonth_len(nmonth)
103      ENDIF
104      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
105         nmonth = 12
106         nyear = nyear - 1
107         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
108         IF( nleapy == 1 )   CALL day_mth
109      ENDIF
110
111      ! day since january 1st
112      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
113
114      !compute number of days between last monday and today
115      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
116      inbday = FLOOR(fjulday - zjul)            ! compute nb day between  01.01.1900 and start of current day
117      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day
118      IF (idweek .lt. 0) idweek=idweek+7       ! Avoid negative values for dates before 01.01.1900
119
120      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
121      IF (nhour*3600+nminute*60-ndt05 .gt. 0) THEN
122         ! 1 timestep before current middle of first time step is still the same day
123         nsec_year  = (nday_year-1) * nsecd + nhour*3600+nminute*60 - ndt05 
124         nsec_month = (nday-1)      * nsecd + nhour*3600+nminute*60 - ndt05   
125      ELSE
126         ! 1 time step before the middle of the first time step is the previous day
127         nsec_year  = nday_year * nsecd + nhour*3600+nminute*60 - ndt05 
128         nsec_month = nday      * nsecd + nhour*3600+nminute*60 - ndt05   
129      ENDIF
130      nsec_week  = idweek    * nsecd + nhour*3600+nminute*60 - ndt05
131      nsec_day   =             nhour*3600+nminute*60 - ndt05 
132      IF( nsec_day .lt. 0 ) nsec_day = nsec_day + nsecd
133      IF( nsec_week .lt. 0 ) nsec_week = nsec_week + nsecd*7
134
135      ! control print
136      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8,a,i8,a,i8)')   &
137           &                   ' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
138           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week, '  &
139           &                   nsec_month:', nsec_month , '  nsec_year:' , nsec_year
140
141      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
142      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
143      CALL day( nit000 )
144      !
145   END SUBROUTINE day_init
146
147
148   SUBROUTINE day_mth
149      !!----------------------------------------------------------------------
150      !!                   ***  ROUTINE day_init  ***
151      !!
152      !! ** Purpose :   calendar values related to the months
153      !!
154      !! ** Action  : - nmonth_len    : length in days of the months of the current year
155      !!              - nyear_len     : length in days of the previous/current year
156      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
157      !!              - nmonth_end    : second since the beginning of the year and the end of the months
158      !!----------------------------------------------------------------------
159      INTEGER  ::   jm               ! dummy loop indice
160      !!----------------------------------------------------------------------
161
162      ! length of the month of the current year (from nleapy, read in namelist)
163      IF ( nleapy < 2 ) THEN
164         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
165         nyear_len(:) = 365
166         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
167            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
168               nyear_len(0)  = 366
169            ENDIF
170            IF ( MOD(nyear  , 4) == 0 .AND. ( MOD(nyear  , 400) == 0 .OR. MOD(nyear  , 100) /= 0 ) ) THEN
171               nmonth_len(2) = 29
172               nyear_len(1)  = 366
173            ENDIF
174            IF ( MOD(nyear+1, 4) == 0 .AND. ( MOD(nyear+1, 400) == 0 .OR. MOD(nyear+1, 100) /= 0 ) ) THEN
175               nyear_len(2)  = 366
176            ENDIF
177         ENDIF
178      ELSE
179         nmonth_len(:) = nleapy   ! all months with nleapy days per year
180         nyear_len(:) = 12 * nleapy
181      ENDIF
182
183      ! half month in second since the begining of the year:
184      ! time since Jan 1st   0     1     2    ...    11    12    13
185      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
186      !                 <---> <---> <--->  ...  <---> <---> <--->
187      ! month number      0     1     2    ...    11    12    13
188      !
189      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
190      nmonth_half(0) = - nsecd05 * nmonth_len(0)
191      DO jm = 1, 13
192         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
193      END DO
194
195      nmonth_end(0) = 0
196      DO jm = 1, 13
197         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
198      END DO
199      !
200   END SUBROUTINE
201
202
203   SUBROUTINE day( kt )
204      !!----------------------------------------------------------------------
205      !!                      ***  ROUTINE day  ***
206      !!
207      !! ** Purpose :   Compute the date with a day iteration IF necessary.
208      !!
209      !! ** Method  : - ???
210      !!
211      !! ** Action  : - nyear     : current year
212      !!              - nmonth    : current month of the year nyear
213      !!              - nday      : current day of the month nmonth
214      !!              - nday_year : current day of the year nyear
215      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
216      !!              - adatrj    : date in days since the beginning of the run
217      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
218      !!----------------------------------------------------------------------
219      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
220      !
221      CHARACTER (len=25) ::   charout
222      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
223      !!----------------------------------------------------------------------
224      !
225      IF( nn_timing == 1 )  CALL timing_start('day')
226      !
227      zprec = 0.1 / rday
228      !                                                 ! New time-step
229      nsec_year  = nsec_year  + ndt
230      nsec_month = nsec_month + ndt
231      nsec_week  = nsec_week  + ndt
232      nsec_day   = nsec_day   + ndt
233      adatrj  = adatrj  + rdt / rday
234      fjulday = fjulday + rdt / rday
235      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
236      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
237
238      IF( nsec_day > nsecd ) THEN                       ! New day
239         !
240         nday      = nday + 1
241         nday_year = nday_year + 1
242         nsec_day  = ndt05
243         !
244         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
245            nday   = 1
246            nmonth = nmonth + 1
247            nsec_month = ndt05
248            IF( nmonth == 13 ) THEN                     ! New year
249               nyear     = nyear + 1
250               nmonth    = 1
251               nday_year = 1
252               nsec_year = ndt05
253               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
254               IF( nleapy == 1 )   CALL day_mth
255            ENDIF
256         ENDIF
257         !
258         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
259         !
260         !compute first day of the year in julian days
261         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
262         !
263         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
264              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
265         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
266              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
267      ENDIF
268
269      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
270
271      IF(ln_ctl) THEN
272         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
273         CALL prt_ctl_info(charout)
274      ENDIF
275
276      IF( .NOT. l_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
277      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
278      !
279      IF( nn_timing == 1 )  CALL timing_stop('day')
280      !
281   END SUBROUTINE day
282
283
284   SUBROUTINE day_rst( kt, cdrw )
285      !!---------------------------------------------------------------------
286      !!                   ***  ROUTINE ts_rst  ***
287      !!
288      !!  ** Purpose : Read or write calendar in restart file:
289      !!
290      !!  WRITE(READ) mode:
291      !!       kt        : number of time step since the begining of the experiment at the
292      !!                   end of the current(previous) run
293      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
294      !!                   end of the current(previous) run (REAL -> keep fractions of day)
295      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
296      !!
297      !!   According to namelist parameter nrstdt,
298      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
299      !!       nrstdt = 1  we verify that nit000 is equal to the last
300      !!                   time step of previous run + 1.
301      !!       In both those options, the  exact duration of the experiment
302      !!       since the beginning (cumulated duration of all previous restart runs)
303      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
304      !!       This is valid is the time step has remained constant.
305      !!
306      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
307      !!                    has been stored in the restart file.
308      !!----------------------------------------------------------------------
309      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
310      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
311      !
312      REAL(wp) ::   zkt, zndastp, zdayfrac, ksecs, ktime
313      INTEGER  ::   ihour, iminute
314      !!----------------------------------------------------------------------
315
316      IF( TRIM(cdrw) == 'READ' ) THEN
317
318         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
319            ! Get Calendar informations
320            CALL iom_get( numror, 'kt', zk, lrxios = lxios_read )   ! last time-step of previous run
321            IF(lwp) THEN
322               WRITE(numout,*) ' *** Info read in restart : '
323               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
324               WRITE(numout,*) ' *** restart option'
325               SELECT CASE ( nrstdt )
326               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
327               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
328               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
329               END SELECT
330               WRITE(numout,*)
331            ENDIF
332            ! Control of date
333            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
334                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
335                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
336            ! define ndastp and adatrj
337            IF ( nrstdt == 2 ) THEN
338               ! read the parameters corresponding to nit000 - 1 (last time step of previous run)
339               CALL iom_get( numror, 'ndastp', zndastp, lrxios = lxios_read )
340               ndastp = NINT( zndastp )
341               CALL iom_get( numror, 'adatrj', adatrj, lrxios = lxios_read )
342          CALL iom_get( numror, 'ntime', ktime, lrxios = lxios_read )
343          nn_time0=INT(ktime)
344               ! calculate start time in hours and minutes
345          zdayfrac=adatrj-INT(adatrj)
346          ksecs = NINT(zdayfrac*86400)        ! Nearest second to catch rounding errors in adatrj         
347          ihour = INT(ksecs/3600)
348          iminute = ksecs/60-ihour*60
349           
350               ! Add to nn_time0
351               nhour   =   nn_time0 / 100
352               nminute = ( nn_time0 - nhour * 100 )
353          nminute=nminute+iminute
354         
355          IF( nminute >= 60 ) THEN
356             nminute=nminute-60
357        nhour=nhour+1
358          ENDIF
359          nhour=nhour+ihour
360          IF( nhour >= 24 ) THEN
361        nhour=nhour-24
362             adatrj=adatrj+1
363          ENDIF         
364          nn_time0 = nhour * 100 + nminute
365          adatrj = INT(adatrj)                    ! adatrj set to integer as nn_time0 updated         
366            ELSE
367               ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
368               ndastp = ndate0        ! ndate0 read in the namelist in dom_nam
369               nhour   =   nn_time0 / 100
370               nminute = ( nn_time0 - nhour * 100 )
371               IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
372               adatrj = ( REAL( nit000-1, wp ) * rdt ) / rday
373               ! note this is wrong if time step has changed during run
374            ENDIF
375         ELSE
376            ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
377            ndastp = ndate0           ! ndate0 read in the namelist in dom_nam
378            nhour   =   nn_time0 / 100
379       nminute = ( nn_time0 - nhour * 100 )
380            IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
381            adatrj = ( REAL( nit000-1, wp ) * rdt ) / rday
382         ENDIF
383         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
384         !
385         IF(lwp) THEN
386            WRITE(numout,*) ' *** Info used values : '
387            WRITE(numout,*) '   date ndastp                                      : ', ndastp
388            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
389       WRITE(numout,*) '   nn_time0                                         : ',nn_time0
390            WRITE(numout,*)
391         ENDIF
392         !
393      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
394         !
395         IF( kt == nitrst ) THEN
396            IF(lwp) WRITE(numout,*)
397            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
398            IF(lwp) WRITE(numout,*) '~~~~~~~'
399         ENDIF
400         ! calendar control
401         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
402         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
403         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
404         !                                                                     ! the begining of the run [s]
405    CALL iom_rstput( kt, nitrst, numrow, 'ntime'  , REAL( nn_time0, wp) ) ! time
406      ENDIF
407      !
408   END SUBROUTINE day_rst
409
410   !!======================================================================
411END MODULE daymod
Note: See TracBrowser for help on using the repository browser.