source: branches/2017/dev_r8600_xios_read_write/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 8770

Last change on this file since 8770 was 8770, checked in by andmirek, 3 years ago

#1953 and #1962 merged (and some modifications) with write branch

  • Property svn:keywords set to Id
File size: 15.7 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diurnal_bulk
30   USE iom_def, ONLY : lwxios
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   rst_opn         ! routine called by step module
36   PUBLIC   rst_write       ! routine called by step module
37   PUBLIC   rst_read        ! routine called by istate module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE rst_opn( kt )
50      !!---------------------------------------------------------------------
51      !!                   ***  ROUTINE rst_opn  ***
52      !!                     
53      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
54      !!              + open the restart when we are one time step before nitrst
55      !!                   - restart header is defined when kt = nitrst-1
56      !!                   - restart data  are written when kt = nitrst
57      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt     ! ocean time-step
60      !!
61      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
62      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
63      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
64      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
65      !!----------------------------------------------------------------------
66      !
67      IF( kt == nit000 ) THEN   ! default definitions
68         lrst_oce = .FALSE.   
69         IF( ln_rst_list ) THEN
70            nrst_lst = 1
71            nitrst = nstocklist( nrst_lst )
72         ELSE
73            nitrst = nitend
74         ENDIF
75      ENDIF
76
77      ! frequency-based restart dumping (nn_stock)
78      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
79         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
80         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
81         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
82      ENDIF
83      ! to get better performances with NetCDF format:
84      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
85      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
86      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
87         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
88            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
89            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
90            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
91            ENDIF
92            ! create the file
93            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
94            clpath = TRIM(cn_ocerst_outdir)
95            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
96            IF(lwp) THEN
97               WRITE(numout,*)
98               IF(.NOT.lwxios) THEN
99                  SELECT CASE ( jprstlib )
100                  CASE DEFAULT         ;   WRITE(numout,*)                            &
101                      '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
102                  END SELECT
103                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
104                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
105                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
106                  ENDIF
107               ENDIF
108            ENDIF
109            !
110            IF(.NOT.lwxios) THEN
111               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
112            ELSE
113               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
114               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
115                  clpname = clname
116               ELSE
117                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
118               ENDIF
119               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname))
120               CALL xios_update_calendar(nitrst)
121               CALL iom_swap(      cxios_context          )
122            ENDIF
123            lrst_oce = .TRUE.
124         ENDIF
125      ENDIF
126      !
127   END SUBROUTINE rst_opn
128
129
130   SUBROUTINE rst_write( kt )
131      !!---------------------------------------------------------------------
132      !!                   ***  ROUTINE rstwrite  ***
133      !!                     
134      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
135      !!
136      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
137      !!              file, save fields which are necessary for restart
138      !!----------------------------------------------------------------------
139      INTEGER, INTENT(in) ::   kt   ! ocean time-step
140      !!----------------------------------------------------------------------
141                     IF(lwxios) CALL iom_swap(      cwxios_context          )
142                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       , ldxios = lwxios)   ! dynamics time step
143
144      IF ( .NOT. ln_diurnal_only ) THEN
145                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub, ldxios = lwxios        )     ! before fields
146                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb, ldxios = lwxios        )
147                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lwxios )
148                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lwxios )
149                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb, ldxios = lwxios      )
150                     !
151                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un, ldxios = lwxios        )     ! now fields
152                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn, ldxios = lwxios        )
153                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lwxios )
154                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lwxios )
155                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn, ldxios = lwxios      )
156                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, ldxios = lwxios      )
157                  ! extra variable needed for the ice sheet coupling
158                  IF ( ln_iscpl ) THEN
159                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask, ldxios = lwxios ) ! need to extrapolate T/S
160                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask, ldxios = lwxios ) ! need to correct barotropic velocity
161                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
162                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
163                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:), ldxios = lwxios )   ! need to compute temperature correction
164                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
165                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
166                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:), ldxios = lwxios ) ! need to compute extrapolation if vvl
167                  END IF
168      ENDIF
169     
170      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
171      IF(lwxios) CALL iom_swap(      cxios_context          )
172      IF( kt == nitrst ) THEN
173         IF(.NOT.lwxios) THEN
174            CALL iom_close( numrow )     ! close the restart file (only at last time step)
175         ELSE
176            CALL iom_context_finalize(      cwxios_context          )
177         ENDIF
178!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
179!!gm  not sure what to do here   ===>>>  ask to Sebastian
180         lrst_oce = .FALSE.
181            IF( ln_rst_list ) THEN
182               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
183               nitrst = nstocklist( nrst_lst )
184            ENDIF
185      ENDIF
186      !
187   END SUBROUTINE rst_write
188
189
190   SUBROUTINE rst_read_open
191      !!----------------------------------------------------------------------
192      !!                   ***  ROUTINE rst_read_open  ***
193      !!
194      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
195      !!
196      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
197      !!                the file has already been opened
198      !!----------------------------------------------------------------------
199      INTEGER        ::   jlibalt = jprstlib
200      LOGICAL        ::   llok
201      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
202      !!----------------------------------------------------------------------
203      !
204      IF( numror <= 0 ) THEN
205         IF(lwp) THEN                                             ! Contol prints
206            WRITE(numout,*)
207            SELECT CASE ( jprstlib )
208            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
209            END SELECT
210            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
211            WRITE(numout,*) '~~~~~~~~'
212         ENDIF
213         lxios_sini = .FALSE.
214         clpath = TRIM(cn_ocerst_indir)
215         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
216         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
217! are we using XIOS to read the data? Part above will have to modified once XIOS
218! can handle checking if variable is in the restart file (there will be no need to open
219! restart)
220         IF(.NOT.lxios_set) lxios_read = lxios_read.AND.lxios_sini
221         IF( lxios_read) THEN
222           crxios_context = 'nemo_rst'
223         if(.NOT.lxios_set) then
224             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
225             CALL iom_init( crxios_context )
226             lxios_set = .TRUE.
227         endif
228         ENDIF
229         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lxios_read) THEN
230            CALL iom_init( crxios_context )
231            IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
232            lxios_set = .TRUE.
233         ENDIF
234      ENDIF
235
236   END SUBROUTINE rst_read_open
237
238
239   SUBROUTINE rst_read
240      !!----------------------------------------------------------------------
241      !!                   ***  ROUTINE rst_read  ***
242      !!
243      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
244      !!
245      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
246      !!----------------------------------------------------------------------
247      REAL(wp) ::   zrdt
248      INTEGER  ::   jk
249      TYPE(xios_duration):: dtime
250      integer::ni,nj,nk
251      !!----------------------------------------------------------------------
252
253      CALL rst_read_open           ! open restart for reading (if not already opened)
254
255      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
256      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
257         CALL iom_get( numror, 'rdt', zrdt, ldxios = lxios_read )
258         IF( zrdt /= rdt )   neuler = 0
259      ENDIF
260
261      ! Diurnal DSST
262      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lxios_read ) 
263      IF ( ln_diurnal_only ) THEN
264         IF(lwp) WRITE( numout, * ) &
265         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
266         rhop = rau0
267         CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,1,jp_tem), ldxios = lxios_read ) 
268         RETURN
269      ENDIF 
270     
271      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
272         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub, ldxios = lxios_read                )   ! before fields
273         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb, ldxios = lxios_read                )
274         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lxios_read )
275         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lxios_read )
276         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb, ldxios = lxios_read              )
277      ELSE
278         neuler = 0
279      ENDIF
280      !
281      CALL iom_get( numror, jpdom_autoglo, 'un'     , un, ldxios = lxios_read )   ! now    fields
282      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn, ldxios = lxios_read )
283      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lxios_read )
284      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lxios_read )
285      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn, ldxios = lxios_read )
286      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
287         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, ldxios = lxios_read )   ! now    potential density
288      ELSE
289         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
290      ENDIF
291      !
292      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
293         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
294         ub   (:,:,:)   = un   (:,:,:)
295         vb   (:,:,:)   = vn   (:,:,:)
296         sshb (:,:)     = sshn (:,:)
297         !
298         IF( .NOT.ln_linssh ) THEN
299            DO jk = 1, jpk
300               e3t_b(:,:,jk) = e3t_n(:,:,jk)
301            END DO
302         ENDIF
303         !
304      ENDIF
305      !
306   END SUBROUTINE rst_read
307
308   !!=====================================================================
309END MODULE restart
Note: See TracBrowser for help on using the repository browser.