New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

traadv.F90 in branches/2017/dev_r8600_xios_write/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

Context Navigation

source: branches/2017/dev_r8600_xios_write/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 8630

Last change on this file since 8630 was 8630, checked in by andmirek, 7 years ago
#1962 merge with branches/UKMO/dev_r7573_xios_write (doesn't woork)
Property svn:keywords set to `Id`
File size: 17.2 KB

Line
1	MODULE traadv
2	!!==============================================================================
3	!! * MODULE traadv *
4	!! Ocean active tracers: advection trend
5	!!==============================================================================
6	!! History : 2.0 ! 2005-11 (G. Madec) Original code
7	!! 3.3 ! 2010-09 (C. Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport
8	!! 3.6 ! 2011-06 (G. Madec) Addition of Mixed Layer Eddy parameterisation
9	!! 3.7 ! 2014-05 (G. Madec) Add 2nd/4th order cases for CEN and FCT schemes
10	!! - ! 2014-12 (G. Madec) suppression of cross land advection option
11	!! 3.6 ! 2015-06 (E. Clementi) Addition of Stokes drift in case of wave coupling
12	!!----------------------------------------------------------------------
13
14	!!----------------------------------------------------------------------
15	!! tra_adv : compute ocean tracer advection trend
16	!! tra_adv_ctl : control the different options of advection scheme
17	!!----------------------------------------------------------------------
18	USE oce ! ocean dynamics and active tracers
19	USE dom_oce ! ocean space and time domain
20	USE domvvl ! variable vertical scale factors
21	USE traadv_cen ! centered scheme (tra_adv_cen routine)
22	USE traadv_fct ! FCT scheme (tra_adv_fct routine)
23	USE traadv_mus ! MUSCL scheme (tra_adv_mus routine)
24	USE traadv_ubs ! UBS scheme (tra_adv_ubs routine)
25	USE traadv_qck ! QUICKEST scheme (tra_adv_qck routine)
26	USE traadv_mle ! ML eddy induced velocity (tra_adv_mle routine)
27	USE ldftra ! lateral diffusion: eddy diffusivity & EIV coeff.
28	USE ldfslp ! Lateral diffusion: slopes of neutral surfaces
29	USE trd_oce ! trends: ocean variables
30	USE trdtra ! trends manager: tracers
31	!
32	USE in_out_manager ! I/O manager
33	USE iom ! I/O module
34	USE prtctl ! Print control
35	USE lib_mpp ! MPP library
36	USE wrk_nemo ! Memory Allocation
37	USE timing ! Timing
38	USE sbcwave ! wave module
39	USE sbc_oce ! surface boundary condition: ocean
40	USE diaptr ! Poleward heat transport
41
42	IMPLICIT NONE
43	PRIVATE
44
45	PUBLIC tra_adv ! routine called by step module
46	PUBLIC tra_adv_init ! routine called by opa module
47	! !!* Namelist namtra_adv *
48	LOGICAL :: ln_traadv_cen ! centered scheme flag
49	INTEGER :: nn_cen_h, nn_cen_v ! =2/4 : horizontal and vertical choices of the order of CEN scheme
50	LOGICAL :: ln_traadv_fct ! FCT scheme flag
51	INTEGER :: nn_fct_h, nn_fct_v ! =2/4 : horizontal and vertical choices of the order of FCT scheme
52	INTEGER :: nn_fct_zts ! >=1 : 2nd order FCT with vertical sub-timestepping
53	LOGICAL :: ln_traadv_mus ! MUSCL scheme flag
54	LOGICAL :: ln_mus_ups ! use upstream scheme in vivcinity of river mouths
55	LOGICAL :: ln_traadv_ubs ! UBS scheme flag
56	INTEGER :: nn_ubs_v ! =2/4 : vertical choice of the order of UBS scheme
57	LOGICAL :: ln_traadv_qck ! QUICKEST scheme flag
58
59	INTEGER :: nadv ! choice of the type of advection scheme
60	!
61	! ! associated indices:
62	INTEGER, PARAMETER :: np_NO_adv = 0 ! no T-S advection
63	INTEGER, PARAMETER :: np_CEN = 1 ! 2nd/4th order centered scheme
64	INTEGER, PARAMETER :: np_FCT = 2 ! 2nd/4th order Flux Corrected Transport scheme
65	INTEGER, PARAMETER :: np_FCT_zts = 3 ! 2nd order FCT scheme with vertical sub-timestepping
66	INTEGER, PARAMETER :: np_MUS = 4 ! MUSCL scheme
67	INTEGER, PARAMETER :: np_UBS = 5 ! 3rd order Upstream Biased Scheme
68	INTEGER, PARAMETER :: np_QCK = 6 ! QUICK scheme
69
70	!! * Substitutions
71	# include "vectopt_loop_substitute.h90"
72	!!----------------------------------------------------------------------
73	!! NEMO/OPA 3.7 , NEMO Consortium (2014)
74	!! $Id$
75	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
76	!!----------------------------------------------------------------------
77	CONTAINS
78
79	SUBROUTINE tra_adv( kt )
80	!!----------------------------------------------------------------------
81	!! * ROUTINE tra_adv *
82	!!
83	!! ** Purpose : compute the ocean tracer advection trend.
84	!!
85	!! ** Method : - Update (ua,va) with the advection term following nadv
86	!!----------------------------------------------------------------------
87	INTEGER, INTENT( in ) :: kt ! ocean time-step index
88	!
89	INTEGER :: jk ! dummy loop index
90	REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
91	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdt, ztrds ! 3D workspace
92	!!----------------------------------------------------------------------
93	!
94	IF( nn_timing == 1 ) CALL timing_start('tra_adv')
95	!
96	CALL wrk_alloc( jpi,jpj,jpk, zun, zvn, zwn )
97	!
98	! ! set time step
99	zun(:,:,:) = 0.0
100	zvn(:,:,:) = 0.0
101	zwn(:,:,:) = 0.0
102	!
103	IF( neuler == 0 .AND. kt == nit000 ) THEN ! at nit000
104	r2dt = rdt ! = rdt (restarting with Euler time stepping)
105	ELSEIF( kt <= nit000 + 1) THEN ! at nit000 or nit000+1
106	r2dt = 2._wp * rdt ! = 2 rdt (leapfrog)
107	ENDIF
108	!
109	! !== effective transport ==!
110	IF( ln_wave .AND. ln_sdw ) THEN
111	DO jk = 1, jpkm1 ! eulerian transport + Stokes Drift
112	zun(:,:,jk) = e2u (:,:) * e3u_n(:,:,jk) * ( un(:,:,jk) + usd(:,:,jk) )
113	zvn(:,:,jk) = e1v (:,:) * e3v_n(:,:,jk) * ( vn(:,:,jk) + vsd(:,:,jk) )
114	zwn(:,:,jk) = e1e2t(:,:) * ( wn(:,:,jk) + wsd(:,:,jk) )
115	END DO
116	ELSE
117	DO jk = 1, jpkm1
118	zun(:,:,jk) = e2u (:,:) * e3u_n(:,:,jk) * un(:,:,jk) ! eulerian transport only
119	zvn(:,:,jk) = e1v (:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
120	zwn(:,:,jk) = e1e2t(:,:) * wn(:,:,jk)
121	END DO
122	ENDIF
123	!
124	IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN ! add z-tilde and/or vvl corrections
125	zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
126	zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
127	ENDIF
128	!
129	zun(:,:,jpk) = 0._wp ! no transport trough the bottom
130	zvn(:,:,jpk) = 0._wp
131	zwn(:,:,jpk) = 0._wp
132	!
133	IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad ) &
134	& CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the eiv transport (if necessary)
135	!
136	IF( ln_mle ) CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the mle transport (if necessary)
137	!
138	CALL iom_put( "uocetr_eff", zun ) ! output effective transport
139	CALL iom_put( "vocetr_eff", zvn )
140	CALL iom_put( "wocetr_eff", zwn )
141	!
142	!!gm ???
143	IF( ln_diaptr ) CALL dia_ptr( zvn ) ! diagnose the effective MSF
144	!!gm ???
145	!
146	IF( l_trdtra ) THEN !* Save ta and sa trends
147	CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds )
148	ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
149	ztrds(:,:,:) = tsa(:,:,:,jp_sal)
150	ENDIF
151	!
152	SELECT CASE ( nadv ) !== compute advection trend and add it to general trend ==!
153	!
154	CASE ( np_CEN ) ! Centered scheme : 2nd / 4th order
155	CALL tra_adv_cen ( kt, nit000, 'TRA', zun, zvn, zwn , tsn, tsa, jpts, nn_cen_h, nn_cen_v )
156	CASE ( np_FCT ) ! FCT scheme : 2nd / 4th order
157	CALL tra_adv_fct ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts, nn_fct_h, nn_fct_v )
158	CASE ( np_FCT_zts ) ! 2nd order FCT with vertical time-splitting
159	CALL tra_adv_fct_zts( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_fct_zts )
160	CASE ( np_MUS ) ! MUSCL
161	CALL tra_adv_mus ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsa, jpts , ln_mus_ups )
162	CASE ( np_UBS ) ! UBS
163	CALL tra_adv_ubs ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_ubs_v )
164	CASE ( np_QCK ) ! QUICKEST
165	CALL tra_adv_qck ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )
166	!
167	END SELECT
168	!
169	IF( l_trdtra ) THEN ! save the advective trends for further diagnostics
170	DO jk = 1, jpkm1
171	ztrdt(:,:,jk) = tsa(:,:,jk,jp_tem) - ztrdt(:,:,jk)
172	ztrds(:,:,jk) = tsa(:,:,jk,jp_sal) - ztrds(:,:,jk)
173	END DO
174	CALL trd_tra( kt, 'TRA', jp_tem, jptra_totad, ztrdt )
175	CALL trd_tra( kt, 'TRA', jp_sal, jptra_totad, ztrds )
176	CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds )
177	ENDIF
178	! ! print mean trends (used for debugging)
179	IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv - Ta: ', mask1=tmask, &
180	& tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' )
181	!
182	IF( nn_timing == 1 ) CALL timing_stop( 'tra_adv' )
183	!
184	CALL wrk_dealloc( jpi,jpj,jpk, zun, zvn, zwn )
185	!
186	END SUBROUTINE tra_adv
187
188
189	SUBROUTINE tra_adv_init
190	!!---------------------------------------------------------------------
191	!! * ROUTINE tra_adv_init *
192	!!
193	!! ** Purpose : Control the consistency between namelist options for
194	!! tracer advection schemes and set nadv
195	!!----------------------------------------------------------------------
196	INTEGER :: ioptio, ios ! Local integers
197	!
198	NAMELIST/namtra_adv/ ln_traadv_cen, nn_cen_h, nn_cen_v, & ! CEN
199	& ln_traadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts, & ! FCT
200	& ln_traadv_mus, ln_mus_ups, & ! MUSCL
201	& ln_traadv_ubs, nn_ubs_v, & ! UBS
202	& ln_traadv_qck ! QCK
203	!!----------------------------------------------------------------------
204	!
205	! !== Namelist ==!
206	REWIND( numnam_ref ) ! Namelist namtra_adv in reference namelist : Tracer advection scheme
207	READ ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
208	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
209	!
210	REWIND( numnam_cfg ) ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
211	READ ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
212	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
213	IF(lwm) WRITE( numond, namtra_adv )
214	!
215	IF(lwp) THEN ! Namelist print
216	WRITE(numout,*)
217	WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
218	WRITE(numout,*) '~~~~~~~~~~~'
219	WRITE(numout,*) ' Namelist namtra_adv : chose a advection scheme for tracers'
220	WRITE(numout,*) ' centered scheme ln_traadv_cen = ', ln_traadv_cen
221	WRITE(numout,*) ' horizontal 2nd/4th order nn_cen_h = ', nn_fct_h
222	WRITE(numout,*) ' vertical 2nd/4th order nn_cen_v = ', nn_fct_v
223	WRITE(numout,*) ' Flux Corrected Transport scheme ln_traadv_fct = ', ln_traadv_fct
224	WRITE(numout,*) ' horizontal 2nd/4th order nn_fct_h = ', nn_fct_h
225	WRITE(numout,*) ' vertical 2nd/4th order nn_fct_v = ', nn_fct_v
226	WRITE(numout,*) ' 2nd order + vertical sub-timestepping nn_fct_zts = ', nn_fct_zts
227	WRITE(numout,*) ' MUSCL scheme ln_traadv_mus = ', ln_traadv_mus
228	WRITE(numout,*) ' + upstream scheme near river mouths ln_mus_ups = ', ln_mus_ups
229	WRITE(numout,*) ' UBS scheme ln_traadv_ubs = ', ln_traadv_ubs
230	WRITE(numout,*) ' vertical 2nd/4th order nn_ubs_v = ', nn_ubs_v
231	WRITE(numout,*) ' QUICKEST scheme ln_traadv_qck = ', ln_traadv_qck
232	ENDIF
233	!
234	ioptio = 0 !== Parameter control ==!
235	IF( ln_traadv_cen ) ioptio = ioptio + 1
236	IF( ln_traadv_fct ) ioptio = ioptio + 1
237	IF( ln_traadv_mus ) ioptio = ioptio + 1
238	IF( ln_traadv_ubs ) ioptio = ioptio + 1
239	IF( ln_traadv_qck ) ioptio = ioptio + 1
240	!
241	IF( ioptio == 0 ) THEN
242	nadv = np_NO_adv
243	CALL ctl_warn( 'tra_adv_init: You are running without tracer advection.' )
244	ENDIF
245	IF( ioptio /= 1 ) CALL ctl_stop( 'tra_adv_init: Choose ONE advection scheme in namelist namtra_adv' )
246	!
247	IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 ) & ! Centered
248	.AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 ) ) THEN
249	CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
250	ENDIF
251	IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 ) & ! FCT
252	.AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 ) ) THEN
253	CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
254	ENDIF
255	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) THEN
256	IF( nn_fct_h == 4 ) THEN
257	nn_fct_h = 2
258	CALL ctl_stop( 'tra_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
259	ENDIF
260	IF( .NOT.ln_linssh ) THEN
261	CALL ctl_stop( 'tra_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
262	ENDIF
263	IF( nn_fct_zts == 1 ) CALL ctl_warn( 'tra_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
264	ENDIF
265	IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 ) ) THEN ! UBS
266	CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
267	ENDIF
268	IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
269	CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
270	ENDIF
271	IF( ln_isfcav ) THEN ! ice-shelf cavities
272	IF( ln_traadv_cen .AND. nn_cen_v == 4 .OR. & ! NO 4th order with ISF
273	& ln_traadv_fct .AND. nn_fct_v == 4 ) CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
274	ENDIF
275	!
276	! !== used advection scheme ==!
277	! ! set nadv
278	IF( ln_traadv_cen ) nadv = np_CEN
279	IF( ln_traadv_fct ) nadv = np_FCT
280	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) nadv = np_FCT_zts
281	IF( ln_traadv_mus ) nadv = np_MUS
282	IF( ln_traadv_ubs ) nadv = np_UBS
283	IF( ln_traadv_qck ) nadv = np_QCK
284	!
285	IF(lwp) THEN ! Print the choice
286	WRITE(numout,*)
287	SELECT CASE ( nadv )
288	CASE( np_NO_adv ) ; WRITE(numout,*) ' ===>> NO T-S advection'
289	CASE( np_CEN ) ; WRITE(numout,*) ' ===>> CEN scheme is used. Horizontal order: ', nn_cen_h, &
290	& ' Vertical order: ', nn_cen_v
291	CASE( np_FCT ) ; WRITE(numout,*) ' ===>> FCT scheme is used. Horizontal order: ', nn_fct_h, &
292	& ' Vertical order: ', nn_fct_v
293	CASE( np_FCT_zts ) ; WRITE(numout,*) ' ===>> use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
294	CASE( np_MUS ) ; WRITE(numout,*) ' ===>> MUSCL scheme is used'
295	CASE( np_UBS ) ; WRITE(numout,*) ' ===>> UBS scheme is used'
296	CASE( np_QCK ) ; WRITE(numout,*) ' ===>> QUICKEST scheme is used'
297	END SELECT
298	ENDIF
299	!
300	CALL tra_adv_mle_init !== initialisation of the Mixed Layer Eddy parametrisation (MLE) ==!
301	lr_traadv_cen2 = ln_traadv_cen2
302	!
303	END SUBROUTINE tra_adv_init
304
305	!!======================================================================
306	END MODULE traadv

Note: See TracBrowser for help on using the repository browser.

Download in other formats: