New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in branches/2017/dev_r8600_xios_write/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2017/dev_r8600_xios_write/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 8661

Last change on this file since 8661 was 8661, checked in by andmirek, 6 years ago

#1962 put back tabs, spaces and lines removed when implementiong XIOS write functionality
  • Property svn:keywords set to Id
File size: 17.2 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_ctl   : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! variable vertical scale factors
21   USE traadv_cen     ! centered scheme           (tra_adv_cen  routine)
22   USE traadv_fct     ! FCT      scheme           (tra_adv_fct  routine)
23   USE traadv_mus     ! MUSCL    scheme           (tra_adv_mus  routine)
24   USE traadv_ubs     ! UBS      scheme           (tra_adv_ubs  routine)
25   USE traadv_qck     ! QUICKEST scheme           (tra_adv_qck  routine)
26   USE traadv_mle     ! ML eddy induced velocity  (tra_adv_mle  routine)
27   USE ldftra         ! lateral diffusion: eddy diffusivity & EIV coeff.
28   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
29   USE trd_oce         ! trends: ocean variables
30   USE trdtra          ! trends manager: tracers
31   !
32   USE in_out_manager ! I/O manager
33   USE iom            ! I/O module
34   USE prtctl         ! Print control
35   USE lib_mpp        ! MPP library
36   USE wrk_nemo       ! Memory Allocation
37   USE timing         ! Timing
38   USE sbcwave        ! wave module
39   USE sbc_oce        ! surface boundary condition: ocean
40   USE diaptr         ! Poleward heat transport
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   tra_adv        ! routine called by step module
46   PUBLIC   tra_adv_init   ! routine called by opa module
47
48   !                            !!* Namelist namtra_adv *
49   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
50   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
51   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
52   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
53   INTEGER ::      nn_fct_zts           ! >=1 : 2nd order FCT with vertical sub-timestepping
54   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
55   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
56   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
57   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
58   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
59
60   INTEGER ::              nadv             ! choice of the type of advection scheme
61   !
62   !                                        ! associated indices:
63   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
64   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
65   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
66   INTEGER, PARAMETER ::   np_FCT_zts = 3   ! 2nd order FCT scheme with vertical sub-timestepping
67   INTEGER, PARAMETER ::   np_MUS     = 4   ! MUSCL scheme
68   INTEGER, PARAMETER ::   np_UBS     = 5   ! 3rd order Upstream Biased Scheme
69   INTEGER, PARAMETER ::   np_QCK     = 6   ! QUICK scheme
70   
71   !! * Substitutions
72#  include "vectopt_loop_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
75   !! $Id$
76   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE tra_adv( kt )
81      !!----------------------------------------------------------------------
82      !!                  ***  ROUTINE tra_adv  ***
83      !!
84      !! ** Purpose :   compute the ocean tracer advection trend.
85      !!
86      !! ** Method  : - Update (ua,va) with the advection term following nadv
87      !!----------------------------------------------------------------------
88      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
89      !
90      INTEGER ::   jk   ! dummy loop index
91      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
92      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdt, ztrds   ! 3D workspace
93      !!----------------------------------------------------------------------
94      !
95      IF( nn_timing == 1 )  CALL timing_start('tra_adv')
96      !
97      CALL wrk_alloc( jpi,jpj,jpk,   zun, zvn, zwn )
98      !
99      !                                          ! set time step
100      zun(:,:,:) = 0.0
101      zvn(:,:,:) = 0.0
102      zwn(:,:,:) = 0.0
103      !   
104      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
105         r2dt = rdt                                 ! = rdt (restarting with Euler time stepping)
106      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
107         r2dt = 2._wp * rdt                         ! = 2 rdt (leapfrog)
108      ENDIF
109      !
110      !                                         !==  effective transport  ==!
111      IF( ln_wave .AND. ln_sdw )  THEN
112         DO jk = 1, jpkm1                                                       ! eulerian transport + Stokes Drift
113            zun(:,:,jk) = e2u  (:,:) * e3u_n(:,:,jk) * ( un(:,:,jk) + usd(:,:,jk) )
114            zvn(:,:,jk) = e1v  (:,:) * e3v_n(:,:,jk) * ( vn(:,:,jk) + vsd(:,:,jk) )
115            zwn(:,:,jk) = e1e2t(:,:)                 * ( wn(:,:,jk) + wsd(:,:,jk) )
116         END DO
117      ELSE
118         DO jk = 1, jpkm1
119            zun(:,:,jk) = e2u  (:,:) * e3u_n(:,:,jk) * un(:,:,jk)               ! eulerian transport only
120            zvn(:,:,jk) = e1v  (:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
121            zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
122         END DO
123      ENDIF
124      !
125      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
126         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
127         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
128      ENDIF
129      !
130      zun(:,:,jpk) = 0._wp                                                      ! no transport trough the bottom
131      zvn(:,:,jpk) = 0._wp
132      zwn(:,:,jpk) = 0._wp
133      !
134      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
135         &              CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' )   ! add the eiv transport (if necessary)
136      !
137      IF( ln_mle    )   CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' )   ! add the mle transport (if necessary)
138      !
139      CALL iom_put( "uocetr_eff", zun )                                        ! output effective transport     
140      CALL iom_put( "vocetr_eff", zvn )
141      CALL iom_put( "wocetr_eff", zwn )
142      !
143!!gm ???
144      IF( ln_diaptr )   CALL dia_ptr( zvn )                                    ! diagnose the effective MSF
145!!gm ???
146      !
147      IF( l_trdtra )   THEN                    !* Save ta and sa trends
148         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds )
149         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
150         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
151      ENDIF
152      !
153      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
154      !
155      CASE ( np_CEN )                                    ! Centered scheme : 2nd / 4th order
156         CALL tra_adv_cen    ( kt, nit000, 'TRA',         zun, zvn, zwn     , tsn, tsa, jpts, nn_cen_h, nn_cen_v )
157      CASE ( np_FCT )                                    ! FCT scheme      : 2nd / 4th order
158         CALL tra_adv_fct    ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts, nn_fct_h, nn_fct_v )
159      CASE ( np_FCT_zts )                                ! 2nd order FCT with vertical time-splitting
160         CALL tra_adv_fct_zts( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts        , nn_fct_zts )
161      CASE ( np_MUS )                                    ! MUSCL
162         CALL tra_adv_mus    ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb,      tsa, jpts        , ln_mus_ups ) 
163      CASE ( np_UBS )                                    ! UBS
164         CALL tra_adv_ubs    ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts        , nn_ubs_v   )
165      CASE ( np_QCK )                                    ! QUICKEST
166         CALL tra_adv_qck    ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts                     )
167      !
168      END SELECT
169      !
170      IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
171         DO jk = 1, jpkm1
172            ztrdt(:,:,jk) = tsa(:,:,jk,jp_tem) - ztrdt(:,:,jk)
173            ztrds(:,:,jk) = tsa(:,:,jk,jp_sal) - ztrds(:,:,jk)
174         END DO
175         CALL trd_tra( kt, 'TRA', jp_tem, jptra_totad, ztrdt )
176         CALL trd_tra( kt, 'TRA', jp_sal, jptra_totad, ztrds )
177         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds )
178      ENDIF
179      !                                              ! print mean trends (used for debugging)
180      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
181         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
182      !
183      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv' )
184      !
185      CALL wrk_dealloc( jpi,jpj,jpk,   zun, zvn, zwn )
186      !                                         
187   END SUBROUTINE tra_adv
188
189
190   SUBROUTINE tra_adv_init
191      !!---------------------------------------------------------------------
192      !!                  ***  ROUTINE tra_adv_init  ***
193      !!               
194      !! ** Purpose :   Control the consistency between namelist options for
195      !!              tracer advection schemes and set nadv
196      !!----------------------------------------------------------------------
197      INTEGER ::   ioptio, ios   ! Local integers
198      !
199      NAMELIST/namtra_adv/ ln_traadv_cen, nn_cen_h, nn_cen_v,               &   ! CEN
200         &                 ln_traadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts,   &   ! FCT
201         &                 ln_traadv_mus,                     ln_mus_ups,   &   ! MUSCL
202         &                 ln_traadv_ubs,           nn_ubs_v,               &   ! UBS
203         &                 ln_traadv_qck                                        ! QCK
204      !!----------------------------------------------------------------------
205      !
206      !                                !==  Namelist  ==!
207      REWIND( numnam_ref )                   ! Namelist namtra_adv in reference namelist : Tracer advection scheme
208      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
209901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
210      !
211      REWIND( numnam_cfg )                   ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
212      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
213902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
214      IF(lwm) WRITE( numond, namtra_adv )
215      !
216      IF(lwp) THEN                           ! Namelist print
217         WRITE(numout,*)
218         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
219         WRITE(numout,*) '~~~~~~~~~~~'
220         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
221         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
222         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
223         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
224         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
225         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
226         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
227         WRITE(numout,*) '            2nd order + vertical sub-timestepping  nn_fct_zts = ', nn_fct_zts
228         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
229         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
230         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
231         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
232         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
233      ENDIF
234      !
235      ioptio = 0                       !==  Parameter control  ==!
236      IF( ln_traadv_cen )   ioptio = ioptio + 1
237      IF( ln_traadv_fct )   ioptio = ioptio + 1
238      IF( ln_traadv_mus )   ioptio = ioptio + 1
239      IF( ln_traadv_ubs )   ioptio = ioptio + 1
240      IF( ln_traadv_qck )   ioptio = ioptio + 1
241      !
242      IF( ioptio == 0 ) THEN
243         nadv = np_NO_adv
244         CALL ctl_warn( 'tra_adv_init: You are running without tracer advection.' )
245      ENDIF
246      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection scheme in namelist namtra_adv' )
247      !
248      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
249                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
250        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
251      ENDIF
252      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
253                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
254        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
255      ENDIF
256      IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) THEN
257         IF( nn_fct_h == 4 ) THEN
258            nn_fct_h = 2
259            CALL ctl_stop( 'tra_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
260         ENDIF
261         IF( .NOT.ln_linssh ) THEN
262            CALL ctl_stop( 'tra_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
263         ENDIF
264         IF( nn_fct_zts == 1 )   CALL ctl_warn( 'tra_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
265      ENDIF
266      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
267        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
268      ENDIF
269      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
270         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
271      ENDIF
272      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
273         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
274            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
275      ENDIF
276      !
277      !                                !==  used advection scheme  ==! 
278      !                                      ! set nadv
279      IF( ln_traadv_cen                      )   nadv = np_CEN
280      IF( ln_traadv_fct                      )   nadv = np_FCT
281      IF( ln_traadv_fct .AND. nn_fct_zts > 0 )   nadv = np_FCT_zts
282      IF( ln_traadv_mus                      )   nadv = np_MUS
283      IF( ln_traadv_ubs                      )   nadv = np_UBS
284      IF( ln_traadv_qck                      )   nadv = np_QCK
285      !
286      IF(lwp) THEN                           ! Print the choice
287         WRITE(numout,*)
288         SELECT CASE ( nadv )
289         CASE( np_NO_adv  )   ;   WRITE(numout,*) '      ===>>   NO T-S advection'
290         CASE( np_CEN     )   ;   WRITE(numout,*) '      ===>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
291            &                                                                     ' Vertical   order: ', nn_cen_v
292         CASE( np_FCT     )   ;   WRITE(numout,*) '      ===>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
293            &                                                                      ' Vertical   order: ', nn_fct_v
294         CASE( np_FCT_zts )   ;   WRITE(numout,*) '      ===>>   use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
295         CASE( np_MUS     )   ;   WRITE(numout,*) '      ===>>   MUSCL    scheme is used'
296         CASE( np_UBS     )   ;   WRITE(numout,*) '      ===>>   UBS      scheme is used'
297         CASE( np_QCK     )   ;   WRITE(numout,*) '      ===>>   QUICKEST scheme is used'
298         END SELECT
299      ENDIF
300      !
301      CALL tra_adv_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
302      !
303   END SUBROUTINE tra_adv_init
304
305  !!======================================================================
306END MODULE traadv
Note: See TracBrowser for help on using the repository browser.