New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/2017/dev_r8600_xios_write/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/2017/dev_r8600_xios_write/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 8661

Last change on this file since 8661 was 8661, checked in by andmirek, 6 years ago

#1962 put back tabs, spaces and lines removed when implementiong XIOS write functionality

  • Property svn:keywords set to Id
File size: 14.6 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diurnal_bulk
30   USE iom_def, ONLY : lwxios
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   rst_opn         ! routine called by step module
36   PUBLIC   rst_write       ! routine called by step module
37   PUBLIC   rst_read        ! routine called by istate module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE rst_opn( kt )
50      !!---------------------------------------------------------------------
51      !!                   ***  ROUTINE rst_opn  ***
52      !!                     
53      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
54      !!              + open the restart when we are one time step before nitrst
55      !!                   - restart header is defined when kt = nitrst-1
56      !!                   - restart data  are written when kt = nitrst
57      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt     ! ocean time-step
60      !!
61      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
62      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
63      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
64      CHARACTER(LEN=52)   ::   dlname   ! ocean output restart file name including prefix for AGRIF
65      !!----------------------------------------------------------------------
66      !
67      IF( kt == nit000 ) THEN   ! default definitions
68         lrst_oce = .FALSE.   
69         IF( ln_rst_list ) THEN
70            nrst_lst = 1
71            nitrst = nstocklist( nrst_lst )
72         ELSE
73            nitrst = nitend
74         ENDIF
75      ENDIF
76
77      ! frequency-based restart dumping (nn_stock)
78      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
79         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
80         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
81         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
82      ENDIF
83      ! to get better performances with NetCDF format:
84      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
85      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
86      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
87         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
88            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
89            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
90            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
91            ENDIF
92            ! create the file
93            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
94            clpath = TRIM(cn_ocerst_outdir)
95            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
96            IF(lwp) THEN
97               WRITE(numout,*)
98               IF(.NOT.lwxios) THEN
99                  SELECT CASE ( jprstlib )
100                  CASE DEFAULT         ;   WRITE(numout,*)                            &
101                      '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
102                  END SELECT
103                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
104                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
105                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
106                  ENDIF
107               ENDIF
108            ENDIF
109            !
110            IF(.NOT.lwxios) THEN
111               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
112            ELSE
113               wxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
114               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
115                  dlname = clname
116               ELSE
117                  dlname = TRIM(Agrif_CFixed())//"_"//clname   
118               ENDIF
119               CALL iom_init( wxios_context, TRIM(clpath)//TRIM(dlname))
120               CALL xios_update_calendar(nitrst)
121               CALL iom_swap(      cxios_context          )
122            ENDIF
123            lrst_oce = .TRUE.
124         ENDIF
125      ENDIF
126      !
127   END SUBROUTINE rst_opn
128
129
130   SUBROUTINE rst_write( kt )
131      !!---------------------------------------------------------------------
132      !!                   ***  ROUTINE rstwrite  ***
133      !!                     
134      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
135      !!
136      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
137      !!              file, save fields which are necessary for restart
138      !!----------------------------------------------------------------------
139      INTEGER, INTENT(in) ::   kt   ! ocean time-step
140      !!----------------------------------------------------------------------
141                     IF(lwxios) CALL iom_swap(      wxios_context          )
142                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       , lxios = lwxios)   ! dynamics time step
143
144      IF ( .NOT. ln_diurnal_only ) THEN
145                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub, lxios = lwxios        )     ! before fields
146                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb, lxios = lwxios        )
147                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem), lxios = lwxios )
148                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal), lxios = lwxios )
149                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb, lxios = lwxios      )
150                     !
151                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un, lxios = lwxios        )     ! now fields
152                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn, lxios = lwxios        )
153                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem), lxios = lwxios )
154                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal), lxios = lwxios )
155                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn, lxios = lwxios      )
156                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, lxios = lwxios      )
157                  ! extra variable needed for the ice sheet coupling
158                  IF ( ln_iscpl ) THEN
159                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask, lxios = lwxios ) ! need to extrapolate T/S
160                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask, lxios = lwxios ) ! need to correct barotropic velocity
161                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask, lxios = lwxios ) ! need to correct barotropic velocity
162                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask, lxios = lwxios) ! need to correct barotropic velocity
163                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:), lxios = lwxios )   ! need to compute temperature correction
164                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:), lxios = lwxios )   ! need to compute bt conservation
165                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:), lxios = lwxios )   ! need to compute bt conservation
166                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:), lxios = lwxios ) ! need to compute extrapolation if vvl
167                  END IF
168      ENDIF
169     
170      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, lxios = lwxios ) 
171      IF(lwxios) CALL iom_swap(      cxios_context          )
172      IF( kt == nitrst ) THEN
173         IF(.NOT.lwxios) THEN
174            CALL iom_close( numrow )     ! close the restart file (only at last time step)
175         ELSE
176            CALL iom_context_finalize(      wxios_context          )
177         ENDIF
178!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
179!!gm  not sure what to do here   ===>>>  ask to Sebastian
180         lrst_oce = .FALSE.
181            IF( ln_rst_list ) THEN
182               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
183               nitrst = nstocklist( nrst_lst )
184            ENDIF
185      ENDIF
186      !
187   END SUBROUTINE rst_write
188
189
190   SUBROUTINE rst_read_open
191      !!----------------------------------------------------------------------
192      !!                   ***  ROUTINE rst_read_open  ***
193      !!
194      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
195      !!
196      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
197      !!                the file has already been opened
198      !!----------------------------------------------------------------------
199      INTEGER        ::   jlibalt = jprstlib
200      LOGICAL        ::   llok
201      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
202      !!----------------------------------------------------------------------
203      !
204      IF( numror <= 0 ) THEN
205         IF(lwp) THEN                                             ! Contol prints
206            WRITE(numout,*)
207            SELECT CASE ( jprstlib )
208            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
209            END SELECT
210            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
211            WRITE(numout,*) '~~~~~~~~'
212         ENDIF
213
214         clpath = TRIM(cn_ocerst_indir)
215         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
216         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
217      ENDIF
218   END SUBROUTINE rst_read_open
219
220
221   SUBROUTINE rst_read
222      !!----------------------------------------------------------------------
223      !!                   ***  ROUTINE rst_read  ***
224      !!
225      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
226      !!
227      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
228      !!----------------------------------------------------------------------
229      REAL(wp) ::   zrdt
230      INTEGER  ::   jk
231      !!----------------------------------------------------------------------
232
233      CALL rst_read_open           ! open restart for reading (if not already opened)
234
235      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
236      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
237         CALL iom_get( numror, 'rdt', zrdt )
238         IF( zrdt /= rdt )   neuler = 0
239      ENDIF
240
241      ! Diurnal DSST
242      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst  ) 
243      IF ( ln_diurnal_only ) THEN
244         IF(lwp) WRITE( numout, * ) &
245         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
246         rhop = rau0
247         CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,1,jp_tem) ) 
248         RETURN
249      ENDIF 
250     
251      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
252         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
253         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
254         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
255         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
256         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
257      ELSE
258         neuler = 0
259      ENDIF
260      !
261      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
262      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
263      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
264      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
265      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
266      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
267         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
268      ELSE
269         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
270      ENDIF
271      !
272      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
273         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
274         ub   (:,:,:)   = un   (:,:,:)
275         vb   (:,:,:)   = vn   (:,:,:)
276         sshb (:,:)     = sshn (:,:)
277         !
278         IF( .NOT.ln_linssh ) THEN
279            DO jk = 1, jpk
280               e3t_b(:,:,jk) = e3t_n(:,:,jk)
281            END DO
282         ENDIF
283         !
284      ENDIF
285      !
286   END SUBROUTINE rst_read
287
288   !!=====================================================================
289END MODULE restart
Note: See TracBrowser for help on using the repository browser.